configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(src/main.c)
   3 PACKAGE=sylpheed
   4
   5 dnl version number
   6 MAJOR_VERSION=0
   7 MINOR_VERSION=6
   8 MICRO_VERSION=1
   9 INTERFACE_AGE=0
  10 BINARY_AGE=0
  11 EXTRA_VERSION=claws
  12 VERSION=$MAJOR_VERSION.$MINOR_VERSION.$MICRO_VERSION$EXTRA_VERSION
  13
  14 dnl
  15 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  16 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
  17 AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
  18 AC_SUBST(PACKAGE)
  19 AC_SUBST(VERSION)
  20
  21 dnl GNOME installed?
  22 AC_PATH_PROG(GNOME_CONFIG, gnome-config, no)
  23 if test "$GNOME_CONFIG" != no; then
  24         gnomedir="`gnome-config --prefix`"
  25         AC_SUBST(gnomedir)
  26 fi
  27 AM_CONDITIONAL(SYLPHEED_GNOME, test -d "$gnomedir")
  28
  29 dnl Claws version
  30 AC_DEFINE(CLAWS, 1)
  31
  32 dnl libtool versioning
  33 LT_RELEASE=$MAJOR_VERSION.$MINOR_VERSION
  34 LT_CURRENT=`expr $MICRO_VERSION - $INTERFACE_AGE`
  35 LT_REVISION=$INTERFACE_AGE
  36 LT_AGE=`expr $BINARY_AGE - $INTERFACE_AGE`
  37 AC_SUBST(LT_RELEASE)
  38 AC_SUBST(LT_CURRENT)
  39 AC_SUBST(LT_REVISION)
  40 AC_SUBST(LT_AGE)
  41
  42 dnl Specify a header configuration file
  43 AM_CONFIG_HEADER(config.h)
  44
  45 AM_PROG_LIBTOOL
  46 AM_MAINTAINER_MODE
  47
  48 dnl Checks for programs.
  49 AC_ARG_PROGRAM
  50 AC_PROG_CC
  51 AC_ISC_POSIX
  52 AM_PROG_CC_STDC
  53 AC_PROG_INSTALL
  54 AC_PROG_LN_S
  55 AC_PROG_MAKE_SET
  56 AC_PROG_CPP
  57 dnl AC_PROG_RANLIB
  58 AM_PROG_LEX
  59 AC_PROG_YACC
  60
  61 SYLPHEED_ACLOCAL_INCLUDE(ac)
  62
  63 dnl for gettext
  64 ALL_LINGUAS="cs de el es fr hr it ja ko nl pl pt_BR ru zh_CN.GB2312 zh_TW.Big5"
  65 AM_GNU_GETTEXT
  66 dnl AC_CHECK_FUNC(gettext, AC_CHECK_LIB(intl, gettext))
  67 localedir='${prefix}/${DATADIRNAME}/locale'
  68 AC_SUBST(localedir)
  69
  70 manualdir='${prefix}/${DATADIRNAME}/${PACKAGE}/manual'
  71 AC_SUBST(manualdir)
  72
  73 dnl Checks for libraries.
  74 AM_PATH_GLIB(1.2.6,,
  75         AC_MSG_ERROR(Test for GLIB failed. See the file 'INSTALL' for help.),
  76         gthread)
  77 AM_PATH_GTK(1.2.6,,
  78         AC_MSG_ERROR(Test for GTK failed. See the file 'INSTALL' for help.))
  79
  80 dnl Check for built-in image view support
  81 AC_ARG_ENABLE(gdk-pixbuf,
  82         [  --disable-gdk-pixbuf    Do not use gdk-pixbuf],
  83         [ac_cv_enable_gdk_pixbuf=$enableval], [ac_cv_enable_gdk_pixbuf=yes])
  84 AC_ARG_ENABLE(imlib,
  85         [  --disable-imlib         Do not use imlib],
  86         [ac_cv_enable_imlib=$enableval], [ac_cv_enable_imlib=yes])
  87
  88 if test "$ac_cv_enable_gdk_pixbuf" = yes; then
  89         AM_PATH_GDK_PIXBUF(0.8.0,
  90                 [AC_DEFINE(HAVE_GDK_PIXBUF)
  91                  ac_cv_enable_imlib=no], [ac_cv_enable_gdk_pixbuf=no])
  92 fi
  93 if test "$ac_cv_enable_imlib" = yes; then
  94         AM_PATH_GDK_IMLIB(1.9,
  95                 AC_DEFINE(HAVE_GDK_IMLIB), [ac_cv_enable_imlib=no])
  96 fi
  97 if test "$ac_cv_enable_gdk_pixbuf" = no -a "$ac_cv_enable_imlib" = no; then
  98         AC_MSG_WARN(*** Built-in image view will not be supported ***)
  99 fi
 100
 101 dnl GPGME is used to support OpenPGP
 102 AC_ARG_ENABLE(gpgme,
 103         [  --enable-gpgme          Enable GnuPG support using GPGME [default=no]],
 104         [ac_cv_enable_gpgme=$enableval], [ac_cv_enable_gpgme=no])
 105 AC_MSG_CHECKING([whether to use GPGME])
 106 if test $ac_cv_enable_gpgme = yes; then
 107         AC_MSG_RESULT(yes)
 108         AM_PATH_GPGME(0.2.1, AC_DEFINE(USE_GPGME), [use_gpgme=no
 109                                                     ac_cv_enable_gpgme=no])
 110 else
 111         AC_MSG_RESULT(no)
 112 fi
 113
 114 dnl Check for OpenSSL
 115 AC_ARG_ENABLE(ssl,
 116         [  --enable-ssl            Enable SSL support using OpenSSL [default=no]],
 117         [ac_cv_enable_ssl=$enableval], [ac_cv_enable_ssl=no])
 118 AC_MSG_CHECKING([whether to use OpenSSL])
 119 if test $ac_cv_enable_ssl = yes; then
 120         AC_MSG_RESULT(yes)
 121         AC_MSG_CHECKING([if openssl is available])
 122         LIBS="$LIBS -lssl -lcrypto"
 123         AC_TRY_LINK([
 124 #include <openssl/opensslv.h>
 125 ],      [ return OPENSSL_VERSION_NUMBER; ],
 126         [ AC_MSG_RESULT(yes)
 127           AC_DEFINE(USE_SSL) ],
 128         [ AC_MSG_RESULT(no)
 129           LIBS="$ac_save_LIBS"
 130           ac_cv_enable_ssl=no ])
 131 else
 132         AC_MSG_RESULT(no)
 133 fi
 134
 135 dnl Check for X-Face support
 136 AC_ARG_ENABLE(compface,
 137         [  --disable-compface      Do not use compface (X-Face)],
 138         [ac_cv_enable_compface=$enableval], [ac_cv_enable_compface=yes])
 139 if test "$ac_cv_enable_compface" = yes; then
 140         AC_CHECK_LIB(compface, uncompface,,[ac_cv_enable_compface=no])
 141 fi
 142
 143 dnl for JPilot support in addressbook
 144 dnl no check for libraries: these are dynamically loaded
 145 AC_ARG_ENABLE(jpilot,
 146         [  --enable-jpilot         Enable JPilot support [default=no]],
 147         [ac_cv_enable_jpilot=$enableval], [ac_cv_enable_jpilot=no])
 148
 149 AC_MSG_CHECKING([whether to use jpilot])
 150 if test "$ac_cv_enable_jpilot" = yes; then
 151         AC_MSG_RESULT(yes)
 152         if test "$ac_cv_enable_jpilot" = yes; then
 153                 AC_CHECK_HEADERS(pi-args.h pi-appinfo.h pi-address.h, , [ac_cv_enable_jpilot=no])
 154                 if test "$ac_cv_enable_jpilot" = yes; then
 155                         LIBS="$LIBS -lpisock"
 156                         AC_DEFINE(USE_JPILOT)
 157                 fi
 158         fi
 159         AC_MSG_CHECKING(whether jpilot is available)
 160         if test "$ac_cv_enable_jpilot" = yes; then
 161                 AC_MSG_RESULT(yes)
 162         else
 163                 AC_MSG_RESULT(no)
 164         fi
 165 else
 166         AC_MSG_RESULT(no)
 167 fi
 168
 169 dnl for LDAP support in addressbook
 170 dnl no check for libraries; dynamically loaded
 171 AC_ARG_ENABLE(ldap,
 172         [  --enable-ldap         Enable LDAP support [default=no]],
 173         [ac_cv_enable_ldap=$enableval], [ac_cv_enable_ldap=no])
 174
 175 AC_MSG_CHECKING([whether to use ldap])
 176 if test "$ac_cv_enable_ldap" = yes; then
 177         AC_MSG_RESULT(yes)
 178         if test "$ac_cv_enable_ldap" = yes; then
 179                 AC_CHECK_HEADERS(ldap.h lber.h pthread.h, , [ac_cv_enable_ldap=no])
 180                 if test "$ac_cv_enable_ldap" = yes; then
 181                         LIBS="$LIBS -lldap -llber -lpthread -lresolv"
 182                         AC_DEFINE(USE_LDAP)
 183                 fi
 184         fi
 185         AC_MSG_CHECKING(whether ldap is available)
 186         if test "$ac_cv_enable_ldap" = yes; then
 187                 AC_MSG_RESULT(yes)
 188         else
 189                 AC_MSG_RESULT(no)
 190         fi
 191 else
 192         AC_MSG_RESULT(no)
 193 fi
 194
 195 dnl get ispell path
 196 dnl
 197 AC_PATH_PROG(ispell_path, ispell, no)
 198 if test "$ispell_path" != no; then
 199         AC_DEFINE_UNQUOTED(ISPELL_PATH, "$ispell_path")
 200         AC_SUBST(ISPELL_PATH)
 201 else
 202         AC_DEFINE_UNQUOTED(ISPELL_PATH, "/usr/bin/ispell")
 203         AC_SUBST(ISPELL_PATH)
 204 fi
 205
 206 dnl Check for libjconv
 207 AC_ARG_ENABLE(jconv,
 208         [  --disable-jconv         Do not use libjconv],
 209         [ac_cv_enable_jconv=$enableval], [ac_cv_enable_jconv=yes])
 210 if test "$ac_cv_enable_jconv" = yes; then
 211         AC_CHECK_LIB(jconv, jconv_alloc_conv,,[ac_cv_enable_jconv=no])
 212 fi
 213
 214 AC_CHECK_LIB(xpg4, setlocale)
 215 dnl AC_CHECK_LIB(kcc, KCC_filter)
 216
 217 dnl for GThread support (currently disabled)
 218 dnl AC_ARG_ENABLE(threads,
 219 dnl     [  --enable-threads        Enable multithread support [default=no]],
 220 dnl     [use_threads=$enableval], [use_threads=no])
 221
 222 AC_MSG_CHECKING([whether to use threads])
 223 if test x"$use_threads" = xyes ; then
 224         AC_MSG_RESULT(yes)
 225         if test ! -z `$GLIB_CONFIG --help 2>&1 |grep 'gthread'` ; then
 226                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
 227                 LIBS="$LIBS `$GLIB_CONFIG --libs gthread`"
 228                 AC_DEFINE(USE_THREADS)
 229         else
 230                 AC_MSG_ERROR([Sylpheed requires GThread from GLib to use threading.])
 231         fi
 232 else
 233         AC_MSG_RESULT(no)
 234 fi
 235
 236 dnl check for IPv6 option
 237 AC_ARG_ENABLE(ipv6,
 238         [  --enable-ipv6           Enable IPv6 support [default=no]],
 239         [ac_cv_enable_ipv6=$enableval], [ac_cv_enable_ipv6=no])
 240
 241 dnl automated checks for IPv6 support.
 242 AC_MSG_CHECKING([whether to use IPv6])
 243 if test x"$ac_cv_enable_ipv6" = xyes; then
 244         AC_MSG_RESULT(yes)
 245         AC_MSG_CHECKING([for IPv6 support])
 246         AC_CACHE_VAL(ac_cv_ipv6,[
 247                 AC_TRY_COMPILE([#define INET6
 248                                 #include <sys/types.h>
 249                                 #include <netinet/in.h>],
 250                         [int x = IPPROTO_IPV6; struct in6_addr a;],
 251                         ac_cv_ipv6=yes, ac_cv_ipv6=no)
 252         ])
 253         AC_MSG_RESULT($ac_cv_ipv6)
 254         if test $ac_cv_ipv6 = yes; then
 255                 AC_DEFINE(INET6)
 256         else
 257                 AC_MSG_WARN(*** IPv6 will not be supported ***)
 258                 ac_cv_enable_ipv6=no
 259         fi
 260 else
 261         AC_MSG_RESULT(no)
 262 fi
 263
 264 dnl check if gdk / gtk was compiled with USE_XIM
 265 AC_MSG_CHECKING([whether GTK was compiled with XIM support])
 266 CFLAGS_SAVE="$CFLAGS"
 267 LDFLAGS_SAVE="$LDFLAGS"
 268 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags` `gtk-config --cflags`"
 269 LDFLAGS="$LIBS `$GLIB_CONFIG --libs` `gtk-config --libs`"
 270 AC_CACHE_VAL(ac_cv_use_gtkgdk_xim, [
 271         AC_TRY_COMPILE([#include <gtk/gtk.h>
 272                         #include <gdk/gdk.h>],
 273                         [extern gint gdk_im_open(void); gdk_im_open();],
 274                          ac_cv_use_gtkgdk_xim=yes, ac_cv_use_gtkgdk_xim=no)
 275         ])
 276 AC_MSG_RESULT($ac_cv_use_gtkgdk_xim)
 277 if test $ac_cv_use_gtkgdk_xim = yes; then
 278         AC_DEFINE(USE_GTKGDK_XIM)
 279 fi
 280 CFLAGS="$CFLAGS_SAVE"
 281 LDFLAGS="$LDFLAGS_SAVE"
 282
 283
 284 dnl Checks for header files.
 285 AC_HEADER_DIRENT
 286 AC_HEADER_STDC
 287 AC_HEADER_SYS_WAIT
 288 AC_CHECK_HEADERS(fcntl.h sys/file.h unistd.h paths.h \
 289                  sys/param.h sys/utsname.h \
 290                  wchar.h wctype.h)
 291
 292 dnl Checks for typedefs, structures, and compiler characteristics.
 293 AC_C_CONST
 294 AC_TYPE_OFF_T
 295 AC_TYPE_PID_T
 296 AC_TYPE_SIZE_T
 297 AC_STRUCT_TM
 298
 299 dnl AC_CHECK_TYPE(wint_t, unsigned int) does not work because wint_t
 300 dnl may be defined only in wchar.h (this happens with gcc-2.96).
 301 dnl So we need to use this extended macro.
 302 SYLPHEED_CHECK_TYPE(wint_t, unsigned int,
 303 [
 304 #if HAVE_WCHAR_H
 305 #include <wchar.h>
 306 #endif
 307 ])
 308
 309 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
 310 AC_CHECK_SIZEOF(unsigned short, 2)
 311 AC_CHECK_SIZEOF(unsigned int, 4)
 312 AC_CHECK_SIZEOF(unsigned long, 4)
 313
 314 dnl Checks for library functions.
 315 AC_FUNC_ALLOCA
 316 AC_CHECK_FUNCS(gethostname mkdir mktime socket strstr \
 317                wcsstr wcswcs iswalnum iswspace towlower \
 318                wcslen wcscpy wcsncpy \
 319                uname flock lockf inet_aton inet_addr \
 320                fchmod mkstemp)
 321
 322 AC_OUTPUT([
 323 Makefile
 324 sylpheed.spec
 325 intl/Makefile
 326 ac/Makefile
 327 po/Makefile.in
 328 libkcc/Makefile
 329 src/version.h
 330 src/Makefile
 331 manual/Makefile
 332 manual/en/Makefile
 333 manual/ja/Makefile
 334 tools/Makefile
 335 ])
 336
 337 dnl Output the configuration summary
 338 echo ""
 339 echo "$PACKAGE $VERSION"
 340 echo ""
 341 echo "gdk-pixbuf : $ac_cv_enable_gdk_pixbuf"
 342 echo "gdk_imlib  : $ac_cv_enable_imlib"
 343 echo "GPGME      : $ac_cv_enable_gpgme"
 344 echo "JPilot     : $ac_cv_enable_jpilot"
 345 echo "LDAP       : $ac_cv_enable_ldap"
 346 echo "OpenSSL    : $ac_cv_enable_ssl"
 347 echo "compface   : $ac_cv_enable_compface"
 348 echo "libjconv   : $ac_cv_enable_jconv"
 349 echo "IPv6       : $ac_cv_enable_ipv6"
 350 echo ""
 351 echo "The binary will be installed in $prefix/bin"
 352 echo ""
 353 echo "Configure finished, type 'make' to build."