configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.50)
   3 AC_INIT(src/main.c)
   4 AC_CONFIG_AUX_DIR(config)
   5
   6 PACKAGE=sylpheed
   7
   8 dnl version number
   9 MAJOR_VERSION=0
  10 MINOR_VERSION=8
  11 MICRO_VERSION=5
  12 INTERFACE_AGE=0
  13 BINARY_AGE=0
  14 EXTRA_VERSION=claws22
  15 VERSION=$MAJOR_VERSION.$MINOR_VERSION.$MICRO_VERSION$EXTRA_VERSION
  16
  17 dnl set $target
  18 AC_CANONICAL_SYSTEM
  19
  20 dnl
  21 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  22 dnl AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
  23 dnl AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
  24 AC_SUBST(PACKAGE)
  25 AC_SUBST(VERSION)
  26
  27 dnl GNOME installed?
  28 AC_PATH_PROG(GNOME_CONFIG, gnome-config, no)
  29 if test "$GNOME_CONFIG" != no; then
  30         gnomedir="`gnome-config --prefix`"
  31         AC_SUBST(gnomedir)
  32 fi
  33 AM_CONDITIONAL(SYLPHEED_GNOME, test -d "$gnomedir")
  34
  35 dnl Claws version
  36 AC_DEFINE(CLAWS, 1, Compiling Claws branch of sylpheed)
  37
  38 dnl libtool versioning
  39 LT_RELEASE=$MAJOR_VERSION.$MINOR_VERSION
  40 LT_CURRENT=`expr $MICRO_VERSION - $INTERFACE_AGE`
  41 LT_REVISION=$INTERFACE_AGE
  42 LT_AGE=`expr $BINARY_AGE - $INTERFACE_AGE`
  43 AC_SUBST(LT_RELEASE)
  44 AC_SUBST(LT_CURRENT)
  45 AC_SUBST(LT_REVISION)
  46 AC_SUBST(LT_AGE)
  47
  48 dnl Specify a header configuration file
  49 AM_CONFIG_HEADER(config.h)
  50
  51 AM_MAINTAINER_MODE
  52
  53 dnl Checks for programs.
  54 AC_ARG_PROGRAM
  55 AC_PROG_CC
  56 AC_ISC_POSIX
  57 AM_PROG_CC_STDC
  58 AC_PROG_INSTALL
  59 AC_PROG_LN_S
  60 AC_PROG_MAKE_SET
  61 AC_PROG_CPP
  62 dnl AC_PROG_RANLIB
  63 AM_PROG_LEX
  64 AC_PROG_YACC
  65 AC_PROG_LIBTOOL
  66
  67 SYLPHEED_ACLOCAL_INCLUDE(ac)
  68
  69 case "$target" in
  70 *-darwin*)
  71         CFLAGS="$CFLAGS -traditional-cpp -fno-common"
  72         ;;
  73 esac
  74
  75 dnl for gettext
  76 ALL_LINGUAS="bg cs de el en_GB es fr hr it ja ko nl pl pt_BR ru sr sv"
  77 AM_GNU_GETTEXT
  78 dnl AC_CHECK_FUNC(gettext, AC_CHECK_LIB(intl, gettext))
  79 localedir='${prefix}/${DATADIRNAME}/locale'
  80 AC_SUBST(localedir)
  81
  82 manualdir='${prefix}/${DATADIRNAME}/${PACKAGE}/manual'
  83 AC_SUBST(manualdir)
  84 faqdir='${prefix}/${DATADIRNAME}/${PACKAGE}/faq'
  85 AC_SUBST(faqdir)
  86
  87 dnl Set PACKAGE_DATA_DIR in config.h.
  88 if test "x${datadir}" = 'x${prefix}/share'; then
  89   if test "x${prefix}" = "xNONE"; then
  90     AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${ac_default_prefix}/share/${PACKAGE}", PACKAGE_DATA_DIR)
  91   else
  92     AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${prefix}/share/${PACKAGE}", PACKAGE_DATA_DIR)
  93   fi
  94 else
  95   AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${datadir}/${PACKAGE}", PACKAGE_DATA_DIR)
  96 fi
  97
  98 dnl Checks for libraries.
  99 AM_PATH_GLIB(1.2.6,,
 100         AC_MSG_ERROR(Test for GLIB failed. See the file 'INSTALL' for help.),
 101         gthread)
 102 AM_PATH_GTK(1.2.6,,
 103         AC_MSG_ERROR(Test for GTK failed. See the file 'INSTALL' for help.))
 104
 105 dnl Check for built-in image view support
 106 AC_ARG_ENABLE(gdk-pixbuf,
 107         [  --disable-gdk-pixbuf    Do not use gdk-pixbuf],
 108         [ac_cv_enable_gdk_pixbuf=$enableval], [ac_cv_enable_gdk_pixbuf=yes])
 109 AC_ARG_ENABLE(imlib,
 110         [  --disable-imlib         Do not use imlib],
 111         [ac_cv_enable_imlib=$enableval], [ac_cv_enable_imlib=yes])
 112
 113 if test "$ac_cv_enable_gdk_pixbuf" = yes; then
 114         AM_PATH_GDK_PIXBUF(0.8.0,
 115                 [AC_DEFINE(HAVE_GDK_PIXBUF, 1, Use GDK Pixbuf for image rendering)
 116                  ac_cv_enable_imlib=no], [ac_cv_enable_gdk_pixbuf=no])
 117 fi
 118 if test "$ac_cv_enable_imlib" = yes; then
 119         AM_PATH_GDK_IMLIB(1.9,
 120                 AC_DEFINE(HAVE_GDK_IMLIB, 1, Use GDK Imlib for image rendering), [ac_cv_enable_imlib=no])
 121 fi
 122 if test "$ac_cv_enable_gdk_pixbuf" = no -a "$ac_cv_enable_imlib" = no; then
 123         AC_MSG_WARN(*** Built-in image view will not be supported ***)
 124 fi
 125
 126 dnl GPGME is used to support OpenPGP
 127 AC_ARG_ENABLE(gpgme,
 128         [  --enable-gpgme          Enable GnuPG support using GPGME [default=no]],
 129         [ac_cv_enable_gpgme=$enableval], [ac_cv_enable_gpgme=no])
 130 AC_MSG_CHECKING([whether to use GPGME])
 131 if test $ac_cv_enable_gpgme = yes; then
 132         AC_MSG_RESULT(yes)
 133         AM_PATH_GPGME(0.3.5, AC_DEFINE(USE_GPGME, 1, Define if you use GPGME to support OpenPGP),
 134                       [use_gpgme=no ac_cv_enable_gpgme=no])
 135 else
 136         AC_MSG_RESULT(no)
 137 fi
 138
 139 dnl for JPilot support in addressbook
 140 dnl no check for libraries; these are dynamically loaded
 141 AC_ARG_ENABLE(jpilot,
 142         [  --enable-jpilot         Enable JPilot support [default=no]],
 143         [ac_cv_enable_jpilot=$enableval], [ac_cv_enable_jpilot=no])
 144 AC_MSG_CHECKING([whether to use JPilot])
 145 if test "$ac_cv_enable_jpilot" = yes; then
 146         AC_MSG_RESULT(yes)
 147         AC_CHECK_HEADERS(pi-args.h pi-appinfo.h pi-address.h,
 148                          [ AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ],
 149                          [ ac_cv_enable_jpilot=no ])
 150         if test "$ac_cv_enable_jpilot" = no; then
 151                 AC_CHECK_HEADERS(libpisock/pi-args.h libpisock/pi-appinfo.h libpisock/pi-address.h,
 152                                  [ ac_cv_enable_jpilot=yes
 153                                    AC_DEFINE(USE_JPILOT, 1) ])
 154         fi
 155         AC_MSG_CHECKING([whether jpilot is available])
 156         AC_MSG_RESULT($ac_cv_enable_jpilot)
 157
 158         if test "$ac_cv_enable_jpilot" = yes; then
 159                 LIBS="$LIBS -lpisock"
 160         fi
 161 else
 162         AC_MSG_RESULT(no)
 163 fi
 164
 165 dnl for LDAP support in addressbook
 166 AC_ARG_ENABLE(ldap,
 167         [  --enable-ldap           Enable LDAP support [default=no]],
 168         [ac_cv_enable_ldap=$enableval], [ac_cv_enable_ldap=no])
 169 AC_MSG_CHECKING([whether to use LDAP])
 170 if test "$ac_cv_enable_ldap" = yes; then
 171         AC_MSG_RESULT(yes)
 172
 173         dnl check for available libraries, and pull them in
 174         AC_CHECK_LIB(resolv, res_query, LDAP_LIBS="$LDAP_LIBS -lresolv")
 175         AC_CHECK_LIB(socket, bind, LDAP_LIBS="$LDAP_LIBS -lsocket")
 176         AC_CHECK_LIB(nsl, gethostbyaddr, LDAP_LIBS="$LDAP_LIBS -lnsl")
 177         AC_CHECK_LIB(lber, ber_get_tag, LDAP_LIBS="$LDAP_LIBS -llber",,
 178                      $LDAP_LIBS)
 179
 180         dnl we need libpthread for sylpheed ldap,  until we find
 181         dnl a better way to handle ldap requests asynchronously...
 182         AC_CHECK_LIB(pthread, pthread_create, LDAP_LIBS="$LDAP_LIBS -lpthread")
 183
 184         AC_CHECK_HEADERS(ldap.h lber.h pthread.h,
 185                          [ ac_cv_enable_ldap=yes ],
 186                          [ ac_cv_enable_ldap=no ])
 187
 188         if test "$ac_cv_enable_ldap" = yes; then
 189                 AC_CHECK_LIB(ldap, ldap_open,
 190                              [ ac_cv_enable_ldap=yes ],
 191                              [ ac_cv_enable_ldap=no ],
 192                              $LDAP_LIBS)
 193         fi
 194
 195         AC_MSG_CHECKING([whether ldap library is available])
 196         AC_MSG_RESULT($ac_cv_enable_ldap)
 197
 198         if test "$ac_cv_enable_ldap" = yes; then
 199                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
 200                 LDAP_LIBS="$LDAP_LIBS -lldap `$GLIB_CONFIG --libs gthread`"
 201                 AC_DEFINE(USE_LDAP, 1, Define LDAP support in addressbook.)
 202                 AC_SUBST(LDAP_LIBS)
 203         fi
 204 else
 205         AC_MSG_RESULT(no)
 206 fi
 207
 208 dnl Check for OpenSSL
 209 AC_ARG_ENABLE(ssl,
 210         [  --enable-ssl            Enable SSL support using OpenSSL [default=no]],
 211         [ac_cv_enable_ssl=$enableval], [ac_cv_enable_ssl=no])
 212 AC_MSG_CHECKING([whether to use OpenSSL])
 213 if test $ac_cv_enable_ssl = yes; then
 214         AC_MSG_RESULT(yes)
 215         AC_MSG_CHECKING([if openssl is available])
 216         LIBS="$LIBS -lssl -lcrypto"
 217         AC_TRY_LINK([
 218 #include <openssl/opensslv.h>
 219 ],      [ return OPENSSL_VERSION_NUMBER; ],
 220         [ AC_MSG_RESULT(yes)
 221           AC_DEFINE(USE_SSL, 1, Define if you use OpenSSL to support SSL) ],
 222         [ AC_MSG_RESULT(no)
 223           LIBS="$ac_save_LIBS"
 224           ac_cv_enable_ssl=no ])
 225 else
 226         AC_MSG_RESULT(no)
 227 fi
 228
 229 dnl Check for X-Face support
 230 AC_ARG_ENABLE(compface,
 231         [  --disable-compface      Do not use compface (X-Face)],
 232         [ac_cv_enable_compface=$enableval], [ac_cv_enable_compface=yes])
 233 if test "$ac_cv_enable_compface" = yes; then
 234         AC_CHECK_LIB(compface, uncompface,,[ac_cv_enable_compface=no])
 235 fi
 236
 237 dnl Check for libjconv
 238 AC_ARG_ENABLE(jconv,
 239         [  --disable-jconv         Do not use libjconv],
 240         [ac_cv_enable_jconv=$enableval], [ac_cv_enable_jconv=yes])
 241 if test "$ac_cv_enable_jconv" = yes; then
 242         AC_CHECK_LIB(jconv, jconv_alloc_conv,,[ac_cv_enable_jconv=no])
 243 fi
 244
 245 AC_CHECK_LIB(xpg4, setlocale)
 246
 247 dnl for GThread support (currently disabled)
 248 dnl AC_ARG_ENABLE(threads,
 249 dnl     [  --enable-threads        Enable multithread support [default=no]],
 250 dnl     [use_threads=$enableval], [use_threads=no])
 251
 252 AC_MSG_CHECKING([whether to use threads])
 253 if test x"$use_threads" = xyes ; then
 254         AC_MSG_RESULT(yes)
 255         if test ! -z `$GLIB_CONFIG --help 2>&1 |grep 'gthread'` ; then
 256                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
 257                 LIBS="$LIBS `$GLIB_CONFIG --libs gthread`"
 258                 AC_DEFINE(USE_THREADS, 1, Whether to use multithread or not)
 259         else
 260                 AC_MSG_ERROR([Sylpheed requires GThread from GLib to use threading.])
 261         fi
 262 else
 263         AC_MSG_RESULT(no)
 264 fi
 265
 266 dnl check for IPv6 option
 267 AC_ARG_ENABLE(ipv6,
 268         [  --enable-ipv6           Enable IPv6 support [default=no]],
 269         [ac_cv_enable_ipv6=$enableval], [ac_cv_enable_ipv6=no])
 270
 271 dnl automated checks for IPv6 support.
 272 AC_MSG_CHECKING([whether to use IPv6])
 273 if test x"$ac_cv_enable_ipv6" = xyes; then
 274         AC_MSG_RESULT(yes)
 275         AC_MSG_CHECKING([for IPv6 support])
 276         AC_CACHE_VAL(ac_cv_ipv6,[
 277                 AC_TRY_COMPILE([#define INET6
 278                                 #include <sys/types.h>
 279                                 #include <netinet/in.h>],
 280                         [int x = IPPROTO_IPV6; struct in6_addr a;],
 281                         ac_cv_ipv6=yes, ac_cv_ipv6=no)
 282         ])
 283         AC_MSG_RESULT($ac_cv_ipv6)
 284         if test $ac_cv_ipv6 = yes; then
 285                 AC_DEFINE(INET6, 1, Define if you want IPv6 support.)
 286         else
 287                 AC_MSG_WARN(*** IPv6 will not be supported ***)
 288                 ac_cv_enable_ipv6=no
 289         fi
 290 else
 291         AC_MSG_RESULT(no)
 292 fi
 293
 294 dnl ASPELL is user for spell checking
 295 AC_ARG_ENABLE(aspell,
 296         [  --enable-aspell         Enable GNU/aspell support [default=no]],
 297         [ac_cv_enable_aspell=$enableval], [ac_cv_enable_aspell=no])
 298 AC_MSG_CHECKING([whether to use GNU/aspell])
 299 if test $ac_cv_enable_aspell = yes; then
 300         AC_MSG_RESULT(yes)
 301         AM_PATH_ASPELL(0.50, AC_DEFINE(USE_ASPELL, 1, Define if you use ASPELL to support spell checking),
 302                       [use_aspell=no ac_cv_enable_aspell=no])
 303 else
 304         AC_MSG_RESULT(no)
 305 fi
 306
 307 dnl check if gdk / gtk was compiled with USE_XIM
 308 AC_MSG_CHECKING([whether GTK was compiled with XIM support])
 309 CFLAGS_SAVE="$CFLAGS"
 310 LDFLAGS_SAVE="$LDFLAGS"
 311 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags` `gtk-config --cflags`"
 312 LDFLAGS="$LIBS `$GLIB_CONFIG --libs` `gtk-config --libs`"
 313 AC_CACHE_VAL(ac_cv_use_gtkgdk_xim, [
 314         AC_TRY_LINK_FUNC([ gdk_ic_attr_new ],
 315                          ac_cv_use_gtkgdk_xim=yes, ac_cv_use_gtkgdk_xim=no)
 316         ])
 317 AC_MSG_RESULT($ac_cv_use_gtkgdk_xim)
 318 if test $ac_cv_use_gtkgdk_xim = yes; then
 319         AC_DEFINE(USE_GTKGDK_XIM, 1, USE_GTKGDK_XIM)
 320 fi
 321 CFLAGS="$CFLAGS_SAVE"
 322 LDFLAGS="$LDFLAGS_SAVE"
 323
 324 dnl want crash dialog
 325 AC_ARG_ENABLE(crash-dialog,
 326         [  --enable-crash-dialog   Enable crash dialog [default=no]],
 327         [ac_cv_enable_crash_dialog=$enableval], [ac_cv_enable_crash_dialog=no])
 328 if test $ac_cv_enable_crash_dialog = yes; then
 329 dnl check if GDB is somewhere
 330         AC_CHECK_PROG(ac_cv_enable_crash_dialog, gdb, yes, no)
 331         AC_MSG_CHECKING([whether to use crash dialog])
 332         if test $ac_cv_enable_crash_dialog = yes; then
 333                 AC_DEFINE(CRASH_DIALOG, 1, Pop up crash dialog)
 334         fi
 335         AC_MSG_RESULT($ac_cv_enable_crash_dialog)
 336 fi
 337
 338 dnl Checks for header files.
 339 AC_HEADER_DIRENT
 340 AC_HEADER_STDC
 341 AC_HEADER_SYS_WAIT
 342 AC_CHECK_HEADERS(fcntl.h sys/file.h unistd.h paths.h \
 343                  sys/param.h sys/utsname.h sys/select.h \
 344                  wchar.h wctype.h)
 345
 346 dnl Checks for typedefs, structures, and compiler characteristics.
 347 AC_C_CONST
 348 AC_TYPE_OFF_T
 349 AC_TYPE_PID_T
 350 AC_TYPE_SIZE_T
 351 AC_STRUCT_TM
 352
 353 dnl AC_CHECK_TYPE(wint_t, unsigned int) does not work because wint_t
 354 dnl may be defined only in wchar.h (this happens with gcc-2.96).
 355 dnl So we need to use this extended macro.
 356 SYLPHEED_CHECK_TYPE(wint_t, unsigned int,
 357 [
 358 #if HAVE_WCHAR_H
 359 #include <wchar.h>
 360 #endif
 361 ], Define to `unsigned int' if <stddef.h> or <wchar.h> doesn't define.)
 362
 363 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF, Used to test for a u32 typedef)
 364 AC_CHECK_SIZEOF(unsigned short, 2)
 365 AC_CHECK_SIZEOF(unsigned int, 4)
 366 AC_CHECK_SIZEOF(unsigned long, 4)
 367
 368 dnl Checks for library functions.
 369 AC_FUNC_ALLOCA
 370 AC_CHECK_FUNCS(gethostname mkdir mktime socket strstr strchr \
 371                wcsstr wcswcs iswalnum iswspace towlower \
 372                wcslen wcscpy wcsncpy \
 373                uname flock lockf inet_aton inet_addr \
 374                fchmod mkstemp)
 375
 376 AC_OUTPUT([
 377 Makefile
 378 sylpheed.spec
 379 intl/Makefile
 380 ac/Makefile
 381 po/Makefile.in
 382 src/version.h
 383 src/Makefile
 384 faq/Makefile
 385 faq/de/Makefile
 386 faq/en/Makefile
 387 faq/es/Makefile
 388 faq/fr/Makefile
 389 faq/it/Makefile
 390 man/Makefile
 391 manual/Makefile
 392 manual/de/Makefile
 393 manual/en/Makefile
 394 manual/es/Makefile
 395 manual/fr/Makefile
 396 manual/ja/Makefile
 397 tools/Makefile
 398 config/Makefile
 399 ])
 400
 401 dnl Output the configuration summary
 402 echo ""
 403 echo "$PACKAGE $VERSION"
 404 echo ""
 405 if test "$ac_cv_enable_gdk_pixbuf" = yes; then
 406         echo "image support : yes (gdk-pixbuf)"
 407 elif test "$ac_cv_enable_imlib" = yes; then
 408         echo "image support : yes (gdk_imlib)"
 409 else
 410         echo "image support : no"
 411 fi
 412 echo "GnuPG         : $ac_cv_enable_gpgme"
 413 echo "JPilot        : $ac_cv_enable_jpilot"
 414 echo "LDAP          : $ac_cv_enable_ldap"
 415 echo "OpenSSL       : $ac_cv_enable_ssl"
 416 echo "compface      : $ac_cv_enable_compface"
 417 echo "libjconv      : $ac_cv_enable_jconv"
 418 echo "IPv6          : $ac_cv_enable_ipv6"
 419 echo "GNU/aspell    : $ac_cv_enable_aspell"
 420 echo "Crash dialog  : $ac_cv_enable_crash_dialog"
 421 echo ""
 422 echo "The binary will be installed in $prefix/bin"
 423 echo ""
 424 echo "Configure finished, type 'make' to build."