update
[claws.git] / configure.in
1 dnl Process this file with autoconf to produce a configure script.
2 AC_INIT(src/main.c)
3 PACKAGE=sylpheed
4
5 dnl version number
6 MAJOR_VERSION=0
7 MINOR_VERSION=7
8 MICRO_VERSION=3
9 INTERFACE_AGE=0
10 BINARY_AGE=0
11 EXTRA_VERSION=claws3
12 VERSION=$MAJOR_VERSION.$MINOR_VERSION.$MICRO_VERSION$EXTRA_VERSION
13
14 dnl set $target
15 AC_CANONICAL_SYSTEM
16
17 dnl
18 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
19 dnl AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
20 dnl AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
21 AC_SUBST(PACKAGE)
22 AC_SUBST(VERSION)
23
24 dnl GNOME installed?
25 AC_PATH_PROG(GNOME_CONFIG, gnome-config, no)
26 if test "$GNOME_CONFIG" != no; then
27         gnomedir="`gnome-config --prefix`"
28         AC_SUBST(gnomedir)
29 fi
30 AM_CONDITIONAL(SYLPHEED_GNOME, test -d "$gnomedir")
31
32 dnl Claws version
33 AC_DEFINE(CLAWS, 1)
34
35 dnl libtool versioning
36 LT_RELEASE=$MAJOR_VERSION.$MINOR_VERSION
37 LT_CURRENT=`expr $MICRO_VERSION - $INTERFACE_AGE`
38 LT_REVISION=$INTERFACE_AGE
39 LT_AGE=`expr $BINARY_AGE - $INTERFACE_AGE`
40 AC_SUBST(LT_RELEASE)
41 AC_SUBST(LT_CURRENT)
42 AC_SUBST(LT_REVISION)
43 AC_SUBST(LT_AGE)
44
45 dnl Specify a header configuration file
46 AM_CONFIG_HEADER(config.h)
47
48 AM_MAINTAINER_MODE
49
50 dnl Checks for programs.
51 AC_ARG_PROGRAM
52 AC_PROG_CC
53 AC_ISC_POSIX
54 AM_PROG_CC_STDC
55 AC_PROG_INSTALL
56 AC_PROG_LN_S
57 AC_PROG_MAKE_SET
58 AC_PROG_CPP
59 dnl AC_PROG_RANLIB
60 AM_PROG_LEX
61 AC_PROG_YACC
62 AM_PROG_LIBTOOL
63
64 SYLPHEED_ACLOCAL_INCLUDE(ac)
65
66 case "$target" in
67 *-darwin*)
68         CFLAGS="$CFLAGS -traditional-cpp -fno-common"
69         ;;
70 esac
71
72 dnl for gettext
73 ALL_LINGUAS="cs de el es fr hr it ja ko nl pl pt_BR ru sv"
74 AM_GNU_GETTEXT
75 dnl AC_CHECK_FUNC(gettext, AC_CHECK_LIB(intl, gettext))
76 localedir='${prefix}/${DATADIRNAME}/locale'
77 AC_SUBST(localedir)
78
79 manualdir='${prefix}/${DATADIRNAME}/${PACKAGE}/manual'
80 AC_SUBST(manualdir)
81 faqdir='${prefix}/${DATADIRNAME}/${PACKAGE}/faq'
82 AC_SUBST(faqdir)
83
84 dnl Set PACKAGE_DATA_DIR in config.h.
85 if test "x${datadir}" = 'x${prefix}/share'; then
86   if test "x${prefix}" = "xNONE"; then
87     AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${ac_default_prefix}/share/${PACKAGE}")
88   else
89     AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${prefix}/share/${PACKAGE}")
90   fi
91 else
92   AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${datadir}/${PACKAGE}")
93 fi
94
95 dnl Checks for libraries.
96 AM_PATH_GLIB(1.2.6,,
97         AC_MSG_ERROR(Test for GLIB failed. See the file 'INSTALL' for help.),
98         gthread)
99 AM_PATH_GTK(1.2.6,,
100         AC_MSG_ERROR(Test for GTK failed. See the file 'INSTALL' for help.))
101
102 dnl Check for built-in image view support
103 AC_ARG_ENABLE(gdk-pixbuf,
104         [  --disable-gdk-pixbuf    Do not use gdk-pixbuf],
105         [ac_cv_enable_gdk_pixbuf=$enableval], [ac_cv_enable_gdk_pixbuf=yes])
106 AC_ARG_ENABLE(imlib,
107         [  --disable-imlib         Do not use imlib],
108         [ac_cv_enable_imlib=$enableval], [ac_cv_enable_imlib=yes])
109
110 if test "$ac_cv_enable_gdk_pixbuf" = yes; then
111         AM_PATH_GDK_PIXBUF(0.8.0,
112                 [AC_DEFINE(HAVE_GDK_PIXBUF)
113                  ac_cv_enable_imlib=no], [ac_cv_enable_gdk_pixbuf=no])
114 fi
115 if test "$ac_cv_enable_imlib" = yes; then
116         AM_PATH_GDK_IMLIB(1.9,
117                 AC_DEFINE(HAVE_GDK_IMLIB), [ac_cv_enable_imlib=no])
118 fi
119 if test "$ac_cv_enable_gdk_pixbuf" = no -a "$ac_cv_enable_imlib" = no; then
120         AC_MSG_WARN(*** Built-in image view will not be supported ***)
121 fi
122
123 dnl GPGME is used to support OpenPGP 
124 AC_ARG_ENABLE(gpgme,
125         [  --enable-gpgme          Enable GnuPG support using GPGME [default=no]],
126         [ac_cv_enable_gpgme=$enableval], [ac_cv_enable_gpgme=no])
127 AC_MSG_CHECKING([whether to use GPGME])
128 if test $ac_cv_enable_gpgme = yes; then
129         AC_MSG_RESULT(yes)
130         AM_PATH_GPGME(0.2.3, AC_DEFINE(USE_GPGME), [use_gpgme=no
131                                                     ac_cv_enable_gpgme=no])
132 else
133         AC_MSG_RESULT(no)
134 fi
135
136 dnl for JPilot support in addressbook
137 dnl no check for libraries; these are dynamically loaded
138 AC_ARG_ENABLE(jpilot,
139         [  --enable-jpilot         Enable JPilot support [default=no]],
140         [ac_cv_enable_jpilot=$enableval], [ac_cv_enable_jpilot=no])
141 AC_MSG_CHECKING([whether to use JPilot])
142 if test "$ac_cv_enable_jpilot" = yes; then
143         AC_MSG_RESULT(yes)
144         AC_CHECK_HEADERS(pi-args.h pi-appinfo.h pi-address.h,
145                          [ AC_DEFINE(USE_JPILOT) ],
146                          [ ac_cv_enable_jpilot=no ])
147         if test "$ac_cv_enable_jpilot" = no; then
148                 AC_CHECK_HEADERS(libpisock/pi-args.h libpisock/pi-appinfo.h libpisock/pi-address.h,
149                                  [ ac_cv_enable_jpilot=yes
150                                    AC_DEFINE(USE_JPILOT) ])
151         fi
152         AC_MSG_CHECKING([whether jpilot is available])
153         AC_MSG_RESULT($ac_cv_enable_jpilot)
154
155         if test "$ac_cv_enable_jpilot" = yes; then
156                 LIBS="$LIBS -lpisock"
157         fi
158 else
159         AC_MSG_RESULT(no)
160 fi
161
162 dnl for LDAP support in addressbook
163 dnl no check for libraries; dynamically loaded
164 AC_ARG_ENABLE(ldap,
165         [  --enable-ldap           Enable LDAP support [default=no]],
166         [ac_cv_enable_ldap=$enableval], [ac_cv_enable_ldap=no])
167 AC_MSG_CHECKING([whether to use LDAP])
168 if test "$ac_cv_enable_ldap" = yes; then
169         AC_MSG_RESULT(yes)
170         AC_CHECK_HEADERS(ldap.h lber.h pthread.h,
171                          [ AC_DEFINE(USE_LDAP) ],
172                          [ ac_cv_enable_ldap=no ])
173         AC_MSG_CHECKING([whether ldap is available])
174         AC_MSG_RESULT($ac_cv_enable_ldap)
175
176         if test "$ac_cv_enable_ldap" = yes; then
177                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
178                 LIBS="$LIBS -lldap -llber -lpthread -lresolv `$GLIB_CONFIG --libs gthread`"
179         fi
180 else
181         AC_MSG_RESULT(no)
182 fi
183
184 dnl Check for OpenSSL
185 AC_ARG_ENABLE(ssl,
186         [  --enable-ssl            Enable SSL support using OpenSSL [default=no]],
187         [ac_cv_enable_ssl=$enableval], [ac_cv_enable_ssl=no])
188 AC_MSG_CHECKING([whether to use OpenSSL])
189 if test $ac_cv_enable_ssl = yes; then
190         AC_MSG_RESULT(yes)
191         AC_MSG_CHECKING([if openssl is available])
192         LIBS="$LIBS -lssl -lcrypto"
193         AC_TRY_LINK([
194 #include <openssl/opensslv.h>
195 ],      [ return OPENSSL_VERSION_NUMBER; ],
196         [ AC_MSG_RESULT(yes)
197           AC_DEFINE(USE_SSL) ],
198         [ AC_MSG_RESULT(no)
199           LIBS="$ac_save_LIBS"
200           ac_cv_enable_ssl=no ])
201 else
202         AC_MSG_RESULT(no)
203 fi
204
205 dnl Check for X-Face support
206 AC_ARG_ENABLE(compface,
207         [  --disable-compface      Do not use compface (X-Face)],
208         [ac_cv_enable_compface=$enableval], [ac_cv_enable_compface=yes])
209 if test "$ac_cv_enable_compface" = yes; then
210         AC_CHECK_LIB(compface, uncompface,,[ac_cv_enable_compface=no])
211 fi
212
213 dnl Check for libjconv
214 AC_ARG_ENABLE(jconv,
215         [  --disable-jconv         Do not use libjconv],
216         [ac_cv_enable_jconv=$enableval], [ac_cv_enable_jconv=yes])
217 if test "$ac_cv_enable_jconv" = yes; then
218         AC_CHECK_LIB(jconv, jconv_alloc_conv,,[ac_cv_enable_jconv=no])
219 fi
220
221 AC_CHECK_LIB(xpg4, setlocale)
222 dnl AC_CHECK_LIB(kcc, KCC_filter)
223
224 dnl for GThread support (currently disabled)
225 dnl AC_ARG_ENABLE(threads,
226 dnl     [  --enable-threads        Enable multithread support [default=no]],
227 dnl     [use_threads=$enableval], [use_threads=no])
228
229 AC_MSG_CHECKING([whether to use threads])
230 if test x"$use_threads" = xyes ; then
231         AC_MSG_RESULT(yes)
232         if test ! -z `$GLIB_CONFIG --help 2>&1 |grep 'gthread'` ; then
233                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
234                 LIBS="$LIBS `$GLIB_CONFIG --libs gthread`"
235                 AC_DEFINE(USE_THREADS)
236         else
237                 AC_MSG_ERROR([Sylpheed requires GThread from GLib to use threading.])
238         fi
239 else
240         AC_MSG_RESULT(no)
241 fi
242
243 dnl check for IPv6 option
244 AC_ARG_ENABLE(ipv6,
245         [  --enable-ipv6           Enable IPv6 support [default=no]],
246         [ac_cv_enable_ipv6=$enableval], [ac_cv_enable_ipv6=no])
247
248 dnl automated checks for IPv6 support.
249 AC_MSG_CHECKING([whether to use IPv6])
250 if test x"$ac_cv_enable_ipv6" = xyes; then
251         AC_MSG_RESULT(yes)
252         AC_MSG_CHECKING([for IPv6 support])
253         AC_CACHE_VAL(ac_cv_ipv6,[
254                 AC_TRY_COMPILE([#define INET6
255                                 #include <sys/types.h>
256                                 #include <netinet/in.h>],
257                         [int x = IPPROTO_IPV6; struct in6_addr a;],
258                         ac_cv_ipv6=yes, ac_cv_ipv6=no)
259         ])
260         AC_MSG_RESULT($ac_cv_ipv6)
261         if test $ac_cv_ipv6 = yes; then
262                 AC_DEFINE(INET6)
263         else
264                 AC_MSG_WARN(*** IPv6 will not be supported ***)
265                 ac_cv_enable_ipv6=no
266         fi
267 else
268         AC_MSG_RESULT(no)
269 fi
270
271 dnl PSPELL is user for spell checking
272 AC_ARG_ENABLE(pspell,
273         [  --enable-pspell           Enable pspell support [default=no]],
274         [ac_cv_enable_pspell=$enableval], [ac_cv_enable_pspell=no])
275 AC_MSG_CHECKING([whether to use pspell])
276 if test $ac_cv_enable_pspell = yes; then
277         AC_MSG_RESULT(yes)
278         AM_PATH_PSPELL(.12.2, AC_DEFINE(USE_PSPELL), [use_pspell=no
279                                                     ac_cv_enable_pspell=no])
280         pspell_path="`pspell-config --pkgdatadir`"
281         AC_DEFINE_UNQUOTED(PSPELL_PATH, "${pspell_path}/")
282 else
283         AC_MSG_RESULT(no)
284 fi
285
286 dnl check if gdk / gtk was compiled with USE_XIM
287 AC_MSG_CHECKING([whether GTK was compiled with XIM support])
288 CFLAGS_SAVE="$CFLAGS"
289 LDFLAGS_SAVE="$LDFLAGS"
290 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags` `gtk-config --cflags`"
291 LDFLAGS="$LIBS `$GLIB_CONFIG --libs` `gtk-config --libs`"
292 AC_CACHE_VAL(ac_cv_use_gtkgdk_xim, [
293         AC_TRY_COMPILE([#include <gtk/gtk.h>
294                         #include <gdk/gdk.h>],
295                         [extern gint gdk_im_open(void); gdk_im_open();],
296                          ac_cv_use_gtkgdk_xim=yes, ac_cv_use_gtkgdk_xim=no)
297         ])
298 AC_MSG_RESULT($ac_cv_use_gtkgdk_xim)
299 if test $ac_cv_use_gtkgdk_xim = yes; then
300         AC_DEFINE(USE_GTKGDK_XIM)
301 fi
302 CFLAGS="$CFLAGS_SAVE"
303 LDFLAGS="$LDFLAGS_SAVE"
304
305
306 dnl Checks for header files.
307 AC_HEADER_DIRENT
308 AC_HEADER_STDC
309 AC_HEADER_SYS_WAIT
310 AC_CHECK_HEADERS(fcntl.h sys/file.h unistd.h paths.h \
311                  sys/param.h sys/utsname.h \
312                  wchar.h wctype.h)
313
314 dnl Checks for typedefs, structures, and compiler characteristics.
315 AC_C_CONST
316 AC_TYPE_OFF_T
317 AC_TYPE_PID_T
318 AC_TYPE_SIZE_T
319 AC_STRUCT_TM
320
321 dnl AC_CHECK_TYPE(wint_t, unsigned int) does not work because wint_t
322 dnl may be defined only in wchar.h (this happens with gcc-2.96).
323 dnl So we need to use this extended macro.
324 SYLPHEED_CHECK_TYPE(wint_t, unsigned int,
325 [
326 #if HAVE_WCHAR_H
327 #include <wchar.h>
328 #endif
329 ])
330
331 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
332 AC_CHECK_SIZEOF(unsigned short, 2)
333 AC_CHECK_SIZEOF(unsigned int, 4)
334 AC_CHECK_SIZEOF(unsigned long, 4)
335
336 dnl Checks for library functions.
337 AC_FUNC_ALLOCA
338 AC_CHECK_FUNCS(gethostname mkdir mktime socket strstr \
339                wcsstr wcswcs iswalnum iswspace towlower \
340                wcslen wcscpy wcsncpy \
341                uname flock lockf inet_aton inet_addr \
342                fchmod mkstemp)
343
344 AC_OUTPUT([
345 Makefile
346 sylpheed.spec
347 intl/Makefile
348 ac/Makefile
349 po/Makefile.in
350 libkcc/Makefile
351 src/version.h
352 src/Makefile
353 faq/Makefile
354 faq/en/Makefile
355 faq/es/Makefile
356 faq/fr/Makefile
357 manual/Makefile
358 manual/en/Makefile
359 manual/fr/Makefile
360 manual/ja/Makefile
361 tools/Makefile
362 ])
363
364 dnl Output the configuration summary
365 echo ""
366 echo "$PACKAGE $VERSION"
367 echo ""
368 if test "$ac_cv_enable_gdk_pixbuf" = yes; then
369         echo "image support : yes (gdk-pixbuf)"
370 elif test "$ac_cv_enable_imlib" = yes; then
371         echo "image support : yes (gdk_imlib)"
372 else
373         echo "image support : no"
374 fi
375 echo "GPGME         : $ac_cv_enable_gpgme"
376 echo "JPilot        : $ac_cv_enable_jpilot"
377 echo "LDAP          : $ac_cv_enable_ldap"
378 echo "OpenSSL       : $ac_cv_enable_ssl"
379 echo "compface      : $ac_cv_enable_compface"
380 echo "libjconv      : $ac_cv_enable_jconv"
381 echo "IPv6          : $ac_cv_enable_ipv6"
382 echo "Pspell        : $ac_cv_enable_pspell"
383 echo ""
384 echo "The binary will be installed in $prefix/bin"
385 echo ""
386 echo "Configure finished, type 'make' to build."