a3d2a672bd35ae284de313e4a68498e546bcf4dc
[claws.git] / configure.ac
1
2 AC_PREREQ(2.59)
3 AC_INIT(src/main.c)
4 AC_CONFIG_AUX_DIR(config)
5 AC_CONFIG_MACRO_DIR([m4])
6
7 PACKAGE=claws-mail
8
9 dnl version number
10 INTERFACE_AGE=0
11 BINARY_AGE=0
12 EXTRA_RELEASE=
13 EXTRA_GTK2_VERSION=
14
15 if test \( -d .git \); then
16     AC_CHECK_PROG([GIT], [git], [yes], [no], [$PATH])
17     if test \( "$GIT" = "no" \); then
18         AC_MSG_ERROR([*** git not found. See http://git-scm.com/])
19     else
20         GIT_VERSION=`git describe --abbrev=6 --dirty --always`
21         echo "echo ${GIT_VERSION}" > ./version
22     fi
23 else
24     GIT_VERSION=`sh -c ". $srcdir/version"`
25 fi
26
27 if test \( -z "$GIT_VERSION" \); then
28         AC_MSG_ERROR([*** could not determine program version])
29 fi
30
31 MAJOR_VERSION=${GIT_VERSION%%.*}
32 MINOR_VERSION=${GIT_VERSION#*.}
33 MINOR_VERSION=${MINOR_VERSION%%.*}
34 MICRO_VERSION=${GIT_VERSION##*.}
35 MICRO_VERSION=${MICRO_VERSION%%-*}
36 EXTRA_VERSION=${GIT_VERSION#*-}
37 EXTRA_VERSION=${EXTRA_VERSION%%-*}
38
39 if test \( "x$EXTRA_VERSION" != "x" -a `echo -n $EXTRA_VERSION | wc -c` -lt 5 \); then
40     VERSION=${MAJOR_VERSION}.${MINOR_VERSION}.${MICRO_VERSION}git${EXTRA_VERSION}
41 else
42     VERSION=${MAJOR_VERSION}.${MINOR_VERSION}.${MICRO_VERSION}
43     EXTRA_VERSION=0
44 fi
45
46 if test \( "x$EXTRA_RELEASE" != "x" \); then
47     VERSION=${VERSION}${EXTRA_RELEASE}${EXTRA_GTK2_VERSION}
48 fi
49
50 dnl set $target
51 AC_CANONICAL_SYSTEM
52
53 dnl
54 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
55 dnl AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
56 dnl AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
57 AC_SUBST(PACKAGE)
58 AC_SUBST(VERSION)
59 AC_SUBST(MAJOR_VERSION)
60 AC_SUBST(MINOR_VERSION)
61 AC_SUBST(MICRO_VERSION)
62 AC_SUBST(EXTRA_VERSION)
63 AC_SUBST(GIT_VERSION)
64
65 AC_CHECK_PROG(HAVE_GTK_ICON_CACHE, gtk-update-icon-cache, yes, no)
66 AM_CONDITIONAL(UPDATE_GTK_ICON_CACHE, test x"$HAVE_GTK_ICON_CACHE" = xyes)
67
68 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
69 if test x$PKG_CONFIG = xno ; then
70   AC_MSG_ERROR([*** pkg-config not found. See http://www.freedesktop.org/software/pkgconfig/])
71 fi
72
73 dnl libtool versioning
74 LT_RELEASE=$MAJOR_VERSION.$MINOR_VERSION
75 LT_CURRENT=`expr $MICRO_VERSION - $INTERFACE_AGE`
76 LT_REVISION=$INTERFACE_AGE
77 LT_AGE=`expr $BINARY_AGE - $INTERFACE_AGE`
78 AC_SUBST(LT_RELEASE)
79 AC_SUBST(LT_CURRENT)
80 AC_SUBST(LT_REVISION)
81 AC_SUBST(LT_AGE)
82
83 dnl Specify a header configuration file
84 AC_CONFIG_HEADERS(config.h)
85 AC_CONFIG_HEADERS(claws-features.h)
86
87 AM_MAINTAINER_MODE
88
89 dnl Checks for programs.
90 dnl AC_ARG_PROGRAM
91 AC_PROG_CC
92 AC_ISC_POSIX
93 AC_PROG_INSTALL
94 AC_PROG_LN_S
95 AC_PROG_MAKE_SET
96 AC_PROG_CPP
97 dnl AC_PROG_RANLIB
98 AM_PROG_LEX
99 AC_PROG_YACC
100 AC_LIB_PREFIX
101 AC_LIBTOOL_WIN32_DLL
102 LT_INIT
103 LT_AC_PROG_RC
104 AC_LIBTOOL_RC
105 AC_PROG_LIBTOOL
106 AC_PROG_AWK
107
108 AC_SYS_LARGEFILE
109
110 dnl ******************************
111 dnl Checks for host
112 dnl Not needed anymore because we
113 dnl do AC_CANONICAL_SYSTEM above
114 dnl ******************************
115 dnl AC_CANONICAL_HOST
116
117 dnl Copied from the official gtk+-2 configure.in
118 AC_MSG_CHECKING([for host platform])
119 case "$host" in
120   *-*-mingw*|*-*-cygwin*)
121     platform_win32=yes
122     LDFLAGS="$LDFLAGS -mwindows -Wl,--export-all-symbols"
123     ;;
124         *-apple-*)
125                 platform_osx=yes
126                 LDFLAGS="$LDFLAGS -Wl,-export_dynamic"
127                 ;;
128   *)
129     platform_win32=no
130                 platform_osx=no
131                 LDFLAGS="$LDFLAGS -Wl,--export-dynamic"
132     ;;
133 esac
134 AM_CONDITIONAL(PLATFORM_WIN32, test x"$platform_win32" = x"yes")
135 AM_CONDITIONAL(PLATFORM_OSX, test x"$platform_osx" = x"yes")
136 AC_MSG_RESULT([$host])
137
138 AC_MSG_CHECKING([for native Win32])
139 case "$host" in
140   *-*-mingw*)
141     os_win32=yes
142     ;;
143   *)
144     os_win32=no
145     ;;
146 esac
147 AC_MSG_RESULT([$os_win32])
148 AM_CONDITIONAL(OS_WIN32, test x"$os_win32" = x"yes")
149
150 AC_MSG_CHECKING([for Cygwin])
151 case "$host" in
152   *-*-cygwin*)
153     env_cygwin=yes
154     ;;
155   *)
156     env_cygwin=no
157     ;;
158 esac
159 AC_MSG_RESULT([$env_cygwin])
160 AM_CONDITIONAL(CYGWIN, test x"$env_cygwin" = x"yes")
161
162 if test "$GCC" = "yes"
163 then
164         CFLAGS="$CFLAGS -Wno-unused-function"
165         #CFLAGS="-g -Wall -Wno-unused-function"
166 fi
167
168 AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
169 _gcc_cflags_save=$CFLAGS
170 CFLAGS="-Wno-pointer-sign"
171 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],_gcc_psign=yes,_gcc_psign=no)
172 AC_MSG_RESULT($_gcc_psign)
173 CFLAGS=$_gcc_cflags_save;
174 if test x"$_gcc_psign" = xyes ; then
175         CFLAGS="$CFLAGS -Wno-pointer-sign"
176 fi
177
178 CFLAGS="$CFLAGS -Wall"
179
180 if test $USE_MAINTAINER_MODE = yes; then
181         CFLAGS="$CFLAGS -g -Wno-pointer-sign -DUSE_MAINTAINER_MODE"
182 fi
183
184 pthread_name=
185 case "$target" in
186 *-darwin*)
187         CFLAGS="$CFLAGS -no-cpp-precomp -fno-common"
188         ;;
189 *-*-mingw*)
190         # Note that we need to link to pthread in all cases. This
191         # is because some locking is used even when pthread support is
192         # disabled.
193         pthread_name=pthread
194         CFLAGS="$CFLAGS -mms-bitfields"
195         LIBS="$LIBS -l${pthread_name} -lws2_32 -lregex"
196         ;;
197 *-*-solaris*)
198         CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
199         CFLAGS="$CFLAGS -std=gnu99 -DSOLARIS"
200         ;;
201 esac
202
203 dnl Checks for iconv
204 AM_ICONV
205
206 dnl floor and ceil are  in -lm
207 LIBS="$LIBS -lm"
208
209 dnl
210 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
211 dnl
212 syl_save_LIBS=$LIBS
213 LIBS="$LIBS $GTK_LIBS"
214 AC_CHECK_FUNCS(bind_textdomain_codeset)
215 LIBS=$syl_save_LIBS
216
217 dnl for gettext
218 ALL_LINGUAS="ca cs da de en_GB es fi fr hu id_ID it ja nb nl pl pt_BR ro ru sk sv tr zh_TW"
219 GETTEXT_PACKAGE=claws-mail
220 AC_SUBST(GETTEXT_PACKAGE)
221 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Define text domain.])
222
223 AM_GNU_GETTEXT_VERSION([0.18])
224 AM_GNU_GETTEXT([external])
225
226 AC_ARG_ENABLE(manual,
227                 [  --disable-manual                Do not build user manual],
228                 [enable_manual=$enableval], [enable_manual=yes])
229
230 AC_ARG_ENABLE(libsm,
231                 [  --disable-libsm                 Do not build libSM support for session management],
232                 [enable_libsm=$enableval], [enable_libsm=yes])
233
234 AC_ARG_ENABLE(ipv6,
235                 [  --disable-ipv6                  Do not build IPv6 support],
236                 [enable_ipv6=$enableval], [enable_ipv6=yes])
237
238 AC_ARG_ENABLE(gnutls,
239                 [  --disable-gnutls                Do not build GnuTLS support for SSL/TLS],
240                     [enable_gnutls=$enableval], [enable_gnutls=yes])
241
242 AC_ARG_ENABLE(enchant,
243                 [  --disable-enchant               Do not build Enchant support for spell-checking],
244                 [enable_enchant=$enableval], [enable_enchant=yes])
245
246 AC_ARG_ENABLE(crash-dialog,
247                 [  --enable-crash-dialog           Build crash dialog],
248                 [enable_crash_dialog=$enableval], [enable_crash_dialog=no])
249
250 AC_ARG_ENABLE(generic-umpc,
251                 [  --enable-generic-umpc           Build generic UMPC code],
252                 [enable_generic_umpc=$enableval], [enable_generic_umpc=no])
253
254 AC_ARG_ENABLE(compface,
255                 [  --disable-compface              Do not build compface support for X-Face],
256                 [enable_compface=$enableval], [enable_compface=yes])
257
258 AC_ARG_ENABLE(pthread,
259                 [  --disable-pthread               Do not build pthread support],
260                 [enable_pthread=$enableval], [enable_pthread=yes])
261
262 AC_ARG_ENABLE(startup-notification,
263                 [  --disable-startup-notification  Do not startup notification support],
264                 [enable_startup_notification=$enableval], [enable_startup_notification=yes])
265
266 AC_ARG_ENABLE(dbus,
267                 [  --disable-dbus                  Do not build DBUS support],
268                 [enable_dbus=$enableval], [enable_dbus=yes])
269
270 AC_ARG_ENABLE(ldap,
271                 [  --disable-ldap                  Do not build LDAP support],
272                 [enable_ldap=$enableval], [enable_ldap=yes])
273
274 AC_ARG_ENABLE(jpilot,
275                 [  --disable-jpilot                Do not build JPilot support],
276                 [enable_jpilot=$enableval], [enable_jpilot=yes])
277
278 AC_ARG_ENABLE(networkmanager,
279                 [  --disable-networkmanager        Do not build NetworkManager support],
280                 [enable_networkmanager=$enableval], [enable_networkmanager=yes])
281
282 AC_ARG_ENABLE(libetpan,
283                 [  --disable-libetpan              Do not build libetpan support for IMAP4/NNTP],
284                 [enable_libetpan=$enableval], [enable_libetpan=yes])
285
286 AC_ARG_ENABLE(valgrind,
287                 [  --disable-valgrind              Do not build valgrind support for debugging],
288                 [enable_valgrind=$enableval], [enable_valgrind=yes])
289
290 AC_ARG_ENABLE(alternate-addressbook,
291                 [  --enable-alternate-addressbook  Build alternate external address book support],
292                 [enable_alternate_addressbook=$enableval], [enable_alternate_addressbook=no])
293
294 AC_ARG_ENABLE(gtk3,
295                 [  --enable-gtk3                   Build GTK3 support],
296                 [enable_gtk3=$enableval], [enable_gtk3=no])
297
298 AC_ARG_ENABLE(svg,
299         [  --disable-svg                   Do not build SVG support],
300         [enable_svg=$enableval], [enable_svg=yes])
301
302 manualdir='${docdir}/manual'
303 AC_ARG_WITH(manualdir,
304         [  --with-manualdir=DIR    Manual directory],
305         [manualdir="$withval"])
306 AC_SUBST(manualdir)
307
308 dnl ******************************
309 dnl ** Check for required tools **
310 dnl ** to build manuals         **
311 dnl ******************************
312
313 AC_PATH_PROG(DOCBOOK2HTML, docbook2html)
314 AC_PATH_PROG(DOCBOOK2TXT, docbook2txt)
315 AC_PATH_PROG(DOCBOOK2PS, docbook2ps)
316 AC_PATH_PROG(DOCBOOK2PDF, docbook2pdf)
317
318 AM_CONDITIONAL(MANUAL_HTML, test -n "$DOCBOOK2HTML")
319 AM_CONDITIONAL(MANUAL_TXT, test -n "$DOCBOOK2TXT")
320 AM_CONDITIONAL(MANUAL_PDF, test -n "$DOCBOOK2PDF")
321 AM_CONDITIONAL(MANUAL_PS, test -n "$DOCBOOK2PS")
322
323 if test x"$enable_manual" = x"yes"; then
324     if test -n "$DOCBOOK2TXT" -o -n "$DOCBOOK2HTML" \
325         -o -n "$DOCBOOK2PS" -o -n "$DOCBOOK2PDF"; then
326             enable_manual=yes
327         else
328             enable_manual=no
329     fi
330 fi
331
332 AM_CONDITIONAL(BUILD_MANUAL, test x"$enable_manual" = xyes)
333
334 dnl Set PACKAGE_DATA_DIR in config.h.
335 if test "x${datarootdir}" = 'x${prefix}/share'; then
336         if test "x${prefix}" = "xNONE"; then
337                 AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${ac_default_prefix}/share/${PACKAGE}",[PACKAGE_DATA_DIR])
338         else
339                 AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${prefix}/share/${PACKAGE}",[PACKAGE_DATA_DIR])
340         fi
341 else
342         AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${datarootdir}/${PACKAGE}",[PACKAGE_DATA_DIR])
343 fi
344
345 AC_CHECK_LIB(xpg4, setlocale)
346
347 SM_LIBS=""
348 dnl Check for LibSM
349 AC_MSG_CHECKING([whether to use LibSM])
350 if test x"$enable_libsm" = xyes; then
351         AC_MSG_RESULT(yes)
352         AC_CHECK_LIB(SM, SmcSaveYourselfDone,
353                 [SM_LIBS="$X_LIBS -lSM -lICE"],enable_libsm=no,
354                 $X_LIBS -lICE)
355         AC_CHECK_HEADERS(X11/SM/SMlib.h,,enable_libsm=no)
356         if test x"$enable_libsm" = xyes; then
357                 AC_DEFINE(HAVE_LIBSM, 1, [Define to 1 if you have libSM installed])
358         else
359                 AC_MSG_RESULT(not found)
360                 AC_MSG_WARN([*** LibSM will not be supported ***])
361         fi
362 else
363         AC_MSG_RESULT(no)
364 fi
365 AC_SUBST(SM_LIBS)
366
367 dnl Check for d_type member in struct dirent
368 AC_MSG_CHECKING([whether struct dirent has d_type member])
369 AC_CACHE_VAL(ac_cv_dirent_d_type,[
370         AC_TRY_COMPILE([#include <dirent.h>],
371                        [struct dirent d; d.d_type = DT_REG;],
372                        ac_cv_dirent_d_type=yes, ac_cv_dirent_d_type=no)
373 ])
374 AC_MSG_RESULT($ac_cv_dirent_d_type)
375 if test $ac_cv_dirent_d_type = yes; then
376         AC_DEFINE(HAVE_DIRENT_D_TYPE, 1,
377                   Define if `struct dirent' has `d_type' member.)
378 fi
379
380 # Check whether mkdir does not take the permission argument.
381 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
382
383 dnl Checks for header files.
384 AC_HEADER_DIRENT
385 AC_HEADER_STDC
386 AC_HEADER_SYS_WAIT
387 AC_CHECK_HEADERS(fcntl.h sys/file.h unistd.h paths.h \
388                  sys/param.h sys/utsname.h sys/select.h \
389                  wchar.h wctype.h locale.h netdb.h)
390 AC_CHECK_HEADER([execinfo.h], [AC_DEFINE(HAVE_BACKTRACE,1,[Has backtrace*() needed for retrieving stack traces])])
391 AC_SEARCH_LIBS(backtrace_symbols, [execinfo])
392
393 dnl Checks for typedefs, structures, and compiler characteristics.
394 AC_C_CONST
395 AC_TYPE_OFF_T
396 AC_TYPE_PID_T
397 AC_TYPE_SIZE_T
398 AC_STRUCT_TM
399
400 dnl AC_CHECK_TYPE(wint_t, unsigned int) does not work because wint_t
401 dnl may be defined only in wchar.h (this happens with gcc-2.96).
402 dnl So we need to use this extended macro.
403 CLAWS_CHECK_TYPE(wint_t, unsigned int,
404 [
405 #if HAVE_WCHAR_H
406 #include <wchar.h>
407 #endif
408 ], Define to `unsigned int' if <stddef.h> or <wchar.h> doesn't define.)
409
410 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF, Used to test for a u32 typedef)
411 AC_CHECK_SIZEOF(unsigned short, 2)
412 AC_CHECK_SIZEOF(unsigned int, 4)
413 AC_CHECK_SIZEOF(unsigned long, 4)
414
415 dnl Checks for library functions.
416 AC_FUNC_ALLOCA
417 AC_CHECK_FUNCS(gethostname mkdir mktime socket strstr strchr \
418                uname flock lockf inet_aton inet_addr \
419                fchmod mkstemp truncate getuid regcomp)
420
421 AC_CHECK_FUNCS(fgets_unlocked fwrite_unlocked)
422
423 dnl *****************
424 dnl ** common code **
425 dnl *****************
426
427 dnl check for glib
428 PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.28 gmodule-2.0 >= 2.28 gobject-2.0 >= 2.28 gthread-2.0 >= 2.28)
429
430 GLIB_GENMARSHAL=`pkg-config --variable=glib_genmarshal glib-2.0`
431 AC_SUBST(GLIB_GENMARSHAL)
432
433 AC_SUBST(GLIB_CFLAGS)
434 AC_SUBST(GLIB_LIBS)
435
436 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
437 syl_save_LIBS=$LIBS
438 LIBS="$LIBS $GTK_LIBS"
439 AC_CHECK_FUNCS(bind_textdomain_codeset)
440 LIBS=$syl_save_LIBS
441
442 dnl check for IPv6 option
443 dnl automated checks for IPv6 support.
444 AC_MSG_CHECKING([whether to use IPv6])
445 if test x"$enable_ipv6" = xyes; then
446         AC_MSG_RESULT(yes)
447         AC_MSG_CHECKING([for IPv6 support])
448         if test x"$platform_win32" = xyes; then
449                 AC_CACHE_VAL(ac_cv_ipv6,[
450                         AC_TRY_COMPILE([
451                                         #include <ws2tcpip.h>
452                                 ], [struct in6_addr a;],
453                                 ac_cv_ipv6=yes, ac_cv_ipv6=no)
454                 ])
455         else
456                 AC_CACHE_VAL(ac_cv_ipv6,[
457                         AC_TRY_COMPILE([
458                                         #define INET6
459                                         #include <sys/types.h>
460                                         #include <netinet/in.h>
461                                 ], [int x = IPPROTO_IPV6; struct in6_addr a;],
462                                 ac_cv_ipv6=yes, ac_cv_ipv6=no)
463                 ])
464         fi
465         AC_MSG_RESULT($ac_cv_ipv6)
466         if test $ac_cv_ipv6 = yes; then
467                 AC_DEFINE(INET6, 1, Define if you want IPv6 support.)
468         else
469                 AC_MSG_WARN(*** IPv6 will not be supported ***)
470                 enable_ipv6=no
471         fi
472 else
473         AC_MSG_RESULT(no)
474 fi
475
476 dnl GNUTLS
477 AC_MSG_CHECKING([whether to use GnuTLS])
478 AC_MSG_RESULT($enable_gnutls)
479 if test "x$enable_gnutls" != "xno"; then
480         PKG_CHECK_MODULES(GNUTLS, gnutls >= 2.2,
481         [
482                 AC_DEFINE(USE_GNUTLS, 1, gnutls)
483                 echo "Building with GnuTLS"
484                 PKG_CHECK_MODULES(GNUTLS, gnutls >= 2.11,
485                 [
486                         dnl No linking against libgcrypt needed
487                 ],
488                 [
489                         dnl linking against libgcrypt *is* needed
490                         GNUTLS_LIBS="$GNUTLS_LIBS -lgcrypt"
491                 ])
492         ],
493         [
494                 echo "Building without GnuTLS"
495                 AC_MSG_RESULT([*** GnuTLS support is recommended ])
496                 AC_MSG_RESULT([*** You can use --disable-gnutls if you don't need it.])
497                 AC_MSG_ERROR([GnuTLS not found])
498         ])
499         AC_SUBST(GNUTLS_LIBS)
500         AC_SUBST(GNUTLS_CFLAGS)
501 fi
502
503 PKG_CHECK_MODULES(NETTLE, nettle)
504 AC_SUBST(NETTLE_LIBS)
505
506 AC_ARG_WITH(passcrypt-key, [  --with-passcrypt-key=KEY     Key used to encode passwords (8 byte string)],
507             with_passcrypt_key="$withval", with_passcrypt_key="passkey0")
508 AC_SUBST(PASSCRYPT_KEY, $with_passcrypt_key)
509
510 dnl RC dir (will be default at a certain point in time)
511 AC_ARG_WITH(config-dir,    [  --with-config-dir=RCDIR      Local configuration dir (default: .claws-mail)],
512               ac_cv_with_config_dir="$withval", ac_cv_with_config_dir="")
513
514 dnl Set correct default value based on platform
515 if test x"$ac_cv_with_config_dir" = x""; then
516         if test x"$platform_win32" = xyes; then
517                 ac_cv_with_config_dir="Claws-mail"
518         else
519                 ac_cv_with_config_dir=".claws-mail"
520         fi
521 fi
522 AC_DEFINE_UNQUOTED(CFG_RC_DIR, "$ac_cv_with_config_dir", Configuration directory)
523
524 AC_ARG_WITH(password-encryption, [  --with-password-encryption=PROVIDER    Which cryptographic library to use for encrypting stored passwords (gnutls, old, default)],
525                                                 pwd_crypto="$withval", pwd_crypto="default")
526
527 if test x"$pwd_crypto" = xdefault; then
528         if test x"$enable_gnutls" = xyes; then
529                 if `$PKG_CONFIG --atleast-version=3.0 gnutls`; then
530                         pwd_crypto="gnutls"
531                 fi
532         fi
533 fi
534 if test x"$pwd_crypto" = xdefault; then
535         pwd_crypto="old"
536 fi
537
538 case $pwd_crypto in
539         gnutls)
540                 if test x"$enable_gnutls" = xno; then
541                         AC_MSG_ERROR([GnuTLS password encryption requested but GnuTLS is not available.])
542                 fi
543                 if ! `$PKG_CONFIG --atleast-version=3.0 gnutls`; then
544                         AC_MSG_ERROR([GnuTLS version at least 3.0 is required for password encryption.])
545                 fi
546                 AC_DEFINE(PASSWORD_CRYPTO_GNUTLS, 1, Use GnuTLS for stored password encryption)
547                 ;;
548         old)
549                 AC_DEFINE(PASSWORD_CRYPTO_OLD, 1, Use old insecure method for stored password encryption)
550                 ;;
551         *)
552                 AC_MSG_ERROR([Unknown password encryption provider requested.])
553                 ;;
554 esac
555
556
557 dnl ************************
558 dnl ** GTK user interface **
559 dnl ************************
560
561 dnl Checks for GTK
562 AM_CONDITIONAL(GTK3, false)
563 AM_CONDITIONAL(GTK2, true)
564 if test x"$enable_gtk3" = x"yes"; then
565         PKG_CHECK_MODULES(GTK, gtk+-3.0 >= 3.0 cairo)
566         AM_CONDITIONAL(GTK3, true)
567         AM_CONDITIONAL(GTK2, false)
568 else
569         PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.24)
570 fi
571 AC_ARG_ENABLE(deprecated,
572                 [  --disable-deprecated            Disable deprecated GTK functions],
573                 [GTK_CFLAGS="$GTK_CFLAGS -DG_DISABLE_DEPRECATED -DGTK_DISABLE_DEPRECATED"], [])
574
575 dnl Make sure the code does not regress to using deprecated GTK stuff...
576 GTK_CFLAGS="$GTK_CFLAGS -DGTK_DISABLE_SINGLE_INCLUDES -DGSEAL_ENABLE"
577
578 AC_SUBST(GTK_CFLAGS)
579 AC_SUBST(GTK_LIBS)
580
581 dnl enchant is used for spell checking
582 AC_MSG_CHECKING([whether to use enchant])
583 AC_MSG_RESULT($enable_enchant)
584 if test $enable_enchant = yes; then
585         PKG_CHECK_MODULES(ENCHANT, enchant >= 1.4.0,
586         [
587                 AC_DEFINE(USE_ENCHANT, 1, enchant)
588                 echo "Building with enchant"
589                 enable_enchant=yes
590         ],
591         [
592                 PKG_CHECK_MODULES(ENCHANT, enchant-2 >= 2.0.0,
593                 [
594                         AC_DEFINE(USE_ENCHANT, 1, enchant-2)
595                         echo "Building with enchant-2"
596                         enable_enchant=yes
597                 ],
598                 [
599                         echo "Building without enchant-notification"
600                         enable_enchant=no
601                 ])
602         ])
603         AC_SUBST(ENCHANT_CFLAGS)
604         AC_SUBST(ENCHANT_LIBS)
605 fi
606
607 dnl want crash dialog
608 if test $enable_crash_dialog = yes; then
609 dnl check if GDB is somewhere
610         AC_CHECK_PROG(enable_crash_dialog, gdb, yes, no)
611         AC_MSG_CHECKING([whether to use crash dialog])
612         if test $enable_crash_dialog = yes; then
613                 AC_DEFINE(CRASH_DIALOG, 1, Pop up crash dialog)
614         fi
615         AC_MSG_RESULT($enable_crash_dialog)
616 fi
617
618 dnl generic umpc
619 if test $enable_generic_umpc = yes; then
620         AC_DEFINE(GENERIC_UMPC, 1, Generic UMPC code)
621         AC_MSG_RESULT($enable_generic_umpc)
622 fi
623
624 dnl Check for X-Face support
625 AC_MSG_CHECKING([whether to use compface])
626 if test x"$enable_compface" = xyes; then
627         AC_MSG_RESULT(yes)
628         AC_CHECK_LIB(compface, uncompface,
629                 [AC_DEFINE(HAVE_LIBCOMPFACE, 1, Define if you want compface support.)],
630                 [enable_compface=no])
631         if test x"$enable_compface" = xyes; then
632                 COMPFACE_LIBS="-lcompface"
633         else
634                 COMPFACE_LIBS=""
635         fi
636         AC_SUBST(COMPFACE_LIBS)
637 else
638         AC_MSG_RESULT(no)
639 fi
640
641 dnl check for pthread support
642 AC_MSG_CHECKING([whether to use pthread])
643 if test x$enable_pthread = xno; then
644         AC_MSG_RESULT(no)
645 else
646         AC_MSG_RESULT(yes)
647
648         # For W32 we need to use a special ptrhead lib. In this case we can't
649         # use AC_CHECK_LIB because it has no means of checking for a
650         # library installed under a different name.  Checking for the
651         # header is okay.
652         if test -n "${pthread_name}" ; then
653            enable_pthread=yes
654         else
655         AC_CHECK_LIB(pthread, pthread_create, :, enable_pthread=no)
656         fi
657         AC_CHECK_HEADERS(pthread.h, :, enable_pthread=no)
658
659         if test x$enable_pthread = xyes; then
660                 AC_DEFINE(USE_PTHREAD, 1, Define if you have pthread)
661                 if test -z "${pthread_name}" ; then
662                 PTHREAD_LIBS="-lpthread"
663         fi
664         fi
665
666 fi
667 AC_SUBST(PTHREAD_LIBS)
668
669 dnl
670 dnl Check whether we need to pass -lresolv
671 dnl We know that we don't need it for W32.
672 dnl
673 if test x$os_win32 = xno; then
674   t_oldLibs="$LIBS"
675   LIBS="$LIBS"
676   ac_cv_var__res_options=no
677   AC_TRY_LINK([#include <sys/types.h>
678              #include <sys/socket.h>
679              #include <netinet/in.h>
680              #include <arpa/nameser.h>
681              #include <resolv.h>],
682                 [_res.options = RES_INIT;],
683                 ac_cv_var__res_options=yes);
684   if test "$ac_cv_var__res_options" != "yes"; then
685         LIBRESOLV="-lresolv"
686   fi
687   LIBS="$t_oldLibs"
688
689   if test "x$LIBRESOLV" = "x"; then
690         AC_CHECK_LIB(resolv, res_query, [LIBRESOLV=-lresolv])
691         LIBS="$t_oldLibs"
692   fi
693 fi
694 AC_SUBST(LIBRESOLV)
695
696 LIBS="$LIBS $LIBRESOLV"
697
698 dnl #######################################################################
699 dnl # Check for startup notification
700 dnl #######################################################################
701 if test "x$enable_startup_notification" = "xyes"; then
702         PKG_CHECK_MODULES(STARTUP_NOTIFICATION, libstartup-notification-1.0 >= 0.5,
703         [
704                 AC_DEFINE(HAVE_STARTUP_NOTIFICATION, 1, [Define if we're using libstartup-notification.])
705                 echo "Building with libstartup-notification"
706                 enable_startup_notification=yes
707         ],
708         [
709                 echo "Building without libstartup-notification"
710                 enable_startup_notification=no
711         ])
712
713         AC_SUBST(STARTUP_NOTIFICATION_CFLAGS)
714         AC_SUBST(STARTUP_NOTIFICATION_LIBS)
715 fi
716
717 dnl #######################################################################
718 dnl # Check for D-Bus support
719 dnl #######################################################################
720 if test "x$enable_dbus" = "xyes"; then
721         PKG_CHECK_MODULES(DBUS, [dbus-1 >= 0.60, dbus-glib-1 >= 0.60],
722         [
723                 AC_DEFINE(HAVE_DBUS_GLIB, 1, [Define if glib bindings of D-Bus are available])
724                 enable_dbus=yes
725         ],
726         [
727                 echo "D-Bus requirements not met. D-Bus support not activated."
728                 enable_dbus=no
729         ])
730         AC_SUBST(DBUS_CFLAGS)
731         AC_SUBST(DBUS_LIBS)
732 fi
733
734 dnl #######################################################################
735 dnl # Configure address book support
736 dnl #######################################################################
737
738 dnl #######################################################################
739 dnl # Check for alternate address book support
740 dnl #######################################################################
741 AC_MSG_CHECKING([whether DBUS support for alternate address book is present])
742 if test x"$enable_dbus" = xyes; then
743         AC_MSG_RESULT([yes])
744         AC_MSG_CHECKING([whether to enable alternate address book])
745         if test x"$enable_alternate_addressbook" = xyes; then
746                 AC_MSG_RESULT([yes])
747                 PKG_CHECK_MODULES(CONTACTS, [claws-contacts],
748                 [
749                         AC_DEFINE(USE_ALT_ADDRBOOK, 1, [Define if alternate address book is to be activated.])
750                         enable_alternate_addressbook=yes
751                         AC_SUBST(CONTACTS_CFLAGS)
752                         AC_SUBST(CONTACTS_LIBS)
753                 ],
754                 [
755                         enable_alternate_addressbook=no
756                 ])
757         else
758                 AC_MSG_RESULT([no])
759                 enable_alternate_addressbook=no
760         fi
761 else
762         AC_MSG_RESULT([no])
763         enable_alternate_addressbook=no
764 fi
765
766 dnl #######################################################################
767 dnl # Check for old address book support
768 dnl #######################################################################
769 if test x"$enable_alternate_addressbook" = xno; then
770         dnl for LDAP support in addressbook
771         dnl no check for libraries; dynamically loaded
772         AC_MSG_CHECKING([whether to use LDAP])
773         if test x"$enable_ldap" = xno; then
774                 AC_MSG_RESULT(no)
775         elif test x"$enable_ldap" = xyes -a x"$enable_pthread" = xno; then
776                 AC_MSG_RESULT(no - LDAP support needs pthread support)
777
778                 enable_ldap=no
779         elif test x"$platform_win32" = xyes; then
780                 AC_MSG_RESULT(yes)
781                 AC_DEFINE(USE_LDAP, 1, Define if you want LDAP support in addressbook.)
782                 LDAP_LIBS="-lwldap32"
783                 AC_SUBST(LDAP_LIBS)
784         else
785                 AC_MSG_RESULT(yes)
786
787                 dnl check for available libraries, and pull them in
788                 AC_CHECK_LIB(resolv, res_query, LDAP_LIBS="$LDAP_LIBS -lresolv")
789                 AC_CHECK_LIB(socket, bind, LDAP_LIBS="$LDAP_LIBS -lsocket")
790                 AC_CHECK_LIB(nsl, gethostbyaddr, LDAP_LIBS="$LDAP_LIBS -lnsl")
791                 AC_CHECK_LIB(lber, ber_get_tag, LDAP_LIBS="$LDAP_LIBS -llber",,
792                                  $LDAP_LIBS)
793
794                 AC_CHECK_HEADERS(ldap.h lber.h,
795                                  [ enable_ldap=yes ],
796                                  [ enable_ldap=no ])
797
798                 if test "$enable_ldap" = yes; then
799                         AC_CHECK_LIB(ldap, ldap_open,
800                                          [ enable_ldap=yes ],
801                                          [ enable_ldap=no ],
802                                          $LDAP_LIBS)
803
804                         AC_CHECK_LIB(ldap, ldap_start_tls_s,
805                                              [ ac_cv_have_tls=yes ],
806                                              [ ac_cv_have_tls=no ])
807
808                 fi
809
810                 AC_MSG_CHECKING([whether ldap library is available])
811                 AC_MSG_RESULT($enable_ldap)
812
813                 AC_MSG_CHECKING([whether TLS library is available])
814                 AC_MSG_RESULT($ac_cv_have_tls)
815
816                 if test "$enable_ldap" = yes; then
817                         AC_DEFINE(USE_LDAP, 1, Define if you want LDAP support in addressbook.)
818                         LDAP_LIBS="$LDAP_LIBS -lldap"
819                         AC_SUBST(LDAP_LIBS)
820                         if test "$ac_cv_have_tls" = yes; then
821                                 AC_DEFINE(USE_LDAP_TLS, 1, Define if you want LDAP TLS support in addressbook.)
822                         fi
823                         dnl As of OpenLDAP API version 3000 a number of functions has
824                         dnl been deprecated. As Claws-mail compiles and runs on many
825                         dnl platforms and many versions of OpenLDAP we need to be able
826                         dnl to switch between the old and new API because new API has
827                         dnl added new functions replacing old ones and at the same time
828                         dnl old functions has been changed.
829                         dnl If cross-compiling defaults to enable deprecated features
830                         dnl for maximum portability
831                         AC_MSG_CHECKING([The API version of OpenLDAP])
832                         AC_RUN_IFELSE(
833                                 [AC_LANG_PROGRAM(
834                                  [#include <ldap.h>],
835                                  [if (LDAP_API_VERSION >= 3000)
836                                                 return 1
837                                 ])],
838                                 [AC_MSG_RESULT([version < 3000])
839                                  AC_DEFINE(OPEN_LDAP_API_AT_LEAST_3000, 0, Define if OpenLDAP API is at least version 3000.)],
840                                 [AC_MSG_RESULT([version >= 3000])
841                                  AC_DEFINE(OPEN_LDAP_API_AT_LEAST_3000, 1, Define if OpenLDAP API is at least version 3000.)],
842                                 [AC_MSG_RESULT([Enabling deprecated features in OpenLDAP])
843                                  AC_DEFINE(OPEN_LDAP_API_AT_LEAST_3000, 0, Define if OpenLDAP API is at least version 3000.)
844                                  AC_DEFINE(LDAP_DEPRECATED, 1, Define to activate deprecated features in OpenLDAP)]
845                         )
846                 fi
847         fi
848
849         dnl for JPilot support in addressbook
850         dnl no check for libraries; these are dynamically loaded
851         AC_MSG_CHECKING([whether to use JPilot])
852         if test "$enable_jpilot" = yes; then
853                 AC_MSG_RESULT(yes)
854                 AC_CHECK_HEADERS(pi-args.h pi-appinfo.h pi-address.h pi-version.h,
855                                  [ AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ],
856                                  [ enable_jpilot=no ])
857                 if test "$enable_jpilot" = no; then
858                         AC_CHECK_HEADERS(libpisock/pi-args.h libpisock/pi-appinfo.h libpisock/pi-address.h libpisock/pi-version.h,
859                                          [ enable_jpilot=yes
860                                            AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ])
861                 fi
862
863                 AC_CHECK_LIB(pisock, unpack_Address, [JPILOT_LIBS="-lpisock"], [JPILOT_LIBS="" enable_jpilot="no"])
864                 if test x"$enable_jpilot" = xyes; then
865                         AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.)
866                 else
867                         AC_MSG_NOTICE([JPilot support not available])
868                 fi
869                 AC_SUBST(JPILOT_LIBS)
870         else
871                 AC_MSG_RESULT(no)
872         fi
873 fi
874
875 AM_CONDITIONAL(BUILD_ALTADDRBOOK, test x"$enable_alternate_addressbook" = x"yes")
876
877 dnl #######################################################################
878 dnl # Check for NetworkManager support
879 dnl #######################################################################
880 if test x"$enable_dbus" = xyes; then
881         if test x"$enable_networkmanager" = xyes; then
882                 PKG_CHECK_MODULES(NETWORKMANAGER_SUPPORT, libnm,
883                 [
884                         AC_DEFINE(HAVE_NETWORKMANAGER_SUPPORT, 1, [Define if NetworkManager support is to be included.])
885                         echo "Building with NetworkManager support"
886                         enable_networkmanager=yes
887                 ],
888                 [
889                         echo "NetworkManager not found."
890                         enable_networkmanager=no
891                 ])
892                 AC_SUBST(NETWORKMANAGER_SUPPORT_CFLAGS)
893         fi
894 else
895         echo "NetworkManager support deactivated as D-Bus requirements were not met."
896         enable_networkmanager=no
897 fi
898
899 dnl Libetpan
900 AC_MSG_CHECKING([whether to use libetpan])
901 if test x"$enable_libetpan" = xyes; then
902         AC_MSG_RESULT(yes)
903         libetpan_result=no
904         AC_PATH_PROG(libetpanconfig, [libetpan-config])
905         if test "x$libetpanconfig" != "x"; then
906           CPPFLAGS="$CPPFLAGS `$libetpanconfig --cflags 2>/dev/null`"
907           AC_CHECK_HEADER(libetpan/libetpan.h, [libetpan_result=yes])
908           if test "x$libetpan_result" = "xyes"; then
909             AC_MSG_CHECKING([whether libetpan-config hints compiles and links fine])
910             LIBS="$LIBS `$libetpanconfig --libs 2>/dev/null`"
911             AC_TRY_LINK([#include <libetpan/dbstorage.h>], [db_mailstorage_init(NULL, NULL);], [libetpan_result=yes], [libetpan_result=no])
912             AC_MSG_RESULT([$libetpan_result])
913           fi
914         fi
915         if test "x$libetpan_result" = "xyes"; then
916            LIBETPAN_CPPFLAGS="`$libetpanconfig --cflags`"
917            LIBETPAN_LIBS="`$libetpanconfig --libs`"
918            LIBETPAN_VERSION=`$libetpanconfig --version | $AWK -F. '{printf "%d", ($1 * 100) + $2}'`
919            if test "$LIBETPAN_VERSION" -lt "57"; then
920                 AC_MSG_RESULT([*** Claws Mail requires libetpan 0.57 or newer. See http://www.etpan.org/])
921                 AC_MSG_RESULT([*** You can use --disable-libetpan if you don't need IMAP4 and/or NNTP support.])
922                 AC_MSG_ERROR([libetpan 0.57 not found])
923            fi
924            AC_SUBST(LIBETPAN_FLAGS)
925            AC_SUBST(LIBETPAN_LIBS)
926            AC_DEFINE(HAVE_LIBETPAN, 1, Define if you want IMAP and/or NNTP support.)
927         else
928            AC_MSG_RESULT([*** Claws Mail requires libetpan 0.57 or newer. See http://www.etpan.org/ ])
929            AC_MSG_RESULT([*** You can use --disable-libetpan if you don't need IMAP4 and/or NNTP support.])
930            AC_MSG_ERROR([libetpan 0.57 not found])
931         fi
932 else
933         AC_MSG_RESULT(no)
934 fi
935 AM_CONDITIONAL(CLAWS_LIBETPAN, test "x$libetpan_result" = "xyes")
936
937 dnl librsvg
938 AC_MSG_CHECKING([whether to use librsvg])
939 if test x"$enable_svg" = xyes; then
940         AC_MSG_RESULT(yes)
941     PKG_CHECK_MODULES([SVG], [librsvg-2.0 >= 2.39.0 cairo >= 1.0.0],
942     [
943         AC_SUBST(SVG_CFLAGS)
944         AC_SUBST(SVG_LIBS)
945                 AC_DEFINE(HAVE_SVG, 1, [Define if librsvg2 is available for SVG support])
946                 enable_svg=yes
947         ],
948         [
949                 AC_MSG_NOTICE([SVG support deactivated as librsvg2 >= 2.39.0 was not found])
950                 enable_svg=no
951         ])
952 else
953         AC_MSG_RESULT(no)
954 fi
955
956 AC_MSG_CHECKING([whether to use valgrind])
957 if test x$enable_valgrind = xyes; then
958         AC_MSG_RESULT(yes)
959         PKG_CHECK_MODULES(VALGRIND, valgrind >= 2.4.0,
960                           enable_valgrind=yes, enable_valgrind=no)
961         if test x"$enable_valgrind" = xyes; then
962                 AC_DEFINE(HAVE_VALGRIND, 1, Define if you want valgrind support)
963         else
964                 AC_MSG_RESULT(not found)
965         fi
966 else
967         AC_MSG_RESULT(no)
968 fi
969 AM_CONDITIONAL(CLAWS_VALGRIND, test x"$enable_valgrind" = x"yes")
970
971 dnl *************************
972 dnl ** section for plugins **
973 dnl *************************
974
975 PLUGINS=""
976 DISABLED_PLUGINS=""
977 MISSING_DEPS_PLUGINS=""
978
979 dnl First we set the enabled status - either enabled (yes), auto-enabled (auto)
980 dnl or (auto-)disabled (no for both)
981 dnl
982 dnl All plugins are auto-enabled except for Demo which is just there to help
983 dnl potential plugins writers.
984
985 AC_ARG_ENABLE(acpi_notifier-plugin,
986                 [  --disable-acpi_notifier-plugin  Do not build acpi_notifier plugin],
987                 [enable_acpi_notifier_plugin=$enableval], [enable_acpi_notifier_plugin=auto])
988
989 AC_ARG_ENABLE(address_keeper-plugin,
990                 [  --disable-address_keeper-plugin Do not build address_keeper plugin],
991                 [enable_address_keeper_plugin=$enableval], [enable_address_keeper_plugin=auto])
992
993 AC_ARG_ENABLE(archive-plugin,
994                 [  --disable-archive-plugin        Do not build archive plugin],
995                 [enable_archive_plugin=$enableval], [enable_archive_plugin=auto])
996
997 AC_ARG_ENABLE(att_remover-plugin,
998                 [  --disable-att_remover-plugin    Do not build att_remover plugin],
999                 [enable_att_remover_plugin=$enableval], [enable_att_remover_plugin=auto])
1000
1001 AC_ARG_ENABLE(attachwarner-plugin,
1002                 [  --disable-attachwarner-plugin   Do not build attachwarner plugin],
1003                 [enable_attachwarner_plugin=$enableval], [enable_attachwarner_plugin=auto])
1004
1005 AC_ARG_ENABLE(bogofilter-plugin,
1006                 [  --disable-bogofilter-plugin     Do not build bogofilter plugin],
1007                 [enable_bogofilter_plugin=$enableval], [enable_bogofilter_plugin=auto])
1008
1009 AC_ARG_ENABLE(bsfilter-plugin,
1010                 [  --disable-bsfilter-plugin       Do not build bsfilter plugin],
1011                 [enable_bsfilter_plugin=$enableval], [enable_bsfilter_plugin=auto])
1012
1013 AC_ARG_ENABLE(clamd-plugin,
1014                 [  --disable-clamd-plugin          Do not build clamd plugin],
1015                 [enable_clamd_plugin=$enableval], [enable_clamd_plugin=auto])
1016
1017 AC_ARG_ENABLE(dillo-plugin,
1018                 [  --disable-dillo-plugin          Do not build dillo plugin],
1019                 [enable_dillo_plugin=$enableval], [enable_dillo_plugin=auto])
1020
1021 AC_ARG_ENABLE(fancy-plugin,
1022                 [  --disable-fancy-plugin          Do not build fancy plugin],
1023                 [enable_fancy_plugin=$enableval], [enable_fancy_plugin=auto])
1024
1025 AC_ARG_ENABLE(fetchinfo-plugin,
1026                 [  --disable-fetchinfo-plugin      Do not build fetchinfo plugin],
1027                 [enable_fetchinfo_plugin=$enableval], [enable_fetchinfo_plugin=auto])
1028
1029 AC_ARG_ENABLE(gdata-plugin,
1030                 [  --disable-gdata-plugin          Do not build gdata plugin],
1031                 [enable_gdata_plugin=$enableval], [enable_gdata_plugin=auto])
1032
1033 AC_ARG_ENABLE(libravatar-plugin,
1034                 [  --disable-libravatar-plugin     Do not build libravatar  plugin],
1035                 [enable_libravatar_plugin=$enableval], [enable_libravatar_plugin=auto])
1036
1037 AC_ARG_ENABLE(mailmbox-plugin,
1038                 [  --disable-mailmbox-plugin       Do not build mailmbox plugin],
1039                 [enable_mailmbox_plugin=$enableval], [enable_mailmbox_plugin=auto])
1040
1041 AC_ARG_ENABLE(managesieve-plugin,
1042                 [  --disable-managesieve-plugin    Do not build managesieve plugin],
1043                 [enable_managesieve_plugin=$enableval], [enable_managesieve_plugin=auto])
1044
1045 AC_ARG_ENABLE(newmail-plugin,
1046                 [  --disable-newmail-plugin        Do not build newmail plugin],
1047                 [enable_newmail_plugin=$enableval], [enable_newmail_plugin=auto])
1048
1049 AC_ARG_ENABLE(notification-plugin,
1050                 [  --disable-notification-plugin   Do not build notification plugin],
1051                 [enable_notification_plugin=$enableval], [enable_notification_plugin=auto])
1052
1053 AC_ARG_ENABLE(pdf_viewer-plugin,
1054                 [  --disable-pdf_viewer-plugin     Do not build pdf_viewer plugin],
1055                 [enable_pdf_viewer_plugin=$enableval], [enable_pdf_viewer_plugin=auto])
1056
1057 AC_ARG_ENABLE(perl-plugin,
1058                 [  --disable-perl-plugin           Do not build perl plugin],
1059                 [enable_perl_plugin=$enableval], [enable_perl_plugin=auto])
1060
1061 AC_ARG_ENABLE(python-plugin,
1062                 [  --disable-python-plugin         Do not build python plugin],
1063                 [enable_python_plugin=$enableval], [enable_python_plugin=auto])
1064
1065 AC_ARG_ENABLE(pgpcore-plugin,
1066                 [  --disable-pgpcore-plugin        Do not build pgpcore plugin],
1067                 [enable_pgpcore_plugin=$enableval], [enable_pgpcore_plugin=auto])
1068
1069 AC_ARG_ENABLE(pgpmime-plugin,
1070                 [  --disable-pgpmime-plugin        Do not build pgpmime plugin],
1071                 [enable_pgpmime_plugin=$enableval], [enable_pgpmime_plugin=auto])
1072
1073 AC_ARG_ENABLE(pgpinline-plugin,
1074                 [  --disable-pgpinline-plugin      Do not build pgpinline plugin],
1075                 [enable_pgpinline_plugin=$enableval], [enable_pgpinline_plugin=auto])
1076
1077 AC_ARG_ENABLE(rssyl-plugin,
1078                 [  --disable-rssyl-plugin          Do not build rssyl plugin],
1079                 [enable_rssyl_plugin=$enableval], [enable_rssyl_plugin=auto])
1080
1081 AC_ARG_ENABLE(smime-plugin,
1082                 [  --disable-smime-plugin          Do not build smime plugin],
1083                 [enable_smime_plugin=$enableval], [enable_smime_plugin=auto])
1084
1085 AC_ARG_ENABLE(spamassassin-plugin,
1086                 [  --disable-spamassassin-plugin   Do not build spamassassin plugin],
1087                 [enable_spamassassin_plugin=$enableval], [enable_spamassassin_plugin=auto])
1088
1089 AC_ARG_ENABLE(spam_report-plugin,
1090                 [  --disable-spam_report-plugin    Do not build spam_report plugin],
1091                 [enable_spam_report_plugin=$enableval], [enable_spam_report_plugin=auto])
1092
1093 AC_ARG_ENABLE(tnef_parse-plugin,
1094                 [  --disable-tnef_parse-plugin     Do not build tnef_parse plugin],
1095                 [enable_tnef_parse_plugin=$enableval], [enable_tnef_parse_plugin=auto])
1096
1097 AC_ARG_ENABLE(vcalendar-plugin,
1098                 [  --disable-vcalendar-plugin      Do not build vcalendar plugin],
1099                 [enable_vcalendar_plugin=$enableval], [enable_vcalendar_plugin=auto])
1100
1101 dnl disabled by default
1102 AC_ARG_ENABLE(demo-plugin,
1103                 [  --enable-demo-plugin         Build demo plugin],
1104                 [enable_demo_plugin=$enableval], [enable_demo_plugin=no])
1105
1106
1107 dnl Then we check (unconditionnaly) for plugins dependencies
1108 dnl Some dependencies are optional, some mandatory. This is taken care of
1109 dnl later.
1110 dnl
1111 dnl During this dependancy check we do the checks themselves, define HAVE_X to
1112 dnl either yes or no, and do the AC_SUBST calls.
1113
1114 dnl Archive:            libarchive
1115 dnl Fancy:              Webkit, curl, optionally libsoup-gnome
1116 dnl Gdata:              libgdata
1117 dnl Libravatar:         libcurl
1118 dnl Notification:       optionally libnotify  unity/messaging-menu
1119 dnl                                libcanberra_gtk hotkey
1120 dnl Pdf-Viewer:         libpoppler
1121 dnl Perl:               sed perl
1122 dnl PGP/Core:           libgpgme
1123 dnl PGP/Mime:           pgpcore libgpgme
1124 dnl PGP/Inline:         pgpcore libgpgme
1125 dnl S/Mime:             pgpcore libgpgme
1126 dnl Python:             Python
1127 dnl RSSyl:              expat libcurl
1128 dnl SpamReport:         libcurl
1129 dnl vCalendar:          libcurl, libical
1130 dnl tnef_parse:         libytnef
1131
1132 dnl libcurl ********************************************************************
1133 PKG_CHECK_MODULES(CURL, libcurl, HAVE_CURL=yes, HAVE_CURL=no)
1134 AC_SUBST(CURL_LIBS)
1135 AC_SUBST(CURL_CFLAGS)
1136
1137 dnl expat **********************************************************************
1138 PKG_CHECK_MODULES(EXPAT, expat, HAVE_EXPAT=yes, HAVE_EXPAT=no)
1139
1140 if test x"$HAVE_EXPAT" = xno; then
1141         AC_CHECK_HEADER(expat.h, [expat_header=yes], [expat_header=no])
1142         AC_CHECK_LIB(expat, XML_ParserCreate, [expat_lib=yes], [expat_lib=no])
1143         if test x"$expat_header" = xyes -a x"$expat_lib"=xyes; then
1144                 HAVE_EXPAT=yes
1145                 EXPAT_CFLAGS=""
1146                 EXPAT_LIBS="-lexpat"
1147         fi
1148 fi
1149
1150 AC_SUBST(EXPAT_CFLAGS)
1151 AC_SUBST(EXPAT_LIBS)
1152
1153 dnl webkit *********************************************************************
1154 PKG_CHECK_MODULES(WEBKIT, webkit-1.0 >= 1.1.14, HAVE_WEBKIT=yes, HAVE_WEBKIT=no)
1155 AC_SUBST(WEBKIT_LIBS)
1156 AC_SUBST(WEBKIT_CFLAGS)
1157
1158 dnl libsoup ********************************************************************
1159 PKG_CHECK_MODULES(LIBSOUP, libsoup-2.4, HAVE_LIBSOUP=yes, HAVE_LIBSOUP=no)
1160 if test x"$HAVE_LIBSOUP" = xyes; then
1161         AC_DEFINE(HAVE_LIBSOUP, 1, [Define if libsoup is available])
1162 fi
1163 AC_SUBST(LIBSOUP_CFLAGS)
1164 AC_SUBST(LIBSOUP_LIBS)
1165
1166 dnl libsoup-gnome **************************************************************
1167 PKG_CHECK_MODULES(LIBSOUP_GNOME, libsoup-gnome-2.4 >= 2.26, HAVE_LIBSOUP_GNOME=yes, HAVE_LIBSOUP_GNOME=no)
1168 if test x"$HAVE_LIBSOUP_GNOME" = xyes; then
1169         AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [Define if libsoup_gnome is available])
1170 fi
1171 AC_SUBST(LIBSOUP_GNOME_CFLAGS)
1172 AC_SUBST(LIBSOUP_GNOME_LIBS)
1173
1174 dnl libarchive *****************************************************************
1175 PKG_CHECK_MODULES(LIBARCHIVE, libarchive, HAVE_ARCHIVE=yes, HAVE_ARCHIVE=no)
1176 AC_SUBST(ARCHIVE_LIBS)
1177 AC_SUBST(ARCHIVE_CFLAGS)
1178 AC_CHECK_LIB([archive], [archive_read_new],
1179                        ARCHIVE_LIBS=-larchive
1180                        HAVE_ARCHIVE=yes
1181                        AC_SUBST(ARCHIVE_LIBS,$ARCHIVE_CFLAGS),
1182                        HAVE_ARCHIVE=no
1183                        )
1184
1185 dnl libgdata *******************************************************************
1186 PKG_CHECK_MODULES(GDATA, libgdata >= 0.17.2, HAVE_GDATA=yes, HAVE_GDATA=no)
1187 AC_SUBST(GDATA_CFLAGS)
1188 AC_SUBST(GDATA_LIBS)
1189
1190 dnl libical ********************************************************************
1191 PKG_CHECK_MODULES(LIBICAL, libical >= 2.0, HAVE_LIBICAL=yes, HAVE_LIBICAL=no)
1192 AC_SUBST(LIBICAL_CFLAGS)
1193 AC_SUBST(LIBICAL_LIBS)
1194
1195 dnl Poppler ********************************************************************
1196 PKG_CHECK_MODULES(POPPLER, poppler-glib >= 0.12.0, HAVE_POPPLER=yes, HAVE_POPPLER=no)
1197 AC_SUBST(POPPLER_LIBS)
1198 AC_SUBST(POPPLER_CFLAGS)
1199
1200 dnl check for Poppler extra features that we conditionally support
1201 if test x"$HAVE_POPPLER" = xyes; then
1202         OLD_CFLAGS=$CFLAGS
1203         CFLAGS="$POPPLER_CFLAGS $GTK_CFLAGS $GLIB_CFLAGS"
1204         AC_CHECK_DECL(POPPLER_DEST_NAMED,
1205                 [AC_DEFINE([HAVE_POPPLER_DEST_NAMED], [], [Description])],
1206                 ,[#include <poppler-action.h>])
1207         AC_CHECK_DECL(POPPLER_DEST_XYZ,
1208                 [AC_DEFINE([HAVE_POPPLER_DEST_XYZ], [], [Description])],
1209                 ,[#include <poppler-action.h>])
1210         CFLAGS=$OLD_CFLAGS
1211 fi
1212
1213 dnl perl ***********************************************************************
1214 AC_CHECK_PROG(HAVE_PERL, perl, yes, no)
1215 if test x"$HAVE_PERL" = xyes; then
1216         AC_MSG_CHECKING(for perl >= 5.8.0)
1217         PERL_VER=`perl -e 'print $] > 5.0079999?"yes":"no"'`
1218         if test "$PERL_VER" = "yes"; then
1219                 AC_MSG_RESULT(yes)
1220         else
1221                 AC_MSG_RESULT(no)
1222                 HAVE_PERL=no
1223         fi
1224 fi
1225 if test x"$HAVE_PERL" = xyes; then
1226         AC_MSG_CHECKING(for Perl compile flags)
1227         PERL_CFLAGS=`perl -MExtUtils::Embed -e ccopts`
1228         PERL_CFLAGS=`echo $PERL_CFLAGS | sed 's/-D_FILE_OFFSET_BITS=[[0-9]]*//'`
1229         PERL_LDFLAGS=`perl -MExtUtils::Embed -e ldopts |sed 's/-lgdbm\>//'`
1230         PERL_LDFLAGS=`echo $PERL_LDFLAGS |sed 's/-ldb\>//'`
1231         PERL_LDFLAGS=`echo $PERL_LDFLAGS |sed 's/-lndbm\>//'`
1232         PERL_LDFLAGS=`echo $PERL_LDFLAGS |sed 's/-lc\>//'`
1233         AC_MSG_RESULT(ok)
1234         AC_MSG_NOTICE([Adding perl LIBS ${PERL_CFLAGS}])
1235         
1236         if test x"$HAVE_PERL" = xyes; then
1237                 AC_CHECK_LIB(perl,perl_alloc,[AC_DEFINE(HAVE_LIBPERL, 1, Check for libperl.)], 
1238                                              [ HAVE_LIBPERL=no ])
1239         fi
1240         if test x"$HAVE_LIBPERL" = xno; then
1241                 LIBPERL_PREFIX=`perl -MExtUtils::Embed -e perl_inc`
1242                 LIBPERL_PREFIX=`echo $LIBPERL_PREFIX |sed 's/-I//'`
1243                 AC_MSG_CHECKING([for libperl.so])
1244                 if test -f "$LIBPERL_PREFIX/libperl.so"; then
1245                         AC_MSG_RESULT(yes)
1246                         HAVE_LIBPERL=yes
1247                 else
1248                         AC_MSG_RESULT(no)
1249                 fi      
1250         fi
1251         PERL="perl"
1252         AC_SUBST(PERL)
1253         AC_SUBST(PERL_CFLAGS)
1254         AC_SUBST(PERL_LDFLAGS)
1255 fi
1256
1257 dnl Gpgme **********************************************************************
1258 AM_PATH_GPGME(1.0.0, HAVE_GPGME=yes, HAVE_GPGME=no)
1259 if test x"$HAVE_GPGME" = xyes; then
1260         AC_DEFINE(USE_GPGME, 1, Define if you use GPGME to support OpenPGP.)
1261         AM_PATH_GPGME(1.1.1, AC_DEFINE(HAVE_GPGME_PKA_TRUST, 1, [Define if GPGME supports PKA.]))
1262 fi
1263
1264 dnl Python *********************************************************************
1265 AM_PATH_PYTHON([2.5], [
1266         AC_PATH_PROG(PYTHON_CONFIG, python$PYTHON_VERSION-config)
1267         if test x"$PYTHON_CONFIG" = x"" ; then
1268                 AC_PATH_PROG(PYTHON_CONFIG, python-config)
1269         fi
1270         if test x"$PYTHON_CONFIG" != x""; then
1271                 PYTHON_CFLAGS=`$PYTHON_CONFIG --includes`
1272                 PYTHON_LIBS=`$PYTHON_CONFIG --libs`
1273                 PYTHON_PREFIX=`$PYTHON_CONFIG --prefix`
1274                 HAVE_PYTHON=yes
1275         else
1276                 AC_MSG_WARN(python-config not found. Maybe you need to install development packages for Python.)
1277                 HAVE_PYTHON=no
1278         fi
1279
1280         if test x"$HAVE_PYTHON" = xyes; then
1281                 _save_libs="$LIBS"
1282                 if test x"$platform_win32" = xno; then
1283                         # libpython.so
1284                         PYTHON_SHARED_LIB="libpython${PYTHON_VERSION}.so"
1285                         AC_CHECK_LIB(dl, dlopen, [LIBS="-ldl"])
1286                         AC_MSG_CHECKING([whether to dlopen $PYTHON_SHARED_LIB works])
1287                         AC_RUN_IFELSE(
1288                                 [AC_LANG_PROGRAM(
1289                                         [#include <dlfcn.h>
1290                                          #define PYTHON_SO_FILE "${PYTHON_SHARED_LIB}"
1291                                         ],
1292                                         [if (!dlopen(PYTHON_SO_FILE, RTLD_NOW | RTLD_GLOBAL)) return 1; return 0;])
1293                                 ],
1294                                 [found_libpython_so="yes"],
1295                                 [found_libpython_so="no"],
1296                                 [AC_MSG_FAILURE([cross-compiling not supported])])
1297                 fi
1298                 if test x"$found_libpython_so" != x"yes"; then
1299                         AC_MSG_RESULT(no)
1300                         AC_MSG_WARN(Could not find Python shared libary: ${PYTHON_SHARED_LIB}. Maybe you need to install development packages for Python.)
1301                         HAVE_PYTHON=no
1302                 else
1303                         AC_MSG_RESULT(yes)
1304                 fi
1305                 LIBS="$_save_libs";
1306         fi
1307         if test x"$HAVE_PYTHON" = xyes; then
1308                 PKG_CHECK_MODULES(PYGTK, pygtk-2.0 >= 2.10.3, [AC_DEFINE(ENABLE_PYTHON, [1], [Enable Python support])], HAVE_PYTHON=no)
1309         fi
1310 ])
1311 AC_SUBST(PYTHON_SHARED_LIB)
1312 AC_SUBST(PYTHON_CFLAGS)
1313 AC_SUBST(PYTHON_LIBS)
1314 AC_SUBST(PYGTK_CFLAGS)
1315 AC_SUBST(PYGTK_LIBS)
1316
1317 dnl libnotify ******************************************************************
1318 PKG_CHECK_MODULES(libnotify, libnotify >= 0.4.3, HAVE_LIBNOTIFY=yes, HAVE_LIBNOTIFY=no)
1319 if test x"$HAVE_LIBNOTIFY" = xyes; then
1320         AC_DEFINE(HAVE_LIBNOTIFY, 1, [Define if libnotify support is enabled])
1321 fi
1322 AC_SUBST(libnotify_CFLAGS)
1323 AC_SUBST(libnotify_LIBS)
1324
1325 dnl libcanberra-gtk ************************************************************
1326 PKG_CHECK_MODULES(libcanberra_gtk, libcanberra-gtk >= 0.6, HAVE_LIBCANBERRA_GTK=yes, HAVE_LIBCANBERRA_GTK=no)
1327 if test x"$HAVE_LIBCANBERRA_GTK" = xyes; then
1328         AC_DEFINE(HAVE_LIBCANBERRA_GTK, 1, [Define if libcanberra-gtk support is enabled])
1329 fi
1330 AC_SUBST(libcanberra_gtk_CFLAGS)
1331 AC_SUBST(libcanberra_gtk_LIBS)
1332
1333 dnl unity/messaging-menu *******************************************************
1334 PKG_CHECK_MODULES(unity, unity messaging-menu, HAVE_UNITY=yes, HAVE_UNITY=no)
1335 if test x"$HAVE_UNITY" = xyes; then
1336         AC_DEFINE(NOTIFICATION_INDICATOR, 1, [Activate support for unity and messaging-menu])
1337 fi
1338 AC_SUBST(unity_CFLAGS)
1339 AC_SUBST(unity_LIBS)
1340
1341 dnl hotkeys ********************************************************************
1342 PKG_CHECK_MODULES(CM_NP_HOTKEY, [gio-2.0 >= 2.15.6 gio-unix-2.0 >= 2.15.6], HAVE_HOTKEYS=yes, HAVE_HOTKEYS=no)
1343 if test x"$HAVE_HOTKEYS" = xyes; then
1344         AC_DEFINE(NOTIFICATION_HOTKEYS, 1, Activate support for global hotkeys)
1345 fi
1346 AC_SUBST(CM_NP_HOTKEY_CFLAGS)
1347 AC_SUBST(CM_NP_HOTKEY_LIBS)
1348
1349 dnl libytnef *******************************************************************
1350 YTNEF_CFLAGS=""
1351 YTNEF_LIBS=""
1352 have_ytnef=0
1353 # Check both ytnef.h and libytnef/ytnef.h, and adjust YTNEF_CFLAGS
1354 # accordingly
1355 AC_CHECK_HEADER(ytnef.h, [have_ytnef=1], [have_ytnef=0])
1356 if test $have_ytnef -eq 0; then
1357         AC_CHECK_HEADER(libytnef/ytnef.h,
1358                                                                         [have_ytnef=1;
1359                                                                          YTNEF_CFLAGS="${YTNEF_CFLAGS} -DYTNEF_H_SUBDIR"],
1360                                                                         [have_ytnef=0])
1361 fi
1362 if test $have_ytnef -eq 1; then
1363         AC_MSG_CHECKING([how libytnef's SwapDDWord() should be called])
1364         # Now we have to figure out which libytnef version we're using,
1365         # based on whether SwapDDWord takes one argument or two.
1366         if test "x${YTNEF_CFLAGS}" = "x"; then
1367                 ytnef_include="#include <ytnef.h>"
1368         else
1369                 ytnef_include="#include <libytnef/ytnef.h>"
1370         fi
1371         AC_TRY_COMPILE([#include <stdio.h>
1372                                                                         ${ytnef_include}],
1373                                                                         [SwapDDWord(0, 0);],
1374                                                                         [have_ytnef=1],
1375                                                                         [have_ytnef=0])
1376         if test $have_ytnef -eq 0; then
1377                 AC_TRY_COMPILE([#include <stdio.h>
1378                                                                                 ${ytnef_include}],
1379                                                                                 [SwapDDWord(0);],
1380                                                                                 [have_ytnef=1;
1381                                                                                  YTNEF_CFLAGS="${YTNEF_CFLAGS} -DYTNEF_OLD_SWAPDDWORD"],
1382                                                                                 [have_ytnef=0])
1383         fi
1384         if test $have_ytnef -eq 1; then
1385                 YTNEF_LIBS="-lytnef"
1386                 AC_MSG_RESULT(ok)
1387         else
1388                 AC_MSG_RESULT(no idea, unsupported libytnef version?)
1389         fi
1390 fi
1391 AC_SUBST(YTNEF_CFLAGS)
1392 AC_SUBST(YTNEF_LIBS)
1393
1394 dnl Third, we now cross the requested plugins and the available dependencies
1395 dnl If some dependencies are missing and the plugin was explicitely enabled,
1396 dnl we error out, else we only inform.
1397
1398 AC_MSG_CHECKING([whether to build acpi_notifier plugin])
1399 if test x"$enable_acpi_notifier_plugin" != xno; then
1400         PLUGINS="$PLUGINS acpi_notifier"
1401         AC_MSG_RESULT(yes)
1402 else
1403         DISABLED_PLUGINS="$DISABLED_PLUGINS acpi_notifier"
1404         AC_MSG_RESULT(no)
1405 fi
1406
1407 AC_MSG_CHECKING([whether to build address_keeper plugin])
1408 if test x"$enable_address_keeper_plugin" != xno; then
1409         PLUGINS="$PLUGINS address_keeper"
1410         AC_MSG_RESULT(yes)
1411 else
1412         DISABLED_PLUGINS="$DISABLED_PLUGINS address_keeper"
1413         AC_MSG_RESULT(no)
1414 fi
1415
1416 AC_MSG_CHECKING([whether to build archive plugin])
1417 if test x"$enable_archive_plugin" != xno; then
1418         dependencies_missing=""
1419
1420         if test x"$HAVE_ARCHIVE" = xno; then
1421                 dependencies_missing="libarchive $dependencies_missing"
1422         fi
1423
1424         if test x"$dependencies_missing" = x; then
1425                 PLUGINS="$PLUGINS archive"
1426                 AC_MSG_RESULT(yes)
1427         elif test x"$enable_archive_plugin" = xauto; then
1428                 AC_MSG_RESULT(no)
1429                 AC_MSG_WARN("Plugin archive will not be built; missing $dependencies_missing")
1430                 enable_archive_plugin=no
1431                 MISSING_DEPS_PLUGINS="$MISSING_DEPS_PLUGINS archive"
1432         else
1433                 AC_MSG_RESULT(no)
1434                 AC_MSG_ERROR("Plugin archive cannot be built; missing $dependencies_missing")
1435         fi
1436 else
1437         DISABLED_PLUGINS="$DISABLED_PLUGINS archive"
1438         AC_MSG_RESULT(no)
1439 fi
1440
1441 AC_MSG_CHECKING([whether to build att_remover plugin])
1442 if test x"$enable_att_remover_plugin" != xno; then
1443         PLUGINS="$PLUGINS att_remover"
1444         AC_MSG_RESULT(yes)
1445 else
1446         DISABLED_PLUGINS="$DISABLED_PLUGINS att_remover"
1447         AC_MSG_RESULT(no)
1448 fi
1449
1450 AC_MSG_CHECKING([whether to build attachwarner plugin])
1451 if test x"$enable_attachwarner_plugin" != xno; then
1452         PLUGINS="$PLUGINS attachwarner"
1453         AC_MSG_RESULT(yes)
1454 else
1455         DISABLED_PLUGINS="$DISABLED_PLUGINS attachwarner"
1456         AC_MSG_RESULT(no)
1457 fi
1458
1459 AC_MSG_CHECKING([whether to build bogofilter plugin])
1460 if test x"$enable_bogofilter_plugin" != xno; then
1461         PLUGINS="$PLUGINS bogofilter"
1462         AC_MSG_RESULT(yes)
1463 else
1464         DISABLED_PLUGINS="$DISABLED_PLUGINS bogofilter"
1465         AC_MSG_RESULT(no)
1466 fi
1467
1468 AC_MSG_CHECKING([whether to build bsfilter plugin])
1469 if test x"$enable_bsfilter_plugin" != xno; then
1470         PLUGINS="$PLUGINS bsfilter"
1471         AC_MSG_RESULT(yes)
1472 else
1473         DISABLED_PLUGINS="$DISABLED_PLUGINS bsfilter"
1474         AC_MSG_RESULT(no)
1475 fi
1476
1477 AC_MSG_CHECKING([whether to build clamd plugin])
1478 if test x"$enable_clamd_plugin" != xno; then
1479         PLUGINS="$PLUGINS clamd"
1480         AC_MSG_RESULT(yes)
1481 else
1482         DISABLED_PLUGINS="$DISABLED_PLUGINS clamd"
1483         AC_MSG_RESULT(no)
1484 fi
1485
1486 AC_MSG_CHECKING([whether to build demo plugin])
1487 if test x"$enable_demo_plugin" != xno; then
1488         PLUGINS="$PLUGINS demo"
1489         AC_MSG_RESULT(yes)
1490 else
1491         DISABLED_PLUGINS="$DISABLED_PLUGINS demo"
1492         AC_MSG_RESULT(no)
1493 fi
1494
1495 AC_MSG_CHECKING([whether to build Dillo plugin])
1496 if test x"$enable_dillo_plugin" != xno; then
1497         PLUGINS="$PLUGINS dillo"
1498         AC_MSG_RESULT(yes)
1499 else
1500         DISABLED_PLUGINS="$DISABLED_PLUGINS dillo"
1501         AC_MSG_RESULT(no)
1502 fi
1503
1504 AC_MSG_CHECKING([whether to build fancy plugin])
1505 if test x"$enable_fancy_plugin" != xno; then
1506         dependencies_missing=""
1507
1508         if test x"$HAVE_WEBKIT" = xno; then
1509                 dependencies_missing="libwebkit-1.0 $dependencies_missing"
1510         fi
1511         if test x"$HAVE_CURL" = xno; then
1512                 dependencies_missing="libcurl $dependencies_missing"
1513         fi
1514
1515         if test x"$dependencies_missing" = x; then
1516                 PLUGINS="$PLUGINS fancy"
1517                 AC_MSG_RESULT(yes)
1518         elif test x"$enable_fancy_plugin" = xauto; then
1519                 AC_MSG_RESULT(no)
1520                 AC_MSG_WARN("Plugin fancy will not be built; missing $dependencies_missing")
1521                 enable_fancy_plugin=no
1522                 MISSING_DEPS_PLUGINS="$MISSING_DEPS_PLUGINS fancy"
1523         else
1524                 AC_MSG_RESULT(no)
1525                 AC_MSG_ERROR("Plugin fancy cannot be built; missing $dependencies_missing")
1526         fi
1527 else
1528         DISABLED_PLUGINS="$DISABLED_PLUGINS fancy"
1529         AC_MSG_RESULT(no)
1530 fi
1531
1532 AC_MSG_CHECKING([whether to build fetchinfo plugin])
1533 if test x"$enable_fetchinfo_plugin" != xno; then
1534         PLUGINS="$PLUGINS fetchinfo"
1535         AC_MSG_RESULT(yes)
1536 else
1537         DISABLED_PLUGINS="$DISABLED_PLUGINS fetchinfo"
1538         AC_MSG_RESULT(no)
1539 fi
1540
1541 AC_MSG_CHECKING([whether to build gdata plugin])
1542 if test x"$enable_gdata_plugin" != xno; then
1543         dependencies_missing=""
1544
1545         if test x"$HAVE_GDATA" = xno; then
1546                 dependencies_missing="libgdata $dependencies_missing"
1547         fi
1548
1549         if test x"$dependencies_missing" = x; then
1550                 PLUGINS="$PLUGINS gdata"
1551                 AC_MSG_RESULT(yes)
1552         elif test x"$enable_gdata_plugin" = xauto; then
1553                 AC_MSG_RESULT(no)
1554                 AC_MSG_WARN("Plugin gdata will not be built; missing $dependencies_missing")
1555                 enable_gdata_plugin=no
1556                 MISSING_DEPS_PLUGINS="$MISSING_DEPS_PLUGINS gdata"
1557         else
1558                 AC_MSG_RESULT(no)
1559                 AC_MSG_ERROR("Plugin gdata cannot be built; missing $dependencies_missing")
1560         fi
1561 else
1562         DISABLED_PLUGINS="$DISABLED_PLUGINS gdata"
1563         AC_MSG_RESULT(no)
1564 fi
1565
1566 AC_MSG_CHECKING([whether to build libravatar plugin])
1567 if test x"$enable_libravatar_plugin" != xno; then
1568         dependencies_missing=""
1569
1570         if test x"$HAVE_CURL" = xno; then
1571                 dependencies_missing="libcurl $dependencies_missing"
1572         fi
1573
1574         if test x"$dependencies_missing" = x; then
1575                 PLUGINS="$PLUGINS libravatar"
1576                 AC_MSG_RESULT(yes)
1577         elif test x"$enable_libravatar_plugin" = xauto; then
1578                 AC_MSG_RESULT(no)
1579                 AC_MSG_WARN("Plugin libravatar will not be built; missing $dependencies_missing")
1580                 enable_libravatar_plugin=no
1581                 MISSING_DEPS_PLUGINS="$MISSING_DEPS_PLUGINS libravatar"
1582         else
1583                 AC_MSG_RESULT(no)
1584                 AC_MSG_ERROR("Plugin libravatar cannot be built; missing $dependencies_missing")
1585         fi
1586 else
1587         DISABLED_PLUGINS="$DISABLED_PLUGINS libravatar"
1588         AC_MSG_RESULT(no)
1589 fi
1590
1591 AC_MSG_CHECKING([whether to build mailmbox plugin])
1592 if test x"$enable_mailmbox_plugin" != xno; then
1593         PLUGINS="$PLUGINS mailmbox"
1594         AC_MSG_RESULT(yes)
1595 else
1596         DISABLED_PLUGINS="$DISABLED_PLUGINS mailmbox"
1597         AC_MSG_RESULT(no)
1598 fi
1599
1600 AC_MSG_CHECKING([whether to build managesieve plugin])
1601 if test x"$enable_managesieve_plugin" != xno; then
1602         PLUGINS="$PLUGINS managesieve"
1603         AC_MSG_RESULT(yes)
1604 else
1605         DISABLED_PLUGINS="$DISABLED_PLUGINS managesieve"
1606         AC_MSG_RESULT(no)
1607 fi
1608
1609 AC_MSG_CHECKING([whether to build newmail plugin])
1610 if test x"$enable_newmail_plugin" != xno; then
1611         PLUGINS="$PLUGINS newmail"
1612         AC_MSG_RESULT(yes)
1613 else
1614         DISABLED_PLUGINS="$DISABLED_PLUGINS newmail"
1615         AC_MSG_RESULT(no)
1616 fi
1617
1618 AC_MSG_CHECKING([whether to build notification plugin])
1619 if test x"$enable_notification_plugin" != xno; then
1620         PLUGINS="$PLUGINS notification"
1621         AC_MSG_RESULT(yes)
1622
1623         AC_DEFINE(NOTIFICATION_POPUP, 1, Activate notification popup)
1624         AC_DEFINE(NOTIFICATION_BANNER, 1, Activate notification banner)
1625         AC_DEFINE(NOTIFICATION_COMMAND, 1, Activate notification shell command)
1626         AC_DEFINE(NOTIFICATION_TRAYICON, 1, Activate notification trayicon)
1627         if test x"$platform_win32" = xno; then
1628                 AC_DEFINE(NOTIFICATION_LCDPROC, 1, Activate lcdproc support)
1629         fi
1630
1631         notification_features="banner command"
1632         notification_missing_dependencies=""
1633         if test x"$HAVE_HOTKEYS" = xyes; then
1634                 notification_features="$notification_features hotkeys"
1635         else
1636                 notification_missing_dependencies="$notification_missing_dependencies hotkeys"
1637         fi
1638         notification_features="$notification_features lcdproc"
1639         if test x"$HAVE_UNITY" = xyes; then
1640                 notification_features="$notification_features unity/messaging-menu"
1641         else
1642                 notification_missing_dependencies="$notification_missing_dependencies unity/messaging-menu"
1643         fi
1644         if test x"$HAVE_LIBNOTIFY" = xyes; then
1645                 notification_features="$notification_features libnotify"
1646         else
1647                 notification_missing_dependencies="$notification_missing_dependencies libnotify"
1648         fi
1649         if test x"$HAVE_LIBCANBERRA_GTK" = xyes; then
1650                 notification_features="$notification_features libcanberra-gtk"
1651         else
1652                 notification_missing_dependencies="$notification_missing_dependencies libcanberra-gtk"
1653         fi
1654         notification_features="$notification_features popup trayicon"
1655 else
1656         DISABLED_PLUGINS="$DISABLED_PLUGINS notification"
1657         AC_MSG_RESULT(no)
1658 fi
1659
1660 AC_MSG_CHECKING([whether to build pdf_viewer plugin])
1661 if test x"$enable_pdf_viewer_plugin" != xno; then
1662         dependencies_missing=""
1663
1664         if test x"$HAVE_POPPLER" = xno; then
1665                 dependencies_missing="libpoppler-glib $dependencies_missing"
1666         fi
1667
1668         if test x"$dependencies_missing" = x; then
1669                 PLUGINS="$PLUGINS pdf_viewer"
1670                 AC_MSG_RESULT(yes)
1671         elif test x"$enable_pdf_viewer_plugin" = xauto; then
1672                 AC_MSG_RESULT(no)
1673                 AC_MSG_WARN("Plugin pdf_viewer will not be built; missing $dependencies_missing")
1674                 enable_pdf_viewer_plugin=no
1675                 MISSING_DEPS_PLUGINS="$MISSING_DEPS_PLUGINS pdf_viewer"
1676         else
1677                 AC_MSG_RESULT(no)
1678                 AC_MSG_ERROR("Plugin pdf_viewer cannot be built; missing $dependencies_missing")
1679         fi
1680 else
1681         DISABLED_PLUGINS="$DISABLED_PLUGINS pdf_viewer"
1682         AC_MSG_RESULT(no)
1683 fi
1684
1685 AC_MSG_CHECKING([whether to build perl plugin])
1686 if test x"$enable_perl_plugin" != xno; then
1687         dependencies_missing=""
1688
1689         if test x"$HAVE_LIBPERL" = xno; then
1690                 dependencies_missing="libperl $dependencies_missing"
1691         fi
1692
1693         if test x"$dependencies_missing" = x; then
1694                 PLUGINS="$PLUGINS perl"
1695                 AC_MSG_RESULT(yes)
1696         elif test x"$enable_perl_plugin" = xauto; then
1697                 AC_MSG_RESULT(no)
1698                 AC_MSG_WARN("Plugin perl will not be built; missing $dependencies_missing")
1699                 enable_perl_plugin=no
1700                 MISSING_DEPS_PLUGINS="$MISSING_DEPS_PLUGINS perl"
1701         else
1702                 AC_MSG_RESULT(no)
1703                 AC_MSG_ERROR("Plugin perl cannot be built; missing $dependencies_missing")
1704         fi
1705 else
1706         DISABLED_PLUGINS="$DISABLED_PLUGINS perl"
1707         AC_MSG_RESULT(no)
1708 fi
1709
1710 AC_MSG_CHECKING([whether to build python plugin])
1711 if test x"$enable_python_plugin" != xno; then
1712         dependencies_missing=""
1713
1714         if test x"$HAVE_PYTHON" = xno; then
1715                 dependencies_missing="python $dependencies_missing"
1716         fi
1717
1718         if test x"$dependencies_missing" = x; then
1719                 PLUGINS="$PLUGINS python"
1720                 AC_MSG_RESULT(yes)
1721         elif test x"$enable_python_plugin" = xauto; then
1722                 AC_MSG_RESULT(no)
1723                 AC_MSG_WARN("Plugin python will not be built; missing $dependencies_missing")
1724                 enable_python_plugin=no
1725                 MISSING_DEPS_PLUGINS="$MISSING_DEPS_PLUGINS python"
1726         else
1727                 AC_MSG_RESULT(no)
1728                 AC_MSG_ERROR("Plugin python cannot be built; missing $dependencies_missing")
1729         fi
1730 else
1731         DISABLED_PLUGINS="$DISABLED_PLUGINS python"
1732         AC_MSG_RESULT(no)
1733 fi
1734
1735 AC_MSG_CHECKING([whether to build pgpcore plugin])
1736 if test x"$enable_pgpcore_plugin" != xno; then
1737         dependencies_missing=""
1738
1739         if test x"$HAVE_GPGME" = xno; then
1740                 dependencies_missing="libgpgme $dependencies_missing"
1741         fi
1742
1743         if test x"$dependencies_missing" = x; then
1744                 PLUGINS="$PLUGINS pgpcore"
1745                 AC_MSG_RESULT(yes)
1746         elif test x"$enable_pgpcore_plugin" = xauto; then
1747                 AC_MSG_RESULT(no)
1748                 AC_MSG_WARN("Plugin pgpcore will not be built; missing $dependencies_missing")
1749                 enable_pgpcore_plugin=no
1750                 MISSING_DEPS_PLUGINS="$MISSING_DEPS_PLUGINS pgpcore"
1751         else
1752                 AC_MSG_RESULT(no)
1753                 AC_MSG_ERROR("Plugin pgpcore cannot be built; missing $dependencies_missing")
1754         fi
1755 else
1756         DISABLED_PLUGINS="$DISABLED_PLUGINS pgpcore"
1757         AC_MSG_RESULT(no)
1758 fi
1759
1760 AC_MSG_CHECKING([whether to build pgpmime plugin])
1761 if test x"$enable_pgpmime_plugin" != xno; then
1762         dependencies_missing=""
1763
1764         if test x"$HAVE_GPGME" = xno; then
1765                 dependencies_missing="libgpgme $dependencies_missing"
1766         fi
1767         if test x"$enable_pgpcore_plugin" = xno; then
1768                 dependencies_missing="pgpcore plugin $dependencies_missing"
1769         fi
1770
1771         if test x"$dependencies_missing" = x; then
1772                 PLUGINS="$PLUGINS pgpmime"
1773                 AC_MSG_RESULT(yes)
1774         elif test x"$enable_pgpmime_plugin" = xauto; then
1775                 AC_MSG_RESULT(no)
1776                 AC_MSG_WARN("Plugin pgpmime will not be built; missing $dependencies_missing")
1777                 enable_pgpmime_plugin=no
1778                 MISSING_DEPS_PLUGINS="$MISSING_DEPS_PLUGINS pgpmime"
1779         else
1780                 AC_MSG_RESULT(no)
1781                 AC_MSG_ERROR("Plugin pgpmime cannot be built; missing $dependencies_missing")
1782         fi
1783 else
1784         DISABLED_PLUGINS="$DISABLED_PLUGINS pgpmime"
1785         AC_MSG_RESULT(no)
1786 fi
1787
1788 AC_MSG_CHECKING([whether to build pgpinline plugin])
1789 if test x"$enable_pgpinline_plugin" != xno; then
1790         dependencies_missing=""
1791
1792         if test x"$HAVE_GPGME" = xno; then
1793                 dependencies_missing="libgpgme $dependencies_missing"
1794         fi
1795         if test x"$enable_pgpcore_plugin" = xno; then
1796                 dependencies_missing="pgpcore plugin $dependencies_missing"
1797         fi
1798
1799         if test x"$dependencies_missing" = x; then
1800                 PLUGINS="$PLUGINS pgpinline"
1801                 AC_MSG_RESULT(yes)
1802         elif test x"$enable_pgpinline_plugin" = xauto; then
1803                 AC_MSG_RESULT(no)
1804                 AC_MSG_WARN("Plugin pgpinline will not be built; missing $dependencies_missing")
1805                 enable_pgpinline_plugin=no
1806                 MISSING_DEPS_PLUGINS="$MISSING_DEPS_PLUGINS pgpinline"
1807         else
1808                 AC_MSG_RESULT(no)
1809                 AC_MSG_ERROR("Plugin pgpinline cannot be built; missing $dependencies_missing")
1810         fi
1811 else
1812         DISABLED_PLUGINS="$DISABLED_PLUGINS pgpinline"
1813         AC_MSG_RESULT(no)
1814 fi
1815
1816 AC_MSG_CHECKING([whether to build rssyl plugin])
1817 if test x"$enable_rssyl_plugin" != xno; then
1818         dependencies_missing=""
1819
1820         if test x"$HAVE_EXPAT" = xno; then
1821                 dependencies_missing="expat $dependencies_missing"
1822         fi
1823         if test x"$HAVE_CURL" = xno; then
1824                 dependencies_missing="libcurl $dependencies_missing"
1825         fi
1826
1827         if test x"$dependencies_missing" = x; then
1828                 PLUGINS="$PLUGINS rssyl"
1829                 AC_MSG_RESULT(yes)
1830         elif test x"$enable_rssyl_plugin" = xauto; then
1831                 AC_MSG_RESULT(no)
1832                 AC_MSG_WARN("Plugin rssyl will not be built; missing $dependencies_missing")
1833                 enable_rssyl_plugin=no
1834                 MISSING_DEPS_PLUGINS="$MISSING_DEPS_PLUGINS rssyl"
1835         else
1836                 AC_MSG_RESULT(no)
1837                 AC_MSG_ERROR("Plugin rssyl cannot be built; missing $dependencies_missing")
1838         fi
1839 else
1840         DISABLED_PLUGINS="$DISABLED_PLUGINS rssyl"
1841         AC_MSG_RESULT(no)
1842 fi
1843
1844 AC_MSG_CHECKING([whether to build spamassassin plugin])
1845 if test x"$enable_spamassassin_plugin" != xno; then
1846         PLUGINS="$PLUGINS spamassassin"
1847         AC_MSG_RESULT(yes)
1848         AC_SPAMASSASSIN
1849
1850         dnl check for zlib (optional)
1851         spamassassin_zlib=0
1852         SPAMASSASSIN_CFLAGS=""
1853         SPAMASSASSIN_LIBS=""
1854         AC_CHECK_HEADER([zlib.h],
1855                         [AC_DEFINE(HAVE_ZLIB_H,1,[optional zlib support for spamassassin plugin])]
1856                         [spamassassin_zlib=1],
1857                         [spamassassin_zlib=0])
1858         if test $spamassassin_zlib -eq 1; then
1859                 AC_CHECK_LIB(z, deflate, [spamassassin_zlib=1], [spamassassin_zlib=0])
1860                 AC_MSG_CHECKING([whether to build spamassassin plugin with zlib support])
1861                 if test $spamassassin_zlib -eq 1; then
1862                         AC_MSG_RESULT(yes)
1863                         SPAMASSASSIN_CFLAGS="-DHAVE_LIBZ"
1864                         SPAMASSASSIN_LIBS="-lz"
1865                 else
1866                         AC_MSG_RESULT(no)
1867                 fi
1868         fi
1869         AC_SUBST(SPAMASSASSIN_CFLAGS)
1870         AC_SUBST(SPAMASSASSIN_LIBS)
1871 else
1872         DISABLED_PLUGINS="$DISABLED_PLUGINS spamassassin"
1873         AC_MSG_RESULT(no)
1874 fi
1875
1876 AC_MSG_CHECKING([whether to build smime plugin])
1877 if test x"$enable_smime_plugin" != xno; then
1878         dependencies_missing=""
1879
1880         if test x"$HAVE_GPGME" = xno; then
1881                 dependencies_missing="libgpgme $dependencies_missing"
1882         fi
1883         if test x"$enable_pgpcore_plugin" = xno; then
1884                 dependencies_missing="pgpcore plugin $dependencies_missing"
1885         fi
1886
1887         if test x"$dependencies_missing" = x; then
1888                 PLUGINS="$PLUGINS smime"
1889                 AC_MSG_RESULT(yes)
1890         elif test x"$enable_smime_plugin" = xauto; then
1891                 AC_MSG_RESULT(no)
1892                 AC_MSG_WARN("Plugin smime will not be built; missing $dependencies_missing")
1893                 enable_smime_plugin=no
1894                 MISSING_DEPS_PLUGINS="$MISSING_DEPS_PLUGINS smime"
1895         else
1896                 AC_MSG_RESULT(no)
1897                 AC_MSG_ERROR("Plugin smime cannot be built; missing $dependencies_missing")
1898         fi
1899 else
1900         DISABLED_PLUGINS="$DISABLED_PLUGINS smime"
1901         AC_MSG_RESULT(no)
1902 fi
1903
1904 AC_MSG_CHECKING([whether to build spam_report plugin])
1905 if test x"$enable_spam_report_plugin" != xno; then
1906         dependencies_missing=""
1907
1908         if test x"$HAVE_CURL" = xno; then
1909                 dependencies_missing="libcurl $dependencies_missing"
1910         fi
1911
1912         if test x"$dependencies_missing" = x; then
1913                 PLUGINS="$PLUGINS spam_report"
1914                 AC_MSG_RESULT(yes)
1915         elif test x"$enable_spam_report_plugin" = xauto; then
1916                 AC_MSG_RESULT(no)
1917                 AC_MSG_WARN("Plugin spam_report will not be built; missing $dependencies_missing")
1918                 enable_spam_report_plugin=no
1919                 MISSING_DEPS_PLUGINS="$MISSING_DEPS_PLUGINS spam_report"
1920         else
1921                 AC_MSG_RESULT(no)
1922                 AC_MSG_ERROR("Plugin spam_report cannot be built; missing $dependencies_missing")
1923         fi
1924 else
1925         DISABLED_PLUGINS="$DISABLED_PLUGINS spam_report"
1926         AC_MSG_RESULT(no)
1927 fi
1928
1929 AC_MSG_CHECKING([whether to build tnef_parse plugin])
1930 if test x"$enable_tnef_parse_plugin" != xno; then
1931         dependencies_missing=""
1932
1933         if test $have_ytnef -eq 0; then
1934                 dependencies_missing="libytnef"
1935         fi
1936
1937         if test x"$dependencies_missing" = x; then
1938                 PLUGINS="$PLUGINS tnef_parse"
1939                 AC_MSG_RESULT(yes)
1940         elif test x"$enable_tnef_parse_plugin" = xauto; then
1941                 AC_MSG_RESULT(no)
1942                 AC_MSG_WARN(Plugin tnef_parse will not be built; missing $dependencies_missing")
1943                 enable_tnef_parse_plugin=no
1944                 MISSING_DEPS_PLUGINS="$MISSING_DEPS_PLUGINS tnef_parse"
1945         else
1946                 AC_MSG_RESULT(no)
1947                 AC_MSG_ERROR(Plugin tnef_parse will not be built; missing $dependencies_missing")
1948         fi
1949 else
1950         DISABLED_PLUGINS="$DISABLED_PLUGINS tnef_parse"
1951         AC_MSG_RESULT(no)
1952 fi
1953
1954
1955 AC_MSG_CHECKING([whether to build vcalendar plugin])
1956 if test x"$enable_vcalendar_plugin" != xno; then
1957         dependencies_missing=""
1958
1959         if test x"$HAVE_CURL" = xno; then
1960                 dependencies_missing="libcurl $dependencies_missing"
1961         fi
1962
1963   if test x"$HAVE_LIBICAL" = xno; then
1964     dependencies_missing="libical $dependencies_missing"
1965   fi
1966
1967         if test x"$HAVE_PERL" = xno; then
1968                 dependencies_missing="perl $dependencies_missing"
1969         fi
1970
1971         if test x"$dependencies_missing" = x; then
1972                 PLUGINS="$PLUGINS vcalendar"
1973                 AC_MSG_RESULT(yes)
1974         elif test x"$enable_vcalendar_plugin" = xauto; then
1975                 AC_MSG_RESULT(no)
1976                 AC_MSG_WARN("Plugin vcalendar will not be built; missing $dependencies_missing")
1977                 enable_vcalendar_plugin=no
1978                 MISSING_DEPS_PLUGINS="$MISSING_DEPS_PLUGINS vcalendar"
1979         else
1980                 AC_MSG_RESULT(no)
1981                 AC_MSG_ERROR("Plugin vcalendar cannot be built; missing $dependencies_missing")
1982         fi
1983 else
1984         DISABLED_PLUGINS="$DISABLED_PLUGINS vcalendar"
1985         AC_MSG_RESULT(no)
1986 fi
1987
1988 dnl And finally the automake conditionals.
1989
1990 AM_CONDITIONAL(BUILD_ACPI_NOTIFIER_PLUGIN,      test x"$enable_acpi_notifier_plugin" != xno)
1991 AM_CONDITIONAL(BUILD_ADDRESS_KEEPER_PLUGIN,     test x"$enable_address_keeper_plugin" != xno)
1992 AM_CONDITIONAL(BUILD_ARCHIVE_PLUGIN,            test x"$enable_archive_plugin" != xno)
1993 AM_CONDITIONAL(BUILD_ATT_REMOVER_PLUGIN,        test x"$enable_att_remover_plugin" != xno)
1994 AM_CONDITIONAL(BUILD_ATTACHWARNER_PLUGIN,       test x"$enable_attachwarner_plugin" != xno)
1995 AM_CONDITIONAL(BUILD_BOGOFILTER_PLUGIN,         test x"$enable_bogofilter_plugin" != xno)
1996 AM_CONDITIONAL(BUILD_BSFILTER_PLUGIN,           test x"$enable_bsfilter_plugin" != xno)
1997 AM_CONDITIONAL(BUILD_CLAMD_PLUGIN,              test x"$enable_clamd_plugin" != xno)
1998 AM_CONDITIONAL(BUILD_DEMO_PLUGIN,               test x"$enable_demo_plugin" != xno)
1999 AM_CONDITIONAL(BUILD_DILLO_PLUGIN,              test x"$enable_dillo_plugin" != xno)
2000 AM_CONDITIONAL(BUILD_FANCY_PLUGIN,              test x"$enable_fancy_plugin" != xno)
2001 AM_CONDITIONAL(BUILD_FETCHINFO_PLUGIN,          test x"$enable_fetchinfo_plugin" != xno)
2002 AM_CONDITIONAL(BUILD_GDATA_PLUGIN,              test x"$enable_gdata_plugin" != xno)
2003 AM_CONDITIONAL(BUILD_LIBRAVATAR_PLUGIN,         test x"$enable_libravatar_plugin" != xno)
2004 AM_CONDITIONAL(BUILD_MAILMBOX_PLUGIN,           test x"$enable_mailmbox_plugin" != xno)
2005 AM_CONDITIONAL(BUILD_MANAGESIEVE_PLUGIN,                test x"$enable_managesieve_plugin" != xno)
2006 AM_CONDITIONAL(BUILD_NEWMAIL_PLUGIN,            test x"$enable_newmail_plugin" != xno)
2007 AM_CONDITIONAL(BUILD_NOTIFICATION_PLUGIN,       test x"$enable_notification_plugin" != xno)
2008 AM_CONDITIONAL(BUILD_HOTKEYS,                   test x"$enable_notification_plugin" != xno -a x"$HAVE_HOTKEYS" = xyes)
2009 AM_CONDITIONAL(BUILD_PDF_VIEWER_PLUGIN,         test x"$enable_pdf_viewer_plugin" != xno)
2010 AM_CONDITIONAL(BUILD_PERL_PLUGIN,               test x"$enable_perl_plugin" != xno)
2011 AM_CONDITIONAL(BUILD_PYTHON_PLUGIN,             test x"$enable_python_plugin" != xno)
2012 AM_CONDITIONAL(BUILD_PGPCORE_PLUGIN,            test x"$enable_pgpcore_plugin" != xno)
2013 AM_CONDITIONAL(BUILD_PGPMIME_PLUGIN,            test x"$enable_pgpmime_plugin" != xno)
2014 AM_CONDITIONAL(BUILD_PGPINLINE_PLUGIN,          test x"$enable_pgpinline_plugin" != xno)
2015 AM_CONDITIONAL(BUILD_RSSYL_PLUGIN,              test x"$enable_rssyl_plugin" != xno)
2016 AM_CONDITIONAL(BUILD_SMIME_PLUGIN,              test x"$enable_smime_plugin" != xno)
2017 AM_CONDITIONAL(BUILD_SPAMASSASSIN_PLUGIN,       test x"$enable_spamassassin_plugin" != xno)
2018 AM_CONDITIONAL(BUILD_SPAM_REPORT_PLUGIN,        test x"$enable_spam_report_plugin" != xno)
2019 AM_CONDITIONAL(BUILD_TNEF_PARSE_PLUGIN,         test x"$enable_tnef_parse_plugin" != xno)
2020 AM_CONDITIONAL(BUILD_VCALENDAR_PLUGIN,          test x"$enable_vcalendar_plugin" != xno)
2021
2022
2023 dnl ****************************
2024 dnl ** Final configure output **
2025 dnl ****************************
2026
2027 AC_OUTPUT([
2028 Makefile
2029 m4/Makefile
2030 po/Makefile.in
2031 src/common/version.h
2032 src/Makefile
2033 src/common/Makefile
2034 src/common/passcrypt.h
2035 src/gtk/Makefile
2036 src/etpan/Makefile
2037 src/plugins/Makefile
2038 src/plugins/acpi_notifier/Makefile
2039 src/plugins/address_keeper/Makefile
2040 src/plugins/archive/Makefile
2041 src/plugins/att_remover/Makefile
2042 src/plugins/attachwarner/Makefile
2043 src/plugins/bogofilter/Makefile
2044 src/plugins/bsfilter/Makefile
2045 src/plugins/clamd/Makefile
2046 src/plugins/clamd/libclamd/Makefile
2047 src/plugins/demo/Makefile
2048 src/plugins/dillo/Makefile
2049 src/plugins/fancy/Makefile
2050 src/plugins/fetchinfo/Makefile
2051 src/plugins/gdata/Makefile
2052 src/plugins/libravatar/Makefile
2053 src/plugins/mailmbox/Makefile
2054 src/plugins/managesieve/Makefile
2055 src/plugins/newmail/Makefile
2056 src/plugins/notification/Makefile
2057 src/plugins/notification/gtkhotkey/Makefile
2058 src/plugins/pdf_viewer/Makefile
2059 src/plugins/perl/Makefile
2060 src/plugins/perl/tools/Makefile
2061 src/plugins/python/Makefile
2062 src/plugins/python/examples/Makefile
2063 src/plugins/pgpcore/Makefile
2064 src/plugins/pgpmime/Makefile
2065 src/plugins/pgpinline/Makefile
2066 src/plugins/rssyl/Makefile
2067 src/plugins/rssyl/libfeed/Makefile
2068 src/plugins/smime/Makefile
2069 src/plugins/spamassassin/Makefile
2070 src/plugins/spam_report/Makefile
2071 src/plugins/tnef_parse/Makefile
2072 src/plugins/vcalendar/Makefile
2073 doc/Makefile
2074 doc/man/Makefile
2075 tools/Makefile
2076 config/Makefile
2077 manual/Makefile
2078 manual/dtd/Makefile
2079 manual/dist/Makefile
2080 manual/dist/pdf/Makefile
2081 manual/dist/ps/Makefile
2082 manual/dist/html/Makefile
2083 manual/dist/txt/Makefile
2084 manual/fr/Makefile
2085 manual/fr/dist/Makefile
2086 manual/fr/dist/pdf/Makefile
2087 manual/fr/dist/ps/Makefile
2088 manual/fr/dist/html/Makefile
2089 manual/fr/dist/txt/Makefile
2090 manual/es/Makefile
2091 manual/es/dist/Makefile
2092 manual/es/dist/pdf/Makefile
2093 manual/es/dist/ps/Makefile
2094 manual/es/dist/html/Makefile
2095 manual/es/dist/txt/Makefile
2096 claws-mail.pc
2097 ])
2098
2099 dnl Output the configuration summary
2100 echo ""
2101 echo "$PACKAGE $VERSION"
2102 echo ""
2103 if test x"$enable_alternate_addressbook" = xyes; then
2104         echo "Using Address Book : Alternate experimental interface"
2105 else
2106         echo "Using Address Book : Original stable interface"
2107         echo "JPilot             : $enable_jpilot"
2108         echo "LDAP               : $enable_ldap"
2109 fi
2110 echo "gnuTLS             : $enable_gnutls"
2111 echo "iconv              : $am_cv_func_iconv"
2112 echo "compface           : $enable_compface"
2113 echo "IPv6               : $enable_ipv6"
2114 echo "enchant            : $enable_enchant"
2115 echo "IMAP4              : $enable_libetpan"
2116 echo "NNTP               : $enable_libetpan"
2117 echo "Crash dialog       : $enable_crash_dialog"
2118 echo "LibSM              : $enable_libsm"
2119 echo "DBUS               : $enable_dbus"
2120 echo "NetworkManager     : $enable_networkmanager"
2121 echo "Manual             : $enable_manual"
2122 echo "Generic UMPC code  : $enable_generic_umpc"
2123 echo "SVG support        : $enable_svg"
2124 echo "Config dir         : $ac_cv_with_config_dir"
2125 echo "Password crypto    : $pwd_crypto"
2126
2127 echo "Plugins"
2128 echo "   Built:"
2129 for plugin in $PLUGINS; do
2130 echo "            - $plugin"
2131 if test x"$plugin" = xnotification; then
2132         echo "                Features:"
2133         for notif_feature in $notification_features; do
2134                 echo "                    $notif_feature"
2135         done;
2136         if test "x$notification_missing_dependencies" != x; then
2137                 echo "                Disabled due to missing dependencies:"
2138                 for notif_miss_dep in $notification_missing_dependencies; do
2139                         echo "                    $notif_miss_dep"
2140                 done;
2141         fi
2142 fi
2143 done;
2144 if test "x$DISABLED_PLUGINS" != x; then
2145 echo "   Disabled:"
2146 for plugin in $DISABLED_PLUGINS; do
2147 echo "            - $plugin"
2148 done;
2149 fi
2150
2151 if test "x$MISSING_DEPS_PLUGINS" != x; then
2152 echo "   Disabled due to missing dependencies:"
2153 for plugin in $MISSING_DEPS_PLUGINS; do
2154 echo "            - $plugin"
2155 done;
2156 fi
2157 echo ""
2158 echo "The binary will be installed in $prefix/bin"
2159 echo ""
2160 echo "Configure finished, type 'make' to build."