configure.ac

   1
   2 AC_PREREQ(2.60)
   3 AC_INIT(src/main.c)
   4 AC_CONFIG_AUX_DIR(config)
   5
   6 PACKAGE=claws-mail
   7
   8 dnl version number
   9 MAJOR_VERSION=3
  10 MINOR_VERSION=4
  11 MICRO_VERSION=0
  12 INTERFACE_AGE=0
  13 BINARY_AGE=0
  14 EXTRA_VERSION=37
  15 EXTRA_RELEASE=
  16 EXTRA_GTK2_VERSION=
  17
  18 if test \( $EXTRA_VERSION -eq 0 \) -o \( "x$EXTRA_RELEASE" != "x" \); then
  19     VERSION=${MAJOR_VERSION}.${MINOR_VERSION}.${MICRO_VERSION}${EXTRA_RELEASE}${EXTRA_GTK2_VERSION}
  20 else
  21     VERSION=${MAJOR_VERSION}.${MINOR_VERSION}.${MICRO_VERSION}cvs${EXTRA_VERSION}${EXTRA_GTK2_VERSION}
  22 fi
  23
  24 dnl set $target
  25 AC_CANONICAL_SYSTEM
  26
  27 dnl
  28 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  29 dnl AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
  30 dnl AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
  31 AC_SUBST(PACKAGE)
  32 AC_SUBST(VERSION)
  33 AC_SUBST(MAJOR_VERSION)
  34 AC_SUBST(MINOR_VERSION)
  35 AC_SUBST(MICRO_VERSION)
  36 AC_SUBST(EXTRA_VERSION)
  37
  38 dnl GNOME installed?
  39 AC_PATH_PROG(GNOME_CONFIG, gnome-config, no)
  40 if test "$GNOME_CONFIG" != no; then
  41         gnomedatadir="`gnome-config --datadir`"
  42         gnomeprefix="`gnome-config --prefix`"
  43         if test "${prefix}" = "NONE"; then
  44                 gnomedatadir="${ac_default_prefix}/${gnomedatadir#${gnomeprefix}}"
  45         else
  46                 gnomedatadir="${prefix}/${gnomedatadir#${gnomeprefix}}"
  47         fi
  48         AC_SUBST(gnomedatadir)
  49 fi
  50 AM_CONDITIONAL(CLAWS_GNOME, test -n "$gnomedatadir")
  51
  52 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
  53 if test x$PKG_CONFIG = xno ; then
  54   AC_MSG_ERROR([*** pkg-config not found. See http://www.freedesktop.org/software/pkgconfig/])
  55 fi
  56
  57 dnl GNOME 2.x installed?
  58 PKG_CHECK_MODULES(GNOME2, libgnome-2.0 >= 2.0, ac_enable_gnome2=yes, ac_enable_gnome2=no)
  59 AM_CONDITIONAL(CLAWS_GNOME2, test x"$ac_enable_gnome2" = x"yes")
  60
  61 dnl libtool versioning
  62 LT_RELEASE=$MAJOR_VERSION.$MINOR_VERSION
  63 LT_CURRENT=`expr $MICRO_VERSION - $INTERFACE_AGE`
  64 LT_REVISION=$INTERFACE_AGE
  65 LT_AGE=`expr $BINARY_AGE - $INTERFACE_AGE`
  66 AC_SUBST(LT_RELEASE)
  67 AC_SUBST(LT_CURRENT)
  68 AC_SUBST(LT_REVISION)
  69 AC_SUBST(LT_AGE)
  70
  71 dnl Specify a header configuration file
  72 AC_CONFIG_HEADERS(config.h)
  73
  74 AM_MAINTAINER_MODE
  75
  76 dnl Checks for programs.
  77 dnl AC_ARG_PROGRAM
  78 AC_PROG_CC
  79 AC_ISC_POSIX
  80 AC_PROG_INSTALL
  81 AC_PROG_LN_S
  82 AC_PROG_MAKE_SET
  83 AC_PROG_CPP
  84 dnl AC_PROG_RANLIB
  85 AM_PROG_LEX
  86 AC_PROG_YACC
  87 AC_LIB_PREFIX
  88 AC_LIBTOOL_WIN32_DLL
  89 AC_LIBTOOL_RC
  90 AC_PROG_LIBTOOL
  91
  92 CLAWS_ACLOCAL_INCLUDE(m4)
  93
  94 dnl ******************************
  95 dnl Checks for host
  96 dnl Not needed anymore because we
  97 dnl do AC_CANONICAL_SYSTEM above
  98 dnl ******************************
  99 dnl AC_CANONICAL_HOST
 100
 101 dnl Copied from the official gtk+-2 configure.in
 102 AC_MSG_CHECKING([for some Win32 platform])
 103 case "$host" in
 104   *-*-mingw*|*-*-cygwin*)
 105     platform_win32=yes
 106     LDFLAGS="$LDFLAGS -mwindows"
 107     ;;
 108   *)
 109     platform_win32=no
 110     ;;
 111 esac
 112 AC_MSG_RESULT([$platform_win32])
 113 AM_CONDITIONAL(PLATFORM_WIN32, test x"$platform_win32" = x"yes")
 114
 115 AC_MSG_CHECKING([for native Win32])
 116 case "$host" in
 117   *-*-mingw*)
 118     os_win32=yes
 119     ;;
 120   *)
 121     os_win32=no
 122     ;;
 123 esac
 124 AC_MSG_RESULT([$os_win32])
 125 AM_CONDITIONAL(OS_WIN32, test x"$os_win32" = x"yes")
 126
 127 AC_MSG_CHECKING([for Cygwin])
 128 case "$host" in
 129   *-*-cygwin*)
 130     env_cygwin=yes
 131     ;;
 132   *)
 133     env_cygwin=no
 134     ;;
 135 esac
 136 AC_MSG_RESULT([$env_cygwin])
 137 AM_CONDITIONAL(CYGWIN, test x"$env_cygwin" = x"yes")
 138
 139 if test "$GCC" = "yes"
 140 then
 141         CFLAGS="$CFLAGS -Wno-unused-function"
 142 fi
 143
 144 CFLAGS="$CFLAGS -Wall"
 145 pthread_name=
 146 case "$target" in
 147 *-darwin*)
 148         CFLAGS="$CFLAGS -no-cpp-precomp -fno-common"
 149         ;;
 150 *-*-mingw*)
 151         # Note that we need to link to pthreadGC2 in all cases. This
 152         # is because some locking is used even when pthread support is
 153         # disabled.
 154         pthread_name=pthreadGC2
 155         CFLAGS="$CFLAGS -mms-bitfields"
 156         LIBS="$LIBS -l${pthread_name} -lws2_32 -lregex"
 157         ;;
 158 *-*-solaris*)
 159         CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 160         CFLAGS="$CFLAGS -DSOLARIS"
 161         ;;
 162 esac
 163
 164 dnl Checks for iconv
 165 AM_ICONV
 166
 167 dnl
 168 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 169 dnl
 170 syl_save_LIBS=$LIBS
 171 LIBS="$LIBS $GTK_LIBS"
 172 AC_CHECK_FUNCS(bind_textdomain_codeset)
 173 LIBS=$syl_save_LIBS
 174
 175 dnl for gettext
 176 ALL_LINGUAS="bg ca cs de el en_GB es fi fr he hr hu it ja ko nb nl pl pt_BR ru sk sr sv zh_CN zh_TW"
 177 GETTEXT_PACKAGE=claws-mail
 178 AC_SUBST(GETTEXT_PACKAGE)
 179 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Define text domain.])
 180
 181 AM_GNU_GETTEXT_VERSION([0.15])
 182 AM_GNU_GETTEXT([external])
 183
 184 manualdir='${docdir}/manual'
 185 AC_ARG_WITH(manualdir,
 186         [  --with-manualdir=DIR    Manual directory],
 187         [manualdir="$withval"])
 188 AC_SUBST(manualdir)
 189
 190 AC_ARG_ENABLE(manual,
 191         [  --disable-manual           do not build manual],
 192         [ac_cv_enable_manual=$enableval], [ac_cv_enable_manual=yes])
 193
 194 AM_CONDITIONAL(BUILD_MANUAL, test x"$ac_cv_enable_manual" = xyes)
 195
 196 dnl Set PACKAGE_DATA_DIR in config.h.
 197 if test "x${datarootdir}" = 'x${prefix}/share'; then
 198         if test "x${prefix}" = "xNONE"; then
 199                 AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${ac_default_prefix}/share/${PACKAGE}",[PACKAGE_DATA_DIR])
 200         else
 201                 AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${prefix}/share/${PACKAGE}",[PACKAGE_DATA_DIR])
 202         fi
 203 else
 204         AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${datarootdir}/${PACKAGE}",[PACKAGE_DATA_DIR])
 205 fi
 206
 207 AC_CHECK_LIB(xpg4, setlocale)
 208
 209 SM_LIBS=""
 210 dnl Check for LibSM
 211 AC_ARG_ENABLE(libsm,
 212         [  --disable-libsm    disable libSM support for session management.],
 213         [ac_cv_enable_libsm=$enableval], [ac_cv_enable_libsm=yes])
 214 AC_MSG_CHECKING([whether to use LibSM])
 215 if test x"$ac_cv_enable_libsm" = xyes; then
 216         AC_MSG_RESULT(yes)
 217         AC_CHECK_LIB(SM, SmcSaveYourselfDone,
 218                 [SM_LIBS="$X_LIBS -lSM -lICE"],ac_cv_enable_libsm=no,
 219                 $X_LIBS -lICE)
 220         AC_CHECK_HEADERS(X11/SM/SMlib.h,,ac_cv_enable_libsm=no)
 221         if test x"$ac_cv_enable_libsm" = xyes; then
 222                 AC_DEFINE(HAVE_LIBSM, 1, [Define to 1 if you have libSM installed])
 223         else
 224                 AC_MSG_RESULT(not found)
 225                 AC_MSG_WARN([*** LibSM will not be supported ***])
 226         fi
 227 else
 228         AC_MSG_RESULT(no)
 229 fi
 230 AC_SUBST(SM_LIBS)
 231
 232 dnl for GThread support (currently disabled)
 233 dnl AC_ARG_ENABLE(threads,
 234 dnl     [  --enable-threads        Enable multithread support [default=no]],
 235 dnl     [use_threads=$enableval], [use_threads=no])
 236
 237 AC_MSG_CHECKING([whether to use threads])
 238 if test x"$use_threads" = xyes ; then
 239         AC_MSG_RESULT(yes)
 240         if test ! -z `$GLIB_CONFIG --help 2>&1 |grep 'gthread'` ; then
 241                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
 242                 LIBS="$LIBS `$GLIB_CONFIG --libs gthread`"
 243                 AC_DEFINE(USE_THREADS, 1, Whether to use multithread or not)
 244         else
 245                 AC_MSG_ERROR([Sylpheed requires GThread from GLib to use threading.])
 246         fi
 247 else
 248         AC_MSG_RESULT(no)
 249 fi
 250
 251 dnl Check for d_type member in struct dirent
 252 AC_MSG_CHECKING([whether struct dirent has d_type member])
 253 AC_CACHE_VAL(ac_cv_dirent_d_type,[
 254         AC_TRY_COMPILE([#include <dirent.h>],
 255                        [struct dirent d; d.d_type = DT_REG;],
 256                        ac_cv_dirent_d_type=yes, ac_cv_dirent_d_type=no)
 257 ])
 258 AC_MSG_RESULT($ac_cv_dirent_d_type)
 259 if test $ac_cv_dirent_d_type = yes; then
 260         AC_DEFINE(HAVE_DIRENT_D_TYPE, 1,
 261                   Define if `struct dirent' has `d_type' member.)
 262 fi
 263
 264 # Check whether mkdir does not take the permission argument.
 265 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
 266
 267 dnl Checks for header files.
 268 AC_HEADER_DIRENT
 269 AC_HEADER_STDC
 270 AC_HEADER_SYS_WAIT
 271 AC_CHECK_HEADERS(fcntl.h sys/file.h unistd.h paths.h \
 272                  sys/param.h sys/utsname.h sys/select.h \
 273                  wchar.h wctype.h locale.h netdb.h)
 274
 275 dnl alf - Check for apache installation f*ck up. apache may also install an
 276 dnl fnmatch, which includes their own regex stuff if USE_HSREGEX is defined
 277 AC_TRY_COMPILE([#include <stdlib.h>
 278                 #include <fnmatch.h>],
 279         [int x = USE_HSREGEX;],
 280         ac_cv_have_apache_fnmatch=yes, ac_cv_have_apache_fnmatch=no)
 281 if test $ac_cv_have_apache_fnmatch = yes; then
 282         AC_DEFINE(HAVE_APACHE_FNMATCH, 1, Define if you need to work around apache regex/fnmatch !KLUDGE!)
 283 fi
 284 AC_MSG_CHECKING([whether to use Apache regex header kludge])
 285 AC_MSG_RESULT($ac_cv_have_apache_fnmatch)
 286
 287 dnl Checks for typedefs, structures, and compiler characteristics.
 288 AC_C_CONST
 289 AC_TYPE_OFF_T
 290 AC_TYPE_PID_T
 291 AC_TYPE_SIZE_T
 292 AC_STRUCT_TM
 293
 294 dnl AC_CHECK_TYPE(wint_t, unsigned int) does not work because wint_t
 295 dnl may be defined only in wchar.h (this happens with gcc-2.96).
 296 dnl So we need to use this extended macro.
 297 CLAWS_CHECK_TYPE(wint_t, unsigned int,
 298 [
 299 #if HAVE_WCHAR_H
 300 #include <wchar.h>
 301 #endif
 302 ], Define to `unsigned int' if <stddef.h> or <wchar.h> doesn't define.)
 303
 304 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF, Used to test for a u32 typedef)
 305 AC_CHECK_SIZEOF(unsigned short, 2)
 306 AC_CHECK_SIZEOF(unsigned int, 4)
 307 AC_CHECK_SIZEOF(unsigned long, 4)
 308
 309 dnl Checks for library functions.
 310 AC_FUNC_ALLOCA
 311 AC_CHECK_FUNCS(gethostname mkdir mktime socket strstr strchr \
 312                uname flock lockf inet_aton inet_addr \
 313                fchmod mkstemp truncate getuid regcomp)
 314
 315 AC_CHECK_FUNCS(fgets_unlocked fwrite_unlocked)
 316
 317 dnl *****************
 318 dnl ** common code **
 319 dnl *****************
 320
 321 dnl check for glib
 322 PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.6 gmodule-2.0 >= 2.6 gobject-2.0 >= 2.6 gthread-2.0 >= 2.6)
 323
 324 GLIB_GENMARSHAL=`pkg-config --variable=glib_genmarshal glib-2.0`
 325 AC_SUBST(GLIB_GENMARSHAL)
 326
 327 AC_SUBST(GLIB_CFLAGS)
 328 AC_SUBST(GLIB_LIBS)
 329
 330 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 331 syl_save_LIBS=$LIBS
 332 LIBS="$LIBS $GTK_LIBS"
 333 AC_CHECK_FUNCS(bind_textdomain_codeset)
 334 LIBS=$syl_save_LIBS
 335
 336 dnl check for IPv6 option
 337 AC_ARG_ENABLE(ipv6,
 338         [  --disable-ipv6           disable build IPv6 support],
 339         [ac_cv_enable_ipv6=$enableval], [ac_cv_enable_ipv6=yes])
 340
 341 dnl automated checks for IPv6 support.
 342 AC_MSG_CHECKING([whether to use IPv6])
 343 if test x"$ac_cv_enable_ipv6" = xyes; then
 344         AC_MSG_RESULT(yes)
 345         AC_MSG_CHECKING([for IPv6 support])
 346         AC_CACHE_VAL(ac_cv_ipv6,[
 347                 AC_TRY_COMPILE([#define INET6
 348                                 #include <sys/types.h>
 349                                 #include <netinet/in.h>],
 350                         [int x = IPPROTO_IPV6; struct in6_addr a;],
 351                         ac_cv_ipv6=yes, ac_cv_ipv6=no)
 352         ])
 353         AC_MSG_RESULT($ac_cv_ipv6)
 354         if test $ac_cv_ipv6 = yes; then
 355                 AC_DEFINE(INET6, 1, Define if you want IPv6 support.)
 356         else
 357                 AC_MSG_WARN(*** IPv6 will not be supported ***)
 358                 ac_cv_enable_ipv6=no
 359         fi
 360 else
 361         AC_MSG_RESULT(no)
 362 fi
 363
 364 dnl Check for OpenSSL
 365 AC_ARG_ENABLE(openssl,
 366         [  --disable-openssl    disable OpenSSL support.],
 367         [ac_cv_enable_openssl=$enableval], [ac_cv_enable_openssl=yes])
 368 dnl GNUTLS
 369 AC_ARG_ENABLE(gnutls,    [ --enable-gnutls      enable GnuTLS support],
 370             [ac_cv_enable_gnutls=$enableval], [ac_cv_enable_gnutls=no])
 371 if test x$ac_cv_enable_openssl = xyes && test x$ac_cv_enable_gnutls != xyes; then
 372         ac_cv_enable_gnutls="no"
 373 fi
 374 if test x$ac_cv_enable_gnutls = xyes; then
 375           ac_cv_enable_openssl="no"
 376 fi
 377
 378 AC_MSG_CHECKING([whether to use OpenSSL])
 379 if test x"$ac_cv_enable_openssl" = xyes; then
 380         AC_MSG_RESULT(yes)
 381         PKG_CHECK_MODULES(OPENSSL, openssl >= 0.9.7, :, ac_cv_enable_openssl=no)
 382         if test x$ac_cv_enable_openssl = xyes; then
 383                 AC_DEFINE(USE_OPENSSL, 1, Define if you want OpenSSL support)
 384         else
 385                 AC_MSG_RESULT(not found)
 386                 AC_MSG_WARN([*** OpenSSL will not be supported ***])
 387         fi
 388 else
 389         AC_MSG_RESULT(no)
 390 fi
 391 AC_SUBST(OPENSSL_CFLAGS)
 392 AC_SUBST(OPENSSL_LIBS)
 393
 394 AC_MSG_CHECKING([whether to use GnuTLS])
 395 if test "x$ac_cv_enable_gnutls" != "xno"; then
 396   OCPPFLAGS="$CPPFLAGS"
 397   OLDFLAGS="$LDFLAGS"
 398   GNUTLS_LIBS=""
 399   AC_CHECK_HEADER(gnutls/gnutls.h, [
 400         AC_CHECK_LIB(gnutls, gnutls_global_deinit,
 401                 [AC_DEFINE(USE_GNUTLS, 1, Define to use GnuTLS.)],
 402                 [ac_cv_enable_gnutls=no])
 403   ],[ac_cv_enable_gnutls=no])
 404   if test "x$ac_cv_enable_gnutls" != "xyes"; then
 405    CPPFLAGS="$OCPPFLAGS"
 406    LDFLAGS="$OLDFLAGS"
 407   fi
 408 fi
 409 if test "x$ac_cv_enable_gnutls" = "xyes"; then
 410   AC_DEFINE([USE_GNUTLS],1, [Define to use GnuTLS])
 411   GNUTLS_LIBS="-lgnutls"
 412 else
 413   GNUTLS_LIBS=""
 414 fi
 415 AC_SUBST(GNUTLS_LIBS)
 416
 417 dnl password encryption
 418 OLDLIBS=$LIBS
 419 LIBS=
 420 case $host_os in
 421         *dragonfly*)
 422                 AC_SEARCH_LIBS(encrypt, cipher, [], AC_MSG_ERROR(['encrypt'-function not found.]))
 423         ;;
 424         *)
 425                 AC_SEARCH_LIBS(encrypt, crypt, [], AC_MSG_ERROR(['encrypt'-function not found.]))
 426         ;;
 427 esac
 428 CRYPT_LIBS=$LIBS
 429 AC_SUBST(CRYPT_LIBS)
 430 LIBS=$OLDLIBS
 431
 432 AC_ARG_WITH(passcrypt-key, [  --with-passcrypt-key=KEY     Key used to encode passwords (8 byte string)],
 433             with_passcrypt_key="$withval", with_passcrypt_key="passkey0")
 434 AC_SUBST(PASSCRYPT_KEY, $with_passcrypt_key)
 435
 436 dnl RC dir (will be default at a certain point in time)
 437 AC_ARG_WITH(config-dir,    [  --with-config-dir=RCDIR      Local configuration dir (default: .claws-mail)],
 438               ac_cv_with_config_dir="$withval", ac_cv_with_config_dir=".claws-mail")
 439 if test x"$ac_cv_with_config_dir" = x""; then
 440         ac_cv_with_config_dir=".claws-mail"
 441 fi
 442 AC_DEFINE_UNQUOTED(CFG_RC_DIR, "$ac_cv_with_config_dir", Configuration directory)
 443
 444 dnl ************************
 445 dnl ** GTK user interface **
 446 dnl ************************
 447
 448 dnl Checks for GTK
 449 PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.6)
 450
 451 dnl --disable-deprecated switch for GTK2 purification
 452 AC_ARG_ENABLE(deprecated, [  --disable-deprecated  disable deprecated GTK functions. ],
 453                           [GTK_CFLAGS="$GTK_CFLAGS -DG_DISABLE_DEPRECATED -DGTK_DISABLE_DEPRECATED"], [])
 454
 455 AC_SUBST(GTK_CFLAGS)
 456 AC_SUBST(GTK_LIBS)
 457
 458 dnl GNU/Aspell is used for spell checking
 459 AC_ARG_ENABLE(aspell,
 460         [  --disable-aspell         disable GNU/aspell support],
 461         [ac_cv_enable_aspell=$enableval], [ac_cv_enable_aspell=yes])
 462 AC_MSG_CHECKING([whether to use GNU/aspell])
 463 if test $ac_cv_enable_aspell = yes; then
 464         AC_MSG_RESULT(yes)
 465         AM_PATH_ASPELL(0.50, AC_DEFINE(USE_ASPELL, 1, Define if you use ASPELL to support spell checking),
 466                       [use_aspell=no ac_cv_enable_aspell=no])
 467 else
 468         AC_MSG_RESULT(no)
 469 fi
 470
 471 dnl want crash dialog
 472 AC_ARG_ENABLE(crash-dialog,
 473         [  --enable-crash-dialog   Enable crash dialog [default=no]],
 474         [ac_cv_enable_crash_dialog=$enableval], [ac_cv_enable_crash_dialog=no])
 475 if test $ac_cv_enable_crash_dialog = yes; then
 476 dnl check if GDB is somewhere
 477         AC_CHECK_PROG(ac_cv_enable_crash_dialog, gdb, yes, no)
 478         AC_MSG_CHECKING([whether to use crash dialog])
 479         if test $ac_cv_enable_crash_dialog = yes; then
 480                 AC_DEFINE(CRASH_DIALOG, 1, Pop up crash dialog)
 481         fi
 482         AC_MSG_RESULT($ac_cv_enable_crash_dialog)
 483 fi
 484
 485 dnl generic umpc
 486 AC_ARG_ENABLE(generic-umpc,
 487         [  --enable-generic-umpc   Enable generic UMPC code [default=no]],
 488         [ac_cv_enable_generic_umpc=$enableval], [ac_cv_enable_generic_umpc=no])
 489 if test $ac_cv_enable_generic_umpc = yes; then
 490         AC_DEFINE(GENERIC_UMPC, 1, Generic UMPC code)
 491         AC_MSG_RESULT($ac_cv_enable_generic_umpc)
 492 fi
 493
 494 dnl Maemo platform
 495 AC_ARG_ENABLE(maemo,
 496         [  --enable-maemo   build for the Maemo platform [default=no]],
 497         [ac_cv_enable_maemo=$enableval], [ac_cv_enable_maemo=no])
 498 if test $ac_cv_enable_maemo = yes; then
 499         PKG_CHECK_MODULES(MAEMO, libosso hildon-libs hildon-fm gnome-vfs-2.0, ac_cv_enable_maemo=yes,
 500                   ac_cv_enable_maemo=no)
 501         AC_SUBST(MAEMO_CFLAGS)
 502         AC_SUBST(MAEMO_LIBS)
 503         if test $ac_cv_enable_maemo = no; then
 504                 #test for chinook
 505                 PKG_CHECK_MODULES(MAEMO, libosso hildon-1 hildon-fm-2 gnome-vfs-2.0 hal, ac_cv_enable_maemo=yes,
 506                           ac_cv_enable_maemo=no)
 507                 AC_SUBST(MAEMO_CFLAGS)
 508                 AC_SUBST(MAEMO_LIBS)
 509                 if test $ac_cv_enable_maemo = no; then
 510                         AC_MSG_ERROR(one of libosso hildon-libs hildon-fm hildon-1 hildon-fm-2 not found)
 511                 else
 512                         AC_DEFINE(MAEMO, 1, Build for maemo)
 513                         AC_DEFINE(CHINOOK, 1, Maemo chinook)
 514                         AC_DEFINE(GENERIC_UMPC, 1, Generic UMPC code)
 515                         ac_cv_enable_generic_umpc=yes
 516                 fi
 517         else
 518                 AC_DEFINE(MAEMO, 1, Build for maemo)
 519                 AC_DEFINE(GENERIC_UMPC, 1, Generic UMPC code)
 520                 ac_cv_enable_generic_umpc=yes
 521         fi
 522 fi
 523
 524 PKG_CHECK_MODULES(CONIC, conic, ac_cv_enable_conic=yes,
 525           ac_cv_enable_conic=no)
 526 AC_SUBST(CONIC_CFLAGS)
 527 AC_SUBST(CONIC_LIBS)
 528 if test $ac_cv_enable_conic = yes; then
 529         AC_DEFINE(CONIC, 1, Have conic lib)
 530 fi
 531
 532 dnl Check for X-Face support
 533 AC_ARG_ENABLE(compface,
 534         [  --disable-compface      disable compface (X-Face) support],
 535         [ac_cv_enable_compface=$enableval], [ac_cv_enable_compface=yes])
 536 AC_MSG_CHECKING([whether to use compface])
 537 if test x"$ac_cv_enable_compface" = xyes; then
 538         AC_MSG_RESULT(yes)
 539         AC_CHECK_LIB(compface, uncompface,
 540                 [AC_DEFINE(HAVE_LIBCOMPFACE, 1, Define if you want compface support.)],
 541                 [ac_cv_enable_compface=no])
 542         if test x"$ac_cv_enable_compface" = xyes; then
 543                 COMPFACE_LIBS="-lcompface"
 544         else
 545                 COMPFACE_LIBS=""
 546         fi
 547         AC_SUBST(COMPFACE_LIBS)
 548 else
 549         AC_MSG_RESULT(no)
 550 fi
 551
 552 dnl check for pthread support
 553 AC_ARG_ENABLE(pthread,
 554         [  --disable-pthread           disable pthread support],
 555         [ac_cv_enable_pthread=$enableval], [ac_cv_enable_pthread=yes])
 556 AC_MSG_CHECKING([whether to use pthread])
 557 if test x$ac_cv_enable_pthread = xno; then
 558         AC_MSG_RESULT(no)
 559 else
 560         AC_MSG_RESULT(yes)
 561
 562         # For W32 we need to use a special ptrhead lib. In this case we can't
 563         # use AC_CHECK_LIB because it has no means of checking for a
 564         # library installed under a different name.  Checking for the
 565         # header is okay.
 566         if test -n "${pthread_name}" ; then
 567            ac_cv_enable_pthread=yes
 568         else
 569         AC_CHECK_LIB(pthread, pthread_create, :, ac_cv_enable_pthread=no)
 570         fi
 571         AC_CHECK_HEADERS(pthread.h, :, ac_cv_enable_pthread=no)
 572
 573         if test x$ac_cv_enable_pthread = xyes; then
 574                 AC_DEFINE(USE_PTHREAD, 1, Define if you have pthread)
 575                 if test -z "${pthread_name}" ; then
 576                 PTHREAD_LIBS="-lpthread"
 577         fi
 578         fi
 579
 580 fi
 581 AC_SUBST(PTHREAD_LIBS)
 582
 583 dnl
 584 dnl Check whether we need to pass -lresolv
 585 dnl We know that we don't need it for W32.
 586 dnl
 587 if test x$os_win32 = xno; then
 588   t_oldLibs="$LIBS"
 589   LIBS="$LIBS"
 590   ac_cv_var__res_options=no
 591   AC_TRY_LINK([#include <sys/types.h>
 592              #include <sys/socket.h>
 593              #include <netinet/in.h>
 594              #include <arpa/nameser.h>
 595              #include <resolv.h>],
 596                 [_res.options = RES_INIT;],
 597                 ac_cv_var__res_options=yes);
 598   if test "$ac_cv_var__res_options" != "yes"; then
 599         LIBRESOLV="-lresolv"
 600   fi
 601   LIBS="$t_oldLibs"
 602
 603   if test "x$LIBRESOLV" = "x"; then
 604         AC_CHECK_LIB(resolv, res_query, [LIBRESOLV=-lresolv])
 605         LIBS="$t_oldLibs"
 606   fi
 607 fi
 608 AC_SUBST(LIBRESOLV)
 609
 610 LIBS="$LIBS $LIBRESOLV"
 611
 612 dnl for LDAP support in addressbook
 613 dnl no check for libraries; dynamically loaded
 614 AC_ARG_ENABLE(ldap,
 615         [  --disable-ldap         disable LDAP support],
 616         [ac_cv_enable_ldap=$enableval], [ac_cv_enable_ldap=yes])
 617 AC_MSG_CHECKING([whether to use LDAP])
 618 if test x"$ac_cv_enable_ldap" = xno; then
 619         AC_MSG_RESULT(no)
 620 elif test x"$ac_cv_enable_ldap" = xyes -a x"$ac_cv_enable_pthread" = xno; then
 621         AC_MSG_RESULT(no - LDAP support needs pthread support)
 622
 623         ac_cv_enable_ldap=no
 624 else
 625         AC_MSG_RESULT(yes)
 626
 627         dnl check for available libraries, and pull them in
 628         AC_CHECK_LIB(resolv, res_query, LDAP_LIBS="$LDAP_LIBS -lresolv")
 629         AC_CHECK_LIB(socket, bind, LDAP_LIBS="$LDAP_LIBS -lsocket")
 630         AC_CHECK_LIB(nsl, gethostbyaddr, LDAP_LIBS="$LDAP_LIBS -lnsl")
 631         AC_CHECK_LIB(lber, ber_get_tag, LDAP_LIBS="$LDAP_LIBS -llber",,
 632                      $LDAP_LIBS)
 633
 634         AC_CHECK_HEADERS(ldap.h lber.h,
 635                          [ ac_cv_enable_ldap=yes ],
 636                          [ ac_cv_enable_ldap=no ])
 637
 638         if test "$ac_cv_enable_ldap" = yes; then
 639                 AC_CHECK_LIB(ldap, ldap_open,
 640                              [ ac_cv_enable_ldap=yes ],
 641                              [ ac_cv_enable_ldap=no ],
 642                              $LDAP_LIBS)
 643
 644                 AC_CHECK_LIB(ldap, ldap_start_tls_s,
 645                              [ ac_cv_have_tls=yes ],
 646                              [ ac_cv_have_tls=no ])
 647
 648         fi
 649
 650         AC_MSG_CHECKING([whether ldap library is available])
 651         AC_MSG_RESULT($ac_cv_enable_ldap)
 652
 653         AC_MSG_CHECKING([whether TLS library is available])
 654         AC_MSG_RESULT($ac_cv_have_tls)
 655
 656         if test "$ac_cv_enable_ldap" = yes; then
 657                 AC_DEFINE(USE_LDAP, 1, Define if you want LDAP support in addressbook.)
 658                 LDAP_LIBS="$LDAP_LIBS -lldap"
 659                 AC_SUBST(LDAP_LIBS)
 660                 if test "$ac_cv_have_tls" = yes; then
 661                         AC_DEFINE(USE_LDAP_TLS, 1, Define if you want LDAP TLS support in addressbook.)
 662                 fi
 663         fi
 664 fi
 665
 666 dnl for JPilot support in addressbook
 667 dnl no check for libraries; these are dynamically loaded
 668 AC_ARG_ENABLE(jpilot,
 669         [  --disable-jpilot         disable JPilot support],
 670         [ac_cv_enable_jpilot=$enableval], [ac_cv_enable_jpilot=yes])
 671 AC_MSG_CHECKING([whether to use JPilot])
 672 if test "$ac_cv_enable_jpilot" = yes; then
 673         AC_MSG_RESULT(yes)
 674         AC_CHECK_HEADERS(pi-args.h pi-appinfo.h pi-address.h pi-version.h,
 675                          [ AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ],
 676                          [ ac_cv_enable_jpilot=no ])
 677         if test "$ac_cv_enable_jpilot" = no; then
 678                 AC_CHECK_HEADERS(libpisock/pi-args.h libpisock/pi-appinfo.h libpisock/pi-address.h libpisock/pi-version.h,
 679                                  [ ac_cv_enable_jpilot=yes
 680                                    AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ])
 681         fi
 682
 683         AC_CHECK_LIB(pisock, unpack_Address, [JPILOT_LIBS="-lpisock"], [JPILOT_LIBS="" ac_cv_enable_jpilot="no"])
 684         if test x"$ac_cv_enable_jpilot" = xyes; then
 685                 AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.)
 686         else
 687                 AC_MSG_NOTICE([JPilot support not available])
 688         fi
 689         AC_SUBST(JPILOT_LIBS)
 690 else
 691         AC_MSG_RESULT(no)
 692 fi
 693
 694 dnl #######################################################################
 695 dnl # Check for startup notification
 696 dnl #######################################################################
 697 AC_ARG_ENABLE(startup-notification, [  --disable-startup-notification    disable startup notification support],,enable_startup_notification=yes)
 698
 699 if test "x$enable_startup_notification" = "xyes"; then
 700         PKG_CHECK_MODULES(STARTUP_NOTIFICATION, libstartup-notification-1.0 >= 0.5,
 701         [
 702                 AC_DEFINE(HAVE_STARTUP_NOTIFICATION, 1, [Define if we're using libstartup-notification.])
 703                 echo "Building with libstartup-notification"
 704                 enable_startup_notification=yes
 705         ],
 706         [
 707                 echo "Building without libstartup-notification"
 708                 enable_startup_notification=no
 709         ])
 710
 711         AC_SUBST(STARTUP_NOTIFICATION_CFLAGS)
 712         AC_SUBST(STARTUP_NOTIFICATION_LIBS)
 713 fi
 714
 715 dnl #######################################################################
 716 dnl # Check for D-Bus support
 717 dnl #######################################################################
 718 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 0.60, dbus-glib-1 >= 0.60],
 719 [
 720         AC_DEFINE(HAVE_DBUS_GLIB, 1, [Define if glib bindings of D-Bus are available])
 721         enable_dbus_glib=yes
 722 ],
 723 [
 724         echo "D-Bus requirements not met. D-Bus support not activated."
 725         enable_dbus_glib=no
 726 ])
 727 AC_SUBST(DBUS_CFLAGS)
 728 AC_SUBST(DBUS_LIBS)
 729
 730 dnl #######################################################################
 731 dnl # Check for NetworkManager support
 732 dnl #######################################################################
 733 if test x"$enable_dbus_glib" = xyes; then
 734         AC_ARG_ENABLE(networkmanager-support, [  --disable-networkmanager-support  disable NetworkManager support],,enable_networkmanager_support=yes)
 735         if test x"$enable_networkmanager_support" = xyes; then
 736                 PKG_CHECK_MODULES(NETWORKMANAGER_SUPPORT, NetworkManager >= 0.6.2,
 737                 [
 738                         AC_DEFINE(HAVE_NETWORKMANAGER_SUPPORT, 1, [Define if NetworkManager support is to be included.])
 739                         echo "Building with NetworkManager support"
 740                         enable_networkmanager_support=yes
 741                 ],
 742                 [
 743                         echo "NetworkManager not found."
 744                         enable_networkmanager_support=no
 745                 ])
 746                 AC_SUBST(NETWORKMANAGER_SUPPORT_CFLAGS)
 747         fi
 748 else
 749         echo "NetworkManager support deactivated as D-Bus requirements were not met."
 750         enable_networkmanager_support=no
 751 fi
 752
 753 dnl *************************
 754 dnl ** section for plugins **
 755 dnl *************************
 756
 757 PLUGINS=""
 758
 759 dnl --- Trayicon ---
 760 AC_MSG_CHECKING([whether to build Trayicon plugin])
 761 AC_ARG_ENABLE(trayicon-plugin,
 762         [  --disable-trayicon-plugin         do not build System Tray Icon plugin],
 763         [ac_cv_enable_trayicon_plugin=$enableval], [ac_cv_enable_trayicon_plugin=yes])
 764 if test x"$ac_cv_enable_trayicon_plugin" = xyes; then
 765         AC_MSG_RESULT(yes)
 766         PLUGINS="trayicon $PLUGINS"
 767 else
 768         AC_MSG_RESULT(no)
 769 fi
 770 AM_CONDITIONAL(BUILD_TRAYICON_PLUGIN, test x"$ac_cv_enable_trayicon_plugin" = xyes)
 771
 772 dnl --- SpamAssassin ---
 773 AC_MSG_CHECKING([whether to build SpamAssassin plugin])
 774 AC_ARG_ENABLE(spamassassin-plugin,
 775         [  --disable-spamassassin-plugin      do not build SpamAssassin plugin],
 776         [ac_cv_enable_spamassassin_plugin=$enableval], [ac_cv_enable_spamassassin_plugin=yes])
 777 if test x"$ac_cv_enable_spamassassin_plugin" = xyes; then
 778         AC_MSG_RESULT(yes)
 779         AC_SPAMASSASSIN
 780         PLUGINS="spamassassin $PLUGINS"
 781         AC_DEFINE(USE_SPAMASSASSIN_PLUGIN, 1, Define if spamassassin plugin is being built.)
 782 else
 783         AC_MSG_RESULT(no)
 784 fi
 785 AM_CONDITIONAL(BUILD_SPAMASSASSIN_PLUGIN, test x"$ac_cv_enable_spamassassin_plugin" = xyes)
 786
 787 dnl --- Bogofilter ---
 788 AC_MSG_CHECKING([whether to build Bogofilter plugin])
 789 AC_ARG_ENABLE(bogofilter-plugin,
 790         [  --disable-bogofilter-plugin      do not build bogofilter plugin],
 791         [ac_cv_enable_bogofilter_plugin=$enableval], [ac_cv_enable_bogofilter_plugin=yes])
 792 if test x"$ac_cv_enable_bogofilter_plugin" = xyes; then
 793         AC_MSG_RESULT(yes)
 794         PLUGINS="bogofilter $PLUGINS"
 795         AC_DEFINE(USE_BOGOFILTER_PLUGIN, 1, Define if bogofilter plugin is being built.)
 796 else
 797         AC_MSG_RESULT(no)
 798 fi
 799 AM_CONDITIONAL(BUILD_BOGOFILTER_PLUGIN, test x"$ac_cv_enable_bogofilter_plugin" = xyes)
 800
 801 dnl --- PGP/CORE ---
 802 AC_MSG_CHECKING([whether to build PGP/CORE plugin])
 803 AC_ARG_ENABLE(pgpcore-plugin,
 804         [  --disable-pgpcore-plugin           do not build PGP/Core plugin],
 805         [ac_cv_enable_pgpcore_plugin=$enableval], [ac_cv_enable_pgpcore_plugin=yes])
 806 if test x"$ac_cv_enable_pgpcore_plugin" = xyes; then
 807         AC_MSG_RESULT(yes)
 808         AM_PATH_GPGME(1.0.0, AC_DEFINE(USE_GPGME, 1, Define if you use GPGME to support OpenPGP.),
 809                       [ac_cv_enable_pgpcore_plugin=no])
 810         if test x"$ac_cv_enable_pgpcore_plugin" = xyes; then
 811                 PLUGINS="pgpcore $PLUGINS"
 812                 AM_PATH_GPGME(1.1.1,
 813                               AC_DEFINE(HAVE_GPGME_PKA_TRUST, 1,
 814                                         [Define if GPGME supports PKA.]))
 815                 #needed to get GPGME_LIBS and al correctly
 816                 AM_PATH_GPGME(1.0.0, AC_DEFINE(USE_GPGME, 1, Define if you use GPGME to support OpenPGP.),
 817                           [ac_cv_enable_pgpcore_plugin=no])
 818         else
 819                 AC_MSG_WARN([*** PGP/CORE plugin will not be built ***])
 820         fi
 821 else
 822         AC_MSG_RESULT(no)
 823 fi
 824 AM_CONDITIONAL(BUILD_PGPCORE_PLUGIN, test x"$ac_cv_enable_pgpcore_plugin" = xyes)
 825
 826 AC_MSG_CHECKING([whether to build PGP/MIME plugin])
 827 AC_ARG_ENABLE(pgpmime-plugin,
 828         [  --disable-pgpmime-plugin           do not build PGP/MIME plugin],
 829         [ac_cv_enable_pgpmime_plugin=$enableval], [ac_cv_enable_pgpmime_plugin=yes])
 830 if test x"$ac_cv_enable_pgpmime_plugin" = xyes; then
 831         AC_MSG_RESULT(yes)
 832         if test x"$ac_cv_enable_pgpcore_plugin" = xyes; then
 833                 PLUGINS="pgpmime $PLUGINS"
 834         else
 835                 AC_MSG_WARN([*** PGP/MIME plugin cannot be built ***])
 836                 AC_MSG_WARN([*** without the PGP/CORE plugin     ***])
 837         fi
 838 else
 839         AC_MSG_RESULT(no)
 840 fi
 841 AM_CONDITIONAL(BUILD_PGPMIME_PLUGIN, test x"$ac_cv_enable_pgpmime_plugin" = xyes)
 842
 843 AC_MSG_CHECKING([whether to build PGP/Inline plugin])
 844 AC_ARG_ENABLE(pgpinline-plugin,
 845         [  --disable-pgpinline-plugin           do not build PGP/Inline plugin],
 846         [ac_cv_enable_pgpinline_plugin=$enableval], [ac_cv_enable_pgpinline_plugin=yes])
 847 if test x"$ac_cv_enable_pgpinline_plugin" = xyes; then
 848         AC_MSG_RESULT(yes)
 849         if test x"$ac_cv_enable_pgpcore_plugin" = xyes; then
 850                 PLUGINS="pgpinline $PLUGINS"
 851         else
 852                 AC_MSG_WARN([*** PGP/Inline plugin cannot be built ***])
 853                 AC_MSG_WARN([*** without the PGP/CORE plugin     ***])
 854         fi
 855 else
 856         AC_MSG_RESULT(no)
 857 fi
 858 AM_CONDITIONAL(BUILD_PGPINLINE_PLUGIN, test x"$ac_cv_enable_pgpinline_plugin" = xyes)
 859
 860 dnl --- Dillo Viewer ---
 861 AC_MSG_CHECKING([whether to build Dillo plugin])
 862 AC_ARG_ENABLE(dillo-viewer-plugin,
 863         [  --disable-dillo-viewer-plugin     do not build Dillo plugin for html mail rendering],
 864         [ac_cv_enable_dillo_viewer_plugin=$enableval], [ac_cv_enable_dillo_viewer_plugin=yes])
 865 if test x"$ac_cv_enable_dillo_viewer_plugin" = xyes; then
 866         AC_MSG_RESULT(yes)
 867         PLUGINS="dillo-viewer $PLUGINS"
 868 else
 869         AC_MSG_RESULT(no)
 870 fi
 871 AM_CONDITIONAL(BUILD_DILLO_VIEWER_PLUGIN, test x"$ac_cv_enable_dillo_viewer_plugin" = xyes)
 872
 873 dnl --- Demo ---
 874 AC_ARG_ENABLE(demo-plugin,
 875         [  --enable-demo-plugin              build demo plugin],
 876         [ac_cv_enable_demo_plugin=$enableval], [ac_cv_enable_demo_plugin=no])
 877 if test x"$ac_cv_enable_demo_plugin" = xyes; then
 878         PLUGINS="demo $PLUGINS"
 879 fi
 880 AM_CONDITIONAL(BUILD_DEMO_PLUGIN, test x"$ac_cv_enable_demo_plugin" = xyes)
 881
 882 dnl Libetpan
 883 AC_MSG_CHECKING([whether to use libetpan])
 884 AC_ARG_ENABLE(libetpan,
 885         [  --disable-libetpan           disable IMAP4/NNTP (libetpan) support],
 886         [ac_cv_enable_libetpan=$enableval], [ac_cv_enable_libetpan=yes])
 887 if test x"$ac_cv_enable_libetpan" = xyes; then
 888         AC_MSG_RESULT(yes)
 889         libetpan_result=no
 890         AC_PATH_PROG(libetpanconfig, [libetpan-config])
 891         if test "x$libetpanconfig" != "x"; then
 892           CPPFLAGS="$CPPFLAGS `$libetpanconfig --cflags 2>/dev/null`"
 893           AC_CHECK_HEADER(libetpan/libetpan.h, [libetpan_result=yes])
 894           if test "x$libetpan_result" = "xyes"; then
 895             AC_MSG_CHECKING([whether libetpan-config hints compiles and links fine])
 896             LIBS="$LIBS `$libetpanconfig --libs 2>/dev/null`"
 897             AC_TRY_LINK([#include <libetpan/dbstorage.h>], [db_mailstorage_init(NULL, NULL);], [libetpan_result=yes], [libetpan_result=no])
 898             AC_MSG_RESULT([$libetpan_result])
 899           fi
 900         fi
 901         if test "x$libetpan_result" = "xyes"; then
 902            LIBETPAN_CPPFLAGS="`$libetpanconfig --cflags`"
 903            LIBETPAN_LIBS="`$libetpanconfig --libs`"
 904            LIBETPAN_VERSION=`$libetpanconfig --version | sed "s/\.//g" | sed "s/-.*$//"`
 905            if test "$LIBETPAN_VERSION" -lt "049"; then
 906                 AC_MSG_RESULT([*** Claws Mail requires libetpan 0.49 or newer. See http://www.etpan.org/])
 907                 AC_MSG_RESULT([*** You can use --disable-libetpan if you don't need IMAP4 and/or NNTP support.])
 908                 AC_MSG_ERROR([libetpan 0.49 not found])
 909            fi
 910            AC_SUBST(LIBETPAN_FLAGS)
 911            AC_SUBST(LIBETPAN_LIBS)
 912            AC_DEFINE(HAVE_LIBETPAN, 1, Define if you want IMAP and/or NNTP support.)
 913         else
 914            AC_MSG_RESULT([*** Claws Mail requires libetpan 0.49 or newer. See http://www.etpan.org/ ])
 915            AC_MSG_RESULT([*** You can use --disable-libetpan if you don't need IMAP4 and/or NNTP support.])
 916            AC_MSG_ERROR([libetpan 0.49 not found])
 917         fi
 918 else
 919         AC_MSG_RESULT(no)
 920 fi
 921 AM_CONDITIONAL(CLAWS_LIBETPAN, test "x$libetpan_result" = "xyes")
 922
 923
 924 dnl Printing support.
 925 PKG_CHECK_MODULES(GTK210, gtk+-2.0 >= 2.10, ac_cv_have_gtk210=yes, ac_cv_have_gtk210=no)
 926
 927 AC_MSG_CHECKING([whether to use libgnomeprint])
 928 AC_ARG_ENABLE(gnomeprint,
 929         [  --disable-gnomeprint         disable libgnomeprint support],
 930         [ac_cv_enable_gnomeprint=$enableval], [ac_cv_enable_gnomeprint=auto])
 931
 932 if test x$ac_cv_have_gtk210 = xyes; then
 933         ac_cv_enable_gnomeprint="no"
 934 fi
 935
 936 if test x$ac_cv_enable_gnomeprint = xyes \
 937         -o \( x$ac_cv_enable_gnomeprint = xauto \
 938            -a x$ac_cv_have_gtk210 = xno \); then
 939         AC_MSG_RESULT(yes)
 940         PKG_CHECK_MODULES(GNOMEPRINT, libgnomeprint-2.2 libgnomeprintui-2.2,
 941                           ac_cv_enable_gnomeprint=yes, ac_cv_enable_gnomeprint=no)
 942         if test x"$ac_cv_enable_gnomeprint" = xyes; then
 943                 AC_DEFINE(USE_GNOMEPRINT, 1, Define if you want libgnomeprint support)
 944         else
 945                 AC_MSG_RESULT(not found)
 946                 AC_MSG_WARN([*** libgnomeprintui wasn't found    ***])
 947                 AC_MSG_WARN([*** using built-in printing support ***])
 948         fi
 949 else
 950         ac_cv_enable_gnomeprint=no
 951         AC_MSG_RESULT(no)
 952 fi
 953 AM_CONDITIONAL(CLAWS_GNOMEPRINT, test x"$ac_cv_enable_gnomeprint" = x"yes")
 954
 955 AC_MSG_CHECKING([whether to use valgrind])
 956 AC_ARG_ENABLE(valgrind,
 957         [  --disable-valgrind           disable valgrind support for debugging],
 958         [ac_cv_enable_valgrind=$enableval], [ac_cv_enable_valgrind=yes])
 959 if test x$ac_cv_enable_valgrind = xyes; then
 960         AC_MSG_RESULT(yes)
 961         PKG_CHECK_MODULES(VALGRIND, valgrind >= 2.4.0,
 962                           ac_cv_enable_valgrind=yes, ac_cv_enable_valgrind=no)
 963         if test x"$ac_cv_enable_valgrind" = xyes; then
 964                 AC_DEFINE(HAVE_VALGRIND, 1, Define if you want valgrind support)
 965         else
 966                 AC_MSG_RESULT(not found)
 967         fi
 968 else
 969         AC_MSG_RESULT(no)
 970 fi
 971 AM_CONDITIONAL(CLAWS_VALGRIND, test x"$ac_cv_enable_valgrind" = x"yes")
 972
 973 dnl ****************************
 974 dnl ** Final configure output **
 975 dnl ****************************
 976
 977 AC_OUTPUT([
 978 Makefile
 979 m4/Makefile
 980 po/Makefile.in
 981 src/common/version.h
 982 src/Makefile
 983 src/common/Makefile
 984 src/common/passcrypt.h
 985 src/gtk/Makefile
 986 src/etpan/Makefile
 987 src/plugins/Makefile
 988 src/plugins/demo/Makefile
 989 src/plugins/bogofilter/Makefile
 990 src/plugins/spamassassin/Makefile
 991 src/plugins/dillo_viewer/Makefile
 992 src/plugins/trayicon/Makefile
 993 src/plugins/trayicon/libeggtrayicon/Makefile
 994 src/plugins/pgpcore/Makefile
 995 src/plugins/pgpmime/Makefile
 996 src/plugins/pgpinline/Makefile
 997 doc/Makefile
 998 doc/man/Makefile
 999 tools/Makefile
1000 config/Makefile
1001 manual/Makefile
1002 manual/dtd/Makefile
1003 manual/dist/Makefile
1004 manual/dist/pdf/Makefile
1005 manual/dist/ps/Makefile
1006 manual/dist/html/Makefile
1007 manual/dist/txt/Makefile
1008 manual/fr/Makefile
1009 manual/fr/dist/Makefile
1010 manual/fr/dist/pdf/Makefile
1011 manual/fr/dist/ps/Makefile
1012 manual/fr/dist/html/Makefile
1013 manual/fr/dist/txt/Makefile
1014 manual/pl/Makefile
1015 manual/pl/dist/Makefile
1016 manual/pl/dist/pdf/Makefile
1017 manual/pl/dist/ps/Makefile
1018 manual/pl/dist/html/Makefile
1019 manual/pl/dist/txt/Makefile
1020 manual/es/Makefile
1021 manual/es/dist/Makefile
1022 manual/es/dist/pdf/Makefile
1023 manual/es/dist/ps/Makefile
1024 manual/es/dist/html/Makefile
1025 manual/es/dist/txt/Makefile
1026 claws-mail.pc
1027 ])
1028
1029 dnl Output the configuration summary
1030 echo ""
1031 echo "$PACKAGE $VERSION"
1032 echo ""
1033 echo "JPilot            : $ac_cv_enable_jpilot"
1034 echo "LDAP              : $ac_cv_enable_ldap"
1035 echo "OpenSSL           : $ac_cv_enable_openssl"
1036 echo "gnuTLS            : $ac_cv_enable_gnutls"
1037 echo "iconv             : $am_cv_func_iconv"
1038 echo "compface          : $ac_cv_enable_compface"
1039 echo "IPv6              : $ac_cv_enable_ipv6"
1040 echo "GNU/aspell        : $ac_cv_enable_aspell"
1041 echo "IMAP4             : $ac_cv_enable_libetpan"
1042 echo "NNTP              : $ac_cv_enable_libetpan"
1043 echo "Crash dialog      : $ac_cv_enable_crash_dialog"
1044 echo "Libgnomeprint     : $ac_cv_enable_gnomeprint"
1045 echo "GTK+ print support: $ac_cv_have_gtk210"
1046 echo "LibSM             : $ac_cv_enable_libsm"
1047 echo "NetworkManager    : $enable_networkmanager_support"
1048 echo "Manual            : $ac_cv_enable_manual"
1049 echo "Plugins           : $PLUGINS"
1050 echo "Generic UMPC code : $ac_cv_enable_generic_umpc"
1051 echo "Maemo  build      : $ac_cv_enable_maemo"
1052 echo "Config dir        : $ac_cv_with_config_dir"
1053 echo ""
1054 echo "The binary will be installed in $prefix/bin"
1055 echo ""
1056 echo "Configure finished, type 'make' to build."