src/quote_fmt_lex.l

   1 %{
   2 #include "quote_fmt_lex.h"
   3 #include "quote_fmt_parse.h"
   4 %}
   5
   6 %option prefix="quote_fmt"
   7 %option outfile="lex.yy.c"
   8
   9 %s S_NORMAL S_DATE
  10
  11 %{
  12 /*
  13  * see notes below.
  14  */
  15 static int firsttime = 1;
  16 %}
  17
  18 %%
  19
  20 %{
  21 /*
  22  * NOTES:
  23  * this lex script used to use characters also in use
  24  * by strftime() (which we want to use for custom
  25  * time formats in replies and templates). to circumvent
  26  * this we have to play a little bit with states.
  27  *
  28  * these are the characters we also want to use in the
  29  * %D time customizer:
  30  *
  31  * %a %A %b %B %c %C %d %H %I %j %m %M %p %S %w %x %y %Y %Z
  32  *
  33  * you can use these characters too, but don't forget to
  34  * prepend them with the <S_NORMAL> state.
  35  *
  36  * also there is also work around for resetting the state
  37  * (firsttime variable). this assumes that yylex() will
  38  * always return to S_NORMAL after quote fmt parsing is
  39  * done.
  40  */
  41 %}
  42
  43 %{
  44         if (firsttime) {
  45                 BEGIN S_NORMAL;
  46                 firsttime = 0;
  47         }
  48 %}
  49
  50 <S_NORMAL>"%c" /* cc */ return SHOW_CC;
  51 <S_NORMAL>"%d" /* date */ return SHOW_DATE;
  52 <S_NORMAL>"%D" /* date */ { BEGIN S_DATE; return SHOW_DATE_EXPR; }
  53 <S_NORMAL>"%f" /* from */ return SHOW_FROM;
  54 <S_NORMAL>"%F" /* first name */ return SHOW_FIRST_NAME;
  55 <S_NORMAL>"%i" /* message-id */ return SHOW_MESSAGEID;
  56 <S_NORMAL>"%I" /* initial of sender */ return SHOW_SENDER_INITIAL;
  57 <S_NORMAL>"%m" /* message with no signature */ return SHOW_MESSAGE_NO_SIGNATURE;
  58 <S_NORMAL>"%M" /* message */ return SHOW_MESSAGE;
  59 <S_NORMAL>"%n" /* newsgroups */ return SHOW_NEWSGROUPS;
  60 <S_NORMAL>"%N" /* full name */ return SHOW_FULLNAME;
  61 <S_NORMAL>"%L" /* last name */ return SHOW_LAST_NAME;
  62 <S_NORMAL>"%r" /* references */ return SHOW_REFERENCES;
  63 <S_NORMAL>"%s" /* subject */ return SHOW_SUBJECT;
  64 <S_NORMAL>"%t" /* to */ return SHOW_TO;
  65 <S_NORMAL>"%Q" /* quoted message */ return SHOW_QUOTED_MESSAGE;
  66 <S_NORMAL>"%q" /* quoted message with no signature */ return SHOW_QUOTED_MESSAGE_NO_SIGNATURE;
  67 "\\\%" /* % */ return SHOW_PERCENT;
  68 "\\\\" /* \ */ return SHOW_BACKSLASH;
  69 "\\t"|"\t" /* tab */ return SHOW_TAB;
  70 "\\n"|"\n" /* return */ return SHOW_EOL;
  71 "\\?" /* ? */ return SHOW_QUESTION_MARK;
  72 "\\|" return SHOW_PIPE;
  73 "\\{" return SHOW_OPARENT;
  74 "\\}" return SHOW_CPARENT;
  75 "?d" /* query date */ return QUERY_DATE;
  76 "?f" /* query from */ return QUERY_FROM;
  77 "?N"|"?F"|"?I" /* query from name */ return QUERY_FULLNAME;
  78 "?s" /* query subject */ return QUERY_SUBJECT;
  79 "?t" /* query to */ return QUERY_TO;
  80 "?c" /* query cc */ return QUERY_CC;
  81 "?n" /* query newsgroups */ return QUERY_NEWSGROUPS;
  82 "?i" /* query message-id */ return QUERY_MESSAGEID;
  83 "?r" /* query references */ return QUERY_REFERENCES;
  84 "|f" /* insert file */ return INSERT_FILE;
  85 "|p" /* insert program output */ return INSERT_PROGRAMOUTPUT;
  86 <S_DATE>"{" return OPARENT;
  87 <S_DATE>"}" { BEGIN S_NORMAL; return CPARENT; }
  88 <S_NORMAL>"{" return OPARENT;
  89 <S_NORMAL>"}" return CPARENT;
  90 . { yylval.chr = yytext[0]; return CHARACTER; }
  91
  92 %%