configure.ac

   1
   2 AC_PREREQ(2.60)
   3 AC_INIT(src/main.c)
   4 AC_CONFIG_AUX_DIR(config)
   5
   6 PACKAGE=claws-mail
   7
   8 dnl version number
   9 MAJOR_VERSION=3
  10 MINOR_VERSION=2
  11 MICRO_VERSION=0
  12 INTERFACE_AGE=0
  13 BINARY_AGE=0
  14 EXTRA_VERSION=9
  15 EXTRA_RELEASE=
  16 EXTRA_GTK2_VERSION=
  17
  18 if test \( $EXTRA_VERSION -eq 0 \) -o \( "x$EXTRA_RELEASE" != "x" \); then
  19     VERSION=${MAJOR_VERSION}.${MINOR_VERSION}.${MICRO_VERSION}${EXTRA_RELEASE}${EXTRA_GTK2_VERSION}
  20 else
  21     VERSION=${MAJOR_VERSION}.${MINOR_VERSION}.${MICRO_VERSION}cvs${EXTRA_VERSION}${EXTRA_GTK2_VERSION}
  22 fi
  23
  24 dnl set $target
  25 AC_CANONICAL_SYSTEM
  26
  27 dnl
  28 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  29 dnl AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
  30 dnl AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
  31 AC_SUBST(PACKAGE)
  32 AC_SUBST(VERSION)
  33 AC_SUBST(MAJOR_VERSION)
  34 AC_SUBST(MINOR_VERSION)
  35 AC_SUBST(MICRO_VERSION)
  36 AC_SUBST(EXTRA_VERSION)
  37
  38 dnl GNOME installed?
  39 AC_PATH_PROG(GNOME_CONFIG, gnome-config, no)
  40 if test "$GNOME_CONFIG" != no; then
  41         gnomedatadir="`gnome-config --datadir`"
  42         gnomeprefix="`gnome-config --prefix`"
  43         if test "${prefix}" = "NONE"; then
  44                 gnomedatadir="${ac_default_prefix}/${gnomedatadir#${gnomeprefix}}"
  45         else
  46                 gnomedatadir="${prefix}/${gnomedatadir#${gnomeprefix}}"
  47         fi
  48         AC_SUBST(gnomedatadir)
  49 fi
  50 AM_CONDITIONAL(CLAWS_GNOME, test -n "$gnomedatadir")
  51
  52 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
  53 if test x$PKG_CONFIG = xno ; then
  54   AC_MSG_ERROR([*** pkg-config not found. See http://www.freedesktop.org/software/pkgconfig/])
  55 fi
  56
  57 dnl GNOME 2.x installed?
  58 PKG_CHECK_MODULES(GNOME2, libgnome-2.0 >= 2.0, ac_enable_gnome2=yes, ac_enable_gnome2=no)
  59 AM_CONDITIONAL(CLAWS_GNOME2, test x"$ac_enable_gnome2" = x"yes")
  60
  61 dnl libtool versioning
  62 LT_RELEASE=$MAJOR_VERSION.$MINOR_VERSION
  63 LT_CURRENT=`expr $MICRO_VERSION - $INTERFACE_AGE`
  64 LT_REVISION=$INTERFACE_AGE
  65 LT_AGE=`expr $BINARY_AGE - $INTERFACE_AGE`
  66 AC_SUBST(LT_RELEASE)
  67 AC_SUBST(LT_CURRENT)
  68 AC_SUBST(LT_REVISION)
  69 AC_SUBST(LT_AGE)
  70
  71 dnl Specify a header configuration file
  72 AC_CONFIG_HEADERS(config.h)
  73
  74 AM_MAINTAINER_MODE
  75
  76 dnl Checks for programs.
  77 dnl AC_ARG_PROGRAM
  78 AC_PROG_CC
  79 AC_ISC_POSIX
  80 AC_PROG_INSTALL
  81 AC_PROG_LN_S
  82 AC_PROG_MAKE_SET
  83 AC_PROG_CPP
  84 dnl AC_PROG_RANLIB
  85 AM_PROG_LEX
  86 AC_PROG_YACC
  87 AC_LIB_PREFIX
  88 AC_LIBTOOL_WIN32_DLL
  89 AC_LIBTOOL_RC
  90 AC_PROG_LIBTOOL
  91
  92 CLAWS_ACLOCAL_INCLUDE(m4)
  93
  94 dnl ******************************
  95 dnl Checks for host
  96 dnl Not needed anymore because we
  97 dnl do AC_CANONICAL_SYSTEM above
  98 dnl ******************************
  99 dnl AC_CANONICAL_HOST
 100
 101 dnl Copied from the official gtk+-2 configure.in
 102 AC_MSG_CHECKING([for some Win32 platform])
 103 case "$host" in
 104   *-*-mingw*|*-*-cygwin*)
 105     platform_win32=yes
 106     LDFLAGS="$LDFLAGS -mwindows"
 107     ;;
 108   *)
 109     platform_win32=no
 110     ;;
 111 esac
 112 AC_MSG_RESULT([$platform_win32])
 113 AM_CONDITIONAL(PLATFORM_WIN32, test x"$platform_win32" = x"yes")
 114
 115 AC_MSG_CHECKING([for native Win32])
 116 case "$host" in
 117   *-*-mingw*)
 118     os_win32=yes
 119     ;;
 120   *)
 121     os_win32=no
 122     ;;
 123 esac
 124 AC_MSG_RESULT([$os_win32])
 125 AM_CONDITIONAL(OS_WIN32, test x"$os_win32" = x"yes")
 126
 127 AC_MSG_CHECKING([for Cygwin])
 128 case "$host" in
 129   *-*-cygwin*)
 130     env_cygwin=yes
 131     ;;
 132   *)
 133     env_cygwin=no
 134     ;;
 135 esac
 136 AC_MSG_RESULT([$env_cygwin])
 137 AM_CONDITIONAL(CYGWIN, test x"$env_cygwin" = x"yes")
 138
 139 if test "$GCC" = "yes"
 140 then
 141         CFLAGS="$CFLAGS -Wno-unused-function"
 142 fi
 143
 144 CFLAGS="$CFLAGS -Wall"
 145 pthread_name=
 146 case "$target" in
 147 *-darwin*)
 148         CFLAGS="$CFLAGS -no-cpp-precomp -fno-common"
 149         ;;
 150 *-*-mingw*)
 151         # Note that we need to link to pthreadGC2 in all cases. This
 152         # is because some locking is used even when pthread support is
 153         # disabled.
 154         pthread_name=pthreadGC2
 155         CFLAGS="$CFLAGS -mms-bitfields"
 156         LIBS="$LIBS -l${pthread_name} -lws2_32 -lregex"
 157         ;;
 158 *-*-solaris*)
 159         CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 160         CFLAGS="$CFLAGS -DSOLARIS"
 161         ;;
 162 esac
 163
 164 dnl Checks for iconv
 165 AM_ICONV
 166
 167 dnl
 168 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 169 dnl
 170 syl_save_LIBS=$LIBS
 171 LIBS="$LIBS $GTK_LIBS"
 172 AC_CHECK_FUNCS(bind_textdomain_codeset)
 173 LIBS=$syl_save_LIBS
 174
 175 dnl for gettext
 176 ALL_LINGUAS="bg ca cs de el en_GB es fi fr hr hu it ja ko nb nl pl pt_BR ru sk sr sv zh_CN zh_TW"
 177 GETTEXT_PACKAGE=claws-mail
 178 AC_SUBST(GETTEXT_PACKAGE)
 179 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Define text domain.])
 180
 181 AM_GNU_GETTEXT_VERSION([0.15])
 182 AM_GNU_GETTEXT([external])
 183
 184 manualdir='${docdir}/manual'
 185 AC_ARG_WITH(manualdir,
 186         [  --with-manualdir=DIR    Manual directory],
 187         [manualdir="$withval"])
 188 AC_SUBST(manualdir)
 189
 190 AC_ARG_ENABLE(manual,
 191         [  --disable-manual           do not build manual],
 192         [ac_cv_enable_manual=$enableval], [ac_cv_enable_manual=yes])
 193
 194 AM_CONDITIONAL(BUILD_MANUAL, test x"$ac_cv_enable_manual" = xyes)
 195
 196 dnl Set PACKAGE_DATA_DIR in config.h.
 197 if test "x${datarootdir}" = 'x${prefix}/share'; then
 198         if test "x${prefix}" = "xNONE"; then
 199                 AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${ac_default_prefix}/share/${PACKAGE}",[PACKAGE_DATA_DIR])
 200         else
 201                 AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${prefix}/share/${PACKAGE}",[PACKAGE_DATA_DIR])
 202         fi
 203 else
 204         AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${datarootdir}/${PACKAGE}",[PACKAGE_DATA_DIR])
 205 fi
 206
 207 AC_CHECK_LIB(xpg4, setlocale)
 208
 209 SM_LIBS=""
 210 dnl Check for LibSM
 211 AC_ARG_ENABLE(libsm,
 212         [  --disable-libsm    disable libSM support for session management.],
 213         [ac_cv_enable_libsm=$enableval], [ac_cv_enable_libsm=yes])
 214 AC_MSG_CHECKING([whether to use LibSM])
 215 if test x"$ac_cv_enable_libsm" = xyes; then
 216         AC_MSG_RESULT(yes)
 217         AC_CHECK_LIB(SM, SmcSaveYourselfDone,
 218                 [SM_LIBS="$X_LIBS -lSM -lICE"],ac_cv_enable_libsm=no,
 219                 $X_LIBS -lICE)
 220         AC_CHECK_HEADERS(X11/SM/SMlib.h,,ac_cv_enable_libsm=no)
 221         if test x"$ac_cv_enable_libsm" = xyes; then
 222                 AC_DEFINE(HAVE_LIBSM, 1, [Define to 1 if you have libSM installed])
 223         else
 224                 AC_MSG_RESULT(not found)
 225                 AC_MSG_WARN([*** LibSM will not be supported ***])
 226         fi
 227 else
 228         AC_MSG_RESULT(no)
 229 fi
 230 AC_SUBST(SM_LIBS)
 231
 232 dnl for GThread support (currently disabled)
 233 dnl AC_ARG_ENABLE(threads,
 234 dnl     [  --enable-threads        Enable multithread support [default=no]],
 235 dnl     [use_threads=$enableval], [use_threads=no])
 236
 237 AC_MSG_CHECKING([whether to use threads])
 238 if test x"$use_threads" = xyes ; then
 239         AC_MSG_RESULT(yes)
 240         if test ! -z `$GLIB_CONFIG --help 2>&1 |grep 'gthread'` ; then
 241                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
 242                 LIBS="$LIBS `$GLIB_CONFIG --libs gthread`"
 243                 AC_DEFINE(USE_THREADS, 1, Whether to use multithread or not)
 244         else
 245                 AC_MSG_ERROR([Sylpheed requires GThread from GLib to use threading.])
 246         fi
 247 else
 248         AC_MSG_RESULT(no)
 249 fi
 250
 251 dnl Check for d_type member in struct dirent
 252 AC_MSG_CHECKING([whether struct dirent has d_type member])
 253 AC_CACHE_VAL(ac_cv_dirent_d_type,[
 254         AC_TRY_COMPILE([#include <dirent.h>],
 255                        [struct dirent d; d.d_type = DT_REG;],
 256                        ac_cv_dirent_d_type=yes, ac_cv_dirent_d_type=no)
 257 ])
 258 AC_MSG_RESULT($ac_cv_dirent_d_type)
 259 if test $ac_cv_dirent_d_type = yes; then
 260         AC_DEFINE(HAVE_DIRENT_D_TYPE, 1,
 261                   Define if `struct dirent' has `d_type' member.)
 262 fi
 263
 264 # Check whether mkdir does not take the permission argument.
 265 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
 266
 267 dnl Checks for header files.
 268 AC_HEADER_DIRENT
 269 AC_HEADER_STDC
 270 AC_HEADER_SYS_WAIT
 271 AC_CHECK_HEADERS(fcntl.h sys/file.h unistd.h paths.h \
 272                  sys/param.h sys/utsname.h sys/select.h \
 273                  wchar.h wctype.h locale.h netdb.h)
 274
 275 dnl alf - Check for apache installation f*ck up. apache may also install an
 276 dnl fnmatch, which includes their own regex stuff if USE_HSREGEX is defined
 277 AC_TRY_COMPILE([#include <stdlib.h>
 278                 #include <fnmatch.h>],
 279         [int x = USE_HSREGEX;],
 280         ac_cv_have_apache_fnmatch=yes, ac_cv_have_apache_fnmatch=no)
 281 if test $ac_cv_have_apache_fnmatch = yes; then
 282         AC_DEFINE(HAVE_APACHE_FNMATCH, 1, Define if you need to work around apache regex/fnmatch !KLUDGE!)
 283 fi
 284 AC_MSG_CHECKING([whether to use Apache regex header kludge])
 285 AC_MSG_RESULT($ac_cv_have_apache_fnmatch)
 286
 287 dnl Checks for typedefs, structures, and compiler characteristics.
 288 AC_C_CONST
 289 AC_TYPE_OFF_T
 290 AC_TYPE_PID_T
 291 AC_TYPE_SIZE_T
 292 AC_STRUCT_TM
 293
 294 dnl AC_CHECK_TYPE(wint_t, unsigned int) does not work because wint_t
 295 dnl may be defined only in wchar.h (this happens with gcc-2.96).
 296 dnl So we need to use this extended macro.
 297 CLAWS_CHECK_TYPE(wint_t, unsigned int,
 298 [
 299 #if HAVE_WCHAR_H
 300 #include <wchar.h>
 301 #endif
 302 ], Define to `unsigned int' if <stddef.h> or <wchar.h> doesn't define.)
 303
 304 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF, Used to test for a u32 typedef)
 305 AC_CHECK_SIZEOF(unsigned short, 2)
 306 AC_CHECK_SIZEOF(unsigned int, 4)
 307 AC_CHECK_SIZEOF(unsigned long, 4)
 308
 309 dnl Checks for library functions.
 310 AC_FUNC_ALLOCA
 311 AC_CHECK_FUNCS(gethostname mkdir mktime socket strstr strchr \
 312                uname flock lockf inet_aton inet_addr \
 313                fchmod mkstemp truncate getuid regcomp)
 314
 315 AC_CHECK_FUNCS(fgets_unlocked fwrite_unlocked)
 316
 317 dnl *****************
 318 dnl ** common code **
 319 dnl *****************
 320
 321 dnl check for glib
 322 PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.6 gmodule-2.0 >= 2.6 gobject-2.0 >= 2.6 gthread-2.0 >= 2.6)
 323
 324 GLIB_GENMARSHAL=`pkg-config --variable=glib_genmarshal glib-2.0`
 325 AC_SUBST(GLIB_GENMARSHAL)
 326
 327 AC_SUBST(GLIB_CFLAGS)
 328 AC_SUBST(GLIB_LIBS)
 329
 330 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 331 syl_save_LIBS=$LIBS
 332 LIBS="$LIBS $GTK_LIBS"
 333 AC_CHECK_FUNCS(bind_textdomain_codeset)
 334 LIBS=$syl_save_LIBS
 335
 336 dnl check for IPv6 option
 337 AC_ARG_ENABLE(ipv6,
 338         [  --disable-ipv6           disable build IPv6 support],
 339         [ac_cv_enable_ipv6=$enableval], [ac_cv_enable_ipv6=yes])
 340
 341 dnl automated checks for IPv6 support.
 342 AC_MSG_CHECKING([whether to use IPv6])
 343 if test x"$ac_cv_enable_ipv6" = xyes; then
 344         AC_MSG_RESULT(yes)
 345         AC_MSG_CHECKING([for IPv6 support])
 346         AC_CACHE_VAL(ac_cv_ipv6,[
 347                 AC_TRY_COMPILE([#define INET6
 348                                 #include <sys/types.h>
 349                                 #include <netinet/in.h>],
 350                         [int x = IPPROTO_IPV6; struct in6_addr a;],
 351                         ac_cv_ipv6=yes, ac_cv_ipv6=no)
 352         ])
 353         AC_MSG_RESULT($ac_cv_ipv6)
 354         if test $ac_cv_ipv6 = yes; then
 355                 AC_DEFINE(INET6, 1, Define if you want IPv6 support.)
 356         else
 357                 AC_MSG_WARN(*** IPv6 will not be supported ***)
 358                 ac_cv_enable_ipv6=no
 359         fi
 360 else
 361         AC_MSG_RESULT(no)
 362 fi
 363
 364 dnl Check for OpenSSL
 365 AC_ARG_ENABLE(openssl,
 366         [  --disable-openssl    disable OpenSSL support.],
 367         [ac_cv_enable_openssl=$enableval], [ac_cv_enable_openssl=yes])
 368 dnl GNUTLS
 369 AC_ARG_ENABLE(gnutls,    [ --enable-gnutls      enable GnuTLS support],
 370             [ac_cv_enable_gnutls=$enableval], [ac_cv_enable_gnutls=no])
 371 if test x$ac_cv_enable_openssl = xyes && test x$ac_cv_enable_gnutls != xyes; then
 372         ac_cv_enable_gnutls="no"
 373 fi
 374 if test x$ac_cv_enable_gnutls = xyes; then
 375           ac_cv_enable_openssl="no"
 376 fi
 377
 378 AC_MSG_CHECKING([whether to use OpenSSL])
 379 if test x"$ac_cv_enable_openssl" = xyes; then
 380         AC_MSG_RESULT(yes)
 381         PKG_CHECK_MODULES(OPENSSL, openssl >= 0.9.7, :, ac_cv_enable_openssl=no)
 382         if test x$ac_cv_enable_openssl = xyes; then
 383                 AC_DEFINE(USE_OPENSSL, 1, Define if you want OpenSSL support)
 384         else
 385                 AC_MSG_RESULT(not found)
 386                 AC_MSG_WARN([*** OpenSSL will not be supported ***])
 387         fi
 388 else
 389         AC_MSG_RESULT(no)
 390 fi
 391 AC_SUBST(OPENSSL_CFLAGS)
 392 AC_SUBST(OPENSSL_LIBS)
 393
 394 AC_MSG_CHECKING([whether to use GnuTLS])
 395 if test "x$ac_cv_enable_gnutls" != "xno"; then
 396   OCPPFLAGS="$CPPFLAGS"
 397   OLDFLAGS="$LDFLAGS"
 398   GNUTLS_LIBS=""
 399   AC_CHECK_HEADER(gnutls/gnutls.h, [
 400         AC_CHECK_LIB(gnutls, gnutls_global_deinit,
 401                 [AC_DEFINE(USE_GNUTLS, 1, Define to use GnuTLS.)],
 402                 [ac_cv_enable_gnutls=no])
 403   ],[ac_cv_enable_gnutls=no])
 404   if test "x$ac_cv_enable_gnutls" != "xyes"; then
 405    CPPFLAGS="$OCPPFLAGS"
 406    LDFLAGS="$OLDFLAGS"
 407   fi
 408 fi
 409 if test "x$ac_cv_enable_gnutls" = "xyes"; then
 410   AC_DEFINE([USE_GNUTLS],1, [Define to use GnuTLS])
 411   GNUTLS_LIBS="-lgnutls"
 412 else
 413   GNUTLS_LIBS=""
 414 fi
 415 AC_SUBST(GNUTLS_LIBS)
 416
 417 dnl password encryption
 418 OLDLIBS=$LIBS
 419 LIBS=
 420 case $host_os in
 421         *dragonfly*)
 422                 AC_SEARCH_LIBS(encrypt, cipher, [], AC_MSG_ERROR(['encrypt'-function not found.]))
 423         ;;
 424         *)
 425                 AC_SEARCH_LIBS(encrypt, crypt, [], AC_MSG_ERROR(['encrypt'-function not found.]))
 426         ;;
 427 esac
 428 CRYPT_LIBS=$LIBS
 429 AC_SUBST(CRYPT_LIBS)
 430 LIBS=$OLDLIBS
 431
 432 AC_ARG_WITH(passcrypt-key, [  --with-passcrypt-key=KEY     Key used to encode passwords (8 byte string)],
 433             with_passcrypt_key="$withval", with_passcrypt_key="passkey0")
 434 AC_SUBST(PASSCRYPT_KEY, $with_passcrypt_key)
 435
 436 dnl RC dir (will be default at a certain point in time)
 437 AC_ARG_WITH(config-dir,    [  --with-config-dir=RCDIR      Local configuration dir (default: .claws-mail)],
 438               ac_cv_with_config_dir="$withval", ac_cv_with_config_dir=".claws-mail")
 439 if test x"$ac_cv_with_config_dir" = x""; then
 440         ac_cv_with_config_dir=".claws-mail"
 441 fi
 442 AC_DEFINE_UNQUOTED(CFG_RC_DIR, "$ac_cv_with_config_dir", Configuration directory)
 443
 444 dnl ************************
 445 dnl ** GTK user interface **
 446 dnl ************************
 447
 448 dnl Checks for GTK
 449 PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.6)
 450
 451 dnl --disable-deprecated switch for GTK2 purification
 452 AC_ARG_ENABLE(deprecated, [  --disable-deprecated  disable deprecated GTK functions. ],
 453                           [GTK_CFLAGS="$GTK_CFLAGS -DG_DISABLE_DEPRECATED -DGTK_DISABLE_DEPRECATED"], [])
 454
 455 AC_SUBST(GTK_CFLAGS)
 456 AC_SUBST(GTK_LIBS)
 457
 458 dnl GNU/Aspell is used for spell checking
 459 AC_ARG_ENABLE(aspell,
 460         [  --disable-aspell         disable GNU/aspell support],
 461         [ac_cv_enable_aspell=$enableval], [ac_cv_enable_aspell=yes])
 462 AC_MSG_CHECKING([whether to use GNU/aspell])
 463 if test $ac_cv_enable_aspell = yes; then
 464         AC_MSG_RESULT(yes)
 465         AM_PATH_ASPELL(0.50, AC_DEFINE(USE_ASPELL, 1, Define if you use ASPELL to support spell checking),
 466                       [use_aspell=no ac_cv_enable_aspell=no])
 467 else
 468         AC_MSG_RESULT(no)
 469 fi
 470
 471 dnl want crash dialog
 472 AC_ARG_ENABLE(crash-dialog,
 473         [  --enable-crash-dialog   Enable crash dialog [default=no]],
 474         [ac_cv_enable_crash_dialog=$enableval], [ac_cv_enable_crash_dialog=no])
 475 if test $ac_cv_enable_crash_dialog = yes; then
 476 dnl check if GDB is somewhere
 477         AC_CHECK_PROG(ac_cv_enable_crash_dialog, gdb, yes, no)
 478         AC_MSG_CHECKING([whether to use crash dialog])
 479         if test $ac_cv_enable_crash_dialog = yes; then
 480                 AC_DEFINE(CRASH_DIALOG, 1, Pop up crash dialog)
 481         fi
 482         AC_MSG_RESULT($ac_cv_enable_crash_dialog)
 483 fi
 484
 485 dnl Maemo platform
 486 AC_ARG_ENABLE(maemo,
 487         [  --enable-maemo   build for the Maemo platform [default=no]],
 488         [ac_cv_enable_maemo=$enableval], [ac_cv_enable_maemo=no])
 489 if test $ac_cv_enable_maemo = yes; then
 490         PKG_CHECK_MODULES(MAEMO, libosso hildon-libs hildon-fm gnome-vfs-2.0, ac_cv_enable_maemo=yes,
 491                   ac_cv_enable_maemo=no)
 492         AC_SUBST(MAEMO_CFLAGS)
 493         AC_SUBST(MAEMO_LIBS)
 494         if test $ac_cv_enable_maemo = no; then
 495                 #test for chinook
 496                 PKG_CHECK_MODULES(MAEMO, libosso hildon-1 hildon-fm-2 gnome-vfs-2.0 hal, ac_cv_enable_maemo=yes,
 497                           ac_cv_enable_maemo=no)
 498                 AC_SUBST(MAEMO_CFLAGS)
 499                 AC_SUBST(MAEMO_LIBS)
 500                 if test $ac_cv_enable_maemo = no; then
 501                         AC_MSG_ERROR(one of libosso hildon-libs hildon-fm hildon-1 hildon-fm-2 not found)
 502                 else
 503                         AC_DEFINE(MAEMO, 1, Build for maemo)
 504                         AC_DEFINE(CHINOOK, 1, Maemo chinook)
 505                 fi
 506         else
 507                 AC_DEFINE(MAEMO, 1, Build for maemo)
 508         fi
 509 fi
 510 PKG_CHECK_MODULES(CONIC, conic, ac_cv_enable_conic=yes,
 511           ac_cv_enable_conic=no)
 512 AC_SUBST(CONIC_CFLAGS)
 513 AC_SUBST(CONIC_LIBS)
 514 if test $ac_cv_enable_conic = yes; then
 515         AC_DEFINE(CONIC, 1, Have conic lib)
 516 fi
 517
 518 dnl Check for X-Face support
 519 AC_ARG_ENABLE(compface,
 520         [  --disable-compface      disable compface (X-Face) support],
 521         [ac_cv_enable_compface=$enableval], [ac_cv_enable_compface=yes])
 522 AC_MSG_CHECKING([whether to use compface])
 523 if test x"$ac_cv_enable_compface" = xyes; then
 524         AC_MSG_RESULT(yes)
 525         AC_CHECK_LIB(compface, uncompface,
 526                 [AC_DEFINE(HAVE_LIBCOMPFACE, 1, Define if you want compface support.)],
 527                 [ac_cv_enable_compface=no])
 528         if test x"$ac_cv_enable_compface" = xyes; then
 529                 COMPFACE_LIBS="-lcompface"
 530         else
 531                 COMPFACE_LIBS=""
 532         fi
 533         AC_SUBST(COMPFACE_LIBS)
 534 else
 535         AC_MSG_RESULT(no)
 536 fi
 537
 538 dnl check for pthread support
 539 AC_ARG_ENABLE(pthread,
 540         [  --disable-pthread           disable pthread support],
 541         [ac_cv_enable_pthread=$enableval], [ac_cv_enable_pthread=yes])
 542 AC_MSG_CHECKING([whether to use pthread])
 543 if test x$ac_cv_enable_pthread = xno; then
 544         AC_MSG_RESULT(no)
 545 else
 546         AC_MSG_RESULT(yes)
 547
 548         # For W32 we need to use a special ptrhead lib. In this case we can't
 549         # use AC_CHECK_LIB because it has no means of checking for a
 550         # library installed under a different name.  Checking for the
 551         # header is okay.
 552         if test -n "${pthread_name}" ; then
 553            ac_cv_enable_pthread=yes
 554         else
 555         AC_CHECK_LIB(pthread, pthread_create, :, ac_cv_enable_pthread=no)
 556         fi
 557         AC_CHECK_HEADERS(pthread.h, :, ac_cv_enable_pthread=no)
 558
 559         if test x$ac_cv_enable_pthread = xyes; then
 560                 AC_DEFINE(USE_PTHREAD, 1, Define if you have pthread)
 561                 if test -z "${pthread_name}" ; then
 562                 PTHREAD_LIBS="-lpthread"
 563         fi
 564         fi
 565
 566 fi
 567 AC_SUBST(PTHREAD_LIBS)
 568
 569 dnl
 570 dnl Check whether we need to pass -lresolv
 571 dnl We know that we don't need it for W32.
 572 dnl
 573 if test x$os_win32 = xno; then
 574   t_oldLibs="$LIBS"
 575   LIBS="$LIBS"
 576   ac_cv_var__res_options=no
 577   AC_TRY_LINK([#include <sys/types.h>
 578              #include <sys/socket.h>
 579              #include <netinet/in.h>
 580              #include <arpa/nameser.h>
 581              #include <resolv.h>],
 582                 [_res.options = RES_INIT;],
 583                 ac_cv_var__res_options=yes);
 584   if test "$ac_cv_var__res_options" != "yes"; then
 585         LIBRESOLV="-lresolv"
 586   fi
 587   LIBS="$t_oldLibs"
 588
 589   if test "x$LIBRESOLV" = "x"; then
 590         AC_CHECK_LIB(resolv, res_query, [LIBRESOLV=-lresolv])
 591         LIBS="$t_oldLibs"
 592   fi
 593 fi
 594 AC_SUBST(LIBRESOLV)
 595
 596 LIBS="$LIBS $LIBRESOLV"
 597
 598 dnl for LDAP support in addressbook
 599 dnl no check for libraries; dynamically loaded
 600 AC_ARG_ENABLE(ldap,
 601         [  --disable-ldap         disable LDAP support],
 602         [ac_cv_enable_ldap=$enableval], [ac_cv_enable_ldap=yes])
 603 AC_MSG_CHECKING([whether to use LDAP])
 604 if test x"$ac_cv_enable_ldap" = xno; then
 605         AC_MSG_RESULT(no)
 606 elif test x"$ac_cv_enable_ldap" = xyes -a x"$ac_cv_enable_pthread" = xno; then
 607         AC_MSG_RESULT(no - LDAP support needs pthread support)
 608
 609         ac_cv_enable_ldap=no
 610 else
 611         AC_MSG_RESULT(yes)
 612
 613         dnl check for available libraries, and pull them in
 614         AC_CHECK_LIB(resolv, res_query, LDAP_LIBS="$LDAP_LIBS -lresolv")
 615         AC_CHECK_LIB(socket, bind, LDAP_LIBS="$LDAP_LIBS -lsocket")
 616         AC_CHECK_LIB(nsl, gethostbyaddr, LDAP_LIBS="$LDAP_LIBS -lnsl")
 617         AC_CHECK_LIB(lber, ber_get_tag, LDAP_LIBS="$LDAP_LIBS -llber",,
 618                      $LDAP_LIBS)
 619
 620         AC_CHECK_HEADERS(ldap.h lber.h,
 621                          [ ac_cv_enable_ldap=yes ],
 622                          [ ac_cv_enable_ldap=no ])
 623
 624         if test "$ac_cv_enable_ldap" = yes; then
 625                 AC_CHECK_LIB(ldap, ldap_open,
 626                              [ ac_cv_enable_ldap=yes ],
 627                              [ ac_cv_enable_ldap=no ],
 628                              $LDAP_LIBS)
 629
 630                 AC_CHECK_LIB(ldap, ldap_start_tls_s,
 631                              [ ac_cv_have_tls=yes ],
 632                              [ ac_cv_have_tls=no ])
 633
 634         fi
 635
 636         AC_MSG_CHECKING([whether ldap library is available])
 637         AC_MSG_RESULT($ac_cv_enable_ldap)
 638
 639         AC_MSG_CHECKING([whether TLS library is available])
 640         AC_MSG_RESULT($ac_cv_have_tls)
 641
 642         if test "$ac_cv_enable_ldap" = yes; then
 643                 AC_DEFINE(USE_LDAP, 1, Define if you want LDAP support in addressbook.)
 644                 LDAP_LIBS="$LDAP_LIBS -lldap"
 645                 AC_SUBST(LDAP_LIBS)
 646                 if test "$ac_cv_have_tls" = yes; then
 647                         AC_DEFINE(USE_LDAP_TLS, 1, Define if you want LDAP TLS support in addressbook.)
 648                 fi
 649         fi
 650 fi
 651
 652 dnl for JPilot support in addressbook
 653 dnl no check for libraries; these are dynamically loaded
 654 AC_ARG_ENABLE(jpilot,
 655         [  --disable-jpilot         disable JPilot support],
 656         [ac_cv_enable_jpilot=$enableval], [ac_cv_enable_jpilot=yes])
 657 AC_MSG_CHECKING([whether to use JPilot])
 658 if test "$ac_cv_enable_jpilot" = yes; then
 659         AC_MSG_RESULT(yes)
 660         AC_CHECK_HEADERS(pi-args.h pi-appinfo.h pi-address.h pi-version.h,
 661                          [ AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ],
 662                          [ ac_cv_enable_jpilot=no ])
 663         if test "$ac_cv_enable_jpilot" = no; then
 664                 AC_CHECK_HEADERS(libpisock/pi-args.h libpisock/pi-appinfo.h libpisock/pi-address.h libpisock/pi-version.h,
 665                                  [ ac_cv_enable_jpilot=yes
 666                                    AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ])
 667         fi
 668
 669         AC_CHECK_LIB(pisock, unpack_Address, [JPILOT_LIBS="-lpisock"], [JPILOT_LIBS="" ac_cv_enable_jpilot="no"])
 670         if test x"$ac_cv_enable_jpilot" = xyes; then
 671                 AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.)
 672         else
 673                 AC_MSG_NOTICE([JPilot support not available])
 674         fi
 675         AC_SUBST(JPILOT_LIBS)
 676 else
 677         AC_MSG_RESULT(no)
 678 fi
 679
 680 dnl #######################################################################
 681 dnl # Check for startup notification
 682 dnl #######################################################################
 683 AC_ARG_ENABLE(startup-notification, [  --disable-startup-notification    disable startup notification support],,enable_startup_notification=yes)
 684
 685 if test "x$enable_startup_notification" = "xyes"; then
 686         PKG_CHECK_MODULES(STARTUP_NOTIFICATION, libstartup-notification-1.0 >= 0.5,
 687         [
 688                 AC_DEFINE(HAVE_STARTUP_NOTIFICATION, 1, [Define if we're using libstartup-notification.])
 689                 echo "Building with libstartup-notification"
 690                 enable_startup_notification=yes
 691         ],
 692         [
 693                 echo "Building without libstartup-notification"
 694                 enable_startup_notification=no
 695         ])
 696
 697         AC_SUBST(STARTUP_NOTIFICATION_CFLAGS)
 698         AC_SUBST(STARTUP_NOTIFICATION_LIBS)
 699 fi
 700
 701 dnl *************************
 702 dnl ** section for plugins **
 703 dnl *************************
 704
 705 PLUGINS=""
 706
 707 dnl --- Trayicon ---
 708 AC_MSG_CHECKING([whether to build Trayicon plugin])
 709 AC_ARG_ENABLE(trayicon-plugin,
 710         [  --disable-trayicon-plugin         do not build System Tray Icon plugin],
 711         [ac_cv_enable_trayicon_plugin=$enableval], [ac_cv_enable_trayicon_plugin=yes])
 712 if test x"$ac_cv_enable_trayicon_plugin" = xyes; then
 713         AC_MSG_RESULT(yes)
 714         PLUGINS="trayicon $PLUGINS"
 715 else
 716         AC_MSG_RESULT(no)
 717 fi
 718 AM_CONDITIONAL(BUILD_TRAYICON_PLUGIN, test x"$ac_cv_enable_trayicon_plugin" = xyes)
 719
 720 dnl --- SpamAssassin ---
 721 AC_MSG_CHECKING([whether to build SpamAssassin plugin])
 722 AC_ARG_ENABLE(spamassassin-plugin,
 723         [  --disable-spamassassin-plugin      do not build SpamAssassin plugin],
 724         [ac_cv_enable_spamassassin_plugin=$enableval], [ac_cv_enable_spamassassin_plugin=yes])
 725 if test x"$ac_cv_enable_spamassassin_plugin" = xyes; then
 726         AC_MSG_RESULT(yes)
 727         AC_SPAMASSASSIN
 728         PLUGINS="spamassassin $PLUGINS"
 729         AC_DEFINE(USE_SPAMASSASSIN_PLUGIN, 1, Define if spamassassin plugin is being built.)
 730 else
 731         AC_MSG_RESULT(no)
 732 fi
 733 AM_CONDITIONAL(BUILD_SPAMASSASSIN_PLUGIN, test x"$ac_cv_enable_spamassassin_plugin" = xyes)
 734
 735 dnl --- Bogofilter ---
 736 AC_MSG_CHECKING([whether to build Bogofilter plugin])
 737 AC_ARG_ENABLE(bogofilter-plugin,
 738         [  --disable-bogofilter-plugin      do not build bogofilter plugin],
 739         [ac_cv_enable_bogofilter_plugin=$enableval], [ac_cv_enable_bogofilter_plugin=yes])
 740 if test x"$ac_cv_enable_bogofilter_plugin" = xyes; then
 741         AC_MSG_RESULT(yes)
 742         PLUGINS="bogofilter $PLUGINS"
 743         AC_DEFINE(USE_BOGOFILTER_PLUGIN, 1, Define if bogofilter plugin is being built.)
 744 else
 745         AC_MSG_RESULT(no)
 746 fi
 747 AM_CONDITIONAL(BUILD_BOGOFILTER_PLUGIN, test x"$ac_cv_enable_bogofilter_plugin" = xyes)
 748
 749 dnl --- PGP/CORE ---
 750 AC_MSG_CHECKING([whether to build PGP/CORE plugin])
 751 AC_ARG_ENABLE(pgpcore-plugin,
 752         [  --disable-pgpcore-plugin           do not build PGP/Core plugin],
 753         [ac_cv_enable_pgpcore_plugin=$enableval], [ac_cv_enable_pgpcore_plugin=yes])
 754 if test x"$ac_cv_enable_pgpcore_plugin" = xyes; then
 755         AC_MSG_RESULT(yes)
 756         AM_PATH_GPGME(1.0.0, AC_DEFINE(USE_GPGME, 1, Define if you use GPGME to support OpenPGP.),
 757                       [ac_cv_enable_pgpcore_plugin=no])
 758         if test x"$ac_cv_enable_pgpcore_plugin" = xyes; then
 759                 PLUGINS="pgpcore $PLUGINS"
 760                 AM_PATH_GPGME(1.1.1,
 761                               AC_DEFINE(HAVE_GPGME_PKA_TRUST, 1,
 762                                         [Define if GPGME supports PKA.]))
 763                 #needed to get GPGME_LIBS and al correctly
 764                 AM_PATH_GPGME(1.0.0, AC_DEFINE(USE_GPGME, 1, Define if you use GPGME to support OpenPGP.),
 765                           [ac_cv_enable_pgpcore_plugin=no])
 766         else
 767                 AC_MSG_WARN([*** PGP/CORE plugin will not be built ***])
 768         fi
 769 else
 770         AC_MSG_RESULT(no)
 771 fi
 772 AM_CONDITIONAL(BUILD_PGPCORE_PLUGIN, test x"$ac_cv_enable_pgpcore_plugin" = xyes)
 773
 774 AC_MSG_CHECKING([whether to build PGP/MIME plugin])
 775 AC_ARG_ENABLE(pgpmime-plugin,
 776         [  --disable-pgpmime-plugin           do not build PGP/MIME plugin],
 777         [ac_cv_enable_pgpmime_plugin=$enableval], [ac_cv_enable_pgpmime_plugin=yes])
 778 if test x"$ac_cv_enable_pgpmime_plugin" = xyes; then
 779         AC_MSG_RESULT(yes)
 780         if test x"$ac_cv_enable_pgpcore_plugin" = xyes; then
 781                 PLUGINS="pgpmime $PLUGINS"
 782         else
 783                 AC_MSG_WARN([*** PGP/MIME plugin cannot be built ***])
 784                 AC_MSG_WARN([*** without the PGP/CORE plugin     ***])
 785         fi
 786 else
 787         AC_MSG_RESULT(no)
 788 fi
 789 AM_CONDITIONAL(BUILD_PGPMIME_PLUGIN, test x"$ac_cv_enable_pgpmime_plugin" = xyes)
 790
 791 AC_MSG_CHECKING([whether to build PGP/Inline plugin])
 792 AC_ARG_ENABLE(pgpinline-plugin,
 793         [  --disable-pgpinline-plugin           do not build PGP/Inline plugin],
 794         [ac_cv_enable_pgpinline_plugin=$enableval], [ac_cv_enable_pgpinline_plugin=yes])
 795 if test x"$ac_cv_enable_pgpinline_plugin" = xyes; then
 796         AC_MSG_RESULT(yes)
 797         if test x"$ac_cv_enable_pgpcore_plugin" = xyes; then
 798                 PLUGINS="pgpinline $PLUGINS"
 799         else
 800                 AC_MSG_WARN([*** PGP/Inline plugin cannot be built ***])
 801                 AC_MSG_WARN([*** without the PGP/CORE plugin     ***])
 802         fi
 803 else
 804         AC_MSG_RESULT(no)
 805 fi
 806 AM_CONDITIONAL(BUILD_PGPINLINE_PLUGIN, test x"$ac_cv_enable_pgpinline_plugin" = xyes)
 807
 808 dnl --- Dillo Viewer ---
 809 AC_MSG_CHECKING([whether to build Dillo plugin])
 810 AC_ARG_ENABLE(dillo-viewer-plugin,
 811         [  --disable-dillo-viewer-plugin     do not build Dillo plugin for html mail rendering],
 812         [ac_cv_enable_dillo_viewer_plugin=$enableval], [ac_cv_enable_dillo_viewer_plugin=yes])
 813 if test x"$ac_cv_enable_dillo_viewer_plugin" = xyes; then
 814         AC_MSG_RESULT(yes)
 815         PLUGINS="dillo-viewer $PLUGINS"
 816 else
 817         AC_MSG_RESULT(no)
 818 fi
 819 AM_CONDITIONAL(BUILD_DILLO_VIEWER_PLUGIN, test x"$ac_cv_enable_dillo_viewer_plugin" = xyes)
 820
 821 dnl --- Demo ---
 822 AC_ARG_ENABLE(demo-plugin,
 823         [  --enable-demo-plugin              build demo plugin],
 824         [ac_cv_enable_demo_plugin=$enableval], [ac_cv_enable_demo_plugin=no])
 825 if test x"$ac_cv_enable_demo_plugin" = xyes; then
 826         PLUGINS="demo $PLUGINS"
 827 fi
 828 AM_CONDITIONAL(BUILD_DEMO_PLUGIN, test x"$ac_cv_enable_demo_plugin" = xyes)
 829
 830 dnl --- ClamAV ---
 831 AC_MSG_CHECKING([whether to build ClamAV plugin])
 832 AC_ARG_ENABLE(clamav-plugin,
 833         [  --disable-clamav-plugin           do not build Clam AntiVirus plugin],
 834         [ac_cv_enable_clamav_plugin=$enableval], [ac_cv_enable_clamav_plugin=yes])
 835 if test x"$ac_cv_enable_clamav_plugin" = xyes; then
 836         AC_MSG_RESULT(yes)
 837         PKG_CHECK_MODULES(CLAMAV, libclamav, ac_cv_enable_clamav_plugin=yes,
 838                           ac_cv_enable_clamav_plugin=no)
 839         if test x"$ac_cv_enable_clamav_plugin" = xyes; then
 840                 PLUGINS="clamav $PLUGINS"
 841         else
 842                 AC_MSG_RESULT(not found)
 843                 AC_MSG_WARN([*** ClamAV plugin will not be built ***])
 844         fi
 845 else
 846         AC_MSG_RESULT(no)
 847 fi
 848 AC_SUBST(CLAMAV_LIBS)
 849 AM_CONDITIONAL(BUILD_CLAMAV_PLUGIN, test x"$ac_cv_enable_clamav_plugin" = xyes)
 850
 851 dnl Libetpan
 852 AC_MSG_CHECKING([whether to use libetpan])
 853 AC_ARG_ENABLE(libetpan,
 854         [  --disable-libetpan           disable IMAP4/NNTP (libetpan) support],
 855         [ac_cv_enable_libetpan=$enableval], [ac_cv_enable_libetpan=yes])
 856 if test x"$ac_cv_enable_libetpan" = xyes; then
 857         AC_MSG_RESULT(yes)
 858         libetpan_result=no
 859         AC_PATH_PROG(libetpanconfig, [libetpan-config])
 860         if test "x$libetpanconfig" != "x"; then
 861           CPPFLAGS="$CPPFLAGS `$libetpanconfig --cflags 2>/dev/null`"
 862           AC_CHECK_HEADER(libetpan/libetpan.h, [libetpan_result=yes])
 863           if test "x$libetpan_result" = "xyes"; then
 864             AC_MSG_CHECKING([whether libetpan-config hints compiles and links fine])
 865             LIBS="$LIBS `$libetpanconfig --libs 2>/dev/null`"
 866             AC_TRY_LINK([#include <libetpan/dbstorage.h>], [db_mailstorage_init(NULL, NULL);], [libetpan_result=yes], [libetpan_result=no])
 867             AC_MSG_RESULT([$libetpan_result])
 868           fi
 869         fi
 870         if test "x$libetpan_result" = "xyes"; then
 871            LIBETPAN_CPPFLAGS="`$libetpanconfig --cflags`"
 872            LIBETPAN_LIBS="`$libetpanconfig --libs`"
 873            LIBETPAN_VERSION=`$libetpanconfig --version | sed "s/\.//g" | sed "s/-.*$//"`
 874            if test "$LIBETPAN_VERSION" -lt "049"; then
 875                 AC_MSG_RESULT([*** Claws Mail requires libetpan 0.49 or newer. See http://www.etpan.org/])
 876                 AC_MSG_RESULT([*** You can use --disable-libetpan if you don't need IMAP4 and/or NNTP support.])
 877                 AC_MSG_ERROR([libetpan 0.49 not found])
 878            fi
 879            AC_SUBST(LIBETPAN_FLAGS)
 880            AC_SUBST(LIBETPAN_LIBS)
 881            AC_DEFINE(HAVE_LIBETPAN, 1, Define if you want IMAP and/or NNTP support.)
 882         else
 883            AC_MSG_RESULT([*** Claws Mail requires libetpan 0.49 or newer. See http://www.etpan.org/ ])
 884            AC_MSG_RESULT([*** You can use --disable-libetpan if you don't need IMAP4 and/or NNTP support.])
 885            AC_MSG_ERROR([libetpan 0.49 not found])
 886         fi
 887 else
 888         AC_MSG_RESULT(no)
 889 fi
 890 AM_CONDITIONAL(CLAWS_LIBETPAN, test "x$libetpan_result" = "xyes")
 891
 892
 893 dnl Printing support.
 894 PKG_CHECK_MODULES(GTK210, gtk+-2.0 >= 2.10, ac_cv_have_gtk210=yes, ac_cv_have_gtk210=no)
 895
 896 AC_MSG_CHECKING([whether to use libgnomeprint])
 897 AC_ARG_ENABLE(gnomeprint,
 898         [  --disable-gnomeprint         disable libgnomeprint support],
 899         [ac_cv_enable_gnomeprint=$enableval], [ac_cv_enable_gnomeprint=auto])
 900
 901 if test x$ac_cv_have_gtk210 = xyes; then
 902         ac_cv_enable_gnomeprint="no"
 903 fi
 904
 905 if test x$ac_cv_enable_gnomeprint = xyes \
 906         -o \( x$ac_cv_enable_gnomeprint = xauto \
 907            -a x$ac_cv_have_gtk210 = xno \); then
 908         AC_MSG_RESULT(yes)
 909         PKG_CHECK_MODULES(GNOMEPRINT, libgnomeprint-2.2 libgnomeprintui-2.2,
 910                           ac_cv_enable_gnomeprint=yes, ac_cv_enable_gnomeprint=no)
 911         if test x"$ac_cv_enable_gnomeprint" = xyes; then
 912                 AC_DEFINE(USE_GNOMEPRINT, 1, Define if you want libgnomeprint support)
 913         else
 914                 AC_MSG_RESULT(not found)
 915                 AC_MSG_WARN([*** libgnomeprintui wasn't found    ***])
 916                 AC_MSG_WARN([*** using built-in printing support ***])
 917         fi
 918 else
 919         ac_cv_enable_gnomeprint=no
 920         AC_MSG_RESULT(no)
 921 fi
 922 AM_CONDITIONAL(CLAWS_GNOMEPRINT, test x"$ac_cv_enable_gnomeprint" = x"yes")
 923
 924 AC_MSG_CHECKING([whether to use valgrind])
 925 AC_ARG_ENABLE(valgrind,
 926         [  --disable-valgrind           disable valgrind support for debugging],
 927         [ac_cv_enable_valgrind=$enableval], [ac_cv_enable_valgrind=yes])
 928 if test x$ac_cv_enable_valgrind = xyes; then
 929         AC_MSG_RESULT(yes)
 930         PKG_CHECK_MODULES(VALGRIND, valgrind >= 2.4.0,
 931                           ac_cv_enable_valgrind=yes, ac_cv_enable_valgrind=no)
 932         if test x"$ac_cv_enable_valgrind" = xyes; then
 933                 AC_DEFINE(HAVE_VALGRIND, 1, Define if you want valgrind support)
 934         else
 935                 AC_MSG_RESULT(not found)
 936         fi
 937 else
 938         AC_MSG_RESULT(no)
 939 fi
 940 AM_CONDITIONAL(CLAWS_VALGRIND, test x"$ac_cv_enable_valgrind" = x"yes")
 941
 942 dnl ****************************
 943 dnl ** Final configure output **
 944 dnl ****************************
 945
 946 AC_OUTPUT([
 947 Makefile
 948 m4/Makefile
 949 po/Makefile.in
 950 src/common/version.h
 951 src/Makefile
 952 src/common/Makefile
 953 src/common/passcrypt.h
 954 src/gtk/Makefile
 955 src/etpan/Makefile
 956 src/plugins/Makefile
 957 src/plugins/demo/Makefile
 958 src/plugins/bogofilter/Makefile
 959 src/plugins/spamassassin/Makefile
 960 src/plugins/dillo_viewer/Makefile
 961 src/plugins/trayicon/Makefile
 962 src/plugins/trayicon/libeggtrayicon/Makefile
 963 src/plugins/clamav/Makefile
 964 src/plugins/pgpcore/Makefile
 965 src/plugins/pgpmime/Makefile
 966 src/plugins/pgpinline/Makefile
 967 doc/Makefile
 968 doc/man/Makefile
 969 tools/Makefile
 970 config/Makefile
 971 manual/Makefile
 972 manual/dtd/Makefile
 973 manual/dist/Makefile
 974 manual/dist/pdf/Makefile
 975 manual/dist/ps/Makefile
 976 manual/dist/html/Makefile
 977 manual/dist/txt/Makefile
 978 manual/fr/Makefile
 979 manual/fr/dist/Makefile
 980 manual/fr/dist/pdf/Makefile
 981 manual/fr/dist/ps/Makefile
 982 manual/fr/dist/html/Makefile
 983 manual/fr/dist/txt/Makefile
 984 manual/pl/Makefile
 985 manual/pl/dist/Makefile
 986 manual/pl/dist/pdf/Makefile
 987 manual/pl/dist/ps/Makefile
 988 manual/pl/dist/html/Makefile
 989 manual/pl/dist/txt/Makefile
 990 manual/es/Makefile
 991 manual/es/dist/Makefile
 992 manual/es/dist/pdf/Makefile
 993 manual/es/dist/ps/Makefile
 994 manual/es/dist/html/Makefile
 995 manual/es/dist/txt/Makefile
 996 claws-mail.pc
 997 ])
 998
 999 dnl Output the configuration summary
1000 echo ""
1001 echo "$PACKAGE $VERSION"
1002 echo ""
1003 echo "JPilot            : $ac_cv_enable_jpilot"
1004 echo "LDAP              : $ac_cv_enable_ldap"
1005 echo "OpenSSL           : $ac_cv_enable_openssl"
1006 echo "gnuTLS            : $ac_cv_enable_gnutls"
1007 echo "iconv             : $am_cv_func_iconv"
1008 echo "compface          : $ac_cv_enable_compface"
1009 echo "IPv6              : $ac_cv_enable_ipv6"
1010 echo "GNU/aspell        : $ac_cv_enable_aspell"
1011 echo "IMAP4             : $ac_cv_enable_libetpan"
1012 echo "NNTP              : $ac_cv_enable_libetpan"
1013 echo "Crash dialog      : $ac_cv_enable_crash_dialog"
1014 echo "Libgnomeprint     : $ac_cv_enable_gnomeprint"
1015 echo "GTK+ print support: $ac_cv_have_gtk210"
1016 echo "LibSM             : $ac_cv_enable_libsm"
1017 echo "Manual            : $ac_cv_enable_manual"
1018 echo "Plugins           : $PLUGINS"
1019 echo "Maemo  build      : $ac_cv_enable_maemo"
1020 echo "Config dir        : $ac_cv_with_config_dir"
1021 echo ""
1022 echo "The binary will be installed in $prefix/bin"
1023 echo ""
1024 echo "Configure finished, type 'make' to build."