configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.50)
   3 AC_INIT(src/main.c)
   4 AC_CONFIG_AUX_DIR(config)
   5
   6 PACKAGE=sylpheed
   7
   8 dnl version number
   9 MAJOR_VERSION=0
  10 MINOR_VERSION=8
  11 MICRO_VERSION=11
  12 INTERFACE_AGE=0
  13 BINARY_AGE=0
  14 EXTRA_VERSION=claws89
  15 VERSION=$MAJOR_VERSION.$MINOR_VERSION.$MICRO_VERSION$EXTRA_VERSION
  16
  17 dnl set $target
  18 AC_CANONICAL_SYSTEM
  19
  20 dnl
  21 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  22 dnl AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
  23 dnl AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
  24 AC_SUBST(PACKAGE)
  25 AC_SUBST(VERSION)
  26
  27 dnl GNOME installed?
  28 AC_PATH_PROG(GNOME_CONFIG, gnome-config, no)
  29 if test "$GNOME_CONFIG" != no; then
  30         gnomedatadir="`gnome-config --datadir`"
  31         gnomeprefix="`gnome-config --prefix`"
  32         if test "${prefix}" = "NONE"; then
  33                 gnomedatadir="${ac_default_prefix}/${gnomedatadir#${gnomeprefix}}"
  34         else
  35                 gnomedatadir="${prefix}/${gnomedatadir#${gnomeprefix}}"
  36         fi
  37         AC_SUBST(gnomedatadir)
  38 fi
  39 AM_CONDITIONAL(SYLPHEED_GNOME, test -n "$gnomedatadir")
  40
  41 dnl Claws version
  42 AC_DEFINE(CLAWS, 1, Compiling Claws branch of sylpheed)
  43
  44 dnl libtool versioning
  45 LT_RELEASE=$MAJOR_VERSION.$MINOR_VERSION
  46 LT_CURRENT=`expr $MICRO_VERSION - $INTERFACE_AGE`
  47 LT_REVISION=$INTERFACE_AGE
  48 LT_AGE=`expr $BINARY_AGE - $INTERFACE_AGE`
  49 AC_SUBST(LT_RELEASE)
  50 AC_SUBST(LT_CURRENT)
  51 AC_SUBST(LT_REVISION)
  52 AC_SUBST(LT_AGE)
  53
  54 dnl Specify a header configuration file
  55 AM_CONFIG_HEADER(config.h)
  56
  57 AM_MAINTAINER_MODE
  58
  59 dnl Checks for programs.
  60 dnl AC_ARG_PROGRAM
  61 AC_PROG_CC
  62 AC_ISC_POSIX
  63 AM_PROG_CC_STDC
  64 AC_PROG_INSTALL
  65 AC_PROG_LN_S
  66 AC_PROG_MAKE_SET
  67 AC_PROG_CPP
  68 dnl AC_PROG_RANLIB
  69 AM_PROG_LEX
  70 AC_PROG_YACC
  71 AM_PROG_LIBTOOL
  72
  73 SYLPHEED_ACLOCAL_INCLUDE(ac)
  74
  75 case "$target" in
  76 *-darwin*)
  77         CFLAGS="$CFLAGS -traditional-cpp -fno-common"
  78         ;;
  79 esac
  80
  81 dnl for gettext
  82 ALL_LINGUAS="bg cs de el en_GB es fr hr hu it ja ko nl pl pt_BR ru sr sv"
  83 AM_GNU_GETTEXT
  84 dnl AC_CHECK_FUNC(gettext, AC_CHECK_LIB(intl, gettext))
  85 localedir='${prefix}/${DATADIRNAME}/locale'
  86 AC_SUBST(localedir)
  87
  88 manualdir='${prefix}/${DATADIRNAME}/${PACKAGE}/manual'
  89 AC_SUBST(manualdir)
  90 faqdir='${prefix}/${DATADIRNAME}/${PACKAGE}/faq'
  91 AC_SUBST(faqdir)
  92
  93 dnl Set PACKAGE_DATA_DIR in config.h.
  94 if test "x${datadir}" = 'x${prefix}/share'; then
  95   if test "x${prefix}" = "xNONE"; then
  96     AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${ac_default_prefix}/share/${PACKAGE}", PACKAGE_DATA_DIR)
  97   else
  98     AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${prefix}/share/${PACKAGE}", PACKAGE_DATA_DIR)
  99   fi
 100 else
 101   AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${datadir}/${PACKAGE}", PACKAGE_DATA_DIR)
 102 fi
 103
 104 AC_CHECK_LIB(xpg4, setlocale)
 105
 106 dnl for GThread support (currently disabled)
 107 dnl AC_ARG_ENABLE(threads,
 108 dnl     [  --enable-threads        Enable multithread support [default=no]],
 109 dnl     [use_threads=$enableval], [use_threads=no])
 110
 111 AC_MSG_CHECKING([whether to use threads])
 112 if test x"$use_threads" = xyes ; then
 113         AC_MSG_RESULT(yes)
 114         if test ! -z `$GLIB_CONFIG --help 2>&1 |grep 'gthread'` ; then
 115                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
 116                 LIBS="$LIBS `$GLIB_CONFIG --libs gthread`"
 117                 AC_DEFINE(USE_THREADS, 1, Whether to use multithread or not)
 118         else
 119                 AC_MSG_ERROR([Sylpheed requires GThread from GLib to use threading.])
 120         fi
 121 else
 122         AC_MSG_RESULT(no)
 123 fi
 124
 125 dnl Checks for header files.
 126 AC_HEADER_DIRENT
 127 AC_HEADER_STDC
 128 AC_HEADER_SYS_WAIT
 129 AC_CHECK_HEADERS(fcntl.h sys/file.h unistd.h paths.h \
 130                  sys/param.h sys/utsname.h sys/select.h \
 131                  wchar.h wctype.h)
 132
 133 dnl Checks for typedefs, structures, and compiler characteristics.
 134 AC_C_CONST
 135 AC_TYPE_OFF_T
 136 AC_TYPE_PID_T
 137 AC_TYPE_SIZE_T
 138 AC_STRUCT_TM
 139
 140 dnl AC_CHECK_TYPE(wint_t, unsigned int) does not work because wint_t
 141 dnl may be defined only in wchar.h (this happens with gcc-2.96).
 142 dnl So we need to use this extended macro.
 143 SYLPHEED_CHECK_TYPE(wint_t, unsigned int,
 144 [
 145 #if HAVE_WCHAR_H
 146 #include <wchar.h>
 147 #endif
 148 ], Define to `unsigned int' if <stddef.h> or <wchar.h> doesn't define.)
 149
 150 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF, Used to test for a u32 typedef)
 151 AC_CHECK_SIZEOF(unsigned short, 2)
 152 AC_CHECK_SIZEOF(unsigned int, 4)
 153 AC_CHECK_SIZEOF(unsigned long, 4)
 154
 155 dnl Checks for library functions.
 156 AC_FUNC_ALLOCA
 157 AC_CHECK_FUNCS(gethostname mkdir mktime socket strstr strchr \
 158                wcsstr wcswcs iswalnum iswspace towlower \
 159                wcslen wcscpy wcsncpy \
 160                uname flock lockf inet_aton inet_addr \
 161                fchmod mkstemp)
 162
 163 dnl *****************
 164 dnl ** common code **
 165 dnl *****************
 166
 167 dnl check for glib
 168 AM_PATH_GLIB(1.2.6,,
 169         AC_MSG_ERROR(Test for GLIB failed. See the file 'INSTALL' for help.),
 170         gthread)
 171
 172 dnl check for IPv6 option
 173 AC_ARG_ENABLE(ipv6,
 174         [  --enable-ipv6           Enable IPv6 support [default=no]],
 175         [ac_cv_enable_ipv6=$enableval], [ac_cv_enable_ipv6=no])
 176
 177 dnl automated checks for IPv6 support.
 178 AC_MSG_CHECKING([whether to use IPv6])
 179 if test x"$ac_cv_enable_ipv6" = xyes; then
 180         AC_MSG_RESULT(yes)
 181         AC_MSG_CHECKING([for IPv6 support])
 182         AC_CACHE_VAL(ac_cv_ipv6,[
 183                 AC_TRY_COMPILE([#define INET6
 184                                 #include <sys/types.h>
 185                                 #include <netinet/in.h>],
 186                         [int x = IPPROTO_IPV6; struct in6_addr a;],
 187                         ac_cv_ipv6=yes, ac_cv_ipv6=no)
 188         ])
 189         AC_MSG_RESULT($ac_cv_ipv6)
 190         if test $ac_cv_ipv6 = yes; then
 191                 AC_DEFINE(INET6, 1, Define if you want IPv6 support.)
 192         else
 193                 AC_MSG_WARN(*** IPv6 will not be supported ***)
 194                 ac_cv_enable_ipv6=no
 195         fi
 196 else
 197         AC_MSG_RESULT(no)
 198 fi
 199
 200 dnl Check for OpenSSL
 201 AM_PATH_OPENSSL
 202
 203 dnl Key for password encryption
 204 AC_ARG_WITH(passcrypt-key, [  --with-passcrypt-key=KEY     Key used to encode passwords (8 byte string)],
 205             with_passcrypt_key="$withval", with_passcrypt_key="passkey0")
 206 AC_SUBST(PASSCRYPT_KEY, $with_passcrypt_key)
 207
 208 dnl ************************
 209 dnl ** GTK user interface **
 210 dnl ************************
 211
 212 dnl Checks for GTK
 213 AM_PATH_GTK(1.2.6,,
 214         AC_MSG_ERROR(Test for GTK failed. See the file 'INSTALL' for help.))
 215
 216 dnl check if gdk / gtk was compiled with USE_XIM
 217 AC_MSG_CHECKING([whether GTK was compiled with XIM support])
 218 CFLAGS_SAVE="$CFLAGS"
 219 LDFLAGS_SAVE="$LDFLAGS"
 220 CFLAGS="$CFLAGS `$GTK_CONFIG --cflags`"
 221 LDFLAGS="$LDFLAGS `$GTK_CONFIG --libs`"
 222 AC_CACHE_VAL(ac_cv_use_xim, [
 223         AC_TRY_LINK_FUNC([gdk_ic_attr_new],
 224                          ac_cv_use_xim=yes, ac_cv_use_xim=no)
 225 ])
 226 AC_MSG_RESULT($ac_cv_use_xim)
 227 if test $ac_cv_use_xim = yes; then
 228         AC_DEFINE(USE_XIM, 1, Whether GTK was compiled with XIM support or not)
 229 fi
 230 CFLAGS="$CFLAGS_SAVE"
 231 LDFLAGS="$LDFLAGS_SAVE"
 232
 233 dnl GNU/Aspell is used for spell checking
 234 AC_ARG_ENABLE(aspell,
 235         [  --enable-aspell         Enable GNU/aspell support [default=no]],
 236         [ac_cv_enable_aspell=$enableval], [ac_cv_enable_aspell=no])
 237 AC_MSG_CHECKING([whether to use GNU/aspell])
 238 if test $ac_cv_enable_aspell = yes; then
 239         AC_MSG_RESULT(yes)
 240         AM_PATH_ASPELL(0.50, AC_DEFINE(USE_ASPELL, 1, Define if you use ASPELL to support spell checking),
 241                       [use_aspell=no ac_cv_enable_aspell=no])
 242 else
 243         AC_MSG_RESULT(no)
 244 fi
 245
 246 dnl want crash dialog
 247 AC_ARG_ENABLE(crash-dialog,
 248         [  --enable-crash-dialog   Enable crash dialog [default=no]],
 249         [ac_cv_enable_crash_dialog=$enableval], [ac_cv_enable_crash_dialog=no])
 250 if test $ac_cv_enable_crash_dialog = yes; then
 251 dnl check if GDB is somewhere
 252         AC_CHECK_PROG(ac_cv_enable_crash_dialog, gdb, yes, no)
 253         AC_MSG_CHECKING([whether to use crash dialog])
 254         if test $ac_cv_enable_crash_dialog = yes; then
 255                 AC_DEFINE(CRASH_DIALOG, 1, Pop up crash dialog)
 256         fi
 257         AC_MSG_RESULT($ac_cv_enable_crash_dialog)
 258 fi
 259
 260 dnl Check for X-Face support
 261 AC_ARG_ENABLE(compface,
 262         [  --disable-compface      Do not use compface (X-Face)],
 263         [ac_cv_enable_compface=$enableval], [ac_cv_enable_compface=yes])
 264 if test "$ac_cv_enable_compface" = yes; then
 265         AC_CHECK_LIB(compface, uncompface,,[ac_cv_enable_compface=no])
 266 fi
 267
 268 dnl for LDAP support in addressbook
 269 dnl no check for libraries; dynamically loaded
 270 AC_ARG_ENABLE(ldap,
 271         [  --enable-ldap           Enable LDAP support [default=no]],
 272         [ac_cv_enable_ldap=$enableval], [ac_cv_enable_ldap=no])
 273 AC_MSG_CHECKING([whether to use LDAP])
 274 if test "$ac_cv_enable_ldap" = yes; then
 275         AC_MSG_RESULT(yes)
 276
 277         dnl check for available libraries, and pull them in
 278         AC_CHECK_LIB(resolv, res_query, LDAP_LIBS="$LDAP_LIBS -lresolv")
 279         AC_CHECK_LIB(socket, bind, LDAP_LIBS="$LDAP_LIBS -lsocket")
 280         AC_CHECK_LIB(nsl, gethostbyaddr, LDAP_LIBS="$LDAP_LIBS -lnsl")
 281         AC_CHECK_LIB(lber, ber_get_tag, LDAP_LIBS="$LDAP_LIBS -llber",,
 282                      $LDAP_LIBS)
 283
 284         dnl we need libpthread for sylpheed ldap,  until we find
 285         dnl a better way to handle ldap requests asynchronously...
 286         AC_CHECK_LIB(pthread, pthread_create, LDAP_LIBS="$LDAP_LIBS -lpthread")
 287
 288         AC_CHECK_HEADERS(ldap.h lber.h pthread.h,
 289                          [ ac_cv_enable_ldap=yes ],
 290                          [ ac_cv_enable_ldap=no ])
 291
 292         if test "$ac_cv_enable_ldap" = yes; then
 293                 AC_CHECK_LIB(ldap, ldap_open,
 294                              [ ac_cv_enable_ldap=yes ],
 295                              [ ac_cv_enable_ldap=no ],
 296                              $LDAP_LIBS)
 297         fi
 298
 299         AC_MSG_CHECKING([whether ldap library is available])
 300         AC_MSG_RESULT($ac_cv_enable_ldap)
 301
 302         if test "$ac_cv_enable_ldap" = yes; then
 303                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
 304                 LDAP_LIBS="$LDAP_LIBS -lldap `$GLIB_CONFIG --libs gthread`"
 305                 AC_DEFINE(USE_LDAP, 1, Define if you want LDAP support in addressbook.)
 306                 AC_SUBST(LDAP_LIBS)
 307         fi
 308 else
 309         AC_MSG_RESULT(no)
 310 fi
 311
 312 dnl for JPilot support in addressbook
 313 dnl no check for libraries; these are dynamically loaded
 314 AC_ARG_ENABLE(jpilot,
 315         [  --enable-jpilot         Enable JPilot support [default=no]],
 316         [ac_cv_enable_jpilot=$enableval], [ac_cv_enable_jpilot=no])
 317 AC_MSG_CHECKING([whether to use JPilot])
 318 if test "$ac_cv_enable_jpilot" = yes; then
 319         AC_MSG_RESULT(yes)
 320         AC_CHECK_HEADERS(pi-args.h pi-appinfo.h pi-address.h,
 321                          [ AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ],
 322                          [ ac_cv_enable_jpilot=no ])
 323         if test "$ac_cv_enable_jpilot" = no; then
 324                 AC_CHECK_HEADERS(libpisock/pi-args.h libpisock/pi-appinfo.h libpisock/pi-address.h,
 325                                  [ ac_cv_enable_jpilot=yes
 326                                    AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ])
 327         fi
 328         AC_MSG_CHECKING([whether jpilot is available])
 329         AC_MSG_RESULT($ac_cv_enable_jpilot)
 330
 331         if test "$ac_cv_enable_jpilot" = yes; then
 332                 LIBS="$LIBS -lpisock"
 333         fi
 334 else
 335         AC_MSG_RESULT(no)
 336 fi
 337
 338 dnl GPGME is used to support OpenPGP
 339 AC_ARG_ENABLE(gpgme,
 340         [  --enable-gpgme          Enable GnuPG support using GPGME [default=no]],
 341         [ac_cv_enable_gpgme=$enableval], [ac_cv_enable_gpgme=no])
 342 AC_MSG_CHECKING([whether to use GPGME])
 343 if test $ac_cv_enable_gpgme = yes; then
 344         AC_MSG_RESULT(yes)
 345         AM_PATH_GPGME(0.3.10, AC_DEFINE(USE_GPGME, 1, Define if you use GPGME to support OpenPGP.),
 346                       [use_gpgme=no
 347                        ac_cv_enable_gpgme=no])
 348 else
 349         AC_MSG_RESULT(no)
 350 fi
 351
 352 dnl *************************
 353 dnl ** section for plugins **
 354 dnl *************************
 355
 356 PLUGINS=""
 357
 358 AC_ARG_ENABLE(demo-plugin,
 359         [  --enable-demo-plugin    Build demo plugin [default=no]],
 360         [ac_cv_enable_demo_plugin=$enableval], [ac_cv_enable_demo_plugin=no])
 361 AM_CONDITIONAL(BUILD_DEMO_PLUGIN, test x"$ac_cv_enable_demo_plugin" = xyes)
 362 if test x"$ac_cv_enable_demo_plugin" = xyes; then
 363         PLUGINS="demo $PLUGINS"
 364 fi
 365
 366 AC_ARG_ENABLE(spamassassin-plugin,
 367         [  --enable-spamassassin-plugin    Build spamassassin plugin [default=no]],
 368         [ac_cv_enable_spamassassin_plugin=$enableval], [ac_cv_enable_spamassassin_plugin=no])
 369 AM_CONDITIONAL(BUILD_SPAMASSASSIN_PLUGIN, test x"$ac_cv_enable_spamassassin_plugin" = xyes)
 370 if test x"$ac_cv_enable_spamassassin_plugin" = xyes; then
 371         AC_SPAMASSASSIN
 372         PLUGINS="spamassassin $PLUGINS"
 373 fi
 374
 375 AC_ARG_ENABLE(mathml-viewer-plugin,
 376         [  --enable-mathml-viewer-plugin    Build MarhML-Viewer plugin [default=no]],
 377         [ac_cv_enable_mathml_viewer_plugin=$enableval], [ac_cv_enable_mathml_viewer_plugin=no])
 378 AM_CONDITIONAL(BUILD_MATHML_VIEWER_PLUGIN, test x"$ac_cv_enable_mathml_viewer_plugin" = xyes)
 379 if test x"$ac_cv_enable_mathml_viewer_plugin" = xyes; then
 380         GTK_MATH_VIEW_CFLAGS=$( gtkmathview-config --cflags )
 381         GTK_MATH_VIEW_LIBS=$( gtkmathview-config --libs )
 382         AC_SUBST(GTK_MATH_VIEW_CFLAGS)
 383         AC_SUBST(GTK_MATH_VIEW_LIBS)
 384
 385         PLUGINS="mathml-viewer $PLUGINS"
 386 fi
 387
 388 AC_ARG_ENABLE(dillo-viewer-plugin,
 389         [  --enable-dillo-viewer-plugin   Build Dillo plugin for html mail rendering [default=no]],
 390         [ac_cv_enable_dillo_viewer_plugin=$enableval], [ac_cv_enable_dillo_viewer_plugin=no])
 391 AM_CONDITIONAL(BUILD_DILLO_VIEWER_PLUGIN, test x"$ac_cv_enable_dillo_viewer_plugin" = xyes)
 392 if test x"$ac_cv_enable_dillo_viewer_plugin" = xyes; then
 393         PLUGINS="dillo-viewer $PLUGINS"
 394 fi
 395
 396 AC_ARG_ENABLE(image-viewer-plugin,
 397         [  --disable-image-viewer-plugin   Do not build image viewer plugin],
 398         [ac_cv_enable_image_viewer_plugin=$enableval], [ac_cv_enable_image_viewer_plugin=yes])
 399 if test x"$ac_cv_enable_image_viewer_plugin" = xyes; then
 400         AC_ARG_ENABLE(gdk-pixbuf,
 401                 [  --disable-gdk-pixbuf    Do not use gdk-pixbuf],
 402                 [ac_cv_enable_gdk_pixbuf=$enableval], [ac_cv_enable_gdk_pixbuf=yes])
 403         AC_ARG_ENABLE(imlib,
 404                 [  --disable-imlib         Do not use imlib],
 405                 [ac_cv_enable_imlib=$enableval], [ac_cv_enable_imlib=yes])
 406
 407         if test "$ac_cv_enable_gdk_pixbuf" = yes; then
 408                 AM_PATH_GDK_PIXBUF(0.8.0,
 409                         [AC_DEFINE(HAVE_GDK_PIXBUF, 1, Define if you use gdk-pixbuf to support image viewer)
 410                          ac_cv_enable_imlib=no], [ac_cv_enable_gdk_pixbuf=no])
 411         fi
 412         if test "$ac_cv_enable_imlib" = yes; then
 413                 AM_PATH_GDK_IMLIB(1.9,
 414                         AC_DEFINE(HAVE_GDK_IMLIB, 1, Define if you use gdk_imlib to support image viewer),
 415                         [ac_cv_enable_imlib=no])
 416         fi
 417         if test "$ac_cv_enable_gdk_pixbuf" = no -a "$ac_cv_enable_imlib" = no; then
 418                 $ac_cv_enable_image_viewer_plugin = no
 419         fi
 420 fi
 421 AM_CONDITIONAL(BUILD_IMAGE_VIEWER_PLUGIN, test x"$ac_cv_enable_image_viewer_plugin" = xyes)
 422 if test x"$ac_cv_enable_image_viewer_plugin" = xyes; then
 423         PLUGINS="image $PLUGINS"
 424 fi
 425
 426 AC_ARG_ENABLE(trayicon-plugin,
 427         [  --enable-trayicon-plugin   System Tray Icon [default=no]],
 428         [ac_cv_enable_trayicon_plugin=$enableval], [ac_cv_enable_trayicon_plugin=no])
 429 AM_CONDITIONAL(BUILD_TRAYICON_PLUGIN, test x"$ac_cv_enable_trayicon_plugin" = xyes)
 430 if test x"$ac_cv_enable_trayicon_plugin" = xyes; then
 431         PLUGINS="trayicon $PLUGINS"
 432 fi
 433
 434 AC_ARG_ENABLE(clamav-plugin,
 435         [  --enable-clamav-plugin    Build clamav plugin [default=no]],
 436         [ac_cv_enable_clamav_plugin=$enableval], [ac_cv_enable_clamav_plugin=no])
 437 AM_CONDITIONAL(BUILD_CLAMAV_PLUGIN, test x"$ac_cv_enable_clamav_plugin" = xyes)
 438 if test x"$ac_cv_enable_clamav_plugin" = xyes; then
 439         AC_CHECK_LIB(clamav, cl_scanfile, clamav_lib=-lclamav)
 440         if test -z "${clamav_lib}"
 441         then
 442                 AC_MSG_ERROR(clamav library not found)
 443         fi
 444         LIBS="${clamav_lib} ${LIBS}"
 445         PLUGINS="clamav $PLUGINS"
 446 fi
 447
 448 dnl ****************************
 449 dnl ** Final configure output **
 450 dnl ****************************
 451
 452 AC_OUTPUT([
 453 Makefile
 454 sylpheed.spec
 455 intl/Makefile
 456 ac/Makefile
 457 po/Makefile.in
 458 src/common/version.h
 459 src/Makefile
 460 src/common/Makefile
 461 src/common/passcrypt.h
 462 src/gtk/Makefile
 463 src/plugins/Makefile
 464 src/plugins/demo/Makefile
 465 src/plugins/spamassassin/Makefile
 466 src/plugins/mathml_viewer/Makefile
 467 src/plugins/dillo_viewer/Makefile
 468 src/plugins/image_viewer/Makefile
 469 src/plugins/trayicon/Makefile
 470 src/plugins/clamav/Makefile
 471 faq/Makefile
 472 faq/de/Makefile
 473 faq/en/Makefile
 474 faq/es/Makefile
 475 faq/fr/Makefile
 476 faq/it/Makefile
 477 man/Makefile
 478 manual/Makefile
 479 manual/de/Makefile
 480 manual/en/Makefile
 481 manual/es/Makefile
 482 manual/fr/Makefile
 483 manual/ja/Makefile
 484 tools/Makefile
 485 config/Makefile
 486 ])
 487
 488 dnl Output the configuration summary
 489 echo ""
 490 echo "$PACKAGE $VERSION"
 491 echo ""
 492 if test "$ac_cv_enable_gdk_pixbuf" = yes; then
 493         echo "image support : yes (gdk-pixbuf)"
 494 elif test "$ac_cv_enable_imlib" = yes; then
 495         echo "image support : yes (gdk_imlib)"
 496 else
 497         echo "image support : no"
 498 fi
 499 echo "GnuPG         : $ac_cv_enable_gpgme"
 500 echo "JPilot        : $ac_cv_enable_jpilot"
 501 echo "LDAP          : $ac_cv_enable_ldap"
 502 echo "OpenSSL       : $ac_cv_enable_openssl"
 503 echo "iconv         : $am_cv_func_iconv"
 504 echo "compface      : $ac_cv_enable_compface"
 505 echo "IPv6          : $ac_cv_enable_ipv6"
 506 echo "GNU/aspell    : $ac_cv_enable_aspell"
 507 echo "Crash dialog  : $ac_cv_enable_crash_dialog"
 508 echo "Plugins       : $PLUGINS"
 509 echo ""
 510 echo "The binary will be installed in $prefix/bin"
 511 echo ""
 512 echo "Configure finished, type 'make' to build."