configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(src/main.c)
   3 PACKAGE=sylpheed
   4
   5 dnl version number
   6 MAJOR_VERSION=0
   7 MINOR_VERSION=6
   8 MICRO_VERSION=1
   9 INTERFACE_AGE=0
  10 BINARY_AGE=0
  11 EXTRA_VERSION=claws1
  12 VERSION=$MAJOR_VERSION.$MINOR_VERSION.$MICRO_VERSION$EXTRA_VERSION
  13
  14 dnl
  15 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  16 dnl AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
  17 dnl AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
  18 AC_SUBST(PACKAGE)
  19 AC_SUBST(VERSION)
  20
  21 dnl GNOME installed?
  22 AC_PATH_PROG(GNOME_CONFIG, gnome-config, no)
  23 if test "$GNOME_CONFIG" != no; then
  24         gnomedir="`gnome-config --prefix`"
  25         AC_SUBST(gnomedir)
  26 fi
  27 AM_CONDITIONAL(SYLPHEED_GNOME, test -d "$gnomedir")
  28
  29 dnl Claws version
  30 AC_DEFINE(CLAWS, 1)
  31
  32 dnl libtool versioning
  33 LT_RELEASE=$MAJOR_VERSION.$MINOR_VERSION
  34 LT_CURRENT=`expr $MICRO_VERSION - $INTERFACE_AGE`
  35 LT_REVISION=$INTERFACE_AGE
  36 LT_AGE=`expr $BINARY_AGE - $INTERFACE_AGE`
  37 AC_SUBST(LT_RELEASE)
  38 AC_SUBST(LT_CURRENT)
  39 AC_SUBST(LT_REVISION)
  40 AC_SUBST(LT_AGE)
  41
  42 dnl Specify a header configuration file
  43 AM_CONFIG_HEADER(config.h)
  44
  45 AM_PROG_LIBTOOL
  46 AM_MAINTAINER_MODE
  47
  48 dnl Checks for programs.
  49 AC_ARG_PROGRAM
  50 AC_PROG_CC
  51 AC_ISC_POSIX
  52 AM_PROG_CC_STDC
  53 AC_PROG_INSTALL
  54 AC_PROG_LN_S
  55 AC_PROG_MAKE_SET
  56 AC_PROG_CPP
  57 dnl AC_PROG_RANLIB
  58 AM_PROG_LEX
  59 AC_PROG_YACC
  60
  61 SYLPHEED_ACLOCAL_INCLUDE(ac)
  62
  63 dnl for gettext
  64 ALL_LINGUAS="cs de el es fr hr it ja ko nl pl pt_BR ru zh_CN.GB2312 zh_TW.Big5"
  65 AM_GNU_GETTEXT
  66 dnl AC_CHECK_FUNC(gettext, AC_CHECK_LIB(intl, gettext))
  67 localedir='${prefix}/${DATADIRNAME}/locale'
  68 AC_SUBST(localedir)
  69
  70 manualdir='${prefix}/${DATADIRNAME}/${PACKAGE}/manual'
  71 AC_SUBST(manualdir)
  72
  73 dnl Checks for libraries.
  74 AM_PATH_GLIB(1.2.6,,
  75         AC_MSG_ERROR(Test for GLIB failed. See the file 'INSTALL' for help.),
  76         gthread)
  77 AM_PATH_GTK(1.2.6,,
  78         AC_MSG_ERROR(Test for GTK failed. See the file 'INSTALL' for help.))
  79
  80 dnl Check for built-in image view support
  81 AC_ARG_ENABLE(gdk-pixbuf,
  82         [  --disable-gdk-pixbuf    Do not use gdk-pixbuf],
  83         [ac_cv_enable_gdk_pixbuf=$enableval], [ac_cv_enable_gdk_pixbuf=yes])
  84 AC_ARG_ENABLE(imlib,
  85         [  --disable-imlib         Do not use imlib],
  86         [ac_cv_enable_imlib=$enableval], [ac_cv_enable_imlib=yes])
  87
  88 if test "$ac_cv_enable_gdk_pixbuf" = yes; then
  89         AM_PATH_GDK_PIXBUF(0.8.0,
  90                 [AC_DEFINE(HAVE_GDK_PIXBUF)
  91                  ac_cv_enable_imlib=no], [ac_cv_enable_gdk_pixbuf=no])
  92 fi
  93 if test "$ac_cv_enable_imlib" = yes; then
  94         AM_PATH_GDK_IMLIB(1.9,
  95                 AC_DEFINE(HAVE_GDK_IMLIB), [ac_cv_enable_imlib=no])
  96 fi
  97 if test "$ac_cv_enable_gdk_pixbuf" = no -a "$ac_cv_enable_imlib" = no; then
  98         AC_MSG_WARN(*** Built-in image view will not be supported ***)
  99 fi
 100
 101 dnl GPGME is used to support OpenPGP
 102 AC_ARG_ENABLE(gpgme,
 103         [  --enable-gpgme          Enable GnuPG support using GPGME [default=no]],
 104         [ac_cv_enable_gpgme=$enableval], [ac_cv_enable_gpgme=no])
 105 AC_MSG_CHECKING([whether to use GPGME])
 106 if test $ac_cv_enable_gpgme = yes; then
 107         AC_MSG_RESULT(yes)
 108         AM_PATH_GPGME(0.2.1, AC_DEFINE(USE_GPGME), [use_gpgme=no
 109                                                     ac_cv_enable_gpgme=no])
 110 else
 111         AC_MSG_RESULT(no)
 112 fi
 113
 114 dnl Check for OpenSSL
 115 AC_ARG_ENABLE(ssl,
 116         [  --enable-ssl            Enable SSL support using OpenSSL [default=no]],
 117         [ac_cv_enable_ssl=$enableval], [ac_cv_enable_ssl=no])
 118 AC_MSG_CHECKING([whether to use OpenSSL])
 119 if test $ac_cv_enable_ssl = yes; then
 120         AC_MSG_RESULT(yes)
 121         AC_MSG_CHECKING([if openssl is available])
 122         LIBS="$LIBS -lssl -lcrypto"
 123         AC_TRY_LINK([
 124 #include <openssl/opensslv.h>
 125 ],      [ return OPENSSL_VERSION_NUMBER; ],
 126         [ AC_MSG_RESULT(yes)
 127           AC_DEFINE(USE_SSL) ],
 128         [ AC_MSG_RESULT(no)
 129           LIBS="$ac_save_LIBS"
 130           ac_cv_enable_ssl=no ])
 131 else
 132         AC_MSG_RESULT(no)
 133 fi
 134
 135 dnl Check for X-Face support
 136 AC_ARG_ENABLE(compface,
 137         [  --disable-compface      Do not use compface (X-Face)],
 138         [ac_cv_enable_compface=$enableval], [ac_cv_enable_compface=yes])
 139 if test "$ac_cv_enable_compface" = yes; then
 140         AC_CHECK_LIB(compface, uncompface,,[ac_cv_enable_compface=no])
 141 fi
 142
 143 dnl for JPilot support in addressbook
 144 dnl no check for libraries; these are dynamically loaded
 145 AC_ARG_ENABLE(jpilot,
 146         [  --enable-jpilot         Enable JPilot support [default=no]],
 147         [ac_cv_enable_jpilot=$enableval], [ac_cv_enable_jpilot=no])
 148 AC_MSG_CHECKING([whether to use JPilot])
 149 if test "$ac_cv_enable_jpilot" = yes; then
 150         AC_MSG_RESULT(yes)
 151         AC_CHECK_HEADERS(pi-args.h pi-appinfo.h pi-address.h,
 152                          [ LIBS="$LIBS -lpisock"
 153                            AC_DEFINE(USE_JPILOT) ],
 154                          [ ac_cv_enable_jpilot=no ])
 155         AC_MSG_CHECKING([whether jpilot is available])
 156         AC_MSG_RESULT($ac_cv_enable_jpilot)
 157 else
 158         AC_MSG_RESULT(no)
 159 fi
 160
 161 dnl for LDAP support in addressbook
 162 dnl no check for libraries; dynamically loaded
 163 AC_ARG_ENABLE(ldap,
 164         [  --enable-ldap           Enable LDAP support [default=no]],
 165         [ac_cv_enable_ldap=$enableval], [ac_cv_enable_ldap=no])
 166 AC_MSG_CHECKING([whether to use LDAP])
 167 if test "$ac_cv_enable_ldap" = yes; then
 168         AC_MSG_RESULT(yes)
 169         AC_CHECK_HEADERS(ldap.h lber.h pthread.h,
 170                          [ LIBS="$LIBS -lldap -llber -lpthread -lresolv"
 171                            AC_DEFINE(USE_LDAP) ],
 172                          [ ac_cv_enable_ldap=no ])
 173         AC_MSG_CHECKING([whether ldap is available])
 174         AC_MSG_RESULT($ac_cv_enable_ldap)
 175 else
 176         AC_MSG_RESULT(no)
 177 fi
 178
 179 dnl get ispell path
 180 dnl
 181 AC_PATH_PROG(ispell_path, ispell, no)
 182 if test "$ispell_path" != no; then
 183         AC_DEFINE_UNQUOTED(ISPELL_PATH, "$ispell_path")
 184         AC_SUBST(ISPELL_PATH)
 185 else
 186         AC_DEFINE_UNQUOTED(ISPELL_PATH, "/usr/bin/ispell")
 187         AC_SUBST(ISPELL_PATH)
 188 fi
 189
 190 dnl Check for libjconv
 191 AC_ARG_ENABLE(jconv,
 192         [  --disable-jconv         Do not use libjconv],
 193         [ac_cv_enable_jconv=$enableval], [ac_cv_enable_jconv=yes])
 194 if test "$ac_cv_enable_jconv" = yes; then
 195         AC_CHECK_LIB(jconv, jconv_alloc_conv,,[ac_cv_enable_jconv=no])
 196 fi
 197
 198 AC_CHECK_LIB(xpg4, setlocale)
 199 dnl AC_CHECK_LIB(kcc, KCC_filter)
 200
 201 dnl for GThread support (currently disabled)
 202 dnl AC_ARG_ENABLE(threads,
 203 dnl     [  --enable-threads        Enable multithread support [default=no]],
 204 dnl     [use_threads=$enableval], [use_threads=no])
 205
 206 AC_MSG_CHECKING([whether to use threads])
 207 if test x"$use_threads" = xyes ; then
 208         AC_MSG_RESULT(yes)
 209         if test ! -z `$GLIB_CONFIG --help 2>&1 |grep 'gthread'` ; then
 210                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
 211                 LIBS="$LIBS `$GLIB_CONFIG --libs gthread`"
 212                 AC_DEFINE(USE_THREADS)
 213         else
 214                 AC_MSG_ERROR([Sylpheed requires GThread from GLib to use threading.])
 215         fi
 216 else
 217         AC_MSG_RESULT(no)
 218 fi
 219
 220 dnl check for IPv6 option
 221 AC_ARG_ENABLE(ipv6,
 222         [  --enable-ipv6           Enable IPv6 support [default=no]],
 223         [ac_cv_enable_ipv6=$enableval], [ac_cv_enable_ipv6=no])
 224
 225 dnl automated checks for IPv6 support.
 226 AC_MSG_CHECKING([whether to use IPv6])
 227 if test x"$ac_cv_enable_ipv6" = xyes; then
 228         AC_MSG_RESULT(yes)
 229         AC_MSG_CHECKING([for IPv6 support])
 230         AC_CACHE_VAL(ac_cv_ipv6,[
 231                 AC_TRY_COMPILE([#define INET6
 232                                 #include <sys/types.h>
 233                                 #include <netinet/in.h>],
 234                         [int x = IPPROTO_IPV6; struct in6_addr a;],
 235                         ac_cv_ipv6=yes, ac_cv_ipv6=no)
 236         ])
 237         AC_MSG_RESULT($ac_cv_ipv6)
 238         if test $ac_cv_ipv6 = yes; then
 239                 AC_DEFINE(INET6)
 240         else
 241                 AC_MSG_WARN(*** IPv6 will not be supported ***)
 242                 ac_cv_enable_ipv6=no
 243         fi
 244 else
 245         AC_MSG_RESULT(no)
 246 fi
 247
 248 dnl check if gdk / gtk was compiled with USE_XIM
 249 AC_MSG_CHECKING([whether GTK was compiled with XIM support])
 250 CFLAGS_SAVE="$CFLAGS"
 251 LDFLAGS_SAVE="$LDFLAGS"
 252 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags` `gtk-config --cflags`"
 253 LDFLAGS="$LIBS `$GLIB_CONFIG --libs` `gtk-config --libs`"
 254 AC_CACHE_VAL(ac_cv_use_gtkgdk_xim, [
 255         AC_TRY_COMPILE([#include <gtk/gtk.h>
 256                         #include <gdk/gdk.h>],
 257                         [extern gint gdk_im_open(void); gdk_im_open();],
 258                          ac_cv_use_gtkgdk_xim=yes, ac_cv_use_gtkgdk_xim=no)
 259         ])
 260 AC_MSG_RESULT($ac_cv_use_gtkgdk_xim)
 261 if test $ac_cv_use_gtkgdk_xim = yes; then
 262         AC_DEFINE(USE_GTKGDK_XIM)
 263 fi
 264 CFLAGS="$CFLAGS_SAVE"
 265 LDFLAGS="$LDFLAGS_SAVE"
 266
 267
 268 dnl Checks for header files.
 269 AC_HEADER_DIRENT
 270 AC_HEADER_STDC
 271 AC_HEADER_SYS_WAIT
 272 AC_CHECK_HEADERS(fcntl.h sys/file.h unistd.h paths.h \
 273                  sys/param.h sys/utsname.h \
 274                  wchar.h wctype.h)
 275
 276 dnl Checks for typedefs, structures, and compiler characteristics.
 277 AC_C_CONST
 278 AC_TYPE_OFF_T
 279 AC_TYPE_PID_T
 280 AC_TYPE_SIZE_T
 281 AC_STRUCT_TM
 282
 283 dnl AC_CHECK_TYPE(wint_t, unsigned int) does not work because wint_t
 284 dnl may be defined only in wchar.h (this happens with gcc-2.96).
 285 dnl So we need to use this extended macro.
 286 SYLPHEED_CHECK_TYPE(wint_t, unsigned int,
 287 [
 288 #if HAVE_WCHAR_H
 289 #include <wchar.h>
 290 #endif
 291 ])
 292
 293 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
 294 AC_CHECK_SIZEOF(unsigned short, 2)
 295 AC_CHECK_SIZEOF(unsigned int, 4)
 296 AC_CHECK_SIZEOF(unsigned long, 4)
 297
 298 dnl Checks for library functions.
 299 AC_FUNC_ALLOCA
 300 AC_CHECK_FUNCS(gethostname mkdir mktime socket strstr \
 301                wcsstr wcswcs iswalnum iswspace towlower \
 302                wcslen wcscpy wcsncpy \
 303                uname flock lockf inet_aton inet_addr \
 304                fchmod mkstemp)
 305
 306 AC_OUTPUT([
 307 Makefile
 308 sylpheed.spec
 309 intl/Makefile
 310 ac/Makefile
 311 po/Makefile.in
 312 libkcc/Makefile
 313 src/version.h
 314 src/Makefile
 315 manual/Makefile
 316 manual/en/Makefile
 317 manual/ja/Makefile
 318 tools/Makefile
 319 ])
 320
 321 dnl Output the configuration summary
 322 echo ""
 323 echo "$PACKAGE $VERSION"
 324 echo ""
 325 echo "gdk-pixbuf : $ac_cv_enable_gdk_pixbuf"
 326 echo "gdk_imlib  : $ac_cv_enable_imlib"
 327 echo "GPGME      : $ac_cv_enable_gpgme"
 328 echo "OpenSSL    : $ac_cv_enable_ssl"
 329 echo "JPilot     : $ac_cv_enable_jpilot"
 330 echo "LDAP       : $ac_cv_enable_ldap"
 331 echo "compface   : $ac_cv_enable_compface"
 332 echo "libjconv   : $ac_cv_enable_jconv"
 333 echo "IPv6       : $ac_cv_enable_ipv6"
 334 echo ""
 335 echo "The binary will be installed in $prefix/bin"
 336 echo ""
 337 echo "Configure finished, type 'make' to build."