configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.50)
   3 AC_INIT(src/main.c)
   4 AC_CONFIG_AUX_DIR(config)
   5
   6 PACKAGE=sylpheed
   7
   8 dnl version number
   9 MAJOR_VERSION=0
  10 MINOR_VERSION=8
  11 MICRO_VERSION=6
  12 INTERFACE_AGE=0
  13 BINARY_AGE=0
  14 EXTRA_VERSION=claws125
  15 VERSION=$MAJOR_VERSION.$MINOR_VERSION.$MICRO_VERSION$EXTRA_VERSION
  16
  17 dnl set $target
  18 AC_CANONICAL_SYSTEM
  19
  20 dnl
  21 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  22 dnl AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
  23 dnl AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
  24 AC_SUBST(PACKAGE)
  25 AC_SUBST(VERSION)
  26
  27 dnl GNOME installed?
  28 AC_PATH_PROG(GNOME_CONFIG, gnome-config, no)
  29 if test "$GNOME_CONFIG" != no; then
  30         gnomedir="`gnome-config --prefix`"
  31         AC_SUBST(gnomedir)
  32 fi
  33 AM_CONDITIONAL(SYLPHEED_GNOME, test -d "$gnomedir")
  34
  35 dnl Claws version
  36 AC_DEFINE(CLAWS, 1, Compiling Claws branch of sylpheed)
  37
  38 dnl libtool versioning
  39 LT_RELEASE=$MAJOR_VERSION.$MINOR_VERSION
  40 LT_CURRENT=`expr $MICRO_VERSION - $INTERFACE_AGE`
  41 LT_REVISION=$INTERFACE_AGE
  42 LT_AGE=`expr $BINARY_AGE - $INTERFACE_AGE`
  43 AC_SUBST(LT_RELEASE)
  44 AC_SUBST(LT_CURRENT)
  45 AC_SUBST(LT_REVISION)
  46 AC_SUBST(LT_AGE)
  47
  48 dnl Specify a header configuration file
  49 AM_CONFIG_HEADER(config.h)
  50
  51 AM_MAINTAINER_MODE
  52
  53 dnl Checks for programs.
  54 dnl AC_ARG_PROGRAM
  55 AC_PROG_CC
  56 AC_ISC_POSIX
  57 AM_PROG_CC_STDC
  58 AC_PROG_INSTALL
  59 AC_PROG_LN_S
  60 AC_PROG_MAKE_SET
  61 AC_PROG_CPP
  62 dnl AC_PROG_RANLIB
  63 AM_PROG_LEX
  64 AC_PROG_YACC
  65 AM_PROG_LIBTOOL
  66
  67 SYLPHEED_ACLOCAL_INCLUDE(ac)
  68
  69 case "$target" in
  70 *-darwin*)
  71         CFLAGS="$CFLAGS -traditional-cpp -fno-common"
  72         ;;
  73 esac
  74
  75 dnl for gettext
  76 ALL_LINGUAS="bg cs de el en_GB es fr hr hu it ja ko nl pl pt_BR ru sr sv"
  77 AM_GNU_GETTEXT
  78 dnl AC_CHECK_FUNC(gettext, AC_CHECK_LIB(intl, gettext))
  79 localedir='${prefix}/${DATADIRNAME}/locale'
  80 AC_SUBST(localedir)
  81
  82 manualdir='${prefix}/${DATADIRNAME}/${PACKAGE}/manual'
  83 AC_SUBST(manualdir)
  84 faqdir='${prefix}/${DATADIRNAME}/${PACKAGE}/faq'
  85 AC_SUBST(faqdir)
  86
  87 dnl Set PACKAGE_DATA_DIR in config.h.
  88 if test "x${datadir}" = 'x${prefix}/share'; then
  89   if test "x${prefix}" = "xNONE"; then
  90     AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${ac_default_prefix}/share/${PACKAGE}", PACKAGE_DATA_DIR)
  91   else
  92     AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${prefix}/share/${PACKAGE}", PACKAGE_DATA_DIR)
  93   fi
  94 else
  95   AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${datadir}/${PACKAGE}", PACKAGE_DATA_DIR)
  96 fi
  97
  98 dnl Checks for libraries.
  99 AM_PATH_GLIB(1.2.6,,
 100         AC_MSG_ERROR(Test for GLIB failed. See the file 'INSTALL' for help.),
 101         gthread)
 102 AM_PATH_GTK(1.2.6,,
 103         AC_MSG_ERROR(Test for GTK failed. See the file 'INSTALL' for help.))
 104
 105 dnl check if gdk / gtk was compiled with USE_XIM
 106 AC_MSG_CHECKING([whether GTK was compiled with XIM support])
 107 CFLAGS_SAVE="$CFLAGS"
 108 LDFLAGS_SAVE="$LDFLAGS"
 109 CFLAGS="$CFLAGS `$GTK_CONFIG --cflags`"
 110 LDFLAGS="$LDFLAGS `$GTK_CONFIG --libs`"
 111 AC_CACHE_VAL(ac_cv_use_xim, [
 112         AC_TRY_LINK_FUNC([gdk_ic_attr_new],
 113                          ac_cv_use_xim=yes, ac_cv_use_xim=no)
 114 ])
 115 AC_MSG_RESULT($ac_cv_use_xim)
 116 if test $ac_cv_use_xim = yes; then
 117         AC_DEFINE(USE_XIM, 1, Whether GTK was compiled with XIM support or not)
 118 fi
 119 CFLAGS="$CFLAGS_SAVE"
 120 LDFLAGS="$LDFLAGS_SAVE"
 121
 122 dnl Check for built-in image view support
 123 AC_ARG_ENABLE(gdk-pixbuf,
 124         [  --disable-gdk-pixbuf    Do not use gdk-pixbuf],
 125         [ac_cv_enable_gdk_pixbuf=$enableval], [ac_cv_enable_gdk_pixbuf=yes])
 126 AC_ARG_ENABLE(imlib,
 127         [  --disable-imlib         Do not use imlib],
 128         [ac_cv_enable_imlib=$enableval], [ac_cv_enable_imlib=yes])
 129
 130 if test "$ac_cv_enable_gdk_pixbuf" = yes; then
 131         AM_PATH_GDK_PIXBUF(0.8.0,
 132                 [AC_DEFINE(HAVE_GDK_PIXBUF, 1, Define if you use gdk-pixbuf to support image view)
 133                  ac_cv_enable_imlib=no], [ac_cv_enable_gdk_pixbuf=no])
 134 fi
 135 if test "$ac_cv_enable_imlib" = yes; then
 136         AM_PATH_GDK_IMLIB(1.9,
 137                 AC_DEFINE(HAVE_GDK_IMLIB, 1, Define if you use gdk_imlib to support image view),
 138                 [ac_cv_enable_imlib=no])
 139 fi
 140 if test "$ac_cv_enable_gdk_pixbuf" = no -a "$ac_cv_enable_imlib" = no; then
 141         AC_MSG_WARN(*** Built-in image view will not be supported ***)
 142 fi
 143
 144 dnl GPGME is used to support OpenPGP
 145 AC_ARG_ENABLE(gpgme,
 146         [  --enable-gpgme          Enable GnuPG support using GPGME [default=no]],
 147         [ac_cv_enable_gpgme=$enableval], [ac_cv_enable_gpgme=no])
 148 AC_MSG_CHECKING([whether to use GPGME])
 149 if test $ac_cv_enable_gpgme = yes; then
 150         AC_MSG_RESULT(yes)
 151         AM_PATH_GPGME(0.3.10, AC_DEFINE(USE_GPGME, 1, Define if you use GPGME to support OpenPGP.),
 152                       [use_gpgme=no
 153                        ac_cv_enable_gpgme=no])
 154 else
 155         AC_MSG_RESULT(no)
 156 fi
 157
 158 dnl for JPilot support in addressbook
 159 dnl no check for libraries; these are dynamically loaded
 160 AC_ARG_ENABLE(jpilot,
 161         [  --enable-jpilot         Enable JPilot support [default=no]],
 162         [ac_cv_enable_jpilot=$enableval], [ac_cv_enable_jpilot=no])
 163 AC_MSG_CHECKING([whether to use JPilot])
 164 if test "$ac_cv_enable_jpilot" = yes; then
 165         AC_MSG_RESULT(yes)
 166         AC_CHECK_HEADERS(pi-args.h pi-appinfo.h pi-address.h,
 167                          [ AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ],
 168                          [ ac_cv_enable_jpilot=no ])
 169         if test "$ac_cv_enable_jpilot" = no; then
 170                 AC_CHECK_HEADERS(libpisock/pi-args.h libpisock/pi-appinfo.h libpisock/pi-address.h,
 171                                  [ ac_cv_enable_jpilot=yes
 172                                    AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ])
 173         fi
 174         AC_MSG_CHECKING([whether jpilot is available])
 175         AC_MSG_RESULT($ac_cv_enable_jpilot)
 176
 177         if test "$ac_cv_enable_jpilot" = yes; then
 178                 LIBS="$LIBS -lpisock"
 179         fi
 180 else
 181         AC_MSG_RESULT(no)
 182 fi
 183
 184 dnl for LDAP support in addressbook
 185 dnl no check for libraries; dynamically loaded
 186 AC_ARG_ENABLE(ldap,
 187         [  --enable-ldap           Enable LDAP support [default=no]],
 188         [ac_cv_enable_ldap=$enableval], [ac_cv_enable_ldap=no])
 189 AC_MSG_CHECKING([whether to use LDAP])
 190 if test "$ac_cv_enable_ldap" = yes; then
 191         AC_MSG_RESULT(yes)
 192
 193         dnl check for available libraries, and pull them in
 194         AC_CHECK_LIB(resolv, res_query, LDAP_LIBS="$LDAP_LIBS -lresolv")
 195         AC_CHECK_LIB(socket, bind, LDAP_LIBS="$LDAP_LIBS -lsocket")
 196         AC_CHECK_LIB(nsl, gethostbyaddr, LDAP_LIBS="$LDAP_LIBS -lnsl")
 197         AC_CHECK_LIB(lber, ber_get_tag, LDAP_LIBS="$LDAP_LIBS -llber",,
 198                      $LDAP_LIBS)
 199
 200         dnl we need libpthread for sylpheed ldap,  until we find
 201         dnl a better way to handle ldap requests asynchronously...
 202         AC_CHECK_LIB(pthread, pthread_create, LDAP_LIBS="$LDAP_LIBS -lpthread")
 203
 204         AC_CHECK_HEADERS(ldap.h lber.h pthread.h,
 205                          [ ac_cv_enable_ldap=yes ],
 206                          [ ac_cv_enable_ldap=no ])
 207
 208         if test "$ac_cv_enable_ldap" = yes; then
 209                 AC_CHECK_LIB(ldap, ldap_open,
 210                              [ ac_cv_enable_ldap=yes ],
 211                              [ ac_cv_enable_ldap=no ],
 212                              $LDAP_LIBS)
 213         fi
 214
 215         AC_MSG_CHECKING([whether ldap library is available])
 216         AC_MSG_RESULT($ac_cv_enable_ldap)
 217
 218         if test "$ac_cv_enable_ldap" = yes; then
 219                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
 220                 LDAP_LIBS="$LDAP_LIBS -lldap `$GLIB_CONFIG --libs gthread`"
 221                 AC_DEFINE(USE_LDAP, 1, Define if you want LDAP support in addressbook.)
 222                 AC_SUBST(LDAP_LIBS)
 223         fi
 224 else
 225         AC_MSG_RESULT(no)
 226 fi
 227
 228 dnl Check for OpenSSL
 229 AM_PATH_OPENSSL
 230
 231 dnl Check for X-Face support
 232 AC_ARG_ENABLE(compface,
 233         [  --disable-compface      Do not use compface (X-Face)],
 234         [ac_cv_enable_compface=$enableval], [ac_cv_enable_compface=yes])
 235 if test "$ac_cv_enable_compface" = yes; then
 236         AC_CHECK_LIB(compface, uncompface,,[ac_cv_enable_compface=no])
 237 fi
 238
 239 dnl Check for libjconv
 240 AC_ARG_ENABLE(jconv,
 241         [  --disable-jconv         Do not use libjconv],
 242         [ac_cv_enable_jconv=$enableval], [ac_cv_enable_jconv=yes])
 243 if test "$ac_cv_enable_jconv" = yes; then
 244         AC_CHECK_LIB(jconv, jconv_alloc_conv,,[ac_cv_enable_jconv=no])
 245 fi
 246
 247 AC_CHECK_LIB(xpg4, setlocale)
 248
 249 dnl for GThread support (currently disabled)
 250 dnl AC_ARG_ENABLE(threads,
 251 dnl     [  --enable-threads        Enable multithread support [default=no]],
 252 dnl     [use_threads=$enableval], [use_threads=no])
 253
 254 AC_MSG_CHECKING([whether to use threads])
 255 if test x"$use_threads" = xyes ; then
 256         AC_MSG_RESULT(yes)
 257         if test ! -z `$GLIB_CONFIG --help 2>&1 |grep 'gthread'` ; then
 258                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
 259                 LIBS="$LIBS `$GLIB_CONFIG --libs gthread`"
 260                 AC_DEFINE(USE_THREADS, 1, Whether to use multithread or not)
 261         else
 262                 AC_MSG_ERROR([Sylpheed requires GThread from GLib to use threading.])
 263         fi
 264 else
 265         AC_MSG_RESULT(no)
 266 fi
 267
 268 dnl check for IPv6 option
 269 AC_ARG_ENABLE(ipv6,
 270         [  --enable-ipv6           Enable IPv6 support [default=no]],
 271         [ac_cv_enable_ipv6=$enableval], [ac_cv_enable_ipv6=no])
 272
 273 dnl automated checks for IPv6 support.
 274 AC_MSG_CHECKING([whether to use IPv6])
 275 if test x"$ac_cv_enable_ipv6" = xyes; then
 276         AC_MSG_RESULT(yes)
 277         AC_MSG_CHECKING([for IPv6 support])
 278         AC_CACHE_VAL(ac_cv_ipv6,[
 279                 AC_TRY_COMPILE([#define INET6
 280                                 #include <sys/types.h>
 281                                 #include <netinet/in.h>],
 282                         [int x = IPPROTO_IPV6; struct in6_addr a;],
 283                         ac_cv_ipv6=yes, ac_cv_ipv6=no)
 284         ])
 285         AC_MSG_RESULT($ac_cv_ipv6)
 286         if test $ac_cv_ipv6 = yes; then
 287                 AC_DEFINE(INET6, 1, Define if you want IPv6 support.)
 288         else
 289                 AC_MSG_WARN(*** IPv6 will not be supported ***)
 290                 ac_cv_enable_ipv6=no
 291         fi
 292 else
 293         AC_MSG_RESULT(no)
 294 fi
 295
 296 dnl GNU/Aspell is used for spell checking
 297 AC_ARG_ENABLE(aspell,
 298         [  --enable-aspell         Enable GNU/aspell support [default=no]],
 299         [ac_cv_enable_aspell=$enableval], [ac_cv_enable_aspell=no])
 300 AC_MSG_CHECKING([whether to use GNU/aspell])
 301 if test $ac_cv_enable_aspell = yes; then
 302         AC_MSG_RESULT(yes)
 303         AM_PATH_ASPELL(0.50, AC_DEFINE(USE_ASPELL, 1, Define if you use ASPELL to support spell checking),
 304                       [use_aspell=no ac_cv_enable_aspell=no])
 305 else
 306         AC_MSG_RESULT(no)
 307 fi
 308
 309 dnl want crash dialog
 310 AC_ARG_ENABLE(crash-dialog,
 311         [  --enable-crash-dialog   Enable crash dialog [default=no]],
 312         [ac_cv_enable_crash_dialog=$enableval], [ac_cv_enable_crash_dialog=no])
 313 if test $ac_cv_enable_crash_dialog = yes; then
 314 dnl check if GDB is somewhere
 315         AC_CHECK_PROG(ac_cv_enable_crash_dialog, gdb, yes, no)
 316         AC_MSG_CHECKING([whether to use crash dialog])
 317         if test $ac_cv_enable_crash_dialog = yes; then
 318                 AC_DEFINE(CRASH_DIALOG, 1, Pop up crash dialog)
 319         fi
 320         AC_MSG_RESULT($ac_cv_enable_crash_dialog)
 321 fi
 322
 323 dnl Checks for header files.
 324 AC_HEADER_DIRENT
 325 AC_HEADER_STDC
 326 AC_HEADER_SYS_WAIT
 327 AC_CHECK_HEADERS(fcntl.h sys/file.h unistd.h paths.h \
 328                  sys/param.h sys/utsname.h sys/select.h \
 329                  wchar.h wctype.h)
 330
 331 dnl Checks for typedefs, structures, and compiler characteristics.
 332 AC_C_CONST
 333 AC_TYPE_OFF_T
 334 AC_TYPE_PID_T
 335 AC_TYPE_SIZE_T
 336 AC_STRUCT_TM
 337
 338 dnl AC_CHECK_TYPE(wint_t, unsigned int) does not work because wint_t
 339 dnl may be defined only in wchar.h (this happens with gcc-2.96).
 340 dnl So we need to use this extended macro.
 341 SYLPHEED_CHECK_TYPE(wint_t, unsigned int,
 342 [
 343 #if HAVE_WCHAR_H
 344 #include <wchar.h>
 345 #endif
 346 ], Define to `unsigned int' if <stddef.h> or <wchar.h> doesn't define.)
 347
 348 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF, Used to test for a u32 typedef)
 349 AC_CHECK_SIZEOF(unsigned short, 2)
 350 AC_CHECK_SIZEOF(unsigned int, 4)
 351 AC_CHECK_SIZEOF(unsigned long, 4)
 352
 353 dnl Checks for library functions.
 354 AC_FUNC_ALLOCA
 355 AC_CHECK_FUNCS(gethostname mkdir mktime socket strstr strchr \
 356                wcsstr wcswcs iswalnum iswspace towlower \
 357                wcslen wcscpy wcsncpy \
 358                uname flock lockf inet_aton inet_addr \
 359                fchmod mkstemp)
 360
 361 AC_OUTPUT([
 362 Makefile
 363 sylpheed.spec
 364 intl/Makefile
 365 ac/Makefile
 366 po/Makefile.in
 367 src/common/version.h
 368 src/Makefile
 369 src/common/Makefile
 370 src/gtk/Makefile
 371 faq/Makefile
 372 faq/de/Makefile
 373 faq/en/Makefile
 374 faq/es/Makefile
 375 faq/fr/Makefile
 376 faq/it/Makefile
 377 man/Makefile
 378 manual/Makefile
 379 manual/de/Makefile
 380 manual/en/Makefile
 381 manual/es/Makefile
 382 manual/fr/Makefile
 383 manual/ja/Makefile
 384 tools/Makefile
 385 config/Makefile
 386 ])
 387
 388 dnl Output the configuration summary
 389 echo ""
 390 echo "$PACKAGE $VERSION"
 391 echo ""
 392 if test "$ac_cv_enable_gdk_pixbuf" = yes; then
 393         echo "image support : yes (gdk-pixbuf)"
 394 elif test "$ac_cv_enable_imlib" = yes; then
 395         echo "image support : yes (gdk_imlib)"
 396 else
 397         echo "image support : no"
 398 fi
 399 echo "GnuPG         : $ac_cv_enable_gpgme"
 400 echo "JPilot        : $ac_cv_enable_jpilot"
 401 echo "LDAP          : $ac_cv_enable_ldap"
 402 echo "OpenSSL       : $ac_cv_enable_openssl"
 403 echo "compface      : $ac_cv_enable_compface"
 404 echo "libjconv      : $ac_cv_enable_jconv"
 405 echo "IPv6          : $ac_cv_enable_ipv6"
 406 echo "GNU/aspell    : $ac_cv_enable_aspell"
 407 echo "Crash dialog  : $ac_cv_enable_crash_dialog"
 408 echo ""
 409 echo "The binary will be installed in $prefix/bin"
 410 echo ""
 411 echo "Configure finished, type 'make' to build."