2004-08-09 [paul] 0.9.12cvs55.2
[claws.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script.
2 AC_PREREQ(2.50)
3 AC_INIT(src/main.c)
4 AC_CONFIG_AUX_DIR(config)
5
6 PACKAGE=sylpheed-claws
7
8 dnl version number
9 MAJOR_VERSION=0
10 MINOR_VERSION=9
11 MICRO_VERSION=12
12 INTERFACE_AGE=0
13 BINARY_AGE=0
14 EXTRA_VERSION=55
15 EXTRA_RELEASE=
16 EXTRA_GTK2_VERSION=.2
17
18 if test \( $EXTRA_VERSION -eq 0 \) -o \( "x$EXTRA_RELEASE" != "x" \); then
19     VERSION=${MAJOR_VERSION}.${MINOR_VERSION}.${MICRO_VERSION}${EXTRA_RELEASE}${EXTRA_GTK2_VERSION}
20 else
21     VERSION=${MAJOR_VERSION}.${MINOR_VERSION}.${MICRO_VERSION}cvs${EXTRA_VERSION}${EXTRA_GTK2_VERSION}
22 fi
23
24 dnl set $target
25 AC_CANONICAL_SYSTEM
26
27 dnl
28 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
29 dnl AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
30 dnl AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
31 AC_SUBST(PACKAGE)
32 AC_SUBST(VERSION)
33 AC_SUBST(MAJOR_VERSION)
34 AC_SUBST(MINOR_VERSION)
35 AC_SUBST(MICRO_VERSION)
36 AC_SUBST(EXTRA_VERSION)
37
38 dnl GNOME installed?
39 AC_PATH_PROG(GNOME_CONFIG, gnome-config, no)
40 if test "$GNOME_CONFIG" != no; then
41         gnomedatadir="`gnome-config --datadir`"
42         gnomeprefix="`gnome-config --prefix`"
43         if test "${prefix}" = "NONE"; then
44                 gnomedatadir="${ac_default_prefix}/${gnomedatadir#${gnomeprefix}}"
45         else
46                 gnomedatadir="${prefix}/${gnomedatadir#${gnomeprefix}}"
47         fi
48         AC_SUBST(gnomedatadir)
49 fi
50 AM_CONDITIONAL(SYLPHEED_GNOME, test -n "$gnomedatadir")
51
52 dnl Claws version
53 AC_DEFINE(CLAWS, 1, Compiling Claws branch of sylpheed)
54
55 dnl libtool versioning
56 LT_RELEASE=$MAJOR_VERSION.$MINOR_VERSION
57 LT_CURRENT=`expr $MICRO_VERSION - $INTERFACE_AGE`
58 LT_REVISION=$INTERFACE_AGE
59 LT_AGE=`expr $BINARY_AGE - $INTERFACE_AGE`
60 AC_SUBST(LT_RELEASE)
61 AC_SUBST(LT_CURRENT)
62 AC_SUBST(LT_REVISION)
63 AC_SUBST(LT_AGE)
64
65 dnl Specify a header configuration file
66 AC_CONFIG_HEADERS(config.h)
67
68 AM_MAINTAINER_MODE
69
70 dnl Checks for programs.
71 dnl AC_ARG_PROGRAM
72 AC_PROG_CC
73 AC_ISC_POSIX
74 AC_PROG_INSTALL
75 AC_PROG_LN_S
76 AC_PROG_MAKE_SET
77 AC_PROG_CPP
78 dnl AC_PROG_RANLIB
79 AM_PROG_LEX
80 AC_PROG_YACC
81 AC_PROG_LIBTOOL
82
83 SYLPHEED_ACLOCAL_INCLUDE(m4)
84   
85 dnl ******************************
86 dnl Checks for host
87 dnl ******************************
88 AC_CANONICAL_HOST
89
90 dnl Copied from the official gtk+-2 configure.in
91 AC_MSG_CHECKING([for some Win32 platform])
92 case "$host" in
93   *-*-mingw*|*-*-cygwin*)
94     platform_win32=yes
95     LDFLAGS="$LDFLAGS -mwindows"
96     ;;
97   *)
98     platform_win32=no
99     ;;
100 esac
101 AC_MSG_RESULT([$platform_win32])
102 AM_CONDITIONAL(PLATFORM_WIN32, test x"$platform_win32" = x"yes")
103
104 if test x"$platform_win32" = x"yes"; then
105     WINDRES=windres
106     AC_SUBST(WINDRES)
107 fi
108
109 AC_MSG_CHECKING([for native Win32])
110 case "$host" in
111   *-*-mingw*)
112     os_win32=yes
113     ;;
114   *)
115     os_win32=no
116     ;;
117 esac
118 AC_MSG_RESULT([$os_win32])
119 AM_CONDITIONAL(OS_WIN32, test x"$os_win32" = x"yes")
120
121 case "$target" in
122 *-darwin*)
123         CFLAGS="$CFLAGS -traditional-cpp -fno-common"
124         ;;
125 esac
126   
127 dnl Checks for iconv
128 AM_ICONV
129
130 dnl for gettext
131 ALL_LINGUAS="bg cs de el en_GB es fr hr hu it ja ko nl pl pt_BR ru sk sr sv zh_CN zh_TW.Big5"
132 AM_GNU_GETTEXT([use-libtool])
133 AM_GNU_GETTEXT_VERSION(0.12.1)
134 dnl AC_CHECK_FUNC(gettext, AC_CHECK_LIB(intl, gettext))
135 localedir='${prefix}/${DATADIRNAME}/locale'
136 AC_SUBST(localedir)
137
138 manualdir='${prefix}/${DATADIRNAME}/${PACKAGE}/manual'
139 AC_SUBST(manualdir)
140 faqdir='${prefix}/${DATADIRNAME}/${PACKAGE}/faq'
141 AC_SUBST(faqdir)
142
143 dnl Set PACKAGE_DATA_DIR in config.h.
144 if test "x${datadir}" = 'x${prefix}/share'; then
145   if test "x${prefix}" = "xNONE"; then
146     AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${ac_default_prefix}/share/${PACKAGE}", PACKAGE_DATA_DIR)
147   else
148     AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${prefix}/share/${PACKAGE}", PACKAGE_DATA_DIR)
149   fi
150 else
151   AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${datadir}/${PACKAGE}", PACKAGE_DATA_DIR)
152 fi
153
154 AC_CHECK_LIB(xpg4, setlocale)
155
156 dnl for GThread support (currently disabled)
157 dnl AC_ARG_ENABLE(threads,
158 dnl     [  --enable-threads        Enable multithread support [default=no]],
159 dnl     [use_threads=$enableval], [use_threads=no])
160
161 AC_MSG_CHECKING([whether to use threads])
162 if test x"$use_threads" = xyes ; then
163         AC_MSG_RESULT(yes)
164         if test ! -z `$GLIB_CONFIG --help 2>&1 |grep 'gthread'` ; then
165                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
166                 LIBS="$LIBS `$GLIB_CONFIG --libs gthread`"
167                 AC_DEFINE(USE_THREADS, 1, Whether to use multithread or not)
168         else
169                 AC_MSG_ERROR([Sylpheed requires GThread from GLib to use threading.])
170         fi
171 else
172         AC_MSG_RESULT(no)
173 fi
174
175 dnl Check for d_type member in struct dirent
176 AC_MSG_CHECKING([whether struct dirent has d_type member])
177 AC_CACHE_VAL(ac_cv_dirent_d_type,[
178         AC_TRY_COMPILE([#include <dirent.h>],
179                        [struct dirent d; d.d_type = DT_REG;],
180                        ac_cv_dirent_d_type=yes, ac_cv_dirent_d_type=no)
181 ])
182 AC_MSG_RESULT($ac_cv_dirent_d_type)
183 if test $ac_cv_dirent_d_type = yes; then
184         AC_DEFINE(HAVE_DIRENT_D_TYPE, 1,
185                   Define if `struct dirent' has `d_type' member.)
186 fi
187
188 dnl Checks for header files.
189 AC_HEADER_DIRENT
190 AC_HEADER_STDC
191 AC_HEADER_SYS_WAIT
192 AC_CHECK_HEADERS(fcntl.h sys/file.h unistd.h paths.h \
193                  sys/param.h sys/utsname.h sys/select.h \
194                  wchar.h wctype.h locale.h)
195
196 dnl alf - Check for apache installation f*ck up. apache may also install an 
197 dnl fnmatch, which includes their own regex stuff if USE_HSREGEX is defined
198 AC_TRY_COMPILE([#include <stdlib.h>
199                 #include <fnmatch.h>],
200         [int x = USE_HSREGEX;],
201         ac_cv_have_apache_fnmatch=yes, ac_cv_have_apache_fnmatch=no)
202 if test $ac_cv_have_apache_fnmatch = yes; then
203         AC_DEFINE(HAVE_APACHE_FNMATCH, 1, Define if you need to work around apache regex/fnmatch !KLUDGE!)
204 fi
205 AC_MSG_CHECKING([whether to use Apache regex header kludge])
206 AC_MSG_RESULT($ac_cv_have_apache_fnmatch)
207
208 dnl Checks for typedefs, structures, and compiler characteristics.
209 AC_C_CONST
210 AC_TYPE_OFF_T
211 AC_TYPE_PID_T
212 AC_TYPE_SIZE_T
213 AC_STRUCT_TM
214
215 dnl AC_CHECK_TYPE(wint_t, unsigned int) does not work because wint_t
216 dnl may be defined only in wchar.h (this happens with gcc-2.96).
217 dnl So we need to use this extended macro.
218 SYLPHEED_CHECK_TYPE(wint_t, unsigned int,
219 [
220 #if HAVE_WCHAR_H
221 #include <wchar.h>
222 #endif
223 ], Define to `unsigned int' if <stddef.h> or <wchar.h> doesn't define.)
224
225 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF, Used to test for a u32 typedef)
226 AC_CHECK_SIZEOF(unsigned short, 2)
227 AC_CHECK_SIZEOF(unsigned int, 4)
228 AC_CHECK_SIZEOF(unsigned long, 4)
229
230 dnl Checks for library functions.
231 AC_FUNC_ALLOCA
232 AC_CHECK_FUNCS(gethostname mkdir mktime socket strstr strchr \
233                wcsstr wcswcs iswalnum iswspace towlower \
234                wcslen wcscpy wcsncpy \
235                uname flock lockf inet_aton inet_addr \
236                fchmod mkstemp)
237
238 dnl *****************
239 dnl ** common code **
240 dnl *****************
241
242 dnl check for glib
243 AM_PATH_GLIB_2_0(2.0.0,,
244         AC_MSG_ERROR(Test for GLIB failed. See the file 'INSTALL' for help.),
245         gmodule gobject gthread)
246
247 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
248 syl_save_LIBS=$LIBS
249 LIBS="$LIBS $GTK_LIBS"
250 AC_CHECK_FUNCS(bind_textdomain_codeset)
251 LIBS=$syl_save_LIBS
252
253 dnl check for IPv6 option
254 AC_ARG_ENABLE(ipv6,
255         [  --disable-ipv6           Disable IPv6 support],
256         [ac_cv_enable_ipv6=$enableval], [ac_cv_enable_ipv6=yes])
257
258 dnl automated checks for IPv6 support.
259 AC_MSG_CHECKING([whether to use IPv6])
260 if test x"$ac_cv_enable_ipv6" = xyes; then
261         AC_MSG_RESULT(yes)
262         AC_MSG_CHECKING([for IPv6 support])
263         AC_CACHE_VAL(ac_cv_ipv6,[
264                 AC_TRY_COMPILE([#define INET6
265                                 #include <sys/types.h>
266                                 #include <netinet/in.h>],
267                         [int x = IPPROTO_IPV6; struct in6_addr a;],
268                         ac_cv_ipv6=yes, ac_cv_ipv6=no)
269         ])
270         AC_MSG_RESULT($ac_cv_ipv6)
271         if test $ac_cv_ipv6 = yes; then
272                 AC_DEFINE(INET6, 1, Define if you want IPv6 support.)
273         else
274                 AC_MSG_WARN(*** IPv6 will not be supported ***)
275                 ac_cv_enable_ipv6=no
276         fi
277 else
278         AC_MSG_RESULT(no)
279 fi
280
281 dnl Check for OpenSSL
282 AC_ARG_ENABLE(openssl,
283         [  --enable-openssl    Attempt to use OpenSSL for SSL support.],
284         [ac_cv_enable_openssl=$enableval], [ac_cv_enable_openssl=yes])
285 if test x"$ac_cv_enable_openssl" = xyes; then
286         PKG_CHECK_MODULES(OPENSSL, openssl >= 0.9.7, :, ac_cv_enable_openssl=no)
287         if test x$ac_cv_enable_openssl = xyes; then
288                 AC_DEFINE(USE_OPENSSL, 1, Define if you want OpenSSL support)
289         fi
290 fi
291 AC_SUBST(OPENSSL_CFLAGS)
292 AC_SUBST(OPENSSL_LIBS)
293
294 dnl password encryption
295 OLDLIBS=$LIBS
296 LIBS=
297 AC_SEARCH_LIBS(encrypt, crypt, [], AC_MSG_ERROR(['encrypt'-function not found.]))
298 CRYPT_LIBS=$LIBS
299 AC_SUBST(CRYPT_LIBS)
300 LIBS=$OLDLIBS
301
302 AC_ARG_WITH(passcrypt-key, [  --with-passcrypt-key=KEY     Key used to encode passwords (8 byte string)],
303             with_passcrypt_key="$withval", with_passcrypt_key="passkey0")
304 AC_SUBST(PASSCRYPT_KEY, $with_passcrypt_key)
305
306 dnl RC dir (will be default at a certain point in time)
307 AC_ARG_WITH(config-dir,    [  --with-config-dir=RCDIR      Local configuration dir (default: .sylpheed)],
308               ac_cv_with_config_dir="$withval", ac_cv_with_config_dir=".sylpheed")
309 if test x"$ac_cv_with_config_dir" = x""; then
310         ac_cv_with_config_dir=".sylpheed"
311 fi 
312 AC_DEFINE_UNQUOTED(CFG_RC_DIR, "$ac_cv_with_config_dir", Configuration directory)
313
314 dnl ************************
315 dnl ** GTK user interface **
316 dnl ************************
317
318 dnl Checks for GTK
319 AM_PATH_GTK_2_0(2.4.0,,
320         AC_MSG_ERROR(Test for GTK failed. See the file 'INSTALL' for help.))
321
322 dnl GNU/Aspell is used for spell checking
323 AC_ARG_ENABLE(aspell,
324         [  --enable-aspell         Enable GNU/aspell support [default=no]],
325         [ac_cv_enable_aspell=$enableval], [ac_cv_enable_aspell=no])
326 AC_MSG_CHECKING([whether to use GNU/aspell])
327 if test $ac_cv_enable_aspell = yes; then
328         AC_MSG_RESULT(yes)
329         AM_PATH_ASPELL(0.50, AC_DEFINE(USE_ASPELL, 1, Define if you use ASPELL to support spell checking),
330                       [use_aspell=no ac_cv_enable_aspell=no])
331 else
332         AC_MSG_RESULT(no)
333 fi
334
335 dnl want crash dialog
336 AC_ARG_ENABLE(crash-dialog,
337         [  --enable-crash-dialog   Enable crash dialog [default=no]],
338         [ac_cv_enable_crash_dialog=$enableval], [ac_cv_enable_crash_dialog=no])
339 if test $ac_cv_enable_crash_dialog = yes; then
340 dnl check if GDB is somewhere
341         AC_CHECK_PROG(ac_cv_enable_crash_dialog, gdb, yes, no)
342         AC_MSG_CHECKING([whether to use crash dialog])
343         if test $ac_cv_enable_crash_dialog = yes; then
344                 AC_DEFINE(CRASH_DIALOG, 1, Pop up crash dialog)
345         fi
346         AC_MSG_RESULT($ac_cv_enable_crash_dialog)
347 fi
348
349 dnl Check for X-Face support
350 AC_ARG_ENABLE(compface,
351         [  --disable-compface      Do not use compface (X-Face)],
352         [ac_cv_enable_compface=$enableval], [ac_cv_enable_compface=yes])
353 AC_MSG_CHECKING([whether to use compface])
354 if test x"$ac_cv_enable_compface" = xyes; then
355         AC_MSG_RESULT(yes)
356         AC_CHECK_LIB(compface, uncompface, 
357                 [AC_DEFINE(HAVE_LIBCOMPFACE, 1, Define if you want compface support.)],
358                 [ac_cv_enable_compface=no])
359         if test x"$ac_cv_enable_compface" = xyes; then
360                 COMPFACE_LIBS="-lcompface"
361         else
362                 COMPFACE_LIBS=""
363         fi
364         AC_SUBST(COMPFACE_LIBS)
365 else
366         AC_MSG_RESULT(no)
367 fi
368
369 dnl for LDAP support in addressbook
370 dnl no check for libraries; dynamically loaded
371 AC_ARG_ENABLE(ldap,
372         [  --enable-ldap           Enable LDAP support [default=no]],
373         [ac_cv_enable_ldap=$enableval], [ac_cv_enable_ldap=no])
374 AC_MSG_CHECKING([whether to use LDAP])
375 if test "$ac_cv_enable_ldap" = yes; then
376         AC_MSG_RESULT(yes)
377
378         dnl check for available libraries, and pull them in
379         AC_CHECK_LIB(resolv, res_query, LDAP_LIBS="$LDAP_LIBS -lresolv")
380         AC_CHECK_LIB(socket, bind, LDAP_LIBS="$LDAP_LIBS -lsocket")
381         AC_CHECK_LIB(nsl, gethostbyaddr, LDAP_LIBS="$LDAP_LIBS -lnsl")
382         AC_CHECK_LIB(lber, ber_get_tag, LDAP_LIBS="$LDAP_LIBS -llber",,
383                      $LDAP_LIBS)
384
385         dnl we need libpthread for sylpheed ldap,  until we find
386         dnl a better way to handle ldap requests asynchronously...
387         AC_CHECK_LIB(pthread, pthread_create, LDAP_LIBS="$LDAP_LIBS -lpthread")
388
389         AC_CHECK_HEADERS(ldap.h lber.h pthread.h,
390                          [ ac_cv_enable_ldap=yes ],
391                          [ ac_cv_enable_ldap=no ])
392
393         if test "$ac_cv_enable_ldap" = yes; then
394                 AC_CHECK_LIB(ldap, ldap_open,
395                              [ ac_cv_enable_ldap=yes ],
396                              [ ac_cv_enable_ldap=no ],
397                              $LDAP_LIBS)
398
399                 AC_CHECK_LIB(ldap, ldap_start_tls_s,
400                              [ ac_cv_have_tls=yes ],
401                              [ ac_cv_have_tls=no ])
402
403         fi
404
405         AC_MSG_CHECKING([whether ldap library is available])
406         AC_MSG_RESULT($ac_cv_enable_ldap)
407
408         AC_MSG_CHECKING([whether TLS library is available])
409         AC_MSG_RESULT($ac_cv_have_tls)
410
411         if test "$ac_cv_enable_ldap" = yes; then
412                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
413                 LDAP_LIBS="$LDAP_LIBS -lldap `$GLIB_CONFIG --libs gthread`"
414                 AC_DEFINE(USE_LDAP, 1, Define if you want LDAP support in addressbook.)
415                 AC_SUBST(LDAP_LIBS)
416                 if test "$ac_cv_have_tls" = yes; then
417                         AC_DEFINE(USE_LDAP_TLS, 1, Define if you want LDAP TLS support in addressbook.)
418                 fi
419         fi
420 else
421         AC_MSG_RESULT(no)
422 fi
423
424 dnl for JPilot support in addressbook
425 dnl no check for libraries; these are dynamically loaded
426 AC_ARG_ENABLE(jpilot,
427         [  --enable-jpilot         Enable JPilot support [default=no]],
428         [ac_cv_enable_jpilot=$enableval], [ac_cv_enable_jpilot=no])
429 AC_MSG_CHECKING([whether to use JPilot])
430 if test "$ac_cv_enable_jpilot" = yes; then
431         AC_MSG_RESULT(yes)
432         AC_CHECK_HEADERS(pi-args.h pi-appinfo.h pi-address.h,
433                          [ AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ],
434                          [ ac_cv_enable_jpilot=no ])
435         if test "$ac_cv_enable_jpilot" = no; then
436                 AC_CHECK_HEADERS(libpisock/pi-args.h libpisock/pi-appinfo.h libpisock/pi-address.h,
437                                  [ ac_cv_enable_jpilot=yes
438                                    AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ])
439         fi
440
441         AC_CHECK_LIB(pisock, unpack_Address, [JPILOT_LIBS="-lpisock"], [JPILOT_LIBS="" ac_cv_enable_jpilot="no"])
442         if test x"$ac_cv_enable_jpilot" = xyes; then
443                 AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.)
444         else
445                 AC_MSG_NOTICE([JPilot support not available])
446         fi
447         AC_SUBST(JPILOT_LIBS)
448 else
449         AC_MSG_RESULT(no)
450 fi
451
452 dnl GPGME is used to support OpenPGP 
453 AC_ARG_ENABLE(gpgme,
454         [  --enable-gpgme          Enable GnuPG support using GPGME [default=no]],
455         [ac_cv_enable_gpgme=$enableval], [ac_cv_enable_gpgme=no])
456 AC_MSG_CHECKING([whether to use GPGME])
457 if test $ac_cv_enable_gpgme = yes; then
458         AC_MSG_RESULT(yes)
459         AM_PATH_GPGME(0.3.10, AC_DEFINE(USE_GPGME, 1, Define if you use GPGME to support OpenPGP.),
460                       [use_gpgme=no
461                        ac_cv_enable_gpgme=no])
462 else
463         AC_MSG_RESULT(no)
464 fi
465
466 dnl *************************
467 dnl ** section for plugins **
468 dnl *************************
469
470 PLUGINS=""
471
472 dnl --- Trayicon ---
473 AC_ARG_ENABLE(trayicon-plugin,
474         [  --disable-trayicon-plugin         Do not build System Tray Icon plugin],
475         [ac_cv_enable_trayicon_plugin=$enableval], [ac_cv_enable_trayicon_plugin=yes])
476 if test x"$ac_cv_enable_trayicon_plugin" = xyes; then
477         PLUGINS="trayicon $PLUGINS"
478 fi
479 AM_CONDITIONAL(BUILD_TRAYICON_PLUGIN, test x"$ac_cv_enable_trayicon_plugin" = xyes)
480
481 dnl --- SpamAssassin ---
482 AC_ARG_ENABLE(spamassassin-plugin,
483         [  --enable-spamassassin-plugin      Build SpamAssassin plugin [default=no]],
484         [ac_cv_enable_spamassassin_plugin=$enableval], [ac_cv_enable_spamassassin_plugin=no])
485 if test x"$ac_cv_enable_spamassassin_plugin" = xyes; then
486         AC_SPAMASSASSIN
487         PLUGINS="spamassassin $PLUGINS"
488 fi
489 AM_CONDITIONAL(BUILD_SPAMASSASSIN_PLUGIN, test x"$ac_cv_enable_spamassassin_plugin" = xyes)
490
491 dnl --- PGP/MIME ---
492 AC_ARG_ENABLE(pgpmime-plugin,
493         [  --disable-pgpmime-plugin           Do not build PGP/MIME plugin],
494         [ac_cv_enable_pgpmime_plugin=$enableval], [ac_cv_enable_pgpmime_plugin=yes])
495 if test x"$ac_cv_enable_gpgme" = xyes -a x"$ac_cv_enable_pgpmime_plugin" = xyes; then
496         PLUGINS="pgpmime $PLUGINS"
497 fi
498 AM_CONDITIONAL(BUILD_PGPMIME_PLUGIN, test x"$ac_cv_enable_pgpmime_plugin" = xyes)
499
500 dnl --- MathML Viewer ---
501 AC_ARG_ENABLE(mathml-viewer-plugin,
502         [  --disable-mathml-viewer-plugin    Do not build MathML-Viewer plugin],
503         [ac_cv_enable_mathml_viewer_plugin=$enableval], [ac_cv_enable_mathml_viewer_plugin=yes])
504 if test x"$ac_cv_enable_mathml_viewer_plugin" = xyes; then
505         PKG_CHECK_MODULES(GTK_MATH_VIEW, gtkmathview >= 0.5, :, ac_cv_enable_mathml_viewer_plugin=no)
506
507         if test x"$ac_cv_enable_mathml_viewer_plugin" = xyes; then
508
509                 PLUGINS="mathml-viewer $PLUGINS"
510         fi
511 fi
512 AC_SUBST(GTK_MATH_VIEW_CFLAGS)
513 AC_SUBST(GTK_MATH_VIEW_LIBS)
514 AM_CONDITIONAL(BUILD_MATHML_VIEWER_PLUGIN, test x"$ac_cv_enable_mathml_viewer_plugin" = xyes)
515
516 dnl --- Image Viewer ---
517 AC_ARG_ENABLE(image-viewer-plugin,
518         [  --disable-image-viewer-plugin     Do not build image viewer plugin],
519         [ac_cv_enable_image_viewer_plugin=$enableval], [ac_cv_enable_image_viewer_plugin=yes])
520 if test x"$ac_cv_enable_image_viewer_plugin" = xyes; then
521         AC_ARG_ENABLE(gdk-pixbuf,
522                 [  --disable-gdk-pixbuf              Do not use gdk-pixbuf],
523                 [ac_cv_enable_gdk_pixbuf=$enableval], [ac_cv_enable_gdk_pixbuf=yes])
524         AC_ARG_ENABLE(imlib,
525                 [  --disable-imlib                   Do not use imlib],
526                 [ac_cv_enable_imlib=$enableval], [ac_cv_enable_imlib=yes])
527
528         if test "$ac_cv_enable_gdk_pixbuf" = yes; then
529                 PKG_CHECK_MODULES(GDK_PIXBUF, \
530                         [ gdk-pixbuf-2.0 ],
531                         [ AC_DEFINE(HAVE_GDK_PIXBUF, 1, Define if you use gdk-pixbuf to support image viewer) ],
532                         [ ac_cv_enable_gdk_pixbuf=no ])
533         fi
534
535         if test "$ac_cv_enable_gdk_pixbuf" = yes; then
536                 PLUGINS="image-viewer(gdk-pixbuf) $PLUGINS"
537         else
538                 ac_cv_enable_image_viewer_plugin=no
539         fi
540 fi
541 AM_CONDITIONAL(BUILD_IMAGE_VIEWER_PLUGIN, test x"$ac_cv_enable_image_viewer_plugin" = xyes)
542
543 dnl --- Dillo Viewer ---
544 AC_ARG_ENABLE(dillo-viewer-plugin,
545         [  --disable-dillo-viewer-plugin     Do not build Dillo plugin for html mail rendering],
546         [ac_cv_enable_dillo_viewer_plugin=$enableval], [ac_cv_enable_dillo_viewer_plugin=yes])
547 if test x"$ac_cv_enable_dillo_viewer_plugin" = xyes; then
548         PLUGINS="dillo-viewer $PLUGINS"
549 fi
550 AM_CONDITIONAL(BUILD_DILLO_VIEWER_PLUGIN, test x"$ac_cv_enable_dillo_viewer_plugin" = xyes)
551
552 dnl --- Demo ---
553 AC_ARG_ENABLE(demo-plugin,
554         [  --enable-demo-plugin              Build demo plugin [default=no]],
555         [ac_cv_enable_demo_plugin=$enableval], [ac_cv_enable_demo_plugin=no])
556 if test x"$ac_cv_enable_demo_plugin" = xyes; then
557         PLUGINS="demo $PLUGINS"
558 fi
559 AM_CONDITIONAL(BUILD_DEMO_PLUGIN, test x"$ac_cv_enable_demo_plugin" = xyes)
560
561 dnl --- ClamAV ---
562 AC_ARG_ENABLE(clamav-plugin,
563         [  --disable-clamav-plugin           Do not build Clam AntiVirus plugin],
564         [ac_cv_enable_clamav_plugin=$enableval], [ac_cv_enable_clamav_plugin=yes])
565 if test x"$ac_cv_enable_clamav_plugin" = xyes; then
566         AC_CHECK_LIB(clamav, cl_scanfile, clamav_lib=-lclamav, ac_cv_enable_clamav_plugin=no)
567         AC_CHECK_HEADERS(clamav.h, :, ac_cv_enable_clamav_plugin=no)
568         if test x"$ac_cv_enable_clamav_plugin" = xyes; then
569                 CLAMAV_LIBS="${clamav_lib}"
570
571                 PLUGINS="clamav $PLUGINS"
572         else
573                 AC_MSG_NOTICE([clamav library not found, will not build clamav plugin])
574         fi
575 fi
576 AC_SUBST(CLAMAV_LIBS)
577 AM_CONDITIONAL(BUILD_CLAMAV_PLUGIN, test x"$ac_cv_enable_clamav_plugin" = xyes)
578
579 AC_CHECK_LIB(pthread, pthread_create,
580         [ OPENSSL_LIBS="$OPENSSL_LIBS -lpthread" AC_DEFINE(USE_PTHREAD, 1, Define if you have lpthread) ])
581
582 dnl ****************************
583 dnl ** Final configure output **
584 dnl ****************************
585
586 AC_OUTPUT([
587 Makefile
588 sylpheed.spec
589 intl/Makefile
590 m4/Makefile
591 po/Makefile.in
592 src/common/version.h
593 src/Makefile
594 src/common/Makefile
595 src/common/passcrypt.h
596 src/gtk/Makefile
597 src/plugins/Makefile
598 src/plugins/demo/Makefile
599 src/plugins/spamassassin/Makefile
600 src/plugins/mathml_viewer/Makefile
601 src/plugins/dillo_viewer/Makefile
602 src/plugins/image_viewer/Makefile
603 src/plugins/trayicon/Makefile
604 src/plugins/trayicon/libeggtrayicon/Makefile
605 src/plugins/clamav/Makefile
606 src/plugins/pgpmime/Makefile
607 doc/Makefile
608 doc/faq/Makefile
609 doc/faq/de/Makefile
610 doc/faq/en/Makefile
611 doc/faq/es/Makefile
612 doc/faq/fr/Makefile
613 doc/faq/it/Makefile
614 doc/man/Makefile
615 doc/manual/Makefile
616 doc/manual/de/Makefile
617 doc/manual/en/Makefile
618 doc/manual/es/Makefile
619 doc/manual/fr/Makefile
620 doc/manual/ja/Makefile
621 tools/Makefile
622 config/Makefile
623 sylpheed-claws.pc
624 ])
625
626 dnl Output the configuration summary
627 echo ""
628 echo "$PACKAGE $VERSION"
629 echo ""
630 echo "GnuPG         : $ac_cv_enable_gpgme"
631 echo "JPilot        : $ac_cv_enable_jpilot"
632 echo "LDAP          : $ac_cv_enable_ldap"
633 echo "OpenSSL       : $ac_cv_enable_openssl"
634 echo "iconv         : $am_cv_func_iconv"
635 echo "compface      : $ac_cv_enable_compface"
636 echo "IPv6          : $ac_cv_enable_ipv6"
637 echo "GNU/aspell    : $ac_cv_enable_aspell"
638 echo "Crash dialog  : $ac_cv_enable_crash_dialog"
639 echo "Plugins       : $PLUGINS"
640 echo "Config dir    : $ac_cv_with_config_dir"
641 echo ""
642 echo "The binary will be installed in $prefix/bin"
643 echo ""
644 echo "Configure finished, type 'make' to build."