configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.50)
   3 AC_INIT(src/main.c)
   4 AC_CONFIG_AUX_DIR(config)
   5
   6 PACKAGE=sylpheed-claws
   7
   8 dnl version number
   9 MAJOR_VERSION=1
  10 MINOR_VERSION=9
  11 MICRO_VERSION=12
  12 INTERFACE_AGE=0
  13 BINARY_AGE=0
  14 EXTRA_VERSION=85
  15 EXTRA_RELEASE=
  16 EXTRA_GTK2_VERSION=
  17
  18 if test \( $EXTRA_VERSION -eq 0 \) -o \( "x$EXTRA_RELEASE" != "x" \); then
  19     VERSION=${MAJOR_VERSION}.${MINOR_VERSION}.${MICRO_VERSION}${EXTRA_RELEASE}${EXTRA_GTK2_VERSION}
  20 else
  21     VERSION=${MAJOR_VERSION}.${MINOR_VERSION}.${MICRO_VERSION}cvs${EXTRA_VERSION}${EXTRA_GTK2_VERSION}
  22 fi
  23
  24 dnl set $target
  25 AC_CANONICAL_SYSTEM
  26
  27 dnl
  28 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  29 dnl AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
  30 dnl AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
  31 AC_SUBST(PACKAGE)
  32 AC_SUBST(VERSION)
  33 AC_SUBST(MAJOR_VERSION)
  34 AC_SUBST(MINOR_VERSION)
  35 AC_SUBST(MICRO_VERSION)
  36 AC_SUBST(EXTRA_VERSION)
  37
  38 dnl GNOME installed?
  39 AC_PATH_PROG(GNOME_CONFIG, gnome-config, no)
  40 if test "$GNOME_CONFIG" != no; then
  41         gnomedatadir="`gnome-config --datadir`"
  42         gnomeprefix="`gnome-config --prefix`"
  43         if test "${prefix}" = "NONE"; then
  44                 gnomedatadir="${ac_default_prefix}/${gnomedatadir#${gnomeprefix}}"
  45         else
  46                 gnomedatadir="${prefix}/${gnomedatadir#${gnomeprefix}}"
  47         fi
  48         AC_SUBST(gnomedatadir)
  49 fi
  50 AM_CONDITIONAL(SYLPHEED_GNOME, test -n "$gnomedatadir")
  51
  52 dnl GNOME 2.x installed?
  53 PKG_CHECK_MODULES(GNOME2, libgnome-2.0 >= 2.0, ac_enable_gnome2=yes, ac_enable_gnome2=no)
  54 AM_CONDITIONAL(SYLPHEED_GNOME2, test x"$ac_enable_gnome2" = x"yes")
  55
  56 dnl Claws version
  57 AC_DEFINE(CLAWS, 1, Compiling Claws branch of sylpheed)
  58
  59 dnl libtool versioning
  60 LT_RELEASE=$MAJOR_VERSION.$MINOR_VERSION
  61 LT_CURRENT=`expr $MICRO_VERSION - $INTERFACE_AGE`
  62 LT_REVISION=$INTERFACE_AGE
  63 LT_AGE=`expr $BINARY_AGE - $INTERFACE_AGE`
  64 AC_SUBST(LT_RELEASE)
  65 AC_SUBST(LT_CURRENT)
  66 AC_SUBST(LT_REVISION)
  67 AC_SUBST(LT_AGE)
  68
  69 dnl Specify a header configuration file
  70 AC_CONFIG_HEADERS(config.h)
  71
  72 AM_MAINTAINER_MODE
  73
  74 dnl Checks for programs.
  75 dnl AC_ARG_PROGRAM
  76 AC_PROG_CC
  77 AC_ISC_POSIX
  78 AC_PROG_INSTALL
  79 AC_PROG_LN_S
  80 AC_PROG_MAKE_SET
  81 AC_PROG_CPP
  82 dnl AC_PROG_RANLIB
  83 AM_PROG_LEX
  84 AC_PROG_YACC
  85 AC_PROG_LIBTOOL
  86
  87 SYLPHEED_ACLOCAL_INCLUDE(m4)
  88
  89 dnl ******************************
  90 dnl Checks for host
  91 dnl ******************************
  92 AC_CANONICAL_HOST
  93
  94 dnl Copied from the official gtk+-2 configure.in
  95 AC_MSG_CHECKING([for some Win32 platform])
  96 case "$host" in
  97   *-*-mingw*|*-*-cygwin*)
  98     platform_win32=yes
  99     LDFLAGS="$LDFLAGS -mwindows"
 100     ;;
 101   *)
 102     platform_win32=no
 103     ;;
 104 esac
 105 AC_MSG_RESULT([$platform_win32])
 106 AM_CONDITIONAL(PLATFORM_WIN32, test x"$platform_win32" = x"yes")
 107
 108 if test x"$platform_win32" = x"yes"; then
 109     WINDRES=windres
 110     AC_SUBST(WINDRES)
 111 fi
 112
 113 AC_MSG_CHECKING([for native Win32])
 114 case "$host" in
 115   *-*-mingw*)
 116     os_win32=yes
 117     ;;
 118   *)
 119     os_win32=no
 120     ;;
 121 esac
 122 AC_MSG_RESULT([$os_win32])
 123 AM_CONDITIONAL(OS_WIN32, test x"$os_win32" = x"yes")
 124
 125 CFLAGS="$CFLAGS -Wall"
 126
 127 case "$target" in
 128 *-darwin*)
 129         CFLAGS="$CFLAGS -no-cpp-precomp -fno-common"
 130         ;;
 131 esac
 132
 133 dnl Checks for iconv
 134 AM_ICONV
 135
 136 dnl
 137 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 138 dnl
 139 syl_save_LIBS=$LIBS
 140 LIBS="$LIBS $GTK_LIBS"
 141 AC_CHECK_FUNCS(bind_textdomain_codeset)
 142 LIBS=$syl_save_LIBS
 143
 144 dnl for gettext
 145 ALL_LINGUAS="bg ca cs de el en_GB es fi fr hr hu it ja ko nl pl pt_BR ru sk sr sv zh_CN zh_TW.Big5"
 146 GETTEXT_PACKAGE=sylpheed-claws
 147 AC_SUBST(GETTEXT_PACKAGE)
 148 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Define text domain.])
 149
 150 AM_GLIB_GNU_GETTEXT
 151 dnl AM_GNU_GETTEXT
 152 dnl AC_CHECK_FUNC(gettext, AC_CHECK_LIB(intl, gettext))
 153 localedir='${prefix}/${DATADIRNAME}/locale'
 154 AC_SUBST(localedir)
 155
 156 manualdir='${prefix}/${DATADIRNAME}/${PACKAGE}/manual'
 157 AC_SUBST(manualdir)
 158 faqdir='${prefix}/${DATADIRNAME}/${PACKAGE}/faq'
 159 AC_SUBST(faqdir)
 160
 161 dnl Set PACKAGE_DATA_DIR in config.h.
 162 if test "x${datadir}" = 'x${prefix}/share'; then
 163   if test "x${prefix}" = "xNONE"; then
 164     AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${ac_default_prefix}/share/${PACKAGE}", PACKAGE_DATA_DIR)
 165   else
 166     AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${prefix}/share/${PACKAGE}", PACKAGE_DATA_DIR)
 167   fi
 168 else
 169   AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${datadir}/${PACKAGE}", PACKAGE_DATA_DIR)
 170 fi
 171
 172 AC_CHECK_LIB(xpg4, setlocale)
 173
 174 dnl for GThread support (currently disabled)
 175 dnl AC_ARG_ENABLE(threads,
 176 dnl     [  --enable-threads        Enable multithread support [default=no]],
 177 dnl     [use_threads=$enableval], [use_threads=no])
 178
 179 AC_MSG_CHECKING([whether to use threads])
 180 if test x"$use_threads" = xyes ; then
 181         AC_MSG_RESULT(yes)
 182         if test ! -z `$GLIB_CONFIG --help 2>&1 |grep 'gthread'` ; then
 183                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
 184                 LIBS="$LIBS `$GLIB_CONFIG --libs gthread`"
 185                 AC_DEFINE(USE_THREADS, 1, Whether to use multithread or not)
 186         else
 187                 AC_MSG_ERROR([Sylpheed requires GThread from GLib to use threading.])
 188         fi
 189 else
 190         AC_MSG_RESULT(no)
 191 fi
 192
 193 dnl Check for d_type member in struct dirent
 194 AC_MSG_CHECKING([whether struct dirent has d_type member])
 195 AC_CACHE_VAL(ac_cv_dirent_d_type,[
 196         AC_TRY_COMPILE([#include <dirent.h>],
 197                        [struct dirent d; d.d_type = DT_REG;],
 198                        ac_cv_dirent_d_type=yes, ac_cv_dirent_d_type=no)
 199 ])
 200 AC_MSG_RESULT($ac_cv_dirent_d_type)
 201 if test $ac_cv_dirent_d_type = yes; then
 202         AC_DEFINE(HAVE_DIRENT_D_TYPE, 1,
 203                   Define if `struct dirent' has `d_type' member.)
 204 fi
 205
 206 dnl Checks for header files.
 207 AC_HEADER_DIRENT
 208 AC_HEADER_STDC
 209 AC_HEADER_SYS_WAIT
 210 AC_CHECK_HEADERS(fcntl.h sys/file.h unistd.h paths.h \
 211                  sys/param.h sys/utsname.h sys/select.h \
 212                  wchar.h wctype.h locale.h)
 213
 214 dnl alf - Check for apache installation f*ck up. apache may also install an
 215 dnl fnmatch, which includes their own regex stuff if USE_HSREGEX is defined
 216 AC_TRY_COMPILE([#include <stdlib.h>
 217                 #include <fnmatch.h>],
 218         [int x = USE_HSREGEX;],
 219         ac_cv_have_apache_fnmatch=yes, ac_cv_have_apache_fnmatch=no)
 220 if test $ac_cv_have_apache_fnmatch = yes; then
 221         AC_DEFINE(HAVE_APACHE_FNMATCH, 1, Define if you need to work around apache regex/fnmatch !KLUDGE!)
 222 fi
 223 AC_MSG_CHECKING([whether to use Apache regex header kludge])
 224 AC_MSG_RESULT($ac_cv_have_apache_fnmatch)
 225
 226 dnl Checks for typedefs, structures, and compiler characteristics.
 227 AC_C_CONST
 228 AC_TYPE_OFF_T
 229 AC_TYPE_PID_T
 230 AC_TYPE_SIZE_T
 231 AC_STRUCT_TM
 232
 233 dnl AC_CHECK_TYPE(wint_t, unsigned int) does not work because wint_t
 234 dnl may be defined only in wchar.h (this happens with gcc-2.96).
 235 dnl So we need to use this extended macro.
 236 SYLPHEED_CHECK_TYPE(wint_t, unsigned int,
 237 [
 238 #if HAVE_WCHAR_H
 239 #include <wchar.h>
 240 #endif
 241 ], Define to `unsigned int' if <stddef.h> or <wchar.h> doesn't define.)
 242
 243 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF, Used to test for a u32 typedef)
 244 AC_CHECK_SIZEOF(unsigned short, 2)
 245 AC_CHECK_SIZEOF(unsigned int, 4)
 246 AC_CHECK_SIZEOF(unsigned long, 4)
 247
 248 dnl Checks for library functions.
 249 AC_FUNC_ALLOCA
 250 AC_CHECK_FUNCS(gethostname mkdir mktime socket strstr strchr \
 251                wcsstr wcswcs iswalnum iswspace towlower \
 252                wcslen wcscpy wcsncpy \
 253                uname flock lockf inet_aton inet_addr \
 254                fchmod mkstemp)
 255
 256 dnl *****************
 257 dnl ** common code **
 258 dnl *****************
 259
 260 dnl check for glib
 261 AM_PATH_GLIB_2_0(2.0.0,,
 262         AC_MSG_ERROR(Test for GLIB failed. See the file 'INSTALL' for help.),
 263         gmodule gobject gthread)
 264
 265 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 266 syl_save_LIBS=$LIBS
 267 LIBS="$LIBS $GTK_LIBS"
 268 AC_CHECK_FUNCS(bind_textdomain_codeset)
 269 LIBS=$syl_save_LIBS
 270
 271 dnl check for IPv6 option
 272 AC_ARG_ENABLE(ipv6,
 273         [  --disable-ipv6           Disable IPv6 support],
 274         [ac_cv_enable_ipv6=$enableval], [ac_cv_enable_ipv6=yes])
 275
 276 dnl automated checks for IPv6 support.
 277 AC_MSG_CHECKING([whether to use IPv6])
 278 if test x"$ac_cv_enable_ipv6" = xyes; then
 279         AC_MSG_RESULT(yes)
 280         AC_MSG_CHECKING([for IPv6 support])
 281         AC_CACHE_VAL(ac_cv_ipv6,[
 282                 AC_TRY_COMPILE([#define INET6
 283                                 #include <sys/types.h>
 284                                 #include <netinet/in.h>],
 285                         [int x = IPPROTO_IPV6; struct in6_addr a;],
 286                         ac_cv_ipv6=yes, ac_cv_ipv6=no)
 287         ])
 288         AC_MSG_RESULT($ac_cv_ipv6)
 289         if test $ac_cv_ipv6 = yes; then
 290                 AC_DEFINE(INET6, 1, Define if you want IPv6 support.)
 291         else
 292                 AC_MSG_WARN(*** IPv6 will not be supported ***)
 293                 ac_cv_enable_ipv6=no
 294         fi
 295 else
 296         AC_MSG_RESULT(no)
 297 fi
 298
 299 dnl Check for OpenSSL
 300 AC_ARG_ENABLE(openssl,
 301         [  --disable-openssl    Do not use OpenSSL for SSL support.],
 302         [ac_cv_enable_openssl=$enableval], [ac_cv_enable_openssl=yes])
 303 AC_MSG_CHECKING([whether to use OpenSSL])
 304 if test x"$ac_cv_enable_openssl" = xyes; then
 305         AC_MSG_RESULT(yes)
 306         PKG_CHECK_MODULES(OPENSSL, openssl >= 0.9.7, :, ac_cv_enable_openssl=no)
 307         if test x$ac_cv_enable_openssl = xyes; then
 308                 AC_DEFINE(USE_OPENSSL, 1, Define if you want OpenSSL support)
 309         else
 310                 AC_MSG_RESULT(not found)
 311                 AC_MSG_WARN([*** OpenSSL will not be supported ***])
 312         fi
 313 else
 314         AC_MSG_RESULT(no)
 315 fi
 316 AC_SUBST(OPENSSL_CFLAGS)
 317 AC_SUBST(OPENSSL_LIBS)
 318
 319 dnl password encryption
 320 OLDLIBS=$LIBS
 321 LIBS=
 322 AC_SEARCH_LIBS(encrypt, crypt, [], AC_MSG_ERROR(['encrypt'-function not found.]))
 323 CRYPT_LIBS=$LIBS
 324 AC_SUBST(CRYPT_LIBS)
 325 LIBS=$OLDLIBS
 326
 327 AC_ARG_WITH(passcrypt-key, [  --with-passcrypt-key=KEY     Key used to encode passwords (8 byte string)],
 328             with_passcrypt_key="$withval", with_passcrypt_key="passkey0")
 329 AC_SUBST(PASSCRYPT_KEY, $with_passcrypt_key)
 330
 331 dnl RC dir (will be default at a certain point in time)
 332 AC_ARG_WITH(config-dir,    [  --with-config-dir=RCDIR      Local configuration dir (default: .sylpheed-gtk2)],
 333               ac_cv_with_config_dir="$withval", ac_cv_with_config_dir=".sylpheed-gtk2")
 334 if test x"$ac_cv_with_config_dir" = x""; then
 335         ac_cv_with_config_dir=".sylpheed-gtk2"
 336 fi
 337 AC_DEFINE_UNQUOTED(CFG_RC_DIR, "$ac_cv_with_config_dir", Configuration directory)
 338
 339 dnl ************************
 340 dnl ** GTK user interface **
 341 dnl ************************
 342
 343 dnl Checks for GTK
 344 AM_PATH_GTK_2_0(2.4.0,,
 345         AC_MSG_ERROR(Test for GTK failed. See the file 'INSTALL' for help.))
 346
 347 dnl --disable-deprecated switch for GTK2 purification
 348 AC_ARG_ENABLE(deprecated, [  --disable-deprecated  Disable deprecated GTK functions. ],
 349                           [GTK_CFLAGS="$GTK_CFLAGS -DG_DISABLE_DEPRECATED -DGTK_DISABLE_DEPRECATED"], [])
 350
 351 AC_SUBST(GTK_CFLAGS)
 352 AC_SUBST(GTK_LIBS)
 353
 354 dnl GNU/Aspell is used for spell checking
 355 AC_ARG_ENABLE(aspell,
 356         [  --enable-aspell         Enable GNU/aspell support [default=no]],
 357         [ac_cv_enable_aspell=$enableval], [ac_cv_enable_aspell=no])
 358 AC_MSG_CHECKING([whether to use GNU/aspell])
 359 if test $ac_cv_enable_aspell = yes; then
 360         AC_MSG_RESULT(yes)
 361         AM_PATH_ASPELL(0.50, AC_DEFINE(USE_ASPELL, 1, Define if you use ASPELL to support spell checking),
 362                       [use_aspell=no ac_cv_enable_aspell=no])
 363 else
 364         AC_MSG_RESULT(no)
 365 fi
 366
 367 dnl want crash dialog
 368 AC_ARG_ENABLE(crash-dialog,
 369         [  --enable-crash-dialog   Enable crash dialog [default=no]],
 370         [ac_cv_enable_crash_dialog=$enableval], [ac_cv_enable_crash_dialog=no])
 371 if test $ac_cv_enable_crash_dialog = yes; then
 372 dnl check if GDB is somewhere
 373         AC_CHECK_PROG(ac_cv_enable_crash_dialog, gdb, yes, no)
 374         AC_MSG_CHECKING([whether to use crash dialog])
 375         if test $ac_cv_enable_crash_dialog = yes; then
 376                 AC_DEFINE(CRASH_DIALOG, 1, Pop up crash dialog)
 377         fi
 378         AC_MSG_RESULT($ac_cv_enable_crash_dialog)
 379 fi
 380
 381 dnl Check for X-Face support
 382 AC_ARG_ENABLE(compface,
 383         [  --disable-compface      Do not use compface (X-Face)],
 384         [ac_cv_enable_compface=$enableval], [ac_cv_enable_compface=yes])
 385 AC_MSG_CHECKING([whether to use compface])
 386 if test x"$ac_cv_enable_compface" = xyes; then
 387         AC_MSG_RESULT(yes)
 388         AC_CHECK_LIB(compface, uncompface,
 389                 [AC_DEFINE(HAVE_LIBCOMPFACE, 1, Define if you want compface support.)],
 390                 [ac_cv_enable_compface=no])
 391         if test x"$ac_cv_enable_compface" = xyes; then
 392                 COMPFACE_LIBS="-lcompface"
 393         else
 394                 COMPFACE_LIBS=""
 395         fi
 396         AC_SUBST(COMPFACE_LIBS)
 397 else
 398         AC_MSG_RESULT(no)
 399 fi
 400
 401 dnl check for pthread support
 402 AC_ARG_ENABLE(pthread,
 403         [  --disable-pthread           Disable pthread support],
 404         [ac_cv_enable_pthread=$enableval], [ac_cv_enable_pthread=yes])
 405 AC_MSG_CHECKING([whether to use pthread])
 406 if test x$ac_cv_enable_pthread = xno; then
 407         AC_MSG_RESULT(no)
 408 else
 409         AC_MSG_RESULT(yes)
 410
 411         AC_CHECK_LIB(pthread, pthread_create, :, ac_cv_enable_pthread=no)
 412         AC_CHECK_HEADERS(pthread.h, :, ac_cv_enable_pthread=no)
 413
 414         if test x$ac_cv_enable_pthread = xyes; then
 415                 AC_DEFINE(USE_PTHREAD, 1, Define if you have pthread)
 416                 PTHREAD_LIBS="-lpthread"
 417         fi
 418
 419 fi
 420 AC_SUBST(PTHREAD_LIBS)
 421
 422 dnl for LDAP support in addressbook
 423 dnl no check for libraries; dynamically loaded
 424 AC_ARG_ENABLE(ldap,
 425         [  --enable-ldap           Enable LDAP support [default=no]],
 426         [ac_cv_enable_ldap=$enableval], [ac_cv_enable_ldap=no])
 427 AC_MSG_CHECKING([whether to use LDAP])
 428 if test x"$ac_cv_enable_ldap" = xno; then
 429         AC_MSG_RESULT(no)
 430 elif test x"$ac_cv_enable_ldap" = xyes -a x"$ac_cv_enable_pthread" = xno; then
 431         AC_MSG_RESULT(no - LDAP support needs pthread support)
 432
 433         ac_cv_enable_ldap=no
 434 else
 435         AC_MSG_RESULT(yes)
 436
 437         dnl check for available libraries, and pull them in
 438         AC_CHECK_LIB(resolv, res_query, LDAP_LIBS="$LDAP_LIBS -lresolv")
 439         AC_CHECK_LIB(socket, bind, LDAP_LIBS="$LDAP_LIBS -lsocket")
 440         AC_CHECK_LIB(nsl, gethostbyaddr, LDAP_LIBS="$LDAP_LIBS -lnsl")
 441         AC_CHECK_LIB(lber, ber_get_tag, LDAP_LIBS="$LDAP_LIBS -llber",,
 442                      $LDAP_LIBS)
 443
 444         AC_CHECK_HEADERS(ldap.h lber.h,
 445                          [ ac_cv_enable_ldap=yes ],
 446                          [ ac_cv_enable_ldap=no ])
 447
 448         if test "$ac_cv_enable_ldap" = yes; then
 449                 AC_CHECK_LIB(ldap, ldap_open,
 450                              [ ac_cv_enable_ldap=yes ],
 451                              [ ac_cv_enable_ldap=no ],
 452                              $LDAP_LIBS)
 453
 454                 AC_CHECK_LIB(ldap, ldap_start_tls_s,
 455                              [ ac_cv_have_tls=yes ],
 456                              [ ac_cv_have_tls=no ])
 457
 458         fi
 459
 460         AC_MSG_CHECKING([whether ldap library is available])
 461         AC_MSG_RESULT($ac_cv_enable_ldap)
 462
 463         AC_MSG_CHECKING([whether TLS library is available])
 464         AC_MSG_RESULT($ac_cv_have_tls)
 465
 466         if test "$ac_cv_enable_ldap" = yes; then
 467                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
 468                 LDAP_LIBS="$LDAP_LIBS -lldap `$GLIB_CONFIG --libs gthread`"
 469                 AC_DEFINE(USE_LDAP, 1, Define if you want LDAP support in addressbook.)
 470                 AC_SUBST(LDAP_LIBS)
 471                 if test "$ac_cv_have_tls" = yes; then
 472                         AC_DEFINE(USE_LDAP_TLS, 1, Define if you want LDAP TLS support in addressbook.)
 473                 fi
 474         fi
 475 fi
 476
 477 dnl for JPilot support in addressbook
 478 dnl no check for libraries; these are dynamically loaded
 479 AC_ARG_ENABLE(jpilot,
 480         [  --enable-jpilot         Enable JPilot support [default=no]],
 481         [ac_cv_enable_jpilot=$enableval], [ac_cv_enable_jpilot=no])
 482 AC_MSG_CHECKING([whether to use JPilot])
 483 if test "$ac_cv_enable_jpilot" = yes; then
 484         AC_MSG_RESULT(yes)
 485         AC_CHECK_HEADERS(pi-args.h pi-appinfo.h pi-address.h,
 486                          [ AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ],
 487                          [ ac_cv_enable_jpilot=no ])
 488         if test "$ac_cv_enable_jpilot" = no; then
 489                 AC_CHECK_HEADERS(libpisock/pi-args.h libpisock/pi-appinfo.h libpisock/pi-address.h,
 490                                  [ ac_cv_enable_jpilot=yes
 491                                    AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ])
 492         fi
 493
 494         AC_CHECK_LIB(pisock, unpack_Address, [JPILOT_LIBS="-lpisock"], [JPILOT_LIBS="" ac_cv_enable_jpilot="no"])
 495         if test x"$ac_cv_enable_jpilot" = xyes; then
 496                 AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.)
 497         else
 498                 AC_MSG_NOTICE([JPilot support not available])
 499         fi
 500         AC_SUBST(JPILOT_LIBS)
 501 else
 502         AC_MSG_RESULT(no)
 503 fi
 504
 505 dnl #######################################################################
 506 dnl # Check for startup notification
 507 dnl #######################################################################
 508 AC_ARG_ENABLE(startup-notification, [  --disable-startup-notification    compile without startup notification support],,enable_startup_notification=yes)
 509
 510 if test "x$enable_startup_notification" = "xyes"; then
 511         PKG_CHECK_MODULES(STARTUP_NOTIFICATION, libstartup-notification-1.0 >= 0.5,
 512         [
 513                 AC_DEFINE(HAVE_STARTUP_NOTIFICATION, 1, [Define if we're using libstartup-notification.])
 514                 echo "Building with libstartup-notification"
 515                 enable_startup_notification=yes
 516         ],
 517         [
 518                 echo "Building without libstartup-notification"
 519                 enable_startup_notification=no
 520         ])
 521
 522         AC_SUBST(STARTUP_NOTIFICATION_CFLAGS)
 523         AC_SUBST(STARTUP_NOTIFICATION_LIBS)
 524 fi
 525
 526 dnl *************************
 527 dnl ** section for plugins **
 528 dnl *************************
 529
 530 PLUGINS=""
 531
 532 dnl --- Trayicon ---
 533 AC_MSG_CHECKING([whether to build Trayicon plugin])
 534 AC_ARG_ENABLE(trayicon-plugin,
 535         [  --disable-trayicon-plugin         Do not build System Tray Icon plugin],
 536         [ac_cv_enable_trayicon_plugin=$enableval], [ac_cv_enable_trayicon_plugin=yes])
 537 if test x"$ac_cv_enable_trayicon_plugin" = xyes; then
 538         AC_MSG_RESULT(yes)
 539         PLUGINS="trayicon $PLUGINS"
 540 else
 541         AC_MSG_RESULT(no)
 542 fi
 543 AM_CONDITIONAL(BUILD_TRAYICON_PLUGIN, test x"$ac_cv_enable_trayicon_plugin" = xyes)
 544
 545 dnl --- SpamAssassin ---
 546 AC_MSG_CHECKING([whether to build SpamAssassin plugin])
 547 AC_ARG_ENABLE(spamassassin-plugin,
 548         [  --enable-spamassassin-plugin      Build SpamAssassin plugin [default=no]],
 549         [ac_cv_enable_spamassassin_plugin=$enableval], [ac_cv_enable_spamassassin_plugin=no])
 550 if test x"$ac_cv_enable_spamassassin_plugin" = xyes; then
 551         AC_MSG_RESULT(yes)
 552         AC_SPAMASSASSIN
 553         PLUGINS="spamassassin $PLUGINS"
 554 else
 555         AC_MSG_RESULT(no)
 556 fi
 557 AM_CONDITIONAL(BUILD_SPAMASSASSIN_PLUGIN, test x"$ac_cv_enable_spamassassin_plugin" = xyes)
 558
 559 dnl --- PGP/CORE ---
 560 AC_MSG_CHECKING([whether to build PGP/CORE plugin])
 561 AC_ARG_ENABLE(pgpcore-plugin,
 562         [  --disable-pgpcore-plugin           Do not build PGP/Core plugin],
 563         [ac_cv_enable_pgpcore_plugin=$enableval], [ac_cv_enable_pgpcore_plugin=yes])
 564 if test x"$ac_cv_enable_pgpcore_plugin" = xyes; then
 565         AC_MSG_RESULT(yes)
 566         AM_PATH_GPGME(0.4.5, AC_DEFINE(USE_GPGME, 1, Define if you use GPGME to support OpenPGP.),
 567                       [ac_cv_enable_pgpcore_plugin=no])
 568         if test x"$ac_cv_enable_pgpcore_plugin" = xyes; then
 569                 PLUGINS="pgpcore $PLUGINS"
 570         else
 571                 AC_MSG_WARN([*** PGP/CORE plugin will not be built ***])
 572         fi
 573 else
 574         AC_MSG_RESULT(no)
 575 fi
 576 AM_CONDITIONAL(BUILD_PGPCORE_PLUGIN, test x"$ac_cv_enable_pgpcore_plugin" = xyes)
 577
 578 AC_MSG_CHECKING([whether to build PGP/MIME plugin])
 579 AC_ARG_ENABLE(pgpmime-plugin,
 580         [  --disable-pgpmime-plugin           Do not build PGP/MIME plugin],
 581         [ac_cv_enable_pgpmime_plugin=$enableval], [ac_cv_enable_pgpmime_plugin=yes])
 582 if test x"$ac_cv_enable_pgpmime_plugin" = xyes; then
 583         AC_MSG_RESULT(yes)
 584         if test x"$ac_cv_enable_pgpcore_plugin" = xyes; then
 585                 PLUGINS="pgpmime $PLUGINS"
 586         else
 587                 AC_MSG_WARN([*** PGP/MIME plugin cannot be built ***])
 588                 AC_MSG_WARN([*** without the PGP/CORE plugin     ***])
 589         fi
 590 else
 591         AC_MSG_RESULT(no)
 592 fi
 593 AM_CONDITIONAL(BUILD_PGPMIME_PLUGIN, test x"$ac_cv_enable_pgpmime_plugin" = xyes)
 594
 595 AC_MSG_CHECKING([whether to build PGP/Inline plugin])
 596 AC_ARG_ENABLE(pgpinline-plugin,
 597         [  --disable-pgpinline-plugin           Do not build PGP/Inline plugin],
 598         [ac_cv_enable_pgpinline_plugin=$enableval], [ac_cv_enable_pgpinline_plugin=yes])
 599 if test x"$ac_cv_enable_pgpinline_plugin" = xyes; then
 600         AC_MSG_RESULT(yes)
 601         if test x"$ac_cv_enable_pgpcore_plugin" = xyes; then
 602                 PLUGINS="pgpinline $PLUGINS"
 603         else
 604                 AC_MSG_WARN([*** PGP/Inline plugin cannot be built ***])
 605                 AC_MSG_WARN([*** without the PGP/CORE plugin     ***])
 606         fi
 607 else
 608         AC_MSG_RESULT(no)
 609 fi
 610 AM_CONDITIONAL(BUILD_PGPINLINE_PLUGIN, test x"$ac_cv_enable_pgpinline_plugin" = xyes)
 611
 612 dnl --- MathML Viewer ---
 613 AC_MSG_CHECKING([whether to build MathML-Viewer plugin])
 614 AC_ARG_ENABLE(mathml-viewer-plugin,
 615         [  --disable-mathml-viewer-plugin    Do not build MathML-Viewer plugin],
 616         [ac_cv_enable_mathml_viewer_plugin=$enableval], [ac_cv_enable_mathml_viewer_plugin=yes])
 617 if test x"$ac_cv_enable_mathml_viewer_plugin" = xyes; then
 618         AC_MSG_RESULT(yes)
 619         PKG_CHECK_MODULES(GTK_MATH_VIEW, gtkmathview >= 0.5, :, ac_cv_enable_mathml_viewer_plugin=no)
 620
 621         if test x"$ac_cv_enable_mathml_viewer_plugin" = xyes; then
 622
 623                 PLUGINS="mathml-viewer $PLUGINS"
 624         else
 625                 AC_MSG_RESULT(not found)
 626                 AC_MSG_WARN([*** MathML-Viewer plugin will not be built ***])
 627         fi
 628 else
 629         AC_MSG_RESULT(no)
 630 fi
 631 AC_SUBST(GTK_MATH_VIEW_CFLAGS)
 632 AC_SUBST(GTK_MATH_VIEW_LIBS)
 633 AM_CONDITIONAL(BUILD_MATHML_VIEWER_PLUGIN, test x"$ac_cv_enable_mathml_viewer_plugin" = xyes)
 634
 635 dnl --- Dillo Viewer ---
 636 AC_MSG_CHECKING([whether to build Dillo plugin])
 637 AC_ARG_ENABLE(dillo-viewer-plugin,
 638         [  --disable-dillo-viewer-plugin     Do not build Dillo plugin for html mail rendering],
 639         [ac_cv_enable_dillo_viewer_plugin=$enableval], [ac_cv_enable_dillo_viewer_plugin=yes])
 640 if test x"$ac_cv_enable_dillo_viewer_plugin" = xyes; then
 641         AC_MSG_RESULT(yes)
 642         PLUGINS="dillo-viewer $PLUGINS"
 643 else
 644         AC_MSG_RESULT(no)
 645 fi
 646 AM_CONDITIONAL(BUILD_DILLO_VIEWER_PLUGIN, test x"$ac_cv_enable_dillo_viewer_plugin" = xyes)
 647
 648 dnl --- Demo ---
 649 AC_ARG_ENABLE(demo-plugin,
 650         [  --enable-demo-plugin              Build demo plugin [default=no]],
 651         [ac_cv_enable_demo_plugin=$enableval], [ac_cv_enable_demo_plugin=no])
 652 if test x"$ac_cv_enable_demo_plugin" = xyes; then
 653         PLUGINS="demo $PLUGINS"
 654 fi
 655 AM_CONDITIONAL(BUILD_DEMO_PLUGIN, test x"$ac_cv_enable_demo_plugin" = xyes)
 656
 657 dnl --- ClamAV ---
 658 AC_MSG_CHECKING([whether to build ClamAV plugin])
 659 AC_ARG_ENABLE(clamav-plugin,
 660         [  --disable-clamav-plugin           Do not build Clam AntiVirus plugin],
 661         [ac_cv_enable_clamav_plugin=$enableval], [ac_cv_enable_clamav_plugin=yes])
 662 if test x"$ac_cv_enable_clamav_plugin" = xyes; then
 663         AC_MSG_RESULT(yes)
 664         PKG_CHECK_MODULES(CLAMAV, libclamav, ac_cv_enable_clamav_plugin=yes,
 665                           ac_cv_enable_clamav_plugin=no)
 666         if test x"$ac_cv_enable_clamav_plugin" = xyes; then
 667                 PLUGINS="clamav $PLUGINS"
 668         else
 669                 AC_MSG_RESULT(not found)
 670                 AC_MSG_WARN([*** ClamAV plugin will not be built ***])
 671         fi
 672 else
 673         AC_MSG_RESULT(no)
 674 fi
 675 AC_SUBST(CLAMAV_LIBS)
 676 AM_CONDITIONAL(BUILD_CLAMAV_PLUGIN, test x"$ac_cv_enable_clamav_plugin" = xyes)
 677
 678 dnl Libetpan
 679 AC_MSG_CHECKING([whether to use libetpan])
 680 AC_ARG_ENABLE(libetpan,
 681         [  --disable-libetpan           Do not compile IMAP4 support with libetpan],
 682         [ac_cv_enable_libetpan=$enableval], [ac_cv_enable_libetpan=yes])
 683 if test x"$ac_cv_enable_libetpan" = xyes; then
 684         AC_MSG_RESULT(yes)
 685         libetpan_result=no
 686         AC_PATH_PROG(libetpanconfig, [libetpan-config])
 687         if test "x$libetpanconfig" != "x"; then
 688           CPPFLAGS="$CPPFLAGS `$libetpanconfig --cflags 2>/dev/null`"
 689           AC_CHECK_HEADER(libetpan/libetpan.h, [libetpan_result=yes])
 690           if test "x$libetpan_result" = "xyes"; then
 691             AC_MSG_CHECKING([whether libetpan-config hints compiles and links fine])
 692             LDFLAGS="$LDFLAGS `$libetpanconfig --libs 2>/dev/null`"
 693             AC_TRY_LINK([], [db_mailstorage_init();], [libetpan_result=yes], [libetpan_result=no])
 694             AC_MSG_RESULT([$libetpan_result])
 695           fi
 696         fi
 697         if test "x$libetpan_result" = "xyes"; then
 698            LIBETPAN_CPPFLAGS="`$libetpanconfig --cflags`"
 699            LIBETPAN_LIBS="`$libetpanconfig --libs`"
 700            LIBETPAN_VERSION=`$libetpanconfig --version | sed "s/\.//g" | sed "s/-.*$//"`
 701            if test "$LIBETPAN_VERSION" -lt "038"; then
 702                 AC_MSG_ERROR([Sylpheed requires libetpan 0.38 or newer. See http://www.etpan.org/])
 703                 AC_MSG_ERROR([You can use --disable-libetpan if you don't need IMAP4 support.])
 704            fi
 705            AC_SUBST(LIBETPAN_FLAGS)
 706            AC_SUBST(LIBETPAN_LIBS)
 707            AC_DEFINE(HAVE_LIBETPAN, 1, Define if you want IMAP support.)
 708         else
 709            AC_MSG_ERROR([Sylpheed requires libetpan 0.38 or newer. See http://www.etpan.org/ ])
 710            AC_MSG_ERROR([You can use --disable-libetpan if you don't need IMAP4 support.])
 711         fi
 712 else
 713         AC_MSG_RESULT(no)
 714 fi
 715
 716 dnl Libgnomeprint
 717 AC_MSG_CHECKING([whether to use libgnomeprint])
 718 AC_ARG_ENABLE(gnomeprint,
 719         [  --disable-gnomeprint         Do not use libgnomeprint for printing],
 720         [ac_cv_enable_gnomeprint=$enableval], [ac_cv_enable_gnomeprint=yes])
 721 if test x$ac_cv_enable_gnomeprint = xyes; then
 722         AC_MSG_RESULT(yes)
 723         PKG_CHECK_MODULES(GNOMEPRINT, libgnomeprint-2.2 libgnomeprintui-2.2,
 724                           ac_cv_enable_gnomeprint=yes, ac_cv_enable_gnomeprint=no)
 725         if test x"$ac_cv_enable_gnomeprint" = xyes; then
 726                 AC_DEFINE(USE_GNOMEPRINT, 1, Define if you want libgnomeprint support)
 727         else
 728                 AC_MSG_RESULT(not found)
 729                 AC_MSG_WARN([*** libgnomeprintui wasn't found    ***])
 730                 AC_MSG_WARN([*** using built-in printing support ***])
 731         fi
 732 else
 733         AC_MSG_RESULT(no)
 734 fi
 735 AM_CONDITIONAL(SYLPHEED_GNOMEPRINT, test x"$ac_cv_enable_gnomeprint" = x"yes")
 736
 737 dnl ****************************
 738 dnl ** Final configure output **
 739 dnl ****************************
 740
 741 AC_OUTPUT([
 742 Makefile
 743 sylpheed.spec
 744 m4/Makefile
 745 po/Makefile.in
 746 src/common/version.h
 747 src/Makefile
 748 src/common/Makefile
 749 src/common/passcrypt.h
 750 src/gtk/Makefile
 751 src/etpan/Makefile
 752 src/plugins/Makefile
 753 src/plugins/demo/Makefile
 754 src/plugins/spamassassin/Makefile
 755 src/plugins/mathml_viewer/Makefile
 756 src/plugins/dillo_viewer/Makefile
 757 src/plugins/trayicon/Makefile
 758 src/plugins/trayicon/libeggtrayicon/Makefile
 759 src/plugins/clamav/Makefile
 760 src/plugins/pgpcore/Makefile
 761 src/plugins/pgpmime/Makefile
 762 src/plugins/pgpinline/Makefile
 763 doc/Makefile
 764 doc/faq/Makefile
 765 doc/faq/de/Makefile
 766 doc/faq/en/Makefile
 767 doc/faq/es/Makefile
 768 doc/faq/fr/Makefile
 769 doc/faq/it/Makefile
 770 doc/man/Makefile
 771 doc/manual/Makefile
 772 doc/manual/de/Makefile
 773 doc/manual/en/Makefile
 774 doc/manual/es/Makefile
 775 doc/manual/fr/Makefile
 776 doc/manual/ja/Makefile
 777 tools/Makefile
 778 config/Makefile
 779 sylpheed-claws.pc
 780 ])
 781
 782 dnl Output the configuration summary
 783 echo ""
 784 echo "$PACKAGE $VERSION"
 785 echo ""
 786 echo "JPilot        : $ac_cv_enable_jpilot"
 787 echo "LDAP          : $ac_cv_enable_ldap"
 788 echo "OpenSSL       : $ac_cv_enable_openssl"
 789 echo "iconv         : $am_cv_func_iconv"
 790 echo "compface      : $ac_cv_enable_compface"
 791 echo "IPv6          : $ac_cv_enable_ipv6"
 792 echo "GNU/aspell    : $ac_cv_enable_aspell"
 793 echo "IMAP4         : $ac_cv_enable_libetpan"
 794 echo "Crash dialog  : $ac_cv_enable_crash_dialog"
 795 echo "libgnomeprint : $ac_cv_enable_gnomeprint"
 796 echo "Plugins       : $PLUGINS"
 797 echo "Config dir    : $ac_cv_with_config_dir"
 798 echo ""
 799 echo "The binary will be installed in $prefix/bin"
 800 echo ""
 801 echo "Configure finished, type 'make' to build."