2007-02-20 [wwp] 2.7.2cvs55
[claws.git] / src / matcher_parser_lex.l
1 %option nounput never-interactive
2
3 %{
4 /*
5  * Sylpheed -- a GTK+ based, lightweight, and fast e-mail client
6  * Copyright (c) 2001-2007 by Hiroyuki Yamamoto & The Claws Mail Team
7  *
8  * This program is free software; you can redistribute it and/or modify
9  * it under the terms of the GNU General Public License as published by
10  * the Free Software Foundation; either version 2 of the License, or
11  * (at your option) any later version.
12  *
13  * This program is distributed in the hope that it will be useful,
14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16  * GNU General Public License for more details.
17  *
18  * You should have received a copy of the GNU General Public License
19  * along with this program; if not, write to the Free Software
20  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
21  */
22
23 #include <string.h>
24 #include <glib.h>
25
26 #include "codeconv.h"
27 #include "matcher.h"
28 #include "matcher_parser_lex.h"
29 #ifndef YYSTYPE
30 #include "matcher_parser_parse.h"
31 #endif
32 #define MAX_STR_CONST 512
33
34 static char string_buf[MAX_STR_CONST];
35 static char *string_buf_ptr;
36
37 static void add_char(char ch)
38 {
39         if (string_buf_ptr - string_buf < sizeof(string_buf))
40                 *string_buf_ptr++ = ch;
41 }
42
43
44 /* this function will reinitializes the parser */
45
46 void matcher_parser_init(void)
47 {
48         BEGIN(0);
49 }
50 %}
51
52 %option prefix="matcher_parser"
53 %option outfile="lex.yy.c"
54 %option yylineno
55
56 %x string
57 %x section
58
59 %%
60                         
61 "in"    return MATCHER_IN; 
62
63                         /*
64                          * a keyword consists of alpha and underscore 
65                          * characters, possibly preceded by a tilde (~)
66                          */
67
68 (~|[a-z])[a-z_]*        {
69                                 gint id;
70
71                                 if (-1 == (id = get_matchparser_tab_id(yytext))) { 
72                                         REJECT;
73                                 } else                                  
74                                         return id;
75                         }
76 [ \t]+
77 "\n"            return MATCHER_EOL;
78 "&"             return MATCHER_AND;
79 "|"             return MATCHER_OR;
80 \"              {
81                 BEGIN(string);
82                 string_buf_ptr = string_buf;
83                 }
84 <string>\"      {
85                 /* get out of the state: string ends. */
86                 BEGIN(0);
87                 *string_buf_ptr = '\0';
88                 if (!g_utf8_validate(string_buf, -1, NULL)) {
89                         gchar *tmp = conv_codeset_strdup(string_buf, conv_get_locale_charset_str(), CS_INTERNAL);
90                         if (tmp) {
91                                 strcpy(string_buf, tmp);
92                                 g_free(tmp);
93                         }
94                 }
95                 yylval.str = string_buf;
96                 return MATCHER_STRING;
97                 }
98 <string>\\.     {
99                 /* take care of quoted characters */
100                 add_char(yytext[1]);
101                 }
102 <string>.       {
103                 add_char(yytext[0]);
104                 }
105 \[[^\[\]]*\]    {
106                 /* for section name in configuration file */
107                 BEGIN(0);
108                 yylval.str = yytext + 1;
109                 yytext[strlen(yytext) - 1] = '\0';
110                 return MATCHER_SECTION;
111                 }
112 [-+]?[0-9]+     {
113                 yylval.str = yytext;
114                 return MATCHER_INTEGER;
115                 }
116 rulename        {
117                 return MATCHER_RULENAME;
118                 }
119 disabled        {
120                 return MATCHER_DISABLED;
121                 }
122 account {
123                 return MATCHER_ACCOUNT;
124                 }
125 enabled {
126                 return MATCHER_ENABLED;
127                 }
128
129 %%