configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(src/main.c)
   3 PACKAGE=sylpheed
   4
   5 dnl version number
   6 MAJOR_VERSION=0
   7 MINOR_VERSION=7
   8 MICRO_VERSION=4
   9 INTERFACE_AGE=0
  10 BINARY_AGE=0
  11 EXTRA_VERSION=claws85
  12 VERSION=$MAJOR_VERSION.$MINOR_VERSION.$MICRO_VERSION$EXTRA_VERSION
  13
  14 dnl set $target
  15 AC_CANONICAL_SYSTEM
  16
  17 dnl
  18 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  19 dnl AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
  20 dnl AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
  21 AC_SUBST(PACKAGE)
  22 AC_SUBST(VERSION)
  23
  24 dnl GNOME installed?
  25 AC_PATH_PROG(GNOME_CONFIG, gnome-config, no)
  26 if test "$GNOME_CONFIG" != no; then
  27         gnomedir="`gnome-config --prefix`"
  28         AC_SUBST(gnomedir)
  29 fi
  30 AM_CONDITIONAL(SYLPHEED_GNOME, test -d "$gnomedir")
  31
  32 dnl Claws version
  33 AC_DEFINE(CLAWS, 1)
  34
  35 dnl libtool versioning
  36 LT_RELEASE=$MAJOR_VERSION.$MINOR_VERSION
  37 LT_CURRENT=`expr $MICRO_VERSION - $INTERFACE_AGE`
  38 LT_REVISION=$INTERFACE_AGE
  39 LT_AGE=`expr $BINARY_AGE - $INTERFACE_AGE`
  40 AC_SUBST(LT_RELEASE)
  41 AC_SUBST(LT_CURRENT)
  42 AC_SUBST(LT_REVISION)
  43 AC_SUBST(LT_AGE)
  44
  45 dnl Specify a header configuration file
  46 AM_CONFIG_HEADER(config.h)
  47
  48 AM_MAINTAINER_MODE
  49
  50 dnl Checks for programs.
  51 AC_ARG_PROGRAM
  52 AC_PROG_CC
  53 AC_ISC_POSIX
  54 AM_PROG_CC_STDC
  55 AC_PROG_INSTALL
  56 AC_PROG_LN_S
  57 AC_PROG_MAKE_SET
  58 AC_PROG_CPP
  59 dnl AC_PROG_RANLIB
  60 AM_PROG_LEX
  61 AC_PROG_YACC
  62 AM_PROG_LIBTOOL
  63
  64 SYLPHEED_ACLOCAL_INCLUDE(ac)
  65
  66 case "$target" in
  67 *-darwin*)
  68         CFLAGS="$CFLAGS -traditional-cpp -fno-common"
  69         ;;
  70 esac
  71
  72 dnl add additional parameters
  73 AC_ARG_WITH(compiler-flags,
  74     [  --with-compiler-flags=FLAGS  add parameters to the compiler command],
  75     CFLAGS="$CFLAGS $withval")
  76
  77 dnl for gettext
  78 ALL_LINGUAS="cs de el en_GB es fr hr it ja ko nl pl pt_BR ru sv"
  79 AM_GNU_GETTEXT
  80 dnl AC_CHECK_FUNC(gettext, AC_CHECK_LIB(intl, gettext))
  81 localedir='${prefix}/${DATADIRNAME}/locale'
  82 AC_SUBST(localedir)
  83
  84 manualdir='${prefix}/${DATADIRNAME}/${PACKAGE}/manual'
  85 AC_SUBST(manualdir)
  86 faqdir='${prefix}/${DATADIRNAME}/${PACKAGE}/faq'
  87 AC_SUBST(faqdir)
  88
  89 dnl Set PACKAGE_DATA_DIR in config.h.
  90 if test "x${datadir}" = 'x${prefix}/share'; then
  91   if test "x${prefix}" = "xNONE"; then
  92     AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${ac_default_prefix}/share/${PACKAGE}")
  93   else
  94     AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${prefix}/share/${PACKAGE}")
  95   fi
  96 else
  97   AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${datadir}/${PACKAGE}")
  98 fi
  99
 100 dnl Checks for libraries.
 101 AM_PATH_GLIB(1.2.6,,
 102         AC_MSG_ERROR(Test for GLIB failed. See the file 'INSTALL' for help.),
 103         gthread)
 104 AM_PATH_GTK(1.2.6,,
 105         AC_MSG_ERROR(Test for GTK failed. See the file 'INSTALL' for help.))
 106
 107 dnl Check for built-in image view support
 108 AC_ARG_ENABLE(gdk-pixbuf,
 109         [  --disable-gdk-pixbuf    Do not use gdk-pixbuf],
 110         [ac_cv_enable_gdk_pixbuf=$enableval], [ac_cv_enable_gdk_pixbuf=yes])
 111 AC_ARG_ENABLE(imlib,
 112         [  --disable-imlib         Do not use imlib],
 113         [ac_cv_enable_imlib=$enableval], [ac_cv_enable_imlib=yes])
 114
 115 if test "$ac_cv_enable_gdk_pixbuf" = yes; then
 116         AM_PATH_GDK_PIXBUF(0.8.0,
 117                 [AC_DEFINE(HAVE_GDK_PIXBUF)
 118                  ac_cv_enable_imlib=no], [ac_cv_enable_gdk_pixbuf=no])
 119 fi
 120 if test "$ac_cv_enable_imlib" = yes; then
 121         AM_PATH_GDK_IMLIB(1.9,
 122                 AC_DEFINE(HAVE_GDK_IMLIB), [ac_cv_enable_imlib=no])
 123 fi
 124 if test "$ac_cv_enable_gdk_pixbuf" = no -a "$ac_cv_enable_imlib" = no; then
 125         AC_MSG_WARN(*** Built-in image view will not be supported ***)
 126 fi
 127
 128 dnl GPGME is used to support OpenPGP
 129 AC_ARG_ENABLE(gpgme,
 130         [  --enable-gpgme          Enable GnuPG support using GPGME [default=no]],
 131         [ac_cv_enable_gpgme=$enableval], [ac_cv_enable_gpgme=no])
 132 AC_MSG_CHECKING([whether to use GPGME])
 133 if test $ac_cv_enable_gpgme = yes; then
 134         AC_MSG_RESULT(yes)
 135         AM_PATH_GPGME(0.2.3, AC_DEFINE(USE_GPGME), [use_gpgme=no
 136                                                     ac_cv_enable_gpgme=no])
 137 else
 138         AC_MSG_RESULT(no)
 139 fi
 140
 141 dnl for JPilot support in addressbook
 142 dnl no check for libraries; these are dynamically loaded
 143 AC_ARG_ENABLE(jpilot,
 144         [  --enable-jpilot         Enable JPilot support [default=no]],
 145         [ac_cv_enable_jpilot=$enableval], [ac_cv_enable_jpilot=no])
 146 AC_MSG_CHECKING([whether to use JPilot])
 147 if test "$ac_cv_enable_jpilot" = yes; then
 148         AC_MSG_RESULT(yes)
 149         AC_CHECK_HEADERS(pi-args.h pi-appinfo.h pi-address.h,
 150                          [ AC_DEFINE(USE_JPILOT) ],
 151                          [ ac_cv_enable_jpilot=no ])
 152         if test "$ac_cv_enable_jpilot" = no; then
 153                 AC_CHECK_HEADERS(libpisock/pi-args.h libpisock/pi-appinfo.h libpisock/pi-address.h,
 154                                  [ ac_cv_enable_jpilot=yes
 155                                    AC_DEFINE(USE_JPILOT) ])
 156         fi
 157         AC_MSG_CHECKING([whether jpilot is available])
 158         AC_MSG_RESULT($ac_cv_enable_jpilot)
 159
 160         if test "$ac_cv_enable_jpilot" = yes; then
 161                 LIBS="$LIBS -lpisock"
 162         fi
 163 else
 164         AC_MSG_RESULT(no)
 165 fi
 166
 167 dnl for LDAP support in addressbook
 168 dnl no check for libraries; dynamically loaded
 169 AC_ARG_ENABLE(ldap,
 170         [  --enable-ldap           Enable LDAP support [default=no]],
 171         [ac_cv_enable_ldap=$enableval], [ac_cv_enable_ldap=no])
 172 AC_MSG_CHECKING([whether to use LDAP])
 173 if test "$ac_cv_enable_ldap" = yes; then
 174         AC_MSG_RESULT(yes)
 175         AC_CHECK_HEADERS(ldap.h lber.h pthread.h,
 176                          [ AC_DEFINE(USE_LDAP) ],
 177                          [ ac_cv_enable_ldap=no ])
 178         AC_MSG_CHECKING([whether ldap is available])
 179         AC_MSG_RESULT($ac_cv_enable_ldap)
 180
 181         if test "$ac_cv_enable_ldap" = yes; then
 182                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
 183                 LIBS="$LIBS -lldap -llber -lpthread -lresolv `$GLIB_CONFIG --libs gthread`"
 184         fi
 185 else
 186         AC_MSG_RESULT(no)
 187 fi
 188
 189 dnl Check for OpenSSL
 190 AC_ARG_ENABLE(ssl,
 191         [  --enable-ssl            Enable SSL support using OpenSSL [default=no]],
 192         [ac_cv_enable_ssl=$enableval], [ac_cv_enable_ssl=no])
 193 AC_MSG_CHECKING([whether to use OpenSSL])
 194 if test $ac_cv_enable_ssl = yes; then
 195         AC_MSG_RESULT(yes)
 196         AC_MSG_CHECKING([if openssl is available])
 197         LIBS="$LIBS -lssl -lcrypto"
 198         AC_TRY_LINK([
 199 #include <openssl/opensslv.h>
 200 ],      [ return OPENSSL_VERSION_NUMBER; ],
 201         [ AC_MSG_RESULT(yes)
 202           AC_DEFINE(USE_SSL) ],
 203         [ AC_MSG_RESULT(no)
 204           LIBS="$ac_save_LIBS"
 205           ac_cv_enable_ssl=no ])
 206 else
 207         AC_MSG_RESULT(no)
 208 fi
 209
 210 dnl Check for X-Face support
 211 AC_ARG_ENABLE(compface,
 212         [  --disable-compface      Do not use compface (X-Face)],
 213         [ac_cv_enable_compface=$enableval], [ac_cv_enable_compface=yes])
 214 if test "$ac_cv_enable_compface" = yes; then
 215         AC_CHECK_LIB(compface, uncompface,,[ac_cv_enable_compface=no])
 216 fi
 217
 218 dnl Check for libjconv
 219 AC_ARG_ENABLE(jconv,
 220         [  --disable-jconv         Do not use libjconv],
 221         [ac_cv_enable_jconv=$enableval], [ac_cv_enable_jconv=yes])
 222 if test "$ac_cv_enable_jconv" = yes; then
 223         AC_CHECK_LIB(jconv, jconv_alloc_conv,,[ac_cv_enable_jconv=no])
 224 fi
 225
 226 AC_CHECK_LIB(xpg4, setlocale)
 227 dnl AC_CHECK_LIB(kcc, KCC_filter)
 228
 229 dnl for GThread support (currently disabled)
 230 dnl AC_ARG_ENABLE(threads,
 231 dnl     [  --enable-threads        Enable multithread support [default=no]],
 232 dnl     [use_threads=$enableval], [use_threads=no])
 233
 234 AC_MSG_CHECKING([whether to use threads])
 235 if test x"$use_threads" = xyes ; then
 236         AC_MSG_RESULT(yes)
 237         if test ! -z `$GLIB_CONFIG --help 2>&1 |grep 'gthread'` ; then
 238                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
 239                 LIBS="$LIBS `$GLIB_CONFIG --libs gthread`"
 240                 AC_DEFINE(USE_THREADS)
 241         else
 242                 AC_MSG_ERROR([Sylpheed requires GThread from GLib to use threading.])
 243         fi
 244 else
 245         AC_MSG_RESULT(no)
 246 fi
 247
 248 dnl check for IPv6 option
 249 AC_ARG_ENABLE(ipv6,
 250         [  --enable-ipv6           Enable IPv6 support [default=no]],
 251         [ac_cv_enable_ipv6=$enableval], [ac_cv_enable_ipv6=no])
 252
 253 dnl automated checks for IPv6 support.
 254 AC_MSG_CHECKING([whether to use IPv6])
 255 if test x"$ac_cv_enable_ipv6" = xyes; then
 256         AC_MSG_RESULT(yes)
 257         AC_MSG_CHECKING([for IPv6 support])
 258         AC_CACHE_VAL(ac_cv_ipv6,[
 259                 AC_TRY_COMPILE([#define INET6
 260                                 #include <sys/types.h>
 261                                 #include <netinet/in.h>],
 262                         [int x = IPPROTO_IPV6; struct in6_addr a;],
 263                         ac_cv_ipv6=yes, ac_cv_ipv6=no)
 264         ])
 265         AC_MSG_RESULT($ac_cv_ipv6)
 266         if test $ac_cv_ipv6 = yes; then
 267                 AC_DEFINE(INET6)
 268         else
 269                 AC_MSG_WARN(*** IPv6 will not be supported ***)
 270                 ac_cv_enable_ipv6=no
 271         fi
 272 else
 273         AC_MSG_RESULT(no)
 274 fi
 275
 276 dnl PSPELL is user for spell checking
 277 AC_ARG_ENABLE(pspell,
 278         [  --enable-pspell           Enable pspell support [default=no]],
 279         [ac_cv_enable_pspell=$enableval], [ac_cv_enable_pspell=no])
 280 AC_MSG_CHECKING([whether to use pspell])
 281 if test $ac_cv_enable_pspell = yes; then
 282         AC_MSG_RESULT(yes)
 283         AM_PATH_PSPELL(.12.2, AC_DEFINE(USE_PSPELL), [use_pspell=no
 284                                                     ac_cv_enable_pspell=no])
 285         pspell_path="`pspell-config --pkgdatadir`"
 286         AC_DEFINE_UNQUOTED(PSPELL_PATH, "${pspell_path}/")
 287 else
 288         AC_MSG_RESULT(no)
 289 fi
 290
 291 dnl check if gdk / gtk was compiled with USE_XIM
 292 AC_MSG_CHECKING([whether GTK was compiled with XIM support])
 293 CFLAGS_SAVE="$CFLAGS"
 294 LDFLAGS_SAVE="$LDFLAGS"
 295 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags` `gtk-config --cflags`"
 296 LDFLAGS="$LIBS `$GLIB_CONFIG --libs` `gtk-config --libs`"
 297 AC_CACHE_VAL(ac_cv_use_gtkgdk_xim, [
 298         AC_TRY_COMPILE([#include <gtk/gtk.h>
 299                         #include <gdk/gdk.h>],
 300                         [extern gint gdk_im_open(void); gdk_im_open();],
 301                          ac_cv_use_gtkgdk_xim=yes, ac_cv_use_gtkgdk_xim=no)
 302         ])
 303 AC_MSG_RESULT($ac_cv_use_gtkgdk_xim)
 304 if test $ac_cv_use_gtkgdk_xim = yes; then
 305         AC_DEFINE(USE_GTKGDK_XIM)
 306 fi
 307 CFLAGS="$CFLAGS_SAVE"
 308 LDFLAGS="$LDFLAGS_SAVE"
 309
 310
 311 dnl Checks for header files.
 312 AC_HEADER_DIRENT
 313 AC_HEADER_STDC
 314 AC_HEADER_SYS_WAIT
 315 AC_CHECK_HEADERS(fcntl.h sys/file.h unistd.h paths.h \
 316                  sys/param.h sys/utsname.h \
 317                  wchar.h wctype.h)
 318
 319 dnl Checks for typedefs, structures, and compiler characteristics.
 320 AC_C_CONST
 321 AC_TYPE_OFF_T
 322 AC_TYPE_PID_T
 323 AC_TYPE_SIZE_T
 324 AC_STRUCT_TM
 325
 326 dnl AC_CHECK_TYPE(wint_t, unsigned int) does not work because wint_t
 327 dnl may be defined only in wchar.h (this happens with gcc-2.96).
 328 dnl So we need to use this extended macro.
 329 SYLPHEED_CHECK_TYPE(wint_t, unsigned int,
 330 [
 331 #if HAVE_WCHAR_H
 332 #include <wchar.h>
 333 #endif
 334 ])
 335
 336 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
 337 AC_CHECK_SIZEOF(unsigned short, 2)
 338 AC_CHECK_SIZEOF(unsigned int, 4)
 339 AC_CHECK_SIZEOF(unsigned long, 4)
 340
 341 dnl Checks for library functions.
 342 AC_FUNC_ALLOCA
 343 AC_CHECK_FUNCS(gethostname mkdir mktime socket strstr \
 344                wcsstr wcswcs iswalnum iswspace towlower \
 345                wcslen wcscpy wcsncpy \
 346                uname flock lockf inet_aton inet_addr \
 347                fchmod mkstemp)
 348
 349 AC_OUTPUT([
 350 Makefile
 351 sylpheed.spec
 352 intl/Makefile
 353 ac/Makefile
 354 po/Makefile.in
 355 libkcc/Makefile
 356 src/version.h
 357 src/Makefile
 358 faq/Makefile
 359 faq/en/Makefile
 360 faq/es/Makefile
 361 faq/fr/Makefile
 362 faq/it/Makefile
 363 manual/Makefile
 364 manual/en/Makefile
 365 manual/fr/Makefile
 366 manual/ja/Makefile
 367 tools/Makefile
 368 ])
 369
 370 dnl Output the configuration summary
 371 echo ""
 372 echo "$PACKAGE $VERSION"
 373 echo ""
 374 if test "$ac_cv_enable_gdk_pixbuf" = yes; then
 375         echo "image support : yes (gdk-pixbuf)"
 376 elif test "$ac_cv_enable_imlib" = yes; then
 377         echo "image support : yes (gdk_imlib)"
 378 else
 379         echo "image support : no"
 380 fi
 381 echo "GPGME         : $ac_cv_enable_gpgme"
 382 echo "JPilot        : $ac_cv_enable_jpilot"
 383 echo "LDAP          : $ac_cv_enable_ldap"
 384 echo "OpenSSL       : $ac_cv_enable_ssl"
 385 echo "compface      : $ac_cv_enable_compface"
 386 echo "libjconv      : $ac_cv_enable_jconv"
 387 echo "IPv6          : $ac_cv_enable_ipv6"
 388 echo "Pspell        : $ac_cv_enable_pspell"
 389 echo ""
 390 echo "The binary will be installed in $prefix/bin"
 391 echo ""
 392 echo "Configure finished, type 'make' to build."