add 'Selective download'
[claws.git] / configure.in
1 dnl Process this file with autoconf to produce a configure script.
2 AC_INIT(src/main.c)
3 PACKAGE=sylpheed
4
5 dnl version number
6 MAJOR_VERSION=0
7 MINOR_VERSION=7
8 MICRO_VERSION=2
9 INTERFACE_AGE=0
10 BINARY_AGE=0
11 EXTRA_VERSION=claws6
12 VERSION=$MAJOR_VERSION.$MINOR_VERSION.$MICRO_VERSION$EXTRA_VERSION
13
14 dnl set $target
15 AC_CANONICAL_SYSTEM
16
17 dnl
18 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
19 dnl AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
20 dnl AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
21 AC_SUBST(PACKAGE)
22 AC_SUBST(VERSION)
23
24 dnl GNOME installed?
25 AC_PATH_PROG(GNOME_CONFIG, gnome-config, no)
26 if test "$GNOME_CONFIG" != no; then
27         gnomedir="`gnome-config --prefix`"
28         AC_SUBST(gnomedir)
29 fi
30 AM_CONDITIONAL(SYLPHEED_GNOME, test -d "$gnomedir")
31
32 dnl Claws version
33 AC_DEFINE(CLAWS, 1)
34
35 dnl libtool versioning
36 LT_RELEASE=$MAJOR_VERSION.$MINOR_VERSION
37 LT_CURRENT=`expr $MICRO_VERSION - $INTERFACE_AGE`
38 LT_REVISION=$INTERFACE_AGE
39 LT_AGE=`expr $BINARY_AGE - $INTERFACE_AGE`
40 AC_SUBST(LT_RELEASE)
41 AC_SUBST(LT_CURRENT)
42 AC_SUBST(LT_REVISION)
43 AC_SUBST(LT_AGE)
44
45 dnl Specify a header configuration file
46 AM_CONFIG_HEADER(config.h)
47
48 AM_MAINTAINER_MODE
49
50 dnl Checks for programs.
51 AC_ARG_PROGRAM
52 AC_PROG_CC
53 AC_ISC_POSIX
54 AM_PROG_CC_STDC
55 AC_PROG_INSTALL
56 AC_PROG_LN_S
57 AC_PROG_MAKE_SET
58 AC_PROG_CPP
59 dnl AC_PROG_RANLIB
60 AM_PROG_LEX
61 AC_PROG_YACC
62 AM_PROG_LIBTOOL
63
64 SYLPHEED_ACLOCAL_INCLUDE(ac)
65
66 case "$target" in
67 *-darwin*)
68         CFLAGS="$CFLAGS -traditional-cpp -fno-common"
69         ;;
70 esac
71
72 dnl for gettext
73 ALL_LINGUAS="cs de el es fr hr it ja ko nl pl pt_BR ru sv"
74 AM_GNU_GETTEXT
75 dnl AC_CHECK_FUNC(gettext, AC_CHECK_LIB(intl, gettext))
76 localedir='${prefix}/${DATADIRNAME}/locale'
77 AC_SUBST(localedir)
78
79 manualdir='${prefix}/${DATADIRNAME}/${PACKAGE}/manual'
80 AC_SUBST(manualdir)
81
82 dnl Set PACKAGE_DATA_DIR in config.h.
83 if test "x${datadir}" = 'x${prefix}/share'; then
84   if test "x${prefix}" = "xNONE"; then
85     AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${ac_default_prefix}/share/${PACKAGE}")
86   else
87     AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${prefix}/share/${PACKAGE}")
88   fi
89 else
90   AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${datadir}/${PACKAGE}")
91 fi
92
93 dnl Checks for libraries.
94 AM_PATH_GLIB(1.2.6,,
95         AC_MSG_ERROR(Test for GLIB failed. See the file 'INSTALL' for help.),
96         gthread)
97 AM_PATH_GTK(1.2.6,,
98         AC_MSG_ERROR(Test for GTK failed. See the file 'INSTALL' for help.))
99
100 dnl Check for built-in image view support
101 AC_ARG_ENABLE(gdk-pixbuf,
102         [  --disable-gdk-pixbuf    Do not use gdk-pixbuf],
103         [ac_cv_enable_gdk_pixbuf=$enableval], [ac_cv_enable_gdk_pixbuf=yes])
104 AC_ARG_ENABLE(imlib,
105         [  --disable-imlib         Do not use imlib],
106         [ac_cv_enable_imlib=$enableval], [ac_cv_enable_imlib=yes])
107
108 if test "$ac_cv_enable_gdk_pixbuf" = yes; then
109         AM_PATH_GDK_PIXBUF(0.8.0,
110                 [AC_DEFINE(HAVE_GDK_PIXBUF)
111                  ac_cv_enable_imlib=no], [ac_cv_enable_gdk_pixbuf=no])
112 fi
113 if test "$ac_cv_enable_imlib" = yes; then
114         AM_PATH_GDK_IMLIB(1.9,
115                 AC_DEFINE(HAVE_GDK_IMLIB), [ac_cv_enable_imlib=no])
116 fi
117 if test "$ac_cv_enable_gdk_pixbuf" = no -a "$ac_cv_enable_imlib" = no; then
118         AC_MSG_WARN(*** Built-in image view will not be supported ***)
119 fi
120
121 dnl GPGME is used to support OpenPGP 
122 AC_ARG_ENABLE(gpgme,
123         [  --enable-gpgme          Enable GnuPG support using GPGME [default=no]],
124         [ac_cv_enable_gpgme=$enableval], [ac_cv_enable_gpgme=no])
125 AC_MSG_CHECKING([whether to use GPGME])
126 if test $ac_cv_enable_gpgme = yes; then
127         AC_MSG_RESULT(yes)
128         AM_PATH_GPGME(0.2.3, AC_DEFINE(USE_GPGME), [use_gpgme=no
129                                                     ac_cv_enable_gpgme=no])
130 else
131         AC_MSG_RESULT(no)
132 fi
133
134 dnl Check for OpenSSL
135 AC_ARG_ENABLE(ssl,
136         [  --enable-ssl            Enable SSL support using OpenSSL [default=no]],
137         [ac_cv_enable_ssl=$enableval], [ac_cv_enable_ssl=no])
138 AC_MSG_CHECKING([whether to use OpenSSL])
139 if test $ac_cv_enable_ssl = yes; then
140         AC_MSG_RESULT(yes)
141         AC_MSG_CHECKING([if openssl is available])
142         LIBS="$LIBS -lssl -lcrypto"
143         AC_TRY_LINK([
144 #include <openssl/opensslv.h>
145 ],      [ return OPENSSL_VERSION_NUMBER; ],
146         [ AC_MSG_RESULT(yes)
147           AC_DEFINE(USE_SSL) ],
148         [ AC_MSG_RESULT(no)
149           LIBS="$ac_save_LIBS"
150           ac_cv_enable_ssl=no ])
151 else
152         AC_MSG_RESULT(no)
153 fi
154
155 dnl Check for X-Face support
156 AC_ARG_ENABLE(compface,
157         [  --disable-compface      Do not use compface (X-Face)],
158         [ac_cv_enable_compface=$enableval], [ac_cv_enable_compface=yes])
159 if test "$ac_cv_enable_compface" = yes; then
160         AC_CHECK_LIB(compface, uncompface,,[ac_cv_enable_compface=no])
161 fi
162
163 dnl for JPilot support in addressbook
164 dnl no check for libraries; these are dynamically loaded
165 AC_ARG_ENABLE(jpilot,
166         [  --enable-jpilot         Enable JPilot support [default=no]],
167         [ac_cv_enable_jpilot=$enableval], [ac_cv_enable_jpilot=no])
168 AC_MSG_CHECKING([whether to use JPilot])
169 if test "$ac_cv_enable_jpilot" = yes; then
170         AC_MSG_RESULT(yes)
171         AC_CHECK_HEADERS(pi-args.h pi-appinfo.h pi-address.h,
172                          [ AC_DEFINE(USE_JPILOT) ],
173                          [ ac_cv_enable_jpilot=no ])
174         if test "$ac_cv_enable_jpilot" = no; then
175                 AC_CHECK_HEADERS(libpisock/pi-args.h libpisock/pi-appinfo.h libpisock/pi-address.h,
176                                  [ ac_cv_enable_jpilot=yes
177                                    AC_DEFINE(USE_JPILOT) ])
178         fi
179         AC_MSG_CHECKING([whether jpilot is available])
180         AC_MSG_RESULT($ac_cv_enable_jpilot)
181
182         if test "$ac_cv_enable_jpilot" = yes; then
183                 LIBS="$LIBS -lpisock"
184         fi
185 else
186         AC_MSG_RESULT(no)
187 fi
188
189 dnl for LDAP support in addressbook
190 dnl no check for libraries; dynamically loaded
191 AC_ARG_ENABLE(ldap,
192         [  --enable-ldap           Enable LDAP support [default=no]],
193         [ac_cv_enable_ldap=$enableval], [ac_cv_enable_ldap=no])
194 AC_MSG_CHECKING([whether to use LDAP])
195 if test "$ac_cv_enable_ldap" = yes; then
196         AC_MSG_RESULT(yes)
197         AC_CHECK_HEADERS(ldap.h lber.h pthread.h,
198                          [ AC_DEFINE(USE_LDAP) ],
199                          [ ac_cv_enable_ldap=no ])
200         AC_MSG_CHECKING([whether ldap is available])
201         AC_MSG_RESULT($ac_cv_enable_ldap)
202
203         if test "$ac_cv_enable_ldap" = yes; then
204                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
205                 LIBS="$LIBS -lldap -llber -lpthread -lresolv `$GLIB_CONFIG --libs gthread`"
206         fi
207 else
208         AC_MSG_RESULT(no)
209 fi
210
211 dnl Check for libjconv
212 AC_ARG_ENABLE(jconv,
213         [  --disable-jconv         Do not use libjconv],
214         [ac_cv_enable_jconv=$enableval], [ac_cv_enable_jconv=yes])
215 if test "$ac_cv_enable_jconv" = yes; then
216         AC_CHECK_LIB(jconv, jconv_alloc_conv,,[ac_cv_enable_jconv=no])
217 fi
218
219 AC_CHECK_LIB(xpg4, setlocale)
220 dnl AC_CHECK_LIB(kcc, KCC_filter)
221
222 dnl for GThread support (currently disabled)
223 dnl AC_ARG_ENABLE(threads,
224 dnl     [  --enable-threads        Enable multithread support [default=no]],
225 dnl     [use_threads=$enableval], [use_threads=no])
226
227 AC_MSG_CHECKING([whether to use threads])
228 if test x"$use_threads" = xyes ; then
229         AC_MSG_RESULT(yes)
230         if test ! -z `$GLIB_CONFIG --help 2>&1 |grep 'gthread'` ; then
231                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
232                 LIBS="$LIBS `$GLIB_CONFIG --libs gthread`"
233                 AC_DEFINE(USE_THREADS)
234         else
235                 AC_MSG_ERROR([Sylpheed requires GThread from GLib to use threading.])
236         fi
237 else
238         AC_MSG_RESULT(no)
239 fi
240
241 dnl check for IPv6 option
242 AC_ARG_ENABLE(ipv6,
243         [  --enable-ipv6           Enable IPv6 support [default=no]],
244         [ac_cv_enable_ipv6=$enableval], [ac_cv_enable_ipv6=no])
245
246 dnl automated checks for IPv6 support.
247 AC_MSG_CHECKING([whether to use IPv6])
248 if test x"$ac_cv_enable_ipv6" = xyes; then
249         AC_MSG_RESULT(yes)
250         AC_MSG_CHECKING([for IPv6 support])
251         AC_CACHE_VAL(ac_cv_ipv6,[
252                 AC_TRY_COMPILE([#define INET6
253                                 #include <sys/types.h>
254                                 #include <netinet/in.h>],
255                         [int x = IPPROTO_IPV6; struct in6_addr a;],
256                         ac_cv_ipv6=yes, ac_cv_ipv6=no)
257         ])
258         AC_MSG_RESULT($ac_cv_ipv6)
259         if test $ac_cv_ipv6 = yes; then
260                 AC_DEFINE(INET6)
261         else
262                 AC_MSG_WARN(*** IPv6 will not be supported ***)
263                 ac_cv_enable_ipv6=no
264         fi
265 else
266         AC_MSG_RESULT(no)
267 fi
268
269 dnl PSPELL is user for spell checking
270 AC_ARG_ENABLE(pspell,
271         [  --enable-pspell           Enable pspell support [default=no]],
272         [ac_cv_enable_pspell=$enableval], [ac_cv_enable_pspell=no])
273 AC_MSG_CHECKING([whether to use pspell])
274 if test $ac_cv_enable_pspell = yes; then
275         AC_MSG_RESULT(yes)
276         AM_PATH_PSPELL(.12.2, AC_DEFINE(USE_PSPELL), [use_pspell=no
277                                                     ac_cv_enable_pspell=no])
278         pspell_path="`pspell-config --pkgdatadir`"
279         AC_DEFINE_UNQUOTED(PSPELL_PATH, "${pspell_path}/")
280 else
281         AC_MSG_RESULT(no)
282 fi
283
284 dnl check if gdk / gtk was compiled with USE_XIM
285 AC_MSG_CHECKING([whether GTK was compiled with XIM support])
286 CFLAGS_SAVE="$CFLAGS"
287 LDFLAGS_SAVE="$LDFLAGS"
288 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags` `gtk-config --cflags`"
289 LDFLAGS="$LIBS `$GLIB_CONFIG --libs` `gtk-config --libs`"
290 AC_CACHE_VAL(ac_cv_use_gtkgdk_xim, [
291         AC_TRY_COMPILE([#include <gtk/gtk.h>
292                         #include <gdk/gdk.h>],
293                         [extern gint gdk_im_open(void); gdk_im_open();],
294                          ac_cv_use_gtkgdk_xim=yes, ac_cv_use_gtkgdk_xim=no)
295         ])
296 AC_MSG_RESULT($ac_cv_use_gtkgdk_xim)
297 if test $ac_cv_use_gtkgdk_xim = yes; then
298         AC_DEFINE(USE_GTKGDK_XIM)
299 fi
300 CFLAGS="$CFLAGS_SAVE"
301 LDFLAGS="$LDFLAGS_SAVE"
302
303
304 dnl Checks for header files.
305 AC_HEADER_DIRENT
306 AC_HEADER_STDC
307 AC_HEADER_SYS_WAIT
308 AC_CHECK_HEADERS(fcntl.h sys/file.h unistd.h paths.h \
309                  sys/param.h sys/utsname.h \
310                  wchar.h wctype.h)
311
312 dnl Checks for typedefs, structures, and compiler characteristics.
313 AC_C_CONST
314 AC_TYPE_OFF_T
315 AC_TYPE_PID_T
316 AC_TYPE_SIZE_T
317 AC_STRUCT_TM
318
319 dnl AC_CHECK_TYPE(wint_t, unsigned int) does not work because wint_t
320 dnl may be defined only in wchar.h (this happens with gcc-2.96).
321 dnl So we need to use this extended macro.
322 SYLPHEED_CHECK_TYPE(wint_t, unsigned int,
323 [
324 #if HAVE_WCHAR_H
325 #include <wchar.h>
326 #endif
327 ])
328
329 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
330 AC_CHECK_SIZEOF(unsigned short, 2)
331 AC_CHECK_SIZEOF(unsigned int, 4)
332 AC_CHECK_SIZEOF(unsigned long, 4)
333
334 dnl Checks for library functions.
335 AC_FUNC_ALLOCA
336 AC_CHECK_FUNCS(gethostname mkdir mktime socket strstr \
337                wcsstr wcswcs iswalnum iswspace towlower \
338                wcslen wcscpy wcsncpy \
339                uname flock lockf inet_aton inet_addr \
340                fchmod mkstemp)
341
342 AC_OUTPUT([
343 Makefile
344 sylpheed.spec
345 intl/Makefile
346 ac/Makefile
347 po/Makefile.in
348 libkcc/Makefile
349 src/version.h
350 src/Makefile
351 manual/Makefile
352 manual/en/Makefile
353 manual/ja/Makefile
354 tools/Makefile
355 ])
356
357 dnl Output the configuration summary
358 echo ""
359 echo "$PACKAGE $VERSION"
360 echo ""
361 echo "gdk-pixbuf : $ac_cv_enable_gdk_pixbuf"
362 echo "gdk_imlib  : $ac_cv_enable_imlib"
363 echo "GPGME      : $ac_cv_enable_gpgme"
364 echo "JPilot     : $ac_cv_enable_jpilot"
365 echo "LDAP       : $ac_cv_enable_ldap"
366 echo "OpenSSL    : $ac_cv_enable_ssl"
367 echo "compface   : $ac_cv_enable_compface"
368 echo "libjconv   : $ac_cv_enable_jconv"
369 echo "IPv6       : $ac_cv_enable_ipv6"
370 echo "Pspell     : $ac_cv_enable_pspell"
371 echo ""
372 echo "The binary will be installed in $prefix/bin"
373 echo ""
374 echo "Configure finished, type 'make' to build."