configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(src/main.c)
   3 PACKAGE=sylpheed
   4
   5 dnl version number
   6 MAJOR_VERSION=0
   7 MINOR_VERSION=7
   8 MICRO_VERSION=2
   9 INTERFACE_AGE=0
  10 BINARY_AGE=0
  11 EXTRA_VERSION=claws31
  12 VERSION=$MAJOR_VERSION.$MINOR_VERSION.$MICRO_VERSION$EXTRA_VERSION
  13
  14 dnl set $target
  15 AC_CANONICAL_SYSTEM
  16
  17 dnl
  18 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  19 dnl AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
  20 dnl AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
  21 AC_SUBST(PACKAGE)
  22 AC_SUBST(VERSION)
  23
  24 dnl GNOME installed?
  25 AC_PATH_PROG(GNOME_CONFIG, gnome-config, no)
  26 if test "$GNOME_CONFIG" != no; then
  27         gnomedir="`gnome-config --prefix`"
  28         AC_SUBST(gnomedir)
  29 fi
  30 AM_CONDITIONAL(SYLPHEED_GNOME, test -d "$gnomedir")
  31
  32 dnl Claws version
  33 AC_DEFINE(CLAWS, 1)
  34
  35 dnl libtool versioning
  36 LT_RELEASE=$MAJOR_VERSION.$MINOR_VERSION
  37 LT_CURRENT=`expr $MICRO_VERSION - $INTERFACE_AGE`
  38 LT_REVISION=$INTERFACE_AGE
  39 LT_AGE=`expr $BINARY_AGE - $INTERFACE_AGE`
  40 AC_SUBST(LT_RELEASE)
  41 AC_SUBST(LT_CURRENT)
  42 AC_SUBST(LT_REVISION)
  43 AC_SUBST(LT_AGE)
  44
  45 dnl Specify a header configuration file
  46 AM_CONFIG_HEADER(config.h)
  47
  48 AM_MAINTAINER_MODE
  49
  50 dnl Checks for programs.
  51 AC_ARG_PROGRAM
  52 AC_PROG_CC
  53 AC_ISC_POSIX
  54 AM_PROG_CC_STDC
  55 AC_PROG_INSTALL
  56 AC_PROG_LN_S
  57 AC_PROG_MAKE_SET
  58 AC_PROG_CPP
  59 dnl AC_PROG_RANLIB
  60 AM_PROG_LEX
  61 AC_PROG_YACC
  62 AM_PROG_LIBTOOL
  63
  64 SYLPHEED_ACLOCAL_INCLUDE(ac)
  65
  66 case "$target" in
  67 *-darwin*)
  68         CFLAGS="$CFLAGS -traditional-cpp -fno-common"
  69         ;;
  70 esac
  71
  72 dnl for gettext
  73 ALL_LINGUAS="cs de el es fr hr it ja ko nl pl pt_BR ru sv"
  74 AM_GNU_GETTEXT
  75 dnl AC_CHECK_FUNC(gettext, AC_CHECK_LIB(intl, gettext))
  76 localedir='${prefix}/${DATADIRNAME}/locale'
  77 AC_SUBST(localedir)
  78
  79 manualdir='${prefix}/${DATADIRNAME}/${PACKAGE}/manual'
  80 AC_SUBST(manualdir)
  81
  82 faqdir='${prefix}/${DATADIRNAME}/${PACKAGE}/faq'
  83 AC_SUBST(faqdir)
  84
  85 dnl Set PACKAGE_DATA_DIR in config.h.
  86 if test "x${datadir}" = 'x${prefix}/share'; then
  87   if test "x${prefix}" = "xNONE"; then
  88     AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${ac_default_prefix}/share/${PACKAGE}")
  89   else
  90     AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${prefix}/share/${PACKAGE}")
  91   fi
  92 else
  93   AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${datadir}/${PACKAGE}")
  94 fi
  95
  96 dnl Checks for libraries.
  97 AM_PATH_GLIB(1.2.6,,
  98         AC_MSG_ERROR(Test for GLIB failed. See the file 'INSTALL' for help.),
  99         gthread)
 100 AM_PATH_GTK(1.2.6,,
 101         AC_MSG_ERROR(Test for GTK failed. See the file 'INSTALL' for help.))
 102
 103 dnl Check for built-in image view support
 104 AC_ARG_ENABLE(gdk-pixbuf,
 105         [  --disable-gdk-pixbuf    Do not use gdk-pixbuf],
 106         [ac_cv_enable_gdk_pixbuf=$enableval], [ac_cv_enable_gdk_pixbuf=yes])
 107 AC_ARG_ENABLE(imlib,
 108         [  --disable-imlib         Do not use imlib],
 109         [ac_cv_enable_imlib=$enableval], [ac_cv_enable_imlib=yes])
 110
 111 if test "$ac_cv_enable_gdk_pixbuf" = yes; then
 112         AM_PATH_GDK_PIXBUF(0.8.0,
 113                 [AC_DEFINE(HAVE_GDK_PIXBUF)
 114                  ac_cv_enable_imlib=no], [ac_cv_enable_gdk_pixbuf=no])
 115 fi
 116 if test "$ac_cv_enable_imlib" = yes; then
 117         AM_PATH_GDK_IMLIB(1.9,
 118                 AC_DEFINE(HAVE_GDK_IMLIB), [ac_cv_enable_imlib=no])
 119 fi
 120 if test "$ac_cv_enable_gdk_pixbuf" = no -a "$ac_cv_enable_imlib" = no; then
 121         AC_MSG_WARN(*** Built-in image view will not be supported ***)
 122 fi
 123
 124 dnl GPGME is used to support OpenPGP
 125 AC_ARG_ENABLE(gpgme,
 126         [  --enable-gpgme          Enable GnuPG support using GPGME [default=no]],
 127         [ac_cv_enable_gpgme=$enableval], [ac_cv_enable_gpgme=no])
 128 AC_MSG_CHECKING([whether to use GPGME])
 129 if test $ac_cv_enable_gpgme = yes; then
 130         AC_MSG_RESULT(yes)
 131         AM_PATH_GPGME(0.2.3, AC_DEFINE(USE_GPGME), [use_gpgme=no
 132                                                     ac_cv_enable_gpgme=no])
 133 else
 134         AC_MSG_RESULT(no)
 135 fi
 136
 137 dnl Check for OpenSSL
 138 AC_ARG_ENABLE(ssl,
 139         [  --enable-ssl            Enable SSL support using OpenSSL [default=no]],
 140         [ac_cv_enable_ssl=$enableval], [ac_cv_enable_ssl=no])
 141 AC_MSG_CHECKING([whether to use OpenSSL])
 142 if test $ac_cv_enable_ssl = yes; then
 143         AC_MSG_RESULT(yes)
 144         AC_MSG_CHECKING([if openssl is available])
 145         LIBS="$LIBS -lssl -lcrypto"
 146         AC_TRY_LINK([
 147 #include <openssl/opensslv.h>
 148 ],      [ return OPENSSL_VERSION_NUMBER; ],
 149         [ AC_MSG_RESULT(yes)
 150           AC_DEFINE(USE_SSL) ],
 151         [ AC_MSG_RESULT(no)
 152           LIBS="$ac_save_LIBS"
 153           ac_cv_enable_ssl=no ])
 154 else
 155         AC_MSG_RESULT(no)
 156 fi
 157
 158 dnl Check for X-Face support
 159 AC_ARG_ENABLE(compface,
 160         [  --disable-compface      Do not use compface (X-Face)],
 161         [ac_cv_enable_compface=$enableval], [ac_cv_enable_compface=yes])
 162 if test "$ac_cv_enable_compface" = yes; then
 163         AC_CHECK_LIB(compface, uncompface,,[ac_cv_enable_compface=no])
 164 fi
 165
 166 dnl for JPilot support in addressbook
 167 dnl no check for libraries; these are dynamically loaded
 168 AC_ARG_ENABLE(jpilot,
 169         [  --enable-jpilot         Enable JPilot support [default=no]],
 170         [ac_cv_enable_jpilot=$enableval], [ac_cv_enable_jpilot=no])
 171 AC_MSG_CHECKING([whether to use JPilot])
 172 if test "$ac_cv_enable_jpilot" = yes; then
 173         AC_MSG_RESULT(yes)
 174         AC_CHECK_HEADERS(pi-args.h pi-appinfo.h pi-address.h,
 175                          [ AC_DEFINE(USE_JPILOT) ],
 176                          [ ac_cv_enable_jpilot=no ])
 177         if test "$ac_cv_enable_jpilot" = no; then
 178                 AC_CHECK_HEADERS(libpisock/pi-args.h libpisock/pi-appinfo.h libpisock/pi-address.h,
 179                                  [ ac_cv_enable_jpilot=yes
 180                                    AC_DEFINE(USE_JPILOT) ])
 181         fi
 182         AC_MSG_CHECKING([whether jpilot is available])
 183         AC_MSG_RESULT($ac_cv_enable_jpilot)
 184
 185         if test "$ac_cv_enable_jpilot" = yes; then
 186                 LIBS="$LIBS -lpisock"
 187         fi
 188 else
 189         AC_MSG_RESULT(no)
 190 fi
 191
 192 dnl for LDAP support in addressbook
 193 dnl no check for libraries; dynamically loaded
 194 AC_ARG_ENABLE(ldap,
 195         [  --enable-ldap           Enable LDAP support [default=no]],
 196         [ac_cv_enable_ldap=$enableval], [ac_cv_enable_ldap=no])
 197 AC_MSG_CHECKING([whether to use LDAP])
 198 if test "$ac_cv_enable_ldap" = yes; then
 199         AC_MSG_RESULT(yes)
 200         AC_CHECK_HEADERS(ldap.h lber.h pthread.h,
 201                          [ AC_DEFINE(USE_LDAP) ],
 202                          [ ac_cv_enable_ldap=no ])
 203         AC_MSG_CHECKING([whether ldap is available])
 204         AC_MSG_RESULT($ac_cv_enable_ldap)
 205
 206         if test "$ac_cv_enable_ldap" = yes; then
 207                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
 208                 LIBS="$LIBS -lldap -llber -lpthread -lresolv `$GLIB_CONFIG --libs gthread`"
 209         fi
 210 else
 211         AC_MSG_RESULT(no)
 212 fi
 213
 214 dnl Check for libjconv
 215 AC_ARG_ENABLE(jconv,
 216         [  --disable-jconv         Do not use libjconv],
 217         [ac_cv_enable_jconv=$enableval], [ac_cv_enable_jconv=yes])
 218 if test "$ac_cv_enable_jconv" = yes; then
 219         AC_CHECK_LIB(jconv, jconv_alloc_conv,,[ac_cv_enable_jconv=no])
 220 fi
 221
 222 AC_CHECK_LIB(xpg4, setlocale)
 223 dnl AC_CHECK_LIB(kcc, KCC_filter)
 224
 225 dnl for GThread support (currently disabled)
 226 dnl AC_ARG_ENABLE(threads,
 227 dnl     [  --enable-threads        Enable multithread support [default=no]],
 228 dnl     [use_threads=$enableval], [use_threads=no])
 229
 230 AC_MSG_CHECKING([whether to use threads])
 231 if test x"$use_threads" = xyes ; then
 232         AC_MSG_RESULT(yes)
 233         if test ! -z `$GLIB_CONFIG --help 2>&1 |grep 'gthread'` ; then
 234                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
 235                 LIBS="$LIBS `$GLIB_CONFIG --libs gthread`"
 236                 AC_DEFINE(USE_THREADS)
 237         else
 238                 AC_MSG_ERROR([Sylpheed requires GThread from GLib to use threading.])
 239         fi
 240 else
 241         AC_MSG_RESULT(no)
 242 fi
 243
 244 dnl check for IPv6 option
 245 AC_ARG_ENABLE(ipv6,
 246         [  --enable-ipv6           Enable IPv6 support [default=no]],
 247         [ac_cv_enable_ipv6=$enableval], [ac_cv_enable_ipv6=no])
 248
 249 dnl automated checks for IPv6 support.
 250 AC_MSG_CHECKING([whether to use IPv6])
 251 if test x"$ac_cv_enable_ipv6" = xyes; then
 252         AC_MSG_RESULT(yes)
 253         AC_MSG_CHECKING([for IPv6 support])
 254         AC_CACHE_VAL(ac_cv_ipv6,[
 255                 AC_TRY_COMPILE([#define INET6
 256                                 #include <sys/types.h>
 257                                 #include <netinet/in.h>],
 258                         [int x = IPPROTO_IPV6; struct in6_addr a;],
 259                         ac_cv_ipv6=yes, ac_cv_ipv6=no)
 260         ])
 261         AC_MSG_RESULT($ac_cv_ipv6)
 262         if test $ac_cv_ipv6 = yes; then
 263                 AC_DEFINE(INET6)
 264         else
 265                 AC_MSG_WARN(*** IPv6 will not be supported ***)
 266                 ac_cv_enable_ipv6=no
 267         fi
 268 else
 269         AC_MSG_RESULT(no)
 270 fi
 271
 272 dnl PSPELL is user for spell checking
 273 AC_ARG_ENABLE(pspell,
 274         [  --enable-pspell           Enable pspell support [default=no]],
 275         [ac_cv_enable_pspell=$enableval], [ac_cv_enable_pspell=no])
 276 AC_MSG_CHECKING([whether to use pspell])
 277 if test $ac_cv_enable_pspell = yes; then
 278         AC_MSG_RESULT(yes)
 279         AM_PATH_PSPELL(.12.2, AC_DEFINE(USE_PSPELL), [use_pspell=no
 280                                                     ac_cv_enable_pspell=no])
 281         pspell_path="`pspell-config --pkgdatadir`"
 282         AC_DEFINE_UNQUOTED(PSPELL_PATH, "${pspell_path}/")
 283 else
 284         AC_MSG_RESULT(no)
 285 fi
 286
 287 dnl check if gdk / gtk was compiled with USE_XIM
 288 AC_MSG_CHECKING([whether GTK was compiled with XIM support])
 289 CFLAGS_SAVE="$CFLAGS"
 290 LDFLAGS_SAVE="$LDFLAGS"
 291 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags` `gtk-config --cflags`"
 292 LDFLAGS="$LIBS `$GLIB_CONFIG --libs` `gtk-config --libs`"
 293 AC_CACHE_VAL(ac_cv_use_gtkgdk_xim, [
 294         AC_TRY_COMPILE([#include <gtk/gtk.h>
 295                         #include <gdk/gdk.h>],
 296                         [extern gint gdk_im_open(void); gdk_im_open();],
 297                          ac_cv_use_gtkgdk_xim=yes, ac_cv_use_gtkgdk_xim=no)
 298         ])
 299 AC_MSG_RESULT($ac_cv_use_gtkgdk_xim)
 300 if test $ac_cv_use_gtkgdk_xim = yes; then
 301         AC_DEFINE(USE_GTKGDK_XIM)
 302 fi
 303 CFLAGS="$CFLAGS_SAVE"
 304 LDFLAGS="$LDFLAGS_SAVE"
 305
 306
 307 dnl Checks for header files.
 308 AC_HEADER_DIRENT
 309 AC_HEADER_STDC
 310 AC_HEADER_SYS_WAIT
 311 AC_CHECK_HEADERS(fcntl.h sys/file.h unistd.h paths.h \
 312                  sys/param.h sys/utsname.h \
 313                  wchar.h wctype.h)
 314
 315 dnl Checks for typedefs, structures, and compiler characteristics.
 316 AC_C_CONST
 317 AC_TYPE_OFF_T
 318 AC_TYPE_PID_T
 319 AC_TYPE_SIZE_T
 320 AC_STRUCT_TM
 321
 322 dnl AC_CHECK_TYPE(wint_t, unsigned int) does not work because wint_t
 323 dnl may be defined only in wchar.h (this happens with gcc-2.96).
 324 dnl So we need to use this extended macro.
 325 SYLPHEED_CHECK_TYPE(wint_t, unsigned int,
 326 [
 327 #if HAVE_WCHAR_H
 328 #include <wchar.h>
 329 #endif
 330 ])
 331
 332 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
 333 AC_CHECK_SIZEOF(unsigned short, 2)
 334 AC_CHECK_SIZEOF(unsigned int, 4)
 335 AC_CHECK_SIZEOF(unsigned long, 4)
 336
 337 dnl Checks for library functions.
 338 AC_FUNC_ALLOCA
 339 AC_CHECK_FUNCS(gethostname mkdir mktime socket strstr \
 340                wcsstr wcswcs iswalnum iswspace towlower \
 341                wcslen wcscpy wcsncpy \
 342                uname flock lockf inet_aton inet_addr \
 343                fchmod mkstemp)
 344
 345 AC_OUTPUT([
 346 Makefile
 347 sylpheed.spec
 348 intl/Makefile
 349 ac/Makefile
 350 faq/Makefile
 351 faq/en/Makefile
 352 faq/es/Makefile
 353 faq/fr/Makefile
 354 po/Makefile.in
 355 libkcc/Makefile
 356 src/version.h
 357 src/Makefile
 358 manual/Makefile
 359 manual/en/Makefile
 360 manual/ja/Makefile
 361 tools/Makefile
 362 ])
 363
 364 dnl Output the configuration summary
 365 echo ""
 366 echo "$PACKAGE $VERSION"
 367 echo ""
 368 echo "gdk-pixbuf : $ac_cv_enable_gdk_pixbuf"
 369 echo "gdk_imlib  : $ac_cv_enable_imlib"
 370 echo "GPGME      : $ac_cv_enable_gpgme"
 371 echo "JPilot     : $ac_cv_enable_jpilot"
 372 echo "LDAP       : $ac_cv_enable_ldap"
 373 echo "OpenSSL    : $ac_cv_enable_ssl"
 374 echo "compface   : $ac_cv_enable_compface"
 375 echo "libjconv   : $ac_cv_enable_jconv"
 376 echo "IPv6       : $ac_cv_enable_ipv6"
 377 echo "Pspell     : $ac_cv_enable_pspell"
 378 echo ""
 379 echo "The binary will be installed in $prefix/bin"
 380 echo ""
 381 echo "Configure finished, type 'make' to build."