configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(src/main.c)
   3 PACKAGE=sylpheed
   4
   5 dnl version number
   6 MAJOR_VERSION=0
   7 MINOR_VERSION=7
   8 MICRO_VERSION=0
   9 INTERFACE_AGE=0
  10 BINARY_AGE=0
  11 EXTRA_VERSION=claws51
  12 VERSION=$MAJOR_VERSION.$MINOR_VERSION.$MICRO_VERSION$EXTRA_VERSION
  13
  14 dnl set $target
  15 AC_CANONICAL_SYSTEM
  16
  17 dnl
  18 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  19 dnl AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
  20 dnl AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
  21 AC_SUBST(PACKAGE)
  22 AC_SUBST(VERSION)
  23
  24 dnl GNOME installed?
  25 AC_PATH_PROG(GNOME_CONFIG, gnome-config, no)
  26 if test "$GNOME_CONFIG" != no; then
  27         gnomedir="`gnome-config --prefix`"
  28         AC_SUBST(gnomedir)
  29 fi
  30 AM_CONDITIONAL(SYLPHEED_GNOME, test -d "$gnomedir")
  31
  32 dnl Claws version
  33 AC_DEFINE(CLAWS, 1)
  34
  35 dnl libtool versioning
  36 LT_RELEASE=$MAJOR_VERSION.$MINOR_VERSION
  37 LT_CURRENT=`expr $MICRO_VERSION - $INTERFACE_AGE`
  38 LT_REVISION=$INTERFACE_AGE
  39 LT_AGE=`expr $BINARY_AGE - $INTERFACE_AGE`
  40 AC_SUBST(LT_RELEASE)
  41 AC_SUBST(LT_CURRENT)
  42 AC_SUBST(LT_REVISION)
  43 AC_SUBST(LT_AGE)
  44
  45 dnl Specify a header configuration file
  46 AM_CONFIG_HEADER(config.h)
  47
  48 AM_MAINTAINER_MODE
  49
  50 dnl Checks for programs.
  51 AC_ARG_PROGRAM
  52 AC_PROG_CC
  53 AC_ISC_POSIX
  54 AM_PROG_CC_STDC
  55 AC_PROG_INSTALL
  56 AC_PROG_LN_S
  57 AC_PROG_MAKE_SET
  58 AC_PROG_CPP
  59 dnl AC_PROG_RANLIB
  60 AM_PROG_LEX
  61 AC_PROG_YACC
  62 AM_PROG_LIBTOOL
  63
  64 SYLPHEED_ACLOCAL_INCLUDE(ac)
  65
  66 case "$target" in
  67 *-darwin*)
  68         CFLAGS="$CFLAGS -traditional-cpp -fno-common"
  69         ;;
  70 esac
  71
  72 dnl for gettext
  73 ALL_LINGUAS="cs de el es fr hr it ja ko nl pl pt_BR ru sv"
  74 AM_GNU_GETTEXT
  75 dnl AC_CHECK_FUNC(gettext, AC_CHECK_LIB(intl, gettext))
  76 localedir='${prefix}/${DATADIRNAME}/locale'
  77 AC_SUBST(localedir)
  78
  79 manualdir='${prefix}/${DATADIRNAME}/${PACKAGE}/manual'
  80 AC_SUBST(manualdir)
  81
  82 dnl Checks for libraries.
  83 AM_PATH_GLIB(1.2.6,,
  84         AC_MSG_ERROR(Test for GLIB failed. See the file 'INSTALL' for help.),
  85         gthread)
  86 AM_PATH_GTK(1.2.6,,
  87         AC_MSG_ERROR(Test for GTK failed. See the file 'INSTALL' for help.))
  88
  89 dnl Check for built-in image view support
  90 AC_ARG_ENABLE(gdk-pixbuf,
  91         [  --disable-gdk-pixbuf    Do not use gdk-pixbuf],
  92         [ac_cv_enable_gdk_pixbuf=$enableval], [ac_cv_enable_gdk_pixbuf=yes])
  93 AC_ARG_ENABLE(imlib,
  94         [  --disable-imlib         Do not use imlib],
  95         [ac_cv_enable_imlib=$enableval], [ac_cv_enable_imlib=yes])
  96
  97 if test "$ac_cv_enable_gdk_pixbuf" = yes; then
  98         AM_PATH_GDK_PIXBUF(0.8.0,
  99                 [AC_DEFINE(HAVE_GDK_PIXBUF)
 100                  ac_cv_enable_imlib=no], [ac_cv_enable_gdk_pixbuf=no])
 101 fi
 102 if test "$ac_cv_enable_imlib" = yes; then
 103         AM_PATH_GDK_IMLIB(1.9,
 104                 AC_DEFINE(HAVE_GDK_IMLIB), [ac_cv_enable_imlib=no])
 105 fi
 106 if test "$ac_cv_enable_gdk_pixbuf" = no -a "$ac_cv_enable_imlib" = no; then
 107         AC_MSG_WARN(*** Built-in image view will not be supported ***)
 108 fi
 109
 110 dnl GPGME is used to support OpenPGP
 111 AC_ARG_ENABLE(gpgme,
 112         [  --enable-gpgme          Enable GnuPG support using GPGME [default=no]],
 113         [ac_cv_enable_gpgme=$enableval], [ac_cv_enable_gpgme=no])
 114 AC_MSG_CHECKING([whether to use GPGME])
 115 if test $ac_cv_enable_gpgme = yes; then
 116         AC_MSG_RESULT(yes)
 117         AM_PATH_GPGME(0.2.3, AC_DEFINE(USE_GPGME), [use_gpgme=no
 118                                                     ac_cv_enable_gpgme=no])
 119 else
 120         AC_MSG_RESULT(no)
 121 fi
 122
 123 dnl Check for OpenSSL
 124 AC_ARG_ENABLE(ssl,
 125         [  --enable-ssl            Enable SSL support using OpenSSL [default=no]],
 126         [ac_cv_enable_ssl=$enableval], [ac_cv_enable_ssl=no])
 127 AC_MSG_CHECKING([whether to use OpenSSL])
 128 if test $ac_cv_enable_ssl = yes; then
 129         AC_MSG_RESULT(yes)
 130         AC_MSG_CHECKING([if openssl is available])
 131         LIBS="$LIBS -lssl -lcrypto"
 132         AC_TRY_LINK([
 133 #include <openssl/opensslv.h>
 134 ],      [ return OPENSSL_VERSION_NUMBER; ],
 135         [ AC_MSG_RESULT(yes)
 136           AC_DEFINE(USE_SSL) ],
 137         [ AC_MSG_RESULT(no)
 138           LIBS="$ac_save_LIBS"
 139           ac_cv_enable_ssl=no ])
 140 else
 141         AC_MSG_RESULT(no)
 142 fi
 143
 144 dnl Check for X-Face support
 145 AC_ARG_ENABLE(compface,
 146         [  --disable-compface      Do not use compface (X-Face)],
 147         [ac_cv_enable_compface=$enableval], [ac_cv_enable_compface=yes])
 148 if test "$ac_cv_enable_compface" = yes; then
 149         AC_CHECK_LIB(compface, uncompface,,[ac_cv_enable_compface=no])
 150 fi
 151
 152 dnl for JPilot support in addressbook
 153 dnl no check for libraries; these are dynamically loaded
 154 AC_ARG_ENABLE(jpilot,
 155         [  --enable-jpilot         Enable JPilot support [default=no]],
 156         [ac_cv_enable_jpilot=$enableval], [ac_cv_enable_jpilot=no])
 157 AC_MSG_CHECKING([whether to use JPilot])
 158 if test "$ac_cv_enable_jpilot" = yes; then
 159         AC_MSG_RESULT(yes)
 160         AC_CHECK_HEADERS(pi-args.h pi-appinfo.h pi-address.h,
 161                          [ AC_DEFINE(USE_JPILOT) ],
 162                          [ ac_cv_enable_jpilot=no ])
 163         if test "$ac_cv_enable_jpilot" = no; then
 164                 AC_CHECK_HEADERS(libpisock/pi-args.h libpisock/pi-appinfo.h libpisock/pi-address.h,
 165                                  [ ac_cv_enable_jpilot=yes
 166                                    AC_DEFINE(USE_JPILOT) ])
 167         fi
 168         AC_MSG_CHECKING([whether jpilot is available])
 169         AC_MSG_RESULT($ac_cv_enable_jpilot)
 170
 171         if test "$ac_cv_enable_jpilot" = yes; then
 172                 LIBS="$LIBS -lpisock"
 173         fi
 174 else
 175         AC_MSG_RESULT(no)
 176 fi
 177
 178 dnl for LDAP support in addressbook
 179 dnl no check for libraries; dynamically loaded
 180 AC_ARG_ENABLE(ldap,
 181         [  --enable-ldap           Enable LDAP support [default=no]],
 182         [ac_cv_enable_ldap=$enableval], [ac_cv_enable_ldap=no])
 183 AC_MSG_CHECKING([whether to use LDAP])
 184 if test "$ac_cv_enable_ldap" = yes; then
 185         AC_MSG_RESULT(yes)
 186         AC_CHECK_HEADERS(ldap.h lber.h pthread.h,
 187                          [ AC_DEFINE(USE_LDAP) ],
 188                          [ ac_cv_enable_ldap=no ])
 189         AC_MSG_CHECKING([whether ldap is available])
 190         AC_MSG_RESULT($ac_cv_enable_ldap)
 191
 192         if test "$ac_cv_enable_ldap" = yes; then
 193                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
 194                 LIBS="$LIBS -lldap -llber -lpthread -lresolv `$GLIB_CONFIG --libs gthread`"
 195         fi
 196 else
 197         AC_MSG_RESULT(no)
 198 fi
 199
 200 dnl get ispell path
 201 dnl
 202 AC_PATH_PROG(ispell_path, ispell, no)
 203 if test "$ispell_path" != no; then
 204         AC_DEFINE_UNQUOTED(ISPELL_PATH, "$ispell_path")
 205         AC_SUBST(ISPELL_PATH)
 206 else
 207         AC_DEFINE_UNQUOTED(ISPELL_PATH, "/usr/bin/ispell")
 208         AC_SUBST(ISPELL_PATH)
 209 fi
 210
 211 dnl Check for libjconv
 212 AC_ARG_ENABLE(jconv,
 213         [  --disable-jconv         Do not use libjconv],
 214         [ac_cv_enable_jconv=$enableval], [ac_cv_enable_jconv=yes])
 215 if test "$ac_cv_enable_jconv" = yes; then
 216         AC_CHECK_LIB(jconv, jconv_alloc_conv,,[ac_cv_enable_jconv=no])
 217 fi
 218
 219 AC_CHECK_LIB(xpg4, setlocale)
 220 dnl AC_CHECK_LIB(kcc, KCC_filter)
 221
 222 dnl for GThread support (currently disabled)
 223 dnl AC_ARG_ENABLE(threads,
 224 dnl     [  --enable-threads        Enable multithread support [default=no]],
 225 dnl     [use_threads=$enableval], [use_threads=no])
 226
 227 AC_MSG_CHECKING([whether to use threads])
 228 if test x"$use_threads" = xyes ; then
 229         AC_MSG_RESULT(yes)
 230         if test ! -z `$GLIB_CONFIG --help 2>&1 |grep 'gthread'` ; then
 231                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
 232                 LIBS="$LIBS `$GLIB_CONFIG --libs gthread`"
 233                 AC_DEFINE(USE_THREADS)
 234         else
 235                 AC_MSG_ERROR([Sylpheed requires GThread from GLib to use threading.])
 236         fi
 237 else
 238         AC_MSG_RESULT(no)
 239 fi
 240
 241 dnl check for IPv6 option
 242 AC_ARG_ENABLE(ipv6,
 243         [  --enable-ipv6           Enable IPv6 support [default=no]],
 244         [ac_cv_enable_ipv6=$enableval], [ac_cv_enable_ipv6=no])
 245
 246 dnl automated checks for IPv6 support.
 247 AC_MSG_CHECKING([whether to use IPv6])
 248 if test x"$ac_cv_enable_ipv6" = xyes; then
 249         AC_MSG_RESULT(yes)
 250         AC_MSG_CHECKING([for IPv6 support])
 251         AC_CACHE_VAL(ac_cv_ipv6,[
 252                 AC_TRY_COMPILE([#define INET6
 253                                 #include <sys/types.h>
 254                                 #include <netinet/in.h>],
 255                         [int x = IPPROTO_IPV6; struct in6_addr a;],
 256                         ac_cv_ipv6=yes, ac_cv_ipv6=no)
 257         ])
 258         AC_MSG_RESULT($ac_cv_ipv6)
 259         if test $ac_cv_ipv6 = yes; then
 260                 AC_DEFINE(INET6)
 261         else
 262                 AC_MSG_WARN(*** IPv6 will not be supported ***)
 263                 ac_cv_enable_ipv6=no
 264         fi
 265 else
 266         AC_MSG_RESULT(no)
 267 fi
 268
 269 dnl PSPELL is user for spell checking
 270 AC_ARG_ENABLE(pspell,
 271         [  --enable-pspell           Enable pspell support [default=no]],
 272         [ac_cv_enable_pspell=$enableval], [ac_cv_enable_pspell=no])
 273 AC_MSG_CHECKING([whether to use pspell])
 274 if test $ac_cv_enable_pspell = yes; then
 275         AC_MSG_RESULT(yes)
 276         AM_PATH_PSPELL(.12.2, AC_DEFINE(USE_PSPELL), [use_pspell=no
 277                                                     ac_cv_enable_pspell=no])
 278 else
 279         AC_MSG_RESULT(no)
 280 fi
 281
 282 dnl check if gdk / gtk was compiled with USE_XIM
 283 AC_MSG_CHECKING([whether GTK was compiled with XIM support])
 284 CFLAGS_SAVE="$CFLAGS"
 285 LDFLAGS_SAVE="$LDFLAGS"
 286 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags` `gtk-config --cflags`"
 287 LDFLAGS="$LIBS `$GLIB_CONFIG --libs` `gtk-config --libs`"
 288 AC_CACHE_VAL(ac_cv_use_gtkgdk_xim, [
 289         AC_TRY_COMPILE([#include <gtk/gtk.h>
 290                         #include <gdk/gdk.h>],
 291                         [extern gint gdk_im_open(void); gdk_im_open();],
 292                          ac_cv_use_gtkgdk_xim=yes, ac_cv_use_gtkgdk_xim=no)
 293         ])
 294 AC_MSG_RESULT($ac_cv_use_gtkgdk_xim)
 295 if test $ac_cv_use_gtkgdk_xim = yes; then
 296         AC_DEFINE(USE_GTKGDK_XIM)
 297 fi
 298 CFLAGS="$CFLAGS_SAVE"
 299 LDFLAGS="$LDFLAGS_SAVE"
 300
 301
 302 dnl Checks for header files.
 303 AC_HEADER_DIRENT
 304 AC_HEADER_STDC
 305 AC_HEADER_SYS_WAIT
 306 AC_CHECK_HEADERS(fcntl.h sys/file.h unistd.h paths.h \
 307                  sys/param.h sys/utsname.h \
 308                  wchar.h wctype.h)
 309
 310 dnl Checks for typedefs, structures, and compiler characteristics.
 311 AC_C_CONST
 312 AC_TYPE_OFF_T
 313 AC_TYPE_PID_T
 314 AC_TYPE_SIZE_T
 315 AC_STRUCT_TM
 316
 317 dnl AC_CHECK_TYPE(wint_t, unsigned int) does not work because wint_t
 318 dnl may be defined only in wchar.h (this happens with gcc-2.96).
 319 dnl So we need to use this extended macro.
 320 SYLPHEED_CHECK_TYPE(wint_t, unsigned int,
 321 [
 322 #if HAVE_WCHAR_H
 323 #include <wchar.h>
 324 #endif
 325 ])
 326
 327 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
 328 AC_CHECK_SIZEOF(unsigned short, 2)
 329 AC_CHECK_SIZEOF(unsigned int, 4)
 330 AC_CHECK_SIZEOF(unsigned long, 4)
 331
 332 dnl Checks for library functions.
 333 AC_FUNC_ALLOCA
 334 AC_CHECK_FUNCS(gethostname mkdir mktime socket strstr \
 335                wcsstr wcswcs iswalnum iswspace towlower \
 336                wcslen wcscpy wcsncpy \
 337                uname flock lockf inet_aton inet_addr \
 338                fchmod mkstemp)
 339
 340 AC_OUTPUT([
 341 Makefile
 342 sylpheed.spec
 343 intl/Makefile
 344 ac/Makefile
 345 po/Makefile.in
 346 libkcc/Makefile
 347 src/version.h
 348 src/Makefile
 349 manual/Makefile
 350 manual/en/Makefile
 351 manual/ja/Makefile
 352 tools/Makefile
 353 ])
 354
 355 dnl Output the configuration summary
 356 echo ""
 357 echo "$PACKAGE $VERSION"
 358 echo ""
 359 echo "gdk-pixbuf : $ac_cv_enable_gdk_pixbuf"
 360 echo "gdk_imlib  : $ac_cv_enable_imlib"
 361 echo "GPGME      : $ac_cv_enable_gpgme"
 362 echo "JPilot     : $ac_cv_enable_jpilot"
 363 echo "LDAP       : $ac_cv_enable_ldap"
 364 echo "OpenSSL    : $ac_cv_enable_ssl"
 365 echo "compface   : $ac_cv_enable_compface"
 366 echo "libjconv   : $ac_cv_enable_jconv"
 367 echo "IPv6       : $ac_cv_enable_ipv6"
 368 echo "Pspell     : $ac_cv_enable_pspell"
 369 echo ""
 370 echo "The binary will be installed in $prefix/bin"
 371 echo ""
 372 echo "Configure finished, type 'make' to build."