2007-07-07 [paul] 2.10.0cvs9
[claws.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script.
2 AC_PREREQ(2.60)
3 AC_INIT(src/main.c)
4 AC_CONFIG_AUX_DIR(config)
5
6 PACKAGE=claws-mail
7
8 dnl version number
9 MAJOR_VERSION=2
10 MINOR_VERSION=10
11 MICRO_VERSION=0
12 INTERFACE_AGE=0
13 BINARY_AGE=0
14 EXTRA_VERSION=9
15 EXTRA_RELEASE=
16 EXTRA_GTK2_VERSION=
17
18 if test \( $EXTRA_VERSION -eq 0 \) -o \( "x$EXTRA_RELEASE" != "x" \); then
19     VERSION=${MAJOR_VERSION}.${MINOR_VERSION}.${MICRO_VERSION}${EXTRA_RELEASE}${EXTRA_GTK2_VERSION}
20 else
21     VERSION=${MAJOR_VERSION}.${MINOR_VERSION}.${MICRO_VERSION}cvs${EXTRA_VERSION}${EXTRA_GTK2_VERSION}
22 fi
23
24 dnl set $target
25 AC_CANONICAL_SYSTEM
26
27 dnl
28 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
29 dnl AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
30 dnl AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
31 AC_SUBST(PACKAGE)
32 AC_SUBST(VERSION)
33 AC_SUBST(MAJOR_VERSION)
34 AC_SUBST(MINOR_VERSION)
35 AC_SUBST(MICRO_VERSION)
36 AC_SUBST(EXTRA_VERSION)
37
38 dnl GNOME installed?
39 AC_PATH_PROG(GNOME_CONFIG, gnome-config, no)
40 if test "$GNOME_CONFIG" != no; then
41         gnomedatadir="`gnome-config --datadir`"
42         gnomeprefix="`gnome-config --prefix`"
43         if test "${prefix}" = "NONE"; then
44                 gnomedatadir="${ac_default_prefix}/${gnomedatadir#${gnomeprefix}}"
45         else
46                 gnomedatadir="${prefix}/${gnomedatadir#${gnomeprefix}}"
47         fi
48         AC_SUBST(gnomedatadir)
49 fi
50 AM_CONDITIONAL(CLAWS_GNOME, test -n "$gnomedatadir")
51
52 dnl GNOME 2.x installed?
53 PKG_CHECK_MODULES(GNOME2, libgnome-2.0 >= 2.0, ac_enable_gnome2=yes, ac_enable_gnome2=no)
54 AM_CONDITIONAL(CLAWS_GNOME2, test x"$ac_enable_gnome2" = x"yes")
55
56 dnl libtool versioning
57 LT_RELEASE=$MAJOR_VERSION.$MINOR_VERSION
58 LT_CURRENT=`expr $MICRO_VERSION - $INTERFACE_AGE`
59 LT_REVISION=$INTERFACE_AGE
60 LT_AGE=`expr $BINARY_AGE - $INTERFACE_AGE`
61 AC_SUBST(LT_RELEASE)
62 AC_SUBST(LT_CURRENT)
63 AC_SUBST(LT_REVISION)
64 AC_SUBST(LT_AGE)
65
66 dnl Specify a header configuration file
67 AC_CONFIG_HEADERS(config.h)
68
69 AM_MAINTAINER_MODE
70
71 dnl Checks for programs.
72 dnl AC_ARG_PROGRAM
73 AC_PROG_CC
74 AC_ISC_POSIX
75 AC_PROG_INSTALL
76 AC_PROG_LN_S
77 AC_PROG_MAKE_SET
78 AC_PROG_CPP
79 dnl AC_PROG_RANLIB
80 AM_PROG_LEX
81 AC_PROG_YACC
82 AC_LIB_PREFIX
83 AC_LIBTOOL_WIN32_DLL
84 AC_LIBTOOL_RC
85 AC_PROG_LIBTOOL
86
87 CLAWS_ACLOCAL_INCLUDE(m4)
88   
89 dnl ******************************
90 dnl Checks for host
91 dnl Not needed anymore because we 
92 dnl do AC_CANONICAL_SYSTEM above
93 dnl ******************************
94 dnl AC_CANONICAL_HOST
95
96 dnl Copied from the official gtk+-2 configure.in
97 AC_MSG_CHECKING([for some Win32 platform])
98 case "$host" in
99   *-*-mingw*|*-*-cygwin*)
100     platform_win32=yes
101     LDFLAGS="$LDFLAGS -mwindows"
102     ;;
103   *)
104     platform_win32=no
105     ;;
106 esac
107 AC_MSG_RESULT([$platform_win32])
108 AM_CONDITIONAL(PLATFORM_WIN32, test x"$platform_win32" = x"yes")
109
110 AC_MSG_CHECKING([for native Win32])
111 case "$host" in
112   *-*-mingw*)
113     os_win32=yes
114     ;;
115   *)
116     os_win32=no
117     ;;
118 esac
119 AC_MSG_RESULT([$os_win32])
120 AM_CONDITIONAL(OS_WIN32, test x"$os_win32" = x"yes")
121
122 AC_MSG_CHECKING([for Cygwin])
123 case "$host" in
124   *-*-cygwin*)
125     env_cygwin=yes
126     ;;
127   *)
128     env_cygwin=no
129     ;;
130 esac
131 AC_MSG_RESULT([$env_cygwin])
132 AM_CONDITIONAL(CYGWIN, test x"$env_cygwin" = x"yes")
133
134 CFLAGS="$CFLAGS -Wall"
135
136 pthread_name=
137 case "$target" in
138 *-darwin*)
139         CFLAGS="$CFLAGS -no-cpp-precomp -fno-common"
140         ;;
141 *-*-mingw*)
142         # Note that we need to link to pthreadGC2 in all cases. This
143         # is because some locking is used even when pthread support is
144         # disabled.
145         pthread_name=pthreadGC2
146         CFLAGS="$CFLAGS -mms-bitfields"
147         LIBS="$LIBS -l${pthread_name} -lws2_32 -lregex"
148         ;;
149 *-sun-solaris2.8)
150         CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
151         CFLAGS="$CFLAGS -DSOLARIS"
152         ;;
153 esac
154   
155 dnl Checks for iconv
156 AM_ICONV
157
158 dnl
159 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
160 dnl
161 syl_save_LIBS=$LIBS
162 LIBS="$LIBS $GTK_LIBS"
163 AC_CHECK_FUNCS(bind_textdomain_codeset)
164 LIBS=$syl_save_LIBS
165
166 dnl for gettext
167 ALL_LINGUAS="bg ca cs de el en_GB es fi fr hr hu it ja ko nb nl pl pt_BR ru sk sr sv zh_CN zh_TW"
168 GETTEXT_PACKAGE=claws-mail
169 AC_SUBST(GETTEXT_PACKAGE)
170 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Define text domain.])
171
172 AM_GNU_GETTEXT_VERSION([0.15])
173 AM_GNU_GETTEXT([external])
174
175 manualdir='${docdir}/manual'
176 AC_ARG_WITH(manualdir,
177         [  --with-manualdir=DIR    Manual directory],
178         [manualdir="$withval"])
179 AC_SUBST(manualdir)
180
181 AC_ARG_ENABLE(manual,
182         [  --disable-manual           Disable manual support],
183         [ac_cv_enable_manual=$enableval], [ac_cv_enable_manual=yes])
184
185 AM_CONDITIONAL(BUILD_MANUAL, test x"$ac_cv_enable_manual" = xyes)
186
187 dnl Set PACKAGE_DATA_DIR in config.h.
188 if test "x${datarootdir}" = 'x${prefix}/share'; then
189         if test "x${prefix}" = "xNONE"; then
190                 AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${ac_default_prefix}/share/${PACKAGE}",[PACKAGE_DATA_DIR])
191         else
192                 AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${prefix}/share/${PACKAGE}",[PACKAGE_DATA_DIR])
193         fi
194 else
195         AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${datarootdir}/${PACKAGE}",[PACKAGE_DATA_DIR])
196 fi
197
198 AC_CHECK_LIB(xpg4, setlocale)
199
200 SM_LIBS=""
201 dnl Check for LibSM
202 AC_ARG_ENABLE(libsm,
203         [  --disable-libsm    Do not use libSM for session management.],
204         [ac_cv_enable_libsm=$enableval], [ac_cv_enable_libsm=yes])
205 AC_MSG_CHECKING([whether to use LibSM])
206 if test x"$ac_cv_enable_libsm" = xyes; then
207         AC_MSG_RESULT(yes)
208         AC_CHECK_LIB(SM, SmcSaveYourselfDone,
209                 [SM_LIBS="$X_LIBS -lSM -lICE"],ac_cv_enable_libsm=no,
210                 $X_LIBS -lICE)
211         AC_CHECK_HEADERS(X11/SM/SMlib.h,,ac_cv_enable_libsm=no)
212         if test x"$ac_cv_enable_libsm" = xyes; then
213                 AC_DEFINE(HAVE_LIBSM, 1, [Define to 1 if you have libSM installed])
214         else
215                 AC_MSG_RESULT(not found)
216                 AC_MSG_WARN([*** LibSM will not be supported ***])
217         fi
218 else
219         AC_MSG_RESULT(no)
220 fi
221 AC_SUBST(SM_LIBS)
222
223 dnl for GThread support (currently disabled)
224 dnl AC_ARG_ENABLE(threads,
225 dnl     [  --enable-threads        Enable multithread support [default=no]],
226 dnl     [use_threads=$enableval], [use_threads=no])
227
228 AC_MSG_CHECKING([whether to use threads])
229 if test x"$use_threads" = xyes ; then
230         AC_MSG_RESULT(yes)
231         if test ! -z `$GLIB_CONFIG --help 2>&1 |grep 'gthread'` ; then
232                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
233                 LIBS="$LIBS `$GLIB_CONFIG --libs gthread`"
234                 AC_DEFINE(USE_THREADS, 1, Whether to use multithread or not)
235         else
236                 AC_MSG_ERROR([Sylpheed requires GThread from GLib to use threading.])
237         fi
238 else
239         AC_MSG_RESULT(no)
240 fi
241
242 dnl Check for d_type member in struct dirent
243 AC_MSG_CHECKING([whether struct dirent has d_type member])
244 AC_CACHE_VAL(ac_cv_dirent_d_type,[
245         AC_TRY_COMPILE([#include <dirent.h>],
246                        [struct dirent d; d.d_type = DT_REG;],
247                        ac_cv_dirent_d_type=yes, ac_cv_dirent_d_type=no)
248 ])
249 AC_MSG_RESULT($ac_cv_dirent_d_type)
250 if test $ac_cv_dirent_d_type = yes; then
251         AC_DEFINE(HAVE_DIRENT_D_TYPE, 1,
252                   Define if `struct dirent' has `d_type' member.)
253 fi
254
255 # Check whether mkdir does not take the permission argument.
256 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
257
258 dnl Checks for header files.
259 AC_HEADER_DIRENT
260 AC_HEADER_STDC
261 AC_HEADER_SYS_WAIT
262 AC_CHECK_HEADERS(fcntl.h sys/file.h unistd.h paths.h \
263                  sys/param.h sys/utsname.h sys/select.h \
264                  wchar.h wctype.h locale.h netdb.h)
265
266 dnl alf - Check for apache installation f*ck up. apache may also install an 
267 dnl fnmatch, which includes their own regex stuff if USE_HSREGEX is defined
268 AC_TRY_COMPILE([#include <stdlib.h>
269                 #include <fnmatch.h>],
270         [int x = USE_HSREGEX;],
271         ac_cv_have_apache_fnmatch=yes, ac_cv_have_apache_fnmatch=no)
272 if test $ac_cv_have_apache_fnmatch = yes; then
273         AC_DEFINE(HAVE_APACHE_FNMATCH, 1, Define if you need to work around apache regex/fnmatch !KLUDGE!)
274 fi
275 AC_MSG_CHECKING([whether to use Apache regex header kludge])
276 AC_MSG_RESULT($ac_cv_have_apache_fnmatch)
277
278 dnl Checks for typedefs, structures, and compiler characteristics.
279 AC_C_CONST
280 AC_TYPE_OFF_T
281 AC_TYPE_PID_T
282 AC_TYPE_SIZE_T
283 AC_STRUCT_TM
284
285 dnl AC_CHECK_TYPE(wint_t, unsigned int) does not work because wint_t
286 dnl may be defined only in wchar.h (this happens with gcc-2.96).
287 dnl So we need to use this extended macro.
288 CLAWS_CHECK_TYPE(wint_t, unsigned int,
289 [
290 #if HAVE_WCHAR_H
291 #include <wchar.h>
292 #endif
293 ], Define to `unsigned int' if <stddef.h> or <wchar.h> doesn't define.)
294
295 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF, Used to test for a u32 typedef)
296 AC_CHECK_SIZEOF(unsigned short, 2)
297 AC_CHECK_SIZEOF(unsigned int, 4)
298 AC_CHECK_SIZEOF(unsigned long, 4)
299
300 dnl Checks for library functions.
301 AC_FUNC_ALLOCA
302 AC_CHECK_FUNCS(gethostname mkdir mktime socket strstr strchr \
303                uname flock lockf inet_aton inet_addr \
304                fchmod mkstemp truncate getuid regcomp)
305
306 AC_CHECK_FUNCS(fgets_unlocked fwrite_unlocked)
307
308 dnl *****************
309 dnl ** common code **
310 dnl *****************
311
312 dnl check for glib
313 PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.6 gmodule-2.0 >= 2.6 gobject-2.0 >= 2.6 gthread-2.0 >= 2.6)
314       
315 GLIB_GENMARSHAL=`pkg-config --variable=glib_genmarshal glib-2.0`
316 AC_SUBST(GLIB_GENMARSHAL)
317
318 AC_SUBST(GLIB_CFLAGS)
319 AC_SUBST(GLIB_LIBS)
320
321 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
322 syl_save_LIBS=$LIBS
323 LIBS="$LIBS $GTK_LIBS"
324 AC_CHECK_FUNCS(bind_textdomain_codeset)
325 LIBS=$syl_save_LIBS
326
327 dnl check for IPv6 option
328 AC_ARG_ENABLE(ipv6,
329         [  --disable-ipv6           Disable IPv6 support],
330         [ac_cv_enable_ipv6=$enableval], [ac_cv_enable_ipv6=yes])
331
332 dnl automated checks for IPv6 support.
333 AC_MSG_CHECKING([whether to use IPv6])
334 if test x"$ac_cv_enable_ipv6" = xyes; then
335         AC_MSG_RESULT(yes)
336         AC_MSG_CHECKING([for IPv6 support])
337         AC_CACHE_VAL(ac_cv_ipv6,[
338                 AC_TRY_COMPILE([#define INET6
339                                 #include <sys/types.h>
340                                 #include <netinet/in.h>],
341                         [int x = IPPROTO_IPV6; struct in6_addr a;],
342                         ac_cv_ipv6=yes, ac_cv_ipv6=no)
343         ])
344         AC_MSG_RESULT($ac_cv_ipv6)
345         if test $ac_cv_ipv6 = yes; then
346                 AC_DEFINE(INET6, 1, Define if you want IPv6 support.)
347         else
348                 AC_MSG_WARN(*** IPv6 will not be supported ***)
349                 ac_cv_enable_ipv6=no
350         fi
351 else
352         AC_MSG_RESULT(no)
353 fi
354
355 dnl Check for OpenSSL
356 AC_ARG_ENABLE(openssl,
357         [  --disable-openssl    Do not use OpenSSL for SSL support.],
358         [ac_cv_enable_openssl=$enableval], [ac_cv_enable_openssl=yes])
359 AC_MSG_CHECKING([whether to use OpenSSL])
360 if test x"$ac_cv_enable_openssl" = xyes; then
361         AC_MSG_RESULT(yes)
362         PKG_CHECK_MODULES(OPENSSL, openssl >= 0.9.7, :, ac_cv_enable_openssl=no)
363         if test x$ac_cv_enable_openssl = xyes; then
364                 AC_DEFINE(USE_OPENSSL, 1, Define if you want OpenSSL support)
365         else
366                 AC_MSG_RESULT(not found)
367                 AC_MSG_WARN([*** OpenSSL will not be supported ***])
368         fi
369 else
370         AC_MSG_RESULT(no)
371 fi
372 AC_SUBST(OPENSSL_CFLAGS)
373 AC_SUBST(OPENSSL_LIBS)
374
375 dnl password encryption
376 OLDLIBS=$LIBS
377 LIBS=
378 case $host_os in
379         *dragonfly*)
380                 AC_SEARCH_LIBS(encrypt, cipher, [], AC_MSG_ERROR(['encrypt'-function not found.]))
381         ;;
382         *)
383                 AC_SEARCH_LIBS(encrypt, crypt, [], AC_MSG_ERROR(['encrypt'-function not found.]))
384         ;;
385 esac
386 CRYPT_LIBS=$LIBS
387 AC_SUBST(CRYPT_LIBS)
388 LIBS=$OLDLIBS
389
390 AC_ARG_WITH(passcrypt-key, [  --with-passcrypt-key=KEY     Key used to encode passwords (8 byte string)],
391             with_passcrypt_key="$withval", with_passcrypt_key="passkey0")
392 AC_SUBST(PASSCRYPT_KEY, $with_passcrypt_key)
393
394 dnl RC dir (will be default at a certain point in time)
395 AC_ARG_WITH(config-dir,    [  --with-config-dir=RCDIR      Local configuration dir (default: .claws-mail)],
396               ac_cv_with_config_dir="$withval", ac_cv_with_config_dir=".claws-mail")
397 if test x"$ac_cv_with_config_dir" = x""; then
398         ac_cv_with_config_dir=".claws-mail"
399 fi 
400 AC_DEFINE_UNQUOTED(CFG_RC_DIR, "$ac_cv_with_config_dir", Configuration directory)
401
402 dnl ************************
403 dnl ** GTK user interface **
404 dnl ************************
405
406 dnl Checks for GTK
407 PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.6)
408
409 dnl --disable-deprecated switch for GTK2 purification
410 AC_ARG_ENABLE(deprecated, [  --disable-deprecated  Disable deprecated GTK functions. ],
411                           [GTK_CFLAGS="$GTK_CFLAGS -DG_DISABLE_DEPRECATED -DGTK_DISABLE_DEPRECATED"], [])
412
413 AC_SUBST(GTK_CFLAGS)
414 AC_SUBST(GTK_LIBS)
415
416 dnl GNU/Aspell is used for spell checking
417 AC_ARG_ENABLE(aspell,
418         [  --disable-aspell         Disable GNU/aspell support [default=yes]],
419         [ac_cv_enable_aspell=$enableval], [ac_cv_enable_aspell=yes])
420 AC_MSG_CHECKING([whether to use GNU/aspell])
421 if test $ac_cv_enable_aspell = yes; then
422         AC_MSG_RESULT(yes)
423         AM_PATH_ASPELL(0.50, AC_DEFINE(USE_ASPELL, 1, Define if you use ASPELL to support spell checking),
424                       [use_aspell=no ac_cv_enable_aspell=no])
425 else
426         AC_MSG_RESULT(no)
427 fi
428
429 dnl want crash dialog
430 AC_ARG_ENABLE(crash-dialog,
431         [  --enable-crash-dialog   Enable crash dialog [default=no]],
432         [ac_cv_enable_crash_dialog=$enableval], [ac_cv_enable_crash_dialog=no])
433 if test $ac_cv_enable_crash_dialog = yes; then
434 dnl check if GDB is somewhere
435         AC_CHECK_PROG(ac_cv_enable_crash_dialog, gdb, yes, no)
436         AC_MSG_CHECKING([whether to use crash dialog])
437         if test $ac_cv_enable_crash_dialog = yes; then
438                 AC_DEFINE(CRASH_DIALOG, 1, Pop up crash dialog)
439         fi
440         AC_MSG_RESULT($ac_cv_enable_crash_dialog)
441 fi
442
443 dnl Maemo platform
444 AC_ARG_ENABLE(maemo,
445         [  --enable-maemo   Build for the Maemo platform [default=no]],
446         [ac_cv_enable_maemo=$enableval], [ac_cv_enable_maemo=no])
447 if test $ac_cv_enable_maemo = yes; then
448         PKG_CHECK_MODULES(MAEMO, libosso hildon-libs hildon-fm, ac_cv_enable_maemo=yes,
449                   ac_cv_enable_maemo=no)
450         AC_SUBST(MAEMO_CFLAGS)
451         AC_SUBST(MAEMO_LIBS)
452         if test $ac_cv_enable_maemo = no; then
453                 AC_MSG_ERROR(libosso, hildon-libs or hildon-fm not found)
454         else
455                 AC_DEFINE(MAEMO, 1, Build for maemo)
456         fi
457 fi
458
459 dnl Check for X-Face support
460 AC_ARG_ENABLE(compface,
461         [  --disable-compface      Do not use compface (X-Face)],
462         [ac_cv_enable_compface=$enableval], [ac_cv_enable_compface=yes])
463 AC_MSG_CHECKING([whether to use compface])
464 if test x"$ac_cv_enable_compface" = xyes; then
465         AC_MSG_RESULT(yes)
466         AC_CHECK_LIB(compface, uncompface, 
467                 [AC_DEFINE(HAVE_LIBCOMPFACE, 1, Define if you want compface support.)],
468                 [ac_cv_enable_compface=no])
469         if test x"$ac_cv_enable_compface" = xyes; then
470                 COMPFACE_LIBS="-lcompface"
471         else
472                 COMPFACE_LIBS=""
473         fi
474         AC_SUBST(COMPFACE_LIBS)
475 else
476         AC_MSG_RESULT(no)
477 fi
478
479 dnl check for pthread support
480 AC_ARG_ENABLE(pthread,
481         [  --disable-pthread           Disable pthread support],
482         [ac_cv_enable_pthread=$enableval], [ac_cv_enable_pthread=yes])
483 AC_MSG_CHECKING([whether to use pthread])
484 if test x$ac_cv_enable_pthread = xno; then
485         AC_MSG_RESULT(no)
486 else
487         AC_MSG_RESULT(yes)
488
489         # For W32 we need to use a special ptrhead lib. In this case we can't
490         # use AC_CHECK_LIB because it has no means of checking for a
491         # library installed under a different name.  Checking for the
492         # header is okay.
493         if test -n "${pthread_name}" ; then
494            ac_cv_enable_pthread=yes
495         else
496         AC_CHECK_LIB(pthread, pthread_create, :, ac_cv_enable_pthread=no)
497         fi
498         AC_CHECK_HEADERS(pthread.h, :, ac_cv_enable_pthread=no)
499
500         if test x$ac_cv_enable_pthread = xyes; then
501                 AC_DEFINE(USE_PTHREAD, 1, Define if you have pthread)
502                 if test -z "${pthread_name}" ; then
503                 PTHREAD_LIBS="-lpthread"
504         fi
505         fi
506
507 fi
508 AC_SUBST(PTHREAD_LIBS)
509
510 dnl
511 dnl Check whether we need to pass -lresolv
512 dnl We know that we don't need it for W32.
513 dnl
514 if test x$os_win32 = xno; then
515   t_oldLibs="$LIBS"
516   LIBS="$LIBS"
517   ac_cv_var__res_options=no
518   AC_TRY_LINK([#include <sys/types.h>
519              #include <sys/socket.h>
520              #include <netinet/in.h>
521              #include <arpa/nameser.h>
522              #include <resolv.h>],
523                 [_res.options = RES_INIT;],
524                 ac_cv_var__res_options=yes);
525   if test "$ac_cv_var__res_options" != "yes"; then
526         LIBRESOLV="-lresolv"
527   fi
528   LIBS="$t_oldLibs"
529
530   if test "x$LIBRESOLV" = "x"; then
531         AC_CHECK_LIB(resolv, res_query, [LIBRESOLV=-lresolv])
532         LIBS="$t_oldLibs"
533   fi
534 fi
535 AC_SUBST(LIBRESOLV)
536
537 LIBS="$LIBS $LIBRESOLV"
538                  
539 dnl for LDAP support in addressbook
540 dnl no check for libraries; dynamically loaded
541 AC_ARG_ENABLE(ldap,
542         [  --disable-ldap         Do not build LDAP support [default=yes]],
543         [ac_cv_enable_ldap=$enableval], [ac_cv_enable_ldap=yes])
544 AC_MSG_CHECKING([whether to use LDAP])
545 if test x"$ac_cv_enable_ldap" = xno; then
546         AC_MSG_RESULT(no)
547 elif test x"$ac_cv_enable_ldap" = xyes -a x"$ac_cv_enable_pthread" = xno; then
548         AC_MSG_RESULT(no - LDAP support needs pthread support)
549
550         ac_cv_enable_ldap=no
551 else
552         AC_MSG_RESULT(yes)
553
554         dnl check for available libraries, and pull them in
555         AC_CHECK_LIB(resolv, res_query, LDAP_LIBS="$LDAP_LIBS -lresolv")
556         AC_CHECK_LIB(socket, bind, LDAP_LIBS="$LDAP_LIBS -lsocket")
557         AC_CHECK_LIB(nsl, gethostbyaddr, LDAP_LIBS="$LDAP_LIBS -lnsl")
558         AC_CHECK_LIB(lber, ber_get_tag, LDAP_LIBS="$LDAP_LIBS -llber",,
559                      $LDAP_LIBS)
560
561         AC_CHECK_HEADERS(ldap.h lber.h,
562                          [ ac_cv_enable_ldap=yes ],
563                          [ ac_cv_enable_ldap=no ])
564
565         if test "$ac_cv_enable_ldap" = yes; then
566                 AC_CHECK_LIB(ldap, ldap_open,
567                              [ ac_cv_enable_ldap=yes ],
568                              [ ac_cv_enable_ldap=no ],
569                              $LDAP_LIBS)
570
571                 AC_CHECK_LIB(ldap, ldap_start_tls_s,
572                              [ ac_cv_have_tls=yes ],
573                              [ ac_cv_have_tls=no ])
574
575         fi
576
577         AC_MSG_CHECKING([whether ldap library is available])
578         AC_MSG_RESULT($ac_cv_enable_ldap)
579
580         AC_MSG_CHECKING([whether TLS library is available])
581         AC_MSG_RESULT($ac_cv_have_tls)
582
583         if test "$ac_cv_enable_ldap" = yes; then
584                 AC_DEFINE(USE_LDAP, 1, Define if you want LDAP support in addressbook.)
585                 LDAP_LIBS="$LDAP_LIBS -lldap"
586                 AC_SUBST(LDAP_LIBS)
587                 if test "$ac_cv_have_tls" = yes; then
588                         AC_DEFINE(USE_LDAP_TLS, 1, Define if you want LDAP TLS support in addressbook.)
589                 fi
590         fi
591 fi
592
593 dnl for JPilot support in addressbook
594 dnl no check for libraries; these are dynamically loaded
595 AC_ARG_ENABLE(jpilot,
596         [  --disable-jpilot         Enable JPilot support [default=yes]],
597         [ac_cv_enable_jpilot=$enableval], [ac_cv_enable_jpilot=yes])
598 AC_MSG_CHECKING([whether to use JPilot])
599 if test "$ac_cv_enable_jpilot" = yes; then
600         AC_MSG_RESULT(yes)
601         AC_CHECK_HEADERS(pi-args.h pi-appinfo.h pi-address.h pi-version.h,
602                          [ AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ],
603                          [ ac_cv_enable_jpilot=no ])
604         if test "$ac_cv_enable_jpilot" = no; then
605                 AC_CHECK_HEADERS(libpisock/pi-args.h libpisock/pi-appinfo.h libpisock/pi-address.h libpisock/pi-version.h,
606                                  [ ac_cv_enable_jpilot=yes
607                                    AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ])
608         fi
609
610         AC_CHECK_LIB(pisock, unpack_Address, [JPILOT_LIBS="-lpisock"], [JPILOT_LIBS="" ac_cv_enable_jpilot="no"])
611         if test x"$ac_cv_enable_jpilot" = xyes; then
612                 AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.)
613         else
614                 AC_MSG_NOTICE([JPilot support not available])
615         fi
616         AC_SUBST(JPILOT_LIBS)
617 else
618         AC_MSG_RESULT(no)
619 fi
620
621 dnl #######################################################################
622 dnl # Check for startup notification
623 dnl #######################################################################
624 AC_ARG_ENABLE(startup-notification, [  --disable-startup-notification    compile without startup notification support],,enable_startup_notification=yes)
625
626 if test "x$enable_startup_notification" = "xyes"; then
627         PKG_CHECK_MODULES(STARTUP_NOTIFICATION, libstartup-notification-1.0 >= 0.5,
628         [
629                 AC_DEFINE(HAVE_STARTUP_NOTIFICATION, 1, [Define if we're using libstartup-notification.])
630                 echo "Building with libstartup-notification"
631                 enable_startup_notification=yes
632         ],
633         [
634                 echo "Building without libstartup-notification"
635                 enable_startup_notification=no
636         ])
637
638         AC_SUBST(STARTUP_NOTIFICATION_CFLAGS)
639         AC_SUBST(STARTUP_NOTIFICATION_LIBS)
640 fi
641
642 dnl *************************
643 dnl ** section for plugins **
644 dnl *************************
645
646 PLUGINS=""
647
648 dnl --- Trayicon ---
649 AC_MSG_CHECKING([whether to build Trayicon plugin])
650 AC_ARG_ENABLE(trayicon-plugin,
651         [  --disable-trayicon-plugin         Do not build System Tray Icon plugin],
652         [ac_cv_enable_trayicon_plugin=$enableval], [ac_cv_enable_trayicon_plugin=yes])
653 if test x"$ac_cv_enable_trayicon_plugin" = xyes; then
654         AC_MSG_RESULT(yes)
655         PLUGINS="trayicon $PLUGINS"
656 else
657         AC_MSG_RESULT(no)
658 fi
659 AM_CONDITIONAL(BUILD_TRAYICON_PLUGIN, test x"$ac_cv_enable_trayicon_plugin" = xyes)
660
661 dnl --- SpamAssassin ---
662 AC_MSG_CHECKING([whether to build SpamAssassin plugin])
663 AC_ARG_ENABLE(spamassassin-plugin,
664         [  --disable-spamassassin-plugin      Build SpamAssassin plugin [default=yes]],
665         [ac_cv_enable_spamassassin_plugin=$enableval], [ac_cv_enable_spamassassin_plugin=yes])
666 if test x"$ac_cv_enable_spamassassin_plugin" = xyes; then
667         AC_MSG_RESULT(yes)
668         AC_SPAMASSASSIN
669         PLUGINS="spamassassin $PLUGINS"
670         AC_DEFINE(USE_SPAMASSASSIN_PLUGIN, 1, Define if spamassassin plugin is being built.)
671 else
672         AC_MSG_RESULT(no)
673 fi
674 AM_CONDITIONAL(BUILD_SPAMASSASSIN_PLUGIN, test x"$ac_cv_enable_spamassassin_plugin" = xyes)
675
676 dnl --- Bogofilter ---
677 AC_MSG_CHECKING([whether to build Bogofilter plugin])
678 AC_ARG_ENABLE(bogofilter-plugin,
679         [  --disable-bogofilter-plugin      Build bogofilter plugin [default=yes]],
680         [ac_cv_enable_bogofilter_plugin=$enableval], [ac_cv_enable_bogofilter_plugin=yes])
681 if test x"$ac_cv_enable_bogofilter_plugin" = xyes; then
682         AC_MSG_RESULT(yes)
683         PLUGINS="bogofilter $PLUGINS"
684         AC_DEFINE(USE_BOGOFILTER_PLUGIN, 1, Define if bogofilter plugin is being built.)
685 else
686         AC_MSG_RESULT(no)
687 fi
688 AM_CONDITIONAL(BUILD_BOGOFILTER_PLUGIN, test x"$ac_cv_enable_bogofilter_plugin" = xyes)
689
690 dnl --- PGP/CORE ---
691 AC_MSG_CHECKING([whether to build PGP/CORE plugin])
692 AC_ARG_ENABLE(pgpcore-plugin,
693         [  --disable-pgpcore-plugin           Do not build PGP/Core plugin],
694         [ac_cv_enable_pgpcore_plugin=$enableval], [ac_cv_enable_pgpcore_plugin=yes])
695 if test x"$ac_cv_enable_pgpcore_plugin" = xyes; then
696         AC_MSG_RESULT(yes)
697         AM_PATH_GPGME(1.0.0, AC_DEFINE(USE_GPGME, 1, Define if you use GPGME to support OpenPGP.),
698                       [ac_cv_enable_pgpcore_plugin=no])
699         if test x"$ac_cv_enable_pgpcore_plugin" = xyes; then
700                 PLUGINS="pgpcore $PLUGINS"
701                 AM_PATH_GPGME(1.1.1,
702                               AC_DEFINE(HAVE_GPGME_PKA_TRUST, 1,
703                                         [Define if GPGME supports PKA.]))
704                 #needed to get GPGME_LIBS and al correctly
705                 AM_PATH_GPGME(1.0.0, AC_DEFINE(USE_GPGME, 1, Define if you use GPGME to support OpenPGP.),
706                           [ac_cv_enable_pgpcore_plugin=no])
707         else
708                 AC_MSG_WARN([*** PGP/CORE plugin will not be built ***])
709         fi
710 else
711         AC_MSG_RESULT(no)
712 fi
713 AM_CONDITIONAL(BUILD_PGPCORE_PLUGIN, test x"$ac_cv_enable_pgpcore_plugin" = xyes)
714
715 AC_MSG_CHECKING([whether to build PGP/MIME plugin])
716 AC_ARG_ENABLE(pgpmime-plugin,
717         [  --disable-pgpmime-plugin           Do not build PGP/MIME plugin],
718         [ac_cv_enable_pgpmime_plugin=$enableval], [ac_cv_enable_pgpmime_plugin=yes])
719 if test x"$ac_cv_enable_pgpmime_plugin" = xyes; then
720         AC_MSG_RESULT(yes)
721         if test x"$ac_cv_enable_pgpcore_plugin" = xyes; then
722                 PLUGINS="pgpmime $PLUGINS"
723         else
724                 AC_MSG_WARN([*** PGP/MIME plugin cannot be built ***])
725                 AC_MSG_WARN([*** without the PGP/CORE plugin     ***])
726         fi
727 else
728         AC_MSG_RESULT(no)
729 fi
730 AM_CONDITIONAL(BUILD_PGPMIME_PLUGIN, test x"$ac_cv_enable_pgpmime_plugin" = xyes)
731
732 AC_MSG_CHECKING([whether to build PGP/Inline plugin])
733 AC_ARG_ENABLE(pgpinline-plugin,
734         [  --disable-pgpinline-plugin           Do not build PGP/Inline plugin],
735         [ac_cv_enable_pgpinline_plugin=$enableval], [ac_cv_enable_pgpinline_plugin=yes])
736 if test x"$ac_cv_enable_pgpinline_plugin" = xyes; then
737         AC_MSG_RESULT(yes)
738         if test x"$ac_cv_enable_pgpcore_plugin" = xyes; then
739                 PLUGINS="pgpinline $PLUGINS"
740         else
741                 AC_MSG_WARN([*** PGP/Inline plugin cannot be built ***])
742                 AC_MSG_WARN([*** without the PGP/CORE plugin     ***])
743         fi
744 else
745         AC_MSG_RESULT(no)
746 fi
747 AM_CONDITIONAL(BUILD_PGPINLINE_PLUGIN, test x"$ac_cv_enable_pgpinline_plugin" = xyes)
748
749 dnl --- Dillo Viewer ---
750 AC_MSG_CHECKING([whether to build Dillo plugin])
751 AC_ARG_ENABLE(dillo-viewer-plugin,
752         [  --disable-dillo-viewer-plugin     Do not build Dillo plugin for html mail rendering],
753         [ac_cv_enable_dillo_viewer_plugin=$enableval], [ac_cv_enable_dillo_viewer_plugin=yes])
754 if test x"$ac_cv_enable_dillo_viewer_plugin" = xyes; then
755         AC_MSG_RESULT(yes)
756         PLUGINS="dillo-viewer $PLUGINS"
757 else
758         AC_MSG_RESULT(no)
759 fi
760 AM_CONDITIONAL(BUILD_DILLO_VIEWER_PLUGIN, test x"$ac_cv_enable_dillo_viewer_plugin" = xyes)
761
762 dnl --- Demo ---
763 AC_ARG_ENABLE(demo-plugin,
764         [  --enable-demo-plugin              Build demo plugin [default=no]],
765         [ac_cv_enable_demo_plugin=$enableval], [ac_cv_enable_demo_plugin=no])
766 if test x"$ac_cv_enable_demo_plugin" = xyes; then
767         PLUGINS="demo $PLUGINS"
768 fi
769 AM_CONDITIONAL(BUILD_DEMO_PLUGIN, test x"$ac_cv_enable_demo_plugin" = xyes)
770
771 dnl --- ClamAV ---
772 AC_MSG_CHECKING([whether to build ClamAV plugin])
773 AC_ARG_ENABLE(clamav-plugin,
774         [  --disable-clamav-plugin           Do not build Clam AntiVirus plugin],
775         [ac_cv_enable_clamav_plugin=$enableval], [ac_cv_enable_clamav_plugin=yes])
776 if test x"$ac_cv_enable_clamav_plugin" = xyes; then
777         AC_MSG_RESULT(yes)
778         PKG_CHECK_MODULES(CLAMAV, libclamav, ac_cv_enable_clamav_plugin=yes,
779                           ac_cv_enable_clamav_plugin=no)
780         if test x"$ac_cv_enable_clamav_plugin" = xyes; then
781                 PLUGINS="clamav $PLUGINS"
782         else
783                 AC_MSG_RESULT(not found)
784                 AC_MSG_WARN([*** ClamAV plugin will not be built ***])
785         fi
786 else
787         AC_MSG_RESULT(no)
788 fi
789 AC_SUBST(CLAMAV_LIBS)
790 AM_CONDITIONAL(BUILD_CLAMAV_PLUGIN, test x"$ac_cv_enable_clamav_plugin" = xyes)
791
792 dnl Libetpan
793 AC_MSG_CHECKING([whether to use libetpan])
794 AC_ARG_ENABLE(libetpan,
795         [  --disable-libetpan           Do not compile IMAP4 support with libetpan],
796         [ac_cv_enable_libetpan=$enableval], [ac_cv_enable_libetpan=yes])
797 if test x"$ac_cv_enable_libetpan" = xyes; then
798         AC_MSG_RESULT(yes)
799         libetpan_result=no
800         AC_PATH_PROG(libetpanconfig, [libetpan-config])
801         if test "x$libetpanconfig" != "x"; then
802           CPPFLAGS="$CPPFLAGS `$libetpanconfig --cflags 2>/dev/null`"
803           AC_CHECK_HEADER(libetpan/libetpan.h, [libetpan_result=yes])
804           if test "x$libetpan_result" = "xyes"; then
805             AC_MSG_CHECKING([whether libetpan-config hints compiles and links fine])
806             LIBS="$LIBS `$libetpanconfig --libs 2>/dev/null`"
807             AC_TRY_LINK([#include <libetpan/dbstorage.h>], [db_mailstorage_init(NULL, NULL);], [libetpan_result=yes], [libetpan_result=no])
808             AC_MSG_RESULT([$libetpan_result])
809           fi
810         fi
811         if test "x$libetpan_result" = "xyes"; then
812            LIBETPAN_CPPFLAGS="`$libetpanconfig --cflags`"
813            LIBETPAN_LIBS="`$libetpanconfig --libs`"
814            LIBETPAN_VERSION=`$libetpanconfig --version | sed "s/\.//g" | sed "s/-.*$//"`
815            if test "$LIBETPAN_VERSION" -lt "049"; then
816                 AC_MSG_RESULT([*** Claws Mail requires libetpan 0.49 or newer. See http://www.etpan.org/])
817                 AC_MSG_RESULT([*** You can use --disable-libetpan if you don't need IMAP4 support.])
818                 AC_MSG_ERROR([libetpan 0.49 not found])
819            fi
820            AC_SUBST(LIBETPAN_FLAGS)
821            AC_SUBST(LIBETPAN_LIBS)
822            AC_DEFINE(HAVE_LIBETPAN, 1, Define if you want IMAP support.)
823         else
824            AC_MSG_RESULT([*** Claws Mail requires libetpan 0.49 or newer. See http://www.etpan.org/ ])
825            AC_MSG_RESULT([*** You can use --disable-libetpan if you don't need IMAP4 support.])
826            AC_MSG_ERROR([libetpan 0.49 not found])
827         fi
828 else
829         AC_MSG_RESULT(no)
830 fi
831 AM_CONDITIONAL(CLAWS_LIBETPAN, test "x$libetpan_result" = "xyes")
832
833
834 dnl Libgnomeprint
835 AC_MSG_CHECKING([whether to use libgnomeprint])
836 AC_ARG_ENABLE(gnomeprint,
837         [  --disable-gnomeprint         Do not use libgnomeprint for printing],
838         [ac_cv_enable_gnomeprint=$enableval], [ac_cv_enable_gnomeprint=yes])
839 if test x$ac_cv_enable_gnomeprint = xyes; then
840         AC_MSG_RESULT(yes)
841         PKG_CHECK_MODULES(GNOMEPRINT, libgnomeprint-2.2 libgnomeprintui-2.2,
842                           ac_cv_enable_gnomeprint=yes, ac_cv_enable_gnomeprint=no)
843         if test x"$ac_cv_enable_gnomeprint" = xyes; then
844                 AC_DEFINE(USE_GNOMEPRINT, 1, Define if you want libgnomeprint support)
845         else
846                 AC_MSG_RESULT(not found)
847                 AC_MSG_WARN([*** libgnomeprintui wasn't found    ***])
848                 AC_MSG_WARN([*** using built-in printing support ***])
849         fi
850 else
851         AC_MSG_RESULT(no)
852 fi
853 AM_CONDITIONAL(CLAWS_GNOMEPRINT, test x"$ac_cv_enable_gnomeprint" = x"yes")
854
855 AC_MSG_CHECKING([whether to use valgrind])
856 AC_ARG_ENABLE(valgrind,
857         [  --disable-valgrind           Do not use valgrind for debugging],
858         [ac_cv_enable_valgrind=$enableval], [ac_cv_enable_valgrind=yes])
859 if test x$ac_cv_enable_valgrind = xyes; then
860         AC_MSG_RESULT(yes)
861         PKG_CHECK_MODULES(VALGRIND, valgrind >= 2.4.0,
862                           ac_cv_enable_valgrind=yes, ac_cv_enable_valgrind=no)
863         if test x"$ac_cv_enable_valgrind" = xyes; then
864                 AC_DEFINE(HAVE_VALGRIND, 1, Define if you want valgrind support)
865         else
866                 AC_MSG_RESULT(not found)
867         fi
868 else
869         AC_MSG_RESULT(no)
870 fi
871 AM_CONDITIONAL(CLAWS_VALGRIND, test x"$ac_cv_enable_valgrind" = x"yes")
872
873 dnl ****************************
874 dnl ** Final configure output **
875 dnl ****************************
876
877 AC_OUTPUT([
878 Makefile
879 m4/Makefile
880 po/Makefile.in
881 src/common/version.h
882 src/Makefile
883 src/common/Makefile
884 src/common/passcrypt.h
885 src/gtk/Makefile
886 src/etpan/Makefile
887 src/plugins/Makefile
888 src/plugins/demo/Makefile
889 src/plugins/bogofilter/Makefile
890 src/plugins/spamassassin/Makefile
891 src/plugins/dillo_viewer/Makefile
892 src/plugins/trayicon/Makefile
893 src/plugins/trayicon/libeggtrayicon/Makefile
894 src/plugins/clamav/Makefile
895 src/plugins/pgpcore/Makefile
896 src/plugins/pgpmime/Makefile
897 src/plugins/pgpinline/Makefile
898 doc/Makefile
899 doc/man/Makefile
900 tools/Makefile
901 config/Makefile
902 manual/Makefile
903 manual/dtd/Makefile
904 manual/dist/Makefile
905 manual/dist/pdf/Makefile
906 manual/dist/ps/Makefile
907 manual/dist/html/Makefile
908 manual/dist/txt/Makefile
909 manual/fr/Makefile
910 manual/fr/dist/Makefile
911 manual/fr/dist/pdf/Makefile
912 manual/fr/dist/ps/Makefile
913 manual/fr/dist/html/Makefile
914 manual/fr/dist/txt/Makefile
915 manual/pl/Makefile
916 manual/pl/dist/Makefile
917 manual/pl/dist/pdf/Makefile
918 manual/pl/dist/ps/Makefile
919 manual/pl/dist/html/Makefile
920 manual/pl/dist/txt/Makefile
921 manual/es/Makefile
922 manual/es/dist/Makefile
923 manual/es/dist/pdf/Makefile
924 manual/es/dist/ps/Makefile
925 manual/es/dist/html/Makefile
926 manual/es/dist/txt/Makefile
927 claws-mail.pc
928 ])
929
930 dnl Output the configuration summary
931 echo ""
932 echo "$PACKAGE $VERSION"
933 echo ""
934 echo "JPilot        : $ac_cv_enable_jpilot"
935 echo "LDAP          : $ac_cv_enable_ldap"
936 echo "OpenSSL       : $ac_cv_enable_openssl"
937 echo "iconv         : $am_cv_func_iconv"
938 echo "compface      : $ac_cv_enable_compface"
939 echo "IPv6          : $ac_cv_enable_ipv6"
940 echo "GNU/aspell    : $ac_cv_enable_aspell"
941 echo "IMAP4         : $ac_cv_enable_libetpan"
942 echo "Crash dialog  : $ac_cv_enable_crash_dialog"
943 echo "Libgnomeprint : $ac_cv_enable_gnomeprint"
944 echo "LibSM         : $ac_cv_enable_libsm"
945 echo "Manual        : $ac_cv_enable_manual"
946 echo "Plugins       : $PLUGINS"
947 echo "Maemo  build  : $ac_cv_enable_maemo"
948 echo "Config dir    : $ac_cv_with_config_dir"
949 echo ""
950 echo "The binary will be installed in $prefix/bin"
951 echo ""
952 echo "Configure finished, type 'make' to build."