configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.50)
   3 AC_INIT(src/main.c)
   4 AC_CONFIG_AUX_DIR(config)
   5
   6 PACKAGE=sylpheed
   7
   8 dnl version number
   9 MAJOR_VERSION=0
  10 MINOR_VERSION=8
  11 MICRO_VERSION=6
  12 INTERFACE_AGE=0
  13 BINARY_AGE=0
  14 EXTRA_VERSION=claws58
  15 VERSION=$MAJOR_VERSION.$MINOR_VERSION.$MICRO_VERSION$EXTRA_VERSION
  16
  17 dnl set $target
  18 AC_CANONICAL_SYSTEM
  19
  20 dnl
  21 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  22 dnl AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
  23 dnl AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
  24 AC_SUBST(PACKAGE)
  25 AC_SUBST(VERSION)
  26
  27 dnl GNOME installed?
  28 AC_PATH_PROG(GNOME_CONFIG, gnome-config, no)
  29 if test "$GNOME_CONFIG" != no; then
  30         gnomedir="`gnome-config --prefix`"
  31         AC_SUBST(gnomedir)
  32 fi
  33 AM_CONDITIONAL(SYLPHEED_GNOME, test -d "$gnomedir")
  34
  35 dnl Claws version
  36 AC_DEFINE(CLAWS, 1, Compiling Claws branch of sylpheed)
  37
  38 dnl libtool versioning
  39 LT_RELEASE=$MAJOR_VERSION.$MINOR_VERSION
  40 LT_CURRENT=`expr $MICRO_VERSION - $INTERFACE_AGE`
  41 LT_REVISION=$INTERFACE_AGE
  42 LT_AGE=`expr $BINARY_AGE - $INTERFACE_AGE`
  43 AC_SUBST(LT_RELEASE)
  44 AC_SUBST(LT_CURRENT)
  45 AC_SUBST(LT_REVISION)
  46 AC_SUBST(LT_AGE)
  47
  48 dnl Specify a header configuration file
  49 AM_CONFIG_HEADER(config.h)
  50
  51 AM_MAINTAINER_MODE
  52
  53 dnl Checks for programs.
  54 dnl AC_ARG_PROGRAM
  55 AC_PROG_CC
  56 AC_ISC_POSIX
  57 AM_PROG_CC_STDC
  58 AC_PROG_INSTALL
  59 AC_PROG_LN_S
  60 AC_PROG_MAKE_SET
  61 AC_PROG_CPP
  62 dnl AC_PROG_RANLIB
  63 AM_PROG_LEX
  64 AC_PROG_YACC
  65 AM_PROG_LIBTOOL
  66
  67 SYLPHEED_ACLOCAL_INCLUDE(ac)
  68
  69 case "$target" in
  70 *-darwin*)
  71         CFLAGS="$CFLAGS -traditional-cpp -fno-common"
  72         ;;
  73 esac
  74
  75 dnl for gettext
  76 ALL_LINGUAS="bg cs de el en_GB es fr hr hu it ja ko nl pl pt_BR ru sr sv"
  77 AM_GNU_GETTEXT
  78 dnl AC_CHECK_FUNC(gettext, AC_CHECK_LIB(intl, gettext))
  79 localedir='${prefix}/${DATADIRNAME}/locale'
  80 AC_SUBST(localedir)
  81
  82 manualdir='${prefix}/${DATADIRNAME}/${PACKAGE}/manual'
  83 AC_SUBST(manualdir)
  84 faqdir='${prefix}/${DATADIRNAME}/${PACKAGE}/faq'
  85 AC_SUBST(faqdir)
  86
  87 dnl Set PACKAGE_DATA_DIR in config.h.
  88 if test "x${datadir}" = 'x${prefix}/share'; then
  89   if test "x${prefix}" = "xNONE"; then
  90     AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${ac_default_prefix}/share/${PACKAGE}", PACKAGE_DATA_DIR)
  91   else
  92     AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${prefix}/share/${PACKAGE}", PACKAGE_DATA_DIR)
  93   fi
  94 else
  95   AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${datadir}/${PACKAGE}", PACKAGE_DATA_DIR)
  96 fi
  97
  98 dnl Checks for libraries.
  99 AM_PATH_GLIB(1.2.6,,
 100         AC_MSG_ERROR(Test for GLIB failed. See the file 'INSTALL' for help.),
 101         gthread)
 102 AM_PATH_GTK(1.2.6,,
 103         AC_MSG_ERROR(Test for GTK failed. See the file 'INSTALL' for help.))
 104
 105 dnl check if gdk / gtk was compiled with USE_XIM
 106 AC_MSG_CHECKING([whether GTK was compiled with XIM support])
 107 CFLAGS_SAVE="$CFLAGS"
 108 LDFLAGS_SAVE="$LDFLAGS"
 109 CFLAGS="$CFLAGS `$GTK_CONFIG --cflags`"
 110 LDFLAGS="$LDFLAGS `$GTK_CONFIG --libs`"
 111 AC_CACHE_VAL(ac_cv_use_xim, [
 112         AC_TRY_LINK_FUNC([gdk_ic_attr_new],
 113                          ac_cv_use_xim=yes, ac_cv_use_xim=no)
 114 ])
 115 AC_MSG_RESULT($ac_cv_use_xim)
 116 if test $ac_cv_use_xim = yes; then
 117         AC_DEFINE(USE_XIM, 1, Whether GTK was compiled with XIM support or not)
 118 fi
 119 CFLAGS="$CFLAGS_SAVE"
 120 LDFLAGS="$LDFLAGS_SAVE"
 121
 122 dnl Check for built-in image view support
 123 AC_ARG_ENABLE(gdk-pixbuf,
 124         [  --disable-gdk-pixbuf    Do not use gdk-pixbuf],
 125         [ac_cv_enable_gdk_pixbuf=$enableval], [ac_cv_enable_gdk_pixbuf=yes])
 126 AC_ARG_ENABLE(imlib,
 127         [  --disable-imlib         Do not use imlib],
 128         [ac_cv_enable_imlib=$enableval], [ac_cv_enable_imlib=yes])
 129
 130 if test "$ac_cv_enable_gdk_pixbuf" = yes; then
 131         AM_PATH_GDK_PIXBUF(0.8.0,
 132                 [AC_DEFINE(HAVE_GDK_PIXBUF, 1, Define if you use gdk-pixbuf to support image view)
 133                  ac_cv_enable_imlib=no], [ac_cv_enable_gdk_pixbuf=no])
 134 fi
 135 if test "$ac_cv_enable_imlib" = yes; then
 136         AM_PATH_GDK_IMLIB(1.9,
 137                 AC_DEFINE(HAVE_GDK_IMLIB, 1, Define if you use gdk_imlib to support image view),
 138                 [ac_cv_enable_imlib=no])
 139 fi
 140 if test "$ac_cv_enable_gdk_pixbuf" = no -a "$ac_cv_enable_imlib" = no; then
 141         AC_MSG_WARN(*** Built-in image view will not be supported ***)
 142 fi
 143
 144 dnl GPGME is used to support OpenPGP
 145 AC_ARG_ENABLE(gpgme,
 146         [  --enable-gpgme          Enable GnuPG support using GPGME [default=no]],
 147         [ac_cv_enable_gpgme=$enableval], [ac_cv_enable_gpgme=no])
 148 AC_MSG_CHECKING([whether to use GPGME])
 149 if test $ac_cv_enable_gpgme = yes; then
 150         AC_MSG_RESULT(yes)
 151         AM_PATH_GPGME(0.3.10, AC_DEFINE(USE_GPGME, 1, Define if you use GPGME to support OpenPGP.),
 152                       [use_gpgme=no
 153                        ac_cv_enable_gpgme=no])
 154 else
 155         AC_MSG_RESULT(no)
 156 fi
 157
 158 dnl for JPilot support in addressbook
 159 dnl no check for libraries; these are dynamically loaded
 160 AC_ARG_ENABLE(jpilot,
 161         [  --enable-jpilot         Enable JPilot support [default=no]],
 162         [ac_cv_enable_jpilot=$enableval], [ac_cv_enable_jpilot=no])
 163 AC_MSG_CHECKING([whether to use JPilot])
 164 if test "$ac_cv_enable_jpilot" = yes; then
 165         AC_MSG_RESULT(yes)
 166         AC_CHECK_HEADERS(pi-args.h pi-appinfo.h pi-address.h,
 167                          [ AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ],
 168                          [ ac_cv_enable_jpilot=no ])
 169         if test "$ac_cv_enable_jpilot" = no; then
 170                 AC_CHECK_HEADERS(libpisock/pi-args.h libpisock/pi-appinfo.h libpisock/pi-address.h,
 171                                  [ ac_cv_enable_jpilot=yes
 172                                    AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ])
 173         fi
 174         AC_MSG_CHECKING([whether jpilot is available])
 175         AC_MSG_RESULT($ac_cv_enable_jpilot)
 176
 177         if test "$ac_cv_enable_jpilot" = yes; then
 178                 LIBS="$LIBS -lpisock"
 179         fi
 180 else
 181         AC_MSG_RESULT(no)
 182 fi
 183
 184 dnl for LDAP support in addressbook
 185 dnl no check for libraries; dynamically loaded
 186 AC_ARG_ENABLE(ldap,
 187         [  --enable-ldap           Enable LDAP support [default=no]],
 188         [ac_cv_enable_ldap=$enableval], [ac_cv_enable_ldap=no])
 189 AC_MSG_CHECKING([whether to use LDAP])
 190 if test "$ac_cv_enable_ldap" = yes; then
 191         AC_MSG_RESULT(yes)
 192
 193         dnl check for available libraries, and pull them in
 194         AC_CHECK_LIB(resolv, res_query, LDAP_LIBS="$LDAP_LIBS -lresolv")
 195         AC_CHECK_LIB(socket, bind, LDAP_LIBS="$LDAP_LIBS -lsocket")
 196         AC_CHECK_LIB(nsl, gethostbyaddr, LDAP_LIBS="$LDAP_LIBS -lnsl")
 197         AC_CHECK_LIB(lber, ber_get_tag, LDAP_LIBS="$LDAP_LIBS -llber",,
 198                      $LDAP_LIBS)
 199
 200         dnl we need libpthread for sylpheed ldap,  until we find
 201         dnl a better way to handle ldap requests asynchronously...
 202         AC_CHECK_LIB(pthread, pthread_create, LDAP_LIBS="$LDAP_LIBS -lpthread")
 203
 204         AC_CHECK_HEADERS(ldap.h lber.h pthread.h,
 205                          [ ac_cv_enable_ldap=yes ],
 206                          [ ac_cv_enable_ldap=no ])
 207
 208         if test "$ac_cv_enable_ldap" = yes; then
 209                 AC_CHECK_LIB(ldap, ldap_open,
 210                              [ ac_cv_enable_ldap=yes ],
 211                              [ ac_cv_enable_ldap=no ],
 212                              $LDAP_LIBS)
 213         fi
 214
 215         AC_MSG_CHECKING([whether ldap library is available])
 216         AC_MSG_RESULT($ac_cv_enable_ldap)
 217
 218         if test "$ac_cv_enable_ldap" = yes; then
 219                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
 220                 LDAP_LIBS="$LDAP_LIBS -lldap `$GLIB_CONFIG --libs gthread`"
 221                 AC_DEFINE(USE_LDAP, 1, Define if you want LDAP support in addressbook.)
 222                 AC_SUBST(LDAP_LIBS)
 223         fi
 224 else
 225         AC_MSG_RESULT(no)
 226 fi
 227
 228 dnl Check for OpenSSL
 229 AC_ARG_ENABLE(ssl,
 230         [  --enable-ssl            Enable SSL support using OpenSSL [default=no]],
 231         [ac_cv_enable_ssl=$enableval], [ac_cv_enable_ssl=no])
 232 AC_MSG_CHECKING([whether to use OpenSSL])
 233 if test $ac_cv_enable_ssl = yes; then
 234         AC_MSG_RESULT(yes)
 235         AC_MSG_CHECKING([if openssl is available])
 236         LIBS="$LIBS -lssl -lcrypto"
 237         AC_TRY_LINK([
 238 #include <openssl/opensslv.h>
 239 ],      [ return OPENSSL_VERSION_NUMBER; ],
 240         [ AC_MSG_RESULT(yes)
 241           AC_DEFINE(USE_SSL, 1, Define if you use OpenSSL to support SSL.) ],
 242         [ AC_MSG_RESULT(no)
 243           LIBS="$ac_save_LIBS"
 244           ac_cv_enable_ssl=no ])
 245 else
 246         AC_MSG_RESULT(no)
 247 fi
 248
 249 dnl Check for X-Face support
 250 AC_ARG_ENABLE(compface,
 251         [  --disable-compface      Do not use compface (X-Face)],
 252         [ac_cv_enable_compface=$enableval], [ac_cv_enable_compface=yes])
 253 if test "$ac_cv_enable_compface" = yes; then
 254         AC_CHECK_LIB(compface, uncompface,,[ac_cv_enable_compface=no])
 255 fi
 256
 257 dnl Check for libjconv
 258 AC_ARG_ENABLE(jconv,
 259         [  --disable-jconv         Do not use libjconv],
 260         [ac_cv_enable_jconv=$enableval], [ac_cv_enable_jconv=yes])
 261 if test "$ac_cv_enable_jconv" = yes; then
 262         AC_CHECK_LIB(jconv, jconv_alloc_conv,,[ac_cv_enable_jconv=no])
 263 fi
 264
 265 AC_CHECK_LIB(xpg4, setlocale)
 266
 267 dnl for GThread support (currently disabled)
 268 dnl AC_ARG_ENABLE(threads,
 269 dnl     [  --enable-threads        Enable multithread support [default=no]],
 270 dnl     [use_threads=$enableval], [use_threads=no])
 271
 272 AC_MSG_CHECKING([whether to use threads])
 273 if test x"$use_threads" = xyes ; then
 274         AC_MSG_RESULT(yes)
 275         if test ! -z `$GLIB_CONFIG --help 2>&1 |grep 'gthread'` ; then
 276                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
 277                 LIBS="$LIBS `$GLIB_CONFIG --libs gthread`"
 278                 AC_DEFINE(USE_THREADS, 1, Whether to use multithread or not)
 279         else
 280                 AC_MSG_ERROR([Sylpheed requires GThread from GLib to use threading.])
 281         fi
 282 else
 283         AC_MSG_RESULT(no)
 284 fi
 285
 286 dnl check for IPv6 option
 287 AC_ARG_ENABLE(ipv6,
 288         [  --enable-ipv6           Enable IPv6 support [default=no]],
 289         [ac_cv_enable_ipv6=$enableval], [ac_cv_enable_ipv6=no])
 290
 291 dnl automated checks for IPv6 support.
 292 AC_MSG_CHECKING([whether to use IPv6])
 293 if test x"$ac_cv_enable_ipv6" = xyes; then
 294         AC_MSG_RESULT(yes)
 295         AC_MSG_CHECKING([for IPv6 support])
 296         AC_CACHE_VAL(ac_cv_ipv6,[
 297                 AC_TRY_COMPILE([#define INET6
 298                                 #include <sys/types.h>
 299                                 #include <netinet/in.h>],
 300                         [int x = IPPROTO_IPV6; struct in6_addr a;],
 301                         ac_cv_ipv6=yes, ac_cv_ipv6=no)
 302         ])
 303         AC_MSG_RESULT($ac_cv_ipv6)
 304         if test $ac_cv_ipv6 = yes; then
 305                 AC_DEFINE(INET6, 1, Define if you want IPv6 support.)
 306         else
 307                 AC_MSG_WARN(*** IPv6 will not be supported ***)
 308                 ac_cv_enable_ipv6=no
 309         fi
 310 else
 311         AC_MSG_RESULT(no)
 312 fi
 313
 314 dnl GNU/Aspell is used for spell checking
 315 AC_ARG_ENABLE(aspell,
 316         [  --enable-aspell         Enable GNU/aspell support [default=no]],
 317         [ac_cv_enable_aspell=$enableval], [ac_cv_enable_aspell=no])
 318 AC_MSG_CHECKING([whether to use GNU/aspell])
 319 if test $ac_cv_enable_aspell = yes; then
 320         AC_MSG_RESULT(yes)
 321         AM_PATH_ASPELL(0.50, AC_DEFINE(USE_ASPELL, 1, Define if you use ASPELL to support spell checking),
 322                       [use_aspell=no ac_cv_enable_aspell=no])
 323 else
 324         AC_MSG_RESULT(no)
 325 fi
 326
 327 dnl want crash dialog
 328 AC_ARG_ENABLE(crash-dialog,
 329         [  --enable-crash-dialog   Enable crash dialog [default=no]],
 330         [ac_cv_enable_crash_dialog=$enableval], [ac_cv_enable_crash_dialog=no])
 331 if test $ac_cv_enable_crash_dialog = yes; then
 332 dnl check if GDB is somewhere
 333         AC_CHECK_PROG(ac_cv_enable_crash_dialog, gdb, yes, no)
 334         AC_MSG_CHECKING([whether to use crash dialog])
 335         if test $ac_cv_enable_crash_dialog = yes; then
 336                 AC_DEFINE(CRASH_DIALOG, 1, Pop up crash dialog)
 337         fi
 338         AC_MSG_RESULT($ac_cv_enable_crash_dialog)
 339 fi
 340
 341 dnl Checks for header files.
 342 AC_HEADER_DIRENT
 343 AC_HEADER_STDC
 344 AC_HEADER_SYS_WAIT
 345 AC_CHECK_HEADERS(fcntl.h sys/file.h unistd.h paths.h \
 346                  sys/param.h sys/utsname.h sys/select.h \
 347                  wchar.h wctype.h)
 348
 349 dnl Checks for typedefs, structures, and compiler characteristics.
 350 AC_C_CONST
 351 AC_TYPE_OFF_T
 352 AC_TYPE_PID_T
 353 AC_TYPE_SIZE_T
 354 AC_STRUCT_TM
 355
 356 dnl AC_CHECK_TYPE(wint_t, unsigned int) does not work because wint_t
 357 dnl may be defined only in wchar.h (this happens with gcc-2.96).
 358 dnl So we need to use this extended macro.
 359 SYLPHEED_CHECK_TYPE(wint_t, unsigned int,
 360 [
 361 #if HAVE_WCHAR_H
 362 #include <wchar.h>
 363 #endif
 364 ], Define to `unsigned int' if <stddef.h> or <wchar.h> doesn't define.)
 365
 366 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF, Used to test for a u32 typedef)
 367 AC_CHECK_SIZEOF(unsigned short, 2)
 368 AC_CHECK_SIZEOF(unsigned int, 4)
 369 AC_CHECK_SIZEOF(unsigned long, 4)
 370
 371 dnl Checks for library functions.
 372 AC_FUNC_ALLOCA
 373 AC_CHECK_FUNCS(gethostname mkdir mktime socket strstr strchr \
 374                wcsstr wcswcs iswalnum iswspace towlower \
 375                wcslen wcscpy wcsncpy \
 376                uname flock lockf inet_aton inet_addr \
 377                fchmod mkstemp)
 378
 379 AC_OUTPUT([
 380 Makefile
 381 sylpheed.spec
 382 intl/Makefile
 383 ac/Makefile
 384 po/Makefile.in
 385 src/version.h
 386 src/Makefile
 387 src/common/Makefile
 388 src/gtk/Makefile
 389 faq/Makefile
 390 faq/de/Makefile
 391 faq/en/Makefile
 392 faq/es/Makefile
 393 faq/fr/Makefile
 394 faq/it/Makefile
 395 man/Makefile
 396 manual/Makefile
 397 manual/de/Makefile
 398 manual/en/Makefile
 399 manual/es/Makefile
 400 manual/fr/Makefile
 401 manual/ja/Makefile
 402 tools/Makefile
 403 config/Makefile
 404 ])
 405
 406 dnl Output the configuration summary
 407 echo ""
 408 echo "$PACKAGE $VERSION"
 409 echo ""
 410 if test "$ac_cv_enable_gdk_pixbuf" = yes; then
 411         echo "image support : yes (gdk-pixbuf)"
 412 elif test "$ac_cv_enable_imlib" = yes; then
 413         echo "image support : yes (gdk_imlib)"
 414 else
 415         echo "image support : no"
 416 fi
 417 echo "GnuPG         : $ac_cv_enable_gpgme"
 418 echo "JPilot        : $ac_cv_enable_jpilot"
 419 echo "LDAP          : $ac_cv_enable_ldap"
 420 echo "OpenSSL       : $ac_cv_enable_ssl"
 421 echo "compface      : $ac_cv_enable_compface"
 422 echo "libjconv      : $ac_cv_enable_jconv"
 423 echo "IPv6          : $ac_cv_enable_ipv6"
 424 echo "GNU/aspell    : $ac_cv_enable_aspell"
 425 echo "Crash dialog  : $ac_cv_enable_crash_dialog"
 426 echo ""
 427 echo "The binary will be installed in $prefix/bin"
 428 echo ""
 429 echo "Configure finished, type 'make' to build."