configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.50)
   3 AC_INIT(src/main.c)
   4 AC_CONFIG_AUX_DIR(config)
   5
   6 PACKAGE=sylpheed-claws
   7
   8 dnl version number
   9 MAJOR_VERSION=0
  10 MINOR_VERSION=9
  11 MICRO_VERSION=12
  12 INTERFACE_AGE=0
  13 BINARY_AGE=0
  14 EXTRA_VERSION=162
  15 EXTRA_RELEASE=
  16
  17 if test \( $EXTRA_VERSION -eq 0 \) -o \( "x$EXTRA_RELEASE" != "x" \); then
  18     VERSION=${MAJOR_VERSION}.${MINOR_VERSION}.${MICRO_VERSION}${EXTRA_RELEASE}
  19 else
  20     VERSION=${MAJOR_VERSION}.${MINOR_VERSION}.${MICRO_VERSION}cvs${EXTRA_VERSION}
  21 fi
  22
  23 dnl set $target
  24 AC_CANONICAL_SYSTEM
  25
  26 dnl
  27 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  28 dnl AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
  29 dnl AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
  30 AC_SUBST(PACKAGE)
  31 AC_SUBST(VERSION)
  32 AC_SUBST(MAJOR_VERSION)
  33 AC_SUBST(MINOR_VERSION)
  34 AC_SUBST(MICRO_VERSION)
  35 AC_SUBST(EXTRA_VERSION)
  36
  37 dnl GNOME installed?
  38 AC_PATH_PROG(GNOME_CONFIG, gnome-config, no)
  39 if test "$GNOME_CONFIG" != no; then
  40         gnomedatadir="`gnome-config --datadir`"
  41         gnomeprefix="`gnome-config --prefix`"
  42         if test "${prefix}" = "NONE"; then
  43                 gnomedatadir="${ac_default_prefix}/${gnomedatadir#${gnomeprefix}}"
  44         else
  45                 gnomedatadir="${prefix}/${gnomedatadir#${gnomeprefix}}"
  46         fi
  47         AC_SUBST(gnomedatadir)
  48 fi
  49 AM_CONDITIONAL(SYLPHEED_GNOME, test -n "$gnomedatadir")
  50
  51 dnl Claws version
  52 AC_DEFINE(CLAWS, 1, Compiling Claws branch of sylpheed)
  53
  54 dnl libtool versioning
  55 LT_RELEASE=$MAJOR_VERSION.$MINOR_VERSION
  56 LT_CURRENT=`expr $MICRO_VERSION - $INTERFACE_AGE`
  57 LT_REVISION=$INTERFACE_AGE
  58 LT_AGE=`expr $BINARY_AGE - $INTERFACE_AGE`
  59 AC_SUBST(LT_RELEASE)
  60 AC_SUBST(LT_CURRENT)
  61 AC_SUBST(LT_REVISION)
  62 AC_SUBST(LT_AGE)
  63
  64 dnl Specify a header configuration file
  65 AC_CONFIG_HEADERS(config.h)
  66
  67 AM_MAINTAINER_MODE
  68
  69 dnl Checks for programs.
  70 dnl AC_ARG_PROGRAM
  71 AC_PROG_CC
  72 AC_ISC_POSIX
  73 AC_PROG_INSTALL
  74 AC_PROG_LN_S
  75 AC_PROG_MAKE_SET
  76 AC_PROG_CPP
  77 dnl AC_PROG_RANLIB
  78 AM_PROG_LEX
  79 AC_PROG_YACC
  80 AC_PROG_LIBTOOL
  81
  82 SYLPHEED_ACLOCAL_INCLUDE(m4)
  83
  84 case "$target" in
  85 *-darwin*)
  86         CFLAGS="$CFLAGS -traditional-cpp -fno-common"
  87         ;;
  88 esac
  89
  90 AM_ICONV
  91
  92 dnl for gettext
  93 ALL_LINGUAS="bg cs de el en_GB es fr hr hu it ja ko nl pl pt_BR ru sk sr sv zh_CN zh_TW.Big5"
  94 AM_GNU_GETTEXT([use-libtool])
  95 AM_GNU_GETTEXT_VERSION(0.12.1)
  96 dnl AC_CHECK_FUNC(gettext, AC_CHECK_LIB(intl, gettext))
  97 localedir='${datadir}/locale'
  98 AC_SUBST(localedir)
  99
 100 manualdir='${prefix}/${DATADIRNAME}/${PACKAGE}/manual'
 101 AC_SUBST(manualdir)
 102 faqdir='${prefix}/${DATADIRNAME}/${PACKAGE}/faq'
 103 AC_SUBST(faqdir)
 104
 105 dnl Set PACKAGE_DATA_DIR in config.h.
 106 if test "x${datadir}" = 'x${prefix}/share'; then
 107   if test "x${prefix}" = "xNONE"; then
 108     AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${ac_default_prefix}/share/${PACKAGE}", PACKAGE_DATA_DIR)
 109   else
 110     AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${prefix}/share/${PACKAGE}", PACKAGE_DATA_DIR)
 111   fi
 112 else
 113   AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${datadir}/${PACKAGE}", PACKAGE_DATA_DIR)
 114 fi
 115
 116 AC_CHECK_LIB(xpg4, setlocale)
 117
 118 dnl for GThread support (currently disabled)
 119 dnl AC_ARG_ENABLE(threads,
 120 dnl     [  --enable-threads        Enable multithread support [default=no]],
 121 dnl     [use_threads=$enableval], [use_threads=no])
 122
 123 AC_MSG_CHECKING([whether to use threads])
 124 if test x"$use_threads" = xyes ; then
 125         AC_MSG_RESULT(yes)
 126         if test ! -z `$GLIB_CONFIG --help 2>&1 |grep 'gthread'` ; then
 127                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
 128                 LIBS="$LIBS `$GLIB_CONFIG --libs gthread`"
 129                 AC_DEFINE(USE_THREADS, 1, Whether to use multithread or not)
 130         else
 131                 AC_MSG_ERROR([Sylpheed requires GThread from GLib to use threading.])
 132         fi
 133 else
 134         AC_MSG_RESULT(no)
 135 fi
 136
 137 dnl Check for d_type member in struct dirent
 138 AC_MSG_CHECKING([whether struct dirent has d_type member])
 139 AC_CACHE_VAL(ac_cv_dirent_d_type,[
 140         AC_TRY_COMPILE([#include <dirent.h>],
 141                        [struct dirent d; d.d_type = DT_REG;],
 142                        ac_cv_dirent_d_type=yes, ac_cv_dirent_d_type=no)
 143 ])
 144 AC_MSG_RESULT($ac_cv_dirent_d_type)
 145 if test $ac_cv_dirent_d_type = yes; then
 146         AC_DEFINE(HAVE_DIRENT_D_TYPE, 1,
 147                   Define if `struct dirent' has `d_type' member.)
 148 fi
 149
 150 dnl Checks for header files.
 151 AC_HEADER_DIRENT
 152 AC_HEADER_STDC
 153 AC_HEADER_SYS_WAIT
 154 AC_CHECK_HEADERS(fcntl.h sys/file.h unistd.h paths.h \
 155                  sys/param.h sys/utsname.h sys/select.h \
 156                  wchar.h wctype.h locale.h)
 157
 158 dnl alf - Check for apache installation f*ck up. apache may also install an
 159 dnl fnmatch, which includes their own regex stuff if USE_HSREGEX is defined
 160 AC_TRY_COMPILE([#include <stdlib.h>
 161                 #include <fnmatch.h>],
 162         [int x = USE_HSREGEX;],
 163         ac_cv_have_apache_fnmatch=yes, ac_cv_have_apache_fnmatch=no)
 164 if test $ac_cv_have_apache_fnmatch = yes; then
 165         AC_DEFINE(HAVE_APACHE_FNMATCH, 1, Define if you need to work around apache regex/fnmatch !KLUDGE!)
 166 fi
 167 AC_MSG_CHECKING([whether to use Apache regex header kludge])
 168 AC_MSG_RESULT($ac_cv_have_apache_fnmatch)
 169
 170 dnl Checks for typedefs, structures, and compiler characteristics.
 171 AC_C_CONST
 172 AC_TYPE_OFF_T
 173 AC_TYPE_PID_T
 174 AC_TYPE_SIZE_T
 175 AC_STRUCT_TM
 176
 177 dnl AC_CHECK_TYPE(wint_t, unsigned int) does not work because wint_t
 178 dnl may be defined only in wchar.h (this happens with gcc-2.96).
 179 dnl So we need to use this extended macro.
 180 SYLPHEED_CHECK_TYPE(wint_t, unsigned int,
 181 [
 182 #if HAVE_WCHAR_H
 183 #include <wchar.h>
 184 #endif
 185 ], Define to `unsigned int' if <stddef.h> or <wchar.h> doesn't define.)
 186
 187 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF, Used to test for a u32 typedef)
 188 AC_CHECK_SIZEOF(unsigned short, 2)
 189 AC_CHECK_SIZEOF(unsigned int, 4)
 190 AC_CHECK_SIZEOF(unsigned long, 4)
 191
 192 dnl Checks for library functions.
 193 AC_FUNC_ALLOCA
 194 AC_CHECK_FUNCS(gethostname mkdir mktime socket strstr strchr \
 195                wcsstr wcswcs iswalnum iswspace towlower \
 196                wcslen wcscpy wcsncpy \
 197                uname flock lockf inet_aton inet_addr \
 198                fchmod mkstemp)
 199
 200 dnl *****************
 201 dnl ** common code **
 202 dnl *****************
 203
 204 dnl check for glib
 205 AM_PATH_GLIB(1.2.6,,
 206         AC_MSG_ERROR(Test for GLIB failed. See the file 'INSTALL' for help.),
 207         gthread)
 208
 209 dnl check for IPv6 option
 210 AC_ARG_ENABLE(ipv6,
 211         [  --disable-ipv6           Disable IPv6 support],
 212         [ac_cv_enable_ipv6=$enableval], [ac_cv_enable_ipv6=yes])
 213
 214 dnl automated checks for IPv6 support.
 215 AC_MSG_CHECKING([whether to use IPv6])
 216 if test x"$ac_cv_enable_ipv6" = xyes; then
 217         AC_MSG_RESULT(yes)
 218         AC_MSG_CHECKING([for IPv6 support])
 219         AC_CACHE_VAL(ac_cv_ipv6,[
 220                 AC_TRY_COMPILE([#define INET6
 221                                 #include <sys/types.h>
 222                                 #include <netinet/in.h>],
 223                         [int x = IPPROTO_IPV6; struct in6_addr a;],
 224                         ac_cv_ipv6=yes, ac_cv_ipv6=no)
 225         ])
 226         AC_MSG_RESULT($ac_cv_ipv6)
 227         if test $ac_cv_ipv6 = yes; then
 228                 AC_DEFINE(INET6, 1, Define if you want IPv6 support.)
 229         else
 230                 AC_MSG_WARN(*** IPv6 will not be supported ***)
 231                 ac_cv_enable_ipv6=no
 232         fi
 233 else
 234         AC_MSG_RESULT(no)
 235 fi
 236
 237 dnl Check for OpenSSL
 238 AC_ARG_ENABLE(openssl,
 239         [  --enable-openssl    Attempt to use OpenSSL for SSL support.],
 240         [ac_cv_enable_openssl=$enableval], [ac_cv_enable_openssl=yes])
 241 if test x"$ac_cv_enable_openssl" = xyes; then
 242         PKG_CHECK_MODULES(OPENSSL, openssl >= 0.9.7, :, ac_cv_enable_openssl=no)
 243         if test x$ac_cv_enable_openssl = xyes; then
 244                 AC_DEFINE(USE_OPENSSL, 1, Define if you want OpenSSL support)
 245         fi
 246 fi
 247 AC_SUBST(OPENSSL_CFLAGS)
 248 AC_SUBST(OPENSSL_LIBS)
 249
 250 dnl password encryption
 251 OLDLIBS=$LIBS
 252 LIBS=
 253 AC_SEARCH_LIBS(encrypt, crypt, [], AC_MSG_ERROR(['encrypt'-function not found.]))
 254 CRYPT_LIBS=$LIBS
 255 AC_SUBST(CRYPT_LIBS)
 256 LIBS=$OLDLIBS
 257
 258 AC_ARG_WITH(passcrypt-key, [  --with-passcrypt-key=KEY     Key used to encode passwords (8 byte string)],
 259             with_passcrypt_key="$withval", with_passcrypt_key="passkey0")
 260 AC_SUBST(PASSCRYPT_KEY, $with_passcrypt_key)
 261
 262 dnl RC dir (will be default at a certain point in time)
 263 AC_ARG_WITH(config-dir,    [  --with-config-dir=RCDIR      Local configuration dir (default: .sylpheed)],
 264               ac_cv_with_config_dir="$withval", ac_cv_with_config_dir=".sylpheed")
 265 if test x"$ac_cv_with_config_dir" = x""; then
 266         ac_cv_with_config_dir=".sylpheed"
 267 fi
 268 AC_DEFINE_UNQUOTED(CFG_RC_DIR, "$ac_cv_with_config_dir", Configuration directory)
 269
 270 dnl ************************
 271 dnl ** GTK user interface **
 272 dnl ************************
 273
 274 dnl Checks for GTK
 275 AM_PATH_GTK(1.2.6,,
 276         AC_MSG_ERROR(Test for GTK failed. See the file 'INSTALL' for help.))
 277
 278 dnl check if gdk / gtk was compiled with USE_XIM
 279 AC_MSG_CHECKING([whether GTK was compiled with XIM support])
 280 CFLAGS_SAVE="$CFLAGS"
 281 LDFLAGS_SAVE="$LDFLAGS"
 282 CFLAGS="$CFLAGS `$GTK_CONFIG --cflags`"
 283 LDFLAGS="$LDFLAGS `$GTK_CONFIG --libs`"
 284 AC_CACHE_VAL(ac_cv_use_xim, [
 285         AC_TRY_LINK_FUNC([gdk_ic_attr_new],
 286                          ac_cv_use_xim=yes, ac_cv_use_xim=no)
 287 ])
 288 AC_MSG_RESULT($ac_cv_use_xim)
 289 if test $ac_cv_use_xim = yes; then
 290         AC_DEFINE(USE_XIM, 1, Whether GTK was compiled with XIM support or not)
 291 fi
 292 CFLAGS="$CFLAGS_SAVE"
 293 LDFLAGS="$LDFLAGS_SAVE"
 294
 295 dnl GNU/Aspell is used for spell checking
 296 AC_ARG_ENABLE(aspell,
 297         [  --enable-aspell         Enable GNU/aspell support [default=no]],
 298         [ac_cv_enable_aspell=$enableval], [ac_cv_enable_aspell=no])
 299 AC_MSG_CHECKING([whether to use GNU/aspell])
 300 if test $ac_cv_enable_aspell = yes; then
 301         AC_MSG_RESULT(yes)
 302         AM_PATH_ASPELL(0.50, AC_DEFINE(USE_ASPELL, 1, Define if you use ASPELL to support spell checking),
 303                       [use_aspell=no ac_cv_enable_aspell=no])
 304 else
 305         AC_MSG_RESULT(no)
 306 fi
 307
 308 dnl want crash dialog
 309 AC_ARG_ENABLE(crash-dialog,
 310         [  --enable-crash-dialog   Enable crash dialog [default=no]],
 311         [ac_cv_enable_crash_dialog=$enableval], [ac_cv_enable_crash_dialog=no])
 312 if test $ac_cv_enable_crash_dialog = yes; then
 313 dnl check if GDB is somewhere
 314         AC_CHECK_PROG(ac_cv_enable_crash_dialog, gdb, yes, no)
 315         AC_MSG_CHECKING([whether to use crash dialog])
 316         if test $ac_cv_enable_crash_dialog = yes; then
 317                 AC_DEFINE(CRASH_DIALOG, 1, Pop up crash dialog)
 318         fi
 319         AC_MSG_RESULT($ac_cv_enable_crash_dialog)
 320 fi
 321
 322 dnl Check for X-Face support
 323 AC_ARG_ENABLE(compface,
 324         [  --disable-compface      Do not use compface (X-Face)],
 325         [ac_cv_enable_compface=$enableval], [ac_cv_enable_compface=yes])
 326 AC_MSG_CHECKING([whether to use compface])
 327 if test x"$ac_cv_enable_compface" = xyes; then
 328         AC_MSG_RESULT(yes)
 329         AC_CHECK_LIB(compface, uncompface,
 330                 [AC_DEFINE(HAVE_LIBCOMPFACE, 1, Define if you want compface support.)],
 331                 [ac_cv_enable_compface=no])
 332         if test x"$ac_cv_enable_compface" = xyes; then
 333                 COMPFACE_LIBS="-lcompface"
 334         else
 335                 COMPFACE_LIBS=""
 336         fi
 337         AC_SUBST(COMPFACE_LIBS)
 338 else
 339         AC_MSG_RESULT(no)
 340 fi
 341
 342 dnl check for pthread support
 343 AC_ARG_ENABLE(pthread,
 344         [  --disable-pthread           Disable pthread support],
 345         [ac_cv_enable_pthread=$enableval], [ac_cv_enable_pthread=yes])
 346 AC_MSG_CHECKING([whether to use pthread])
 347 if test x$ac_cv_enable_pthread = xno; then
 348         AC_MSG_RESULT(no)
 349 else
 350         AC_MSG_RESULT(yes)
 351
 352         AC_CHECK_LIB(pthread, pthread_create, :, ac_cv_enable_pthread=no)
 353         AC_CHECK_HEADERS(pthread.h, :, ac_cv_enable_pthread=no)
 354
 355         if test x$ac_cv_enable_pthread = xyes; then
 356                 AC_DEFINE(USE_PTHREAD, 1, Define if you have pthread)
 357                 PTHREAD_LIBS="-lpthread"
 358         fi
 359
 360 fi
 361 AC_SUBST(PTHREAD_LIBS)
 362
 363 dnl for LDAP support in addressbook
 364 dnl no check for libraries; dynamically loaded
 365 AC_ARG_ENABLE(ldap,
 366         [  --enable-ldap           Enable LDAP support [default=no]],
 367         [ac_cv_enable_ldap=$enableval], [ac_cv_enable_ldap=no])
 368 AC_MSG_CHECKING([whether to use LDAP])
 369 if test x"$ac_cv_enable_ldap" = xno; then
 370         AC_MSG_RESULT(no)
 371 elif test x"$ac_cv_enable_ldap" = xyes -a x"$ac_cv_enable_pthread" = xno; then
 372         AC_MSG_RESULT(no - LDAP support needs pthread support)
 373
 374         ac_cv_enable_ldap=no
 375 else
 376         AC_MSG_RESULT(yes)
 377
 378         dnl check for available libraries, and pull them in
 379         AC_CHECK_LIB(resolv, res_query, LDAP_LIBS="$LDAP_LIBS -lresolv")
 380         AC_CHECK_LIB(socket, bind, LDAP_LIBS="$LDAP_LIBS -lsocket")
 381         AC_CHECK_LIB(nsl, gethostbyaddr, LDAP_LIBS="$LDAP_LIBS -lnsl")
 382         AC_CHECK_LIB(lber, ber_get_tag, LDAP_LIBS="$LDAP_LIBS -llber",,
 383                      $LDAP_LIBS)
 384
 385         AC_CHECK_HEADERS(ldap.h lber.h,
 386                          [ ac_cv_enable_ldap=yes ],
 387                          [ ac_cv_enable_ldap=no ])
 388
 389         if test "$ac_cv_enable_ldap" = yes; then
 390                 AC_CHECK_LIB(ldap, ldap_open,
 391                              [ ac_cv_enable_ldap=yes ],
 392                              [ ac_cv_enable_ldap=no ],
 393                              $LDAP_LIBS)
 394
 395                 AC_CHECK_LIB(ldap, ldap_start_tls_s,
 396                              [ ac_cv_have_tls=yes ],
 397                              [ ac_cv_have_tls=no ])
 398
 399         fi
 400
 401         AC_MSG_CHECKING([whether ldap library is available])
 402         AC_MSG_RESULT($ac_cv_enable_ldap)
 403
 404         AC_MSG_CHECKING([whether TLS library is available])
 405         AC_MSG_RESULT($ac_cv_have_tls)
 406
 407         if test "$ac_cv_enable_ldap" = yes; then
 408                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
 409                 LDAP_LIBS="$LDAP_LIBS -lldap `$GLIB_CONFIG --libs gthread`"
 410                 AC_DEFINE(USE_LDAP, 1, Define if you want LDAP support in addressbook.)
 411                 AC_SUBST(LDAP_LIBS)
 412                 if test "$ac_cv_have_tls" = yes; then
 413                         AC_DEFINE(USE_LDAP_TLS, 1, Define if you want LDAP TLS support in addressbook.)
 414                 fi
 415         fi
 416 fi
 417
 418 dnl for JPilot support in addressbook
 419 dnl no check for libraries; these are dynamically loaded
 420 AC_ARG_ENABLE(jpilot,
 421         [  --enable-jpilot         Enable JPilot support [default=no]],
 422         [ac_cv_enable_jpilot=$enableval], [ac_cv_enable_jpilot=no])
 423 AC_MSG_CHECKING([whether to use JPilot])
 424 if test "$ac_cv_enable_jpilot" = yes; then
 425         AC_MSG_RESULT(yes)
 426         AC_CHECK_HEADERS(pi-args.h pi-appinfo.h pi-address.h,
 427                          [ AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ],
 428                          [ ac_cv_enable_jpilot=no ])
 429         if test "$ac_cv_enable_jpilot" = no; then
 430                 AC_CHECK_HEADERS(libpisock/pi-args.h libpisock/pi-appinfo.h libpisock/pi-address.h,
 431                                  [ ac_cv_enable_jpilot=yes
 432                                    AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ])
 433         fi
 434
 435         AC_CHECK_LIB(pisock, unpack_Address, [JPILOT_LIBS="-lpisock"], [JPILOT_LIBS="" ac_cv_enable_jpilot="no"])
 436         if test x"$ac_cv_enable_jpilot" = xyes; then
 437                 AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.)
 438         else
 439                 AC_MSG_NOTICE([JPilot support not available])
 440         fi
 441         AC_SUBST(JPILOT_LIBS)
 442 else
 443         AC_MSG_RESULT(no)
 444 fi
 445
 446 dnl GPGME is used to support OpenPGP
 447 AC_ARG_ENABLE(gpgme,
 448         [  --enable-gpgme          Enable GnuPG support using GPGME [default=no]],
 449         [ac_cv_enable_gpgme=$enableval], [ac_cv_enable_gpgme=no])
 450 AC_MSG_CHECKING([whether to use GPGME])
 451 if test $ac_cv_enable_gpgme = yes; then
 452         AC_MSG_RESULT(yes)
 453         AM_PATH_GPGME(0.3.10, AC_DEFINE(USE_GPGME, 1, Define if you use GPGME to support OpenPGP.),
 454                       [use_gpgme=no
 455                        ac_cv_enable_gpgme=no])
 456 else
 457         AC_MSG_RESULT(no)
 458 fi
 459
 460 dnl #######################################################################
 461 dnl # Check for startup notification
 462 dnl #######################################################################
 463 AC_ARG_ENABLE(startup-notification, [  --disable-startup-notification    compile without startup notification support],,enable_startup_notification=yes)
 464
 465 if test "x$enable_startup_notification" = "xyes"; then
 466         PKG_CHECK_MODULES(STARTUP_NOTIFICATION, libstartup-notification-1.0 >= 0.5,
 467         [
 468                 AC_DEFINE(HAVE_STARTUP_NOTIFICATION, 1, [Define if we're using libstartup-notification.])
 469                 echo "Building with libstartup-notification"
 470                 enable_startup_notification=yes
 471         ],
 472         [
 473                 echo "Building without libstartup-notification"
 474                 enable_startup_notification=no
 475         ])
 476
 477         AC_SUBST(STARTUP_NOTIFICATION_CFLAGS)
 478         AC_SUBST(STARTUP_NOTIFICATION_LIBS)
 479 fi
 480
 481 dnl *************************
 482 dnl ** section for plugins **
 483 dnl *************************
 484
 485 PLUGINS=""
 486
 487 dnl --- Trayicon ---
 488 AC_ARG_ENABLE(trayicon-plugin,
 489         [  --disable-trayicon-plugin         Do not build System Tray Icon plugin],
 490         [ac_cv_enable_trayicon_plugin=$enableval], [ac_cv_enable_trayicon_plugin=yes])
 491 if test x"$ac_cv_enable_trayicon_plugin" = xyes; then
 492         PLUGINS="trayicon $PLUGINS"
 493 fi
 494 AM_CONDITIONAL(BUILD_TRAYICON_PLUGIN, test x"$ac_cv_enable_trayicon_plugin" = xyes)
 495
 496 dnl --- SpamAssassin ---
 497 AC_ARG_ENABLE(spamassassin-plugin,
 498         [  --enable-spamassassin-plugin      Build SpamAssassin plugin [default=no]],
 499         [ac_cv_enable_spamassassin_plugin=$enableval], [ac_cv_enable_spamassassin_plugin=no])
 500 if test x"$ac_cv_enable_spamassassin_plugin" = xyes; then
 501         AC_SPAMASSASSIN
 502         PLUGINS="spamassassin $PLUGINS"
 503 fi
 504 AM_CONDITIONAL(BUILD_SPAMASSASSIN_PLUGIN, test x"$ac_cv_enable_spamassassin_plugin" = xyes)
 505
 506 dnl --- PGP/MIME ---
 507 AC_ARG_ENABLE(pgpmime-plugin,
 508         [  --disable-pgpmime-plugin           Do not build PGP/MIME plugin],
 509         [ac_cv_enable_pgpmime_plugin=$enableval], [ac_cv_enable_pgpmime_plugin=yes])
 510 if test x"$ac_cv_enable_pgpmime_plugin" = xyes; then
 511         if test x"$ac_cv_enable_gpgme" != xyes; then
 512                 ac_cv_enable_pgpmime_plugin=no
 513         fi
 514
 515         if test x"$ac_cv_enable_pgpmime_plugin" = xyes; then
 516                 PLUGINS="pgpmime $PLUGINS"
 517         fi
 518 fi
 519 AM_CONDITIONAL(BUILD_PGPMIME_PLUGIN, test x"$ac_cv_enable_pgpmime_plugin" = xyes)
 520
 521 dnl --- MathML Viewer ---
 522 AC_ARG_ENABLE(mathml-viewer-plugin,
 523         [  --disable-mathml-viewer-plugin    Do not build MathML-Viewer plugin],
 524         [ac_cv_enable_mathml_viewer_plugin=$enableval], [ac_cv_enable_mathml_viewer_plugin=yes])
 525 if test x"$ac_cv_enable_mathml_viewer_plugin" = xyes; then
 526         PKG_CHECK_MODULES(GTK_MATH_VIEW, gtkmathview >= 0.4.2 gtkmathview < 0.5, :, ac_cv_enable_mathml_viewer_plugin=no)
 527
 528         if test x"$ac_cv_enable_mathml_viewer_plugin" = xyes; then
 529
 530                 PLUGINS="mathml-viewer $PLUGINS"
 531         fi
 532 fi
 533 AC_SUBST(GTK_MATH_VIEW_CFLAGS)
 534 AC_SUBST(GTK_MATH_VIEW_LIBS)
 535 AM_CONDITIONAL(BUILD_MATHML_VIEWER_PLUGIN, test x"$ac_cv_enable_mathml_viewer_plugin" = xyes)
 536
 537 dnl --- Image Viewer ---
 538 AC_ARG_ENABLE(image-viewer-plugin,
 539         [  --disable-image-viewer-plugin     Do not build image viewer plugin],
 540         [ac_cv_enable_image_viewer_plugin=$enableval], [ac_cv_enable_image_viewer_plugin=yes])
 541 if test x"$ac_cv_enable_image_viewer_plugin" = xyes; then
 542         AC_ARG_ENABLE(gdk-pixbuf,
 543                 [  --disable-gdk-pixbuf              Do not use gdk-pixbuf],
 544                 [ac_cv_enable_gdk_pixbuf=$enableval], [ac_cv_enable_gdk_pixbuf=yes])
 545         AC_ARG_ENABLE(imlib,
 546                 [  --disable-imlib                   Do not use imlib],
 547                 [ac_cv_enable_imlib=$enableval], [ac_cv_enable_imlib=yes])
 548
 549         if test "$ac_cv_enable_gdk_pixbuf" = yes; then
 550                 AM_PATH_GDK_PIXBUF(0.8.0,
 551                         [AC_DEFINE(HAVE_GDK_PIXBUF, 1, Define if you use gdk-pixbuf to support image viewer)
 552                          ac_cv_enable_imlib=no], [ac_cv_enable_gdk_pixbuf=no])
 553         fi
 554         if test "$ac_cv_enable_imlib" = yes; then
 555                 AM_PATH_GDK_IMLIB(1.9,
 556                         AC_DEFINE(HAVE_GDK_IMLIB, 1, Define if you use gdk_imlib to support image viewer),
 557                         [ac_cv_enable_imlib=no])
 558         fi
 559
 560         if test "$ac_cv_enable_gdk_pixbuf" = yes; then
 561                 PLUGINS="image-viewer(gdk-pixbuf) $PLUGINS"
 562         elif test "$ac_cv_enable_imlib" = yes; then
 563                 PLUGINS="image-viewer(gdk_imlib) $PLUGINS"
 564         else
 565                 ac_cv_enable_image_viewer_plugin=no
 566         fi
 567 fi
 568 AM_CONDITIONAL(BUILD_IMAGE_VIEWER_PLUGIN, test x"$ac_cv_enable_image_viewer_plugin" = xyes)
 569
 570 dnl --- Dillo Viewer ---
 571 AC_ARG_ENABLE(dillo-viewer-plugin,
 572         [  --disable-dillo-viewer-plugin     Do not build Dillo plugin for html mail rendering],
 573         [ac_cv_enable_dillo_viewer_plugin=$enableval], [ac_cv_enable_dillo_viewer_plugin=yes])
 574 if test x"$ac_cv_enable_dillo_viewer_plugin" = xyes; then
 575         PLUGINS="dillo-viewer $PLUGINS"
 576 fi
 577 AM_CONDITIONAL(BUILD_DILLO_VIEWER_PLUGIN, test x"$ac_cv_enable_dillo_viewer_plugin" = xyes)
 578
 579 dnl --- Demo ---
 580 AC_ARG_ENABLE(demo-plugin,
 581         [  --enable-demo-plugin              Build demo plugin [default=no]],
 582         [ac_cv_enable_demo_plugin=$enableval], [ac_cv_enable_demo_plugin=no])
 583 if test x"$ac_cv_enable_demo_plugin" = xyes; then
 584         PLUGINS="demo $PLUGINS"
 585 fi
 586 AM_CONDITIONAL(BUILD_DEMO_PLUGIN, test x"$ac_cv_enable_demo_plugin" = xyes)
 587
 588 dnl --- ClamAV ---
 589 AC_ARG_ENABLE(clamav-plugin,
 590         [  --disable-clamav-plugin           Do not build Clam AntiVirus plugin],
 591         [ac_cv_enable_clamav_plugin=$enableval], [ac_cv_enable_clamav_plugin=yes])
 592 if test x"$ac_cv_enable_clamav_plugin" = xyes; then
 593         AC_CHECK_LIB(clamav, cl_scanfile, clamav_lib=-lclamav, ac_cv_enable_clamav_plugin=no)
 594         AC_CHECK_HEADERS(clamav.h, :, ac_cv_enable_clamav_plugin=no)
 595         if test x"$ac_cv_enable_clamav_plugin" = xyes; then
 596                 CLAMAV_LIBS="${clamav_lib}"
 597
 598                 PLUGINS="clamav $PLUGINS"
 599         else
 600                 AC_MSG_NOTICE([clamav library not found, will not build clamav plugin])
 601         fi
 602 fi
 603 AC_SUBST(CLAMAV_LIBS)
 604 AM_CONDITIONAL(BUILD_CLAMAV_PLUGIN, test x"$ac_cv_enable_clamav_plugin" = xyes)
 605
 606 dnl ****************************
 607 dnl ** Final configure output **
 608 dnl ****************************
 609
 610 AC_OUTPUT([
 611 Makefile
 612 sylpheed.spec
 613 intl/Makefile
 614 m4/Makefile
 615 po/Makefile.in
 616 src/common/version.h
 617 src/Makefile
 618 src/common/Makefile
 619 src/common/passcrypt.h
 620 src/gtk/Makefile
 621 src/plugins/Makefile
 622 src/plugins/demo/Makefile
 623 src/plugins/spamassassin/Makefile
 624 src/plugins/mathml_viewer/Makefile
 625 src/plugins/dillo_viewer/Makefile
 626 src/plugins/image_viewer/Makefile
 627 src/plugins/trayicon/Makefile
 628 src/plugins/trayicon/libeggtrayicon/Makefile
 629 src/plugins/clamav/Makefile
 630 src/plugins/pgpmime/Makefile
 631 doc/Makefile
 632 doc/faq/Makefile
 633 doc/faq/de/Makefile
 634 doc/faq/en/Makefile
 635 doc/faq/es/Makefile
 636 doc/faq/fr/Makefile
 637 doc/faq/it/Makefile
 638 doc/man/Makefile
 639 doc/manual/Makefile
 640 doc/manual/de/Makefile
 641 doc/manual/en/Makefile
 642 doc/manual/es/Makefile
 643 doc/manual/fr/Makefile
 644 doc/manual/ja/Makefile
 645 tools/Makefile
 646 config/Makefile
 647 sylpheed-claws.pc
 648 ])
 649
 650 dnl Output the configuration summary
 651 echo ""
 652 echo "$PACKAGE $VERSION"
 653 echo ""
 654 echo "GnuPG         : $ac_cv_enable_gpgme"
 655 echo "JPilot        : $ac_cv_enable_jpilot"
 656 echo "LDAP          : $ac_cv_enable_ldap"
 657 echo "OpenSSL       : $ac_cv_enable_openssl"
 658 echo "iconv         : $am_cv_func_iconv"
 659 echo "compface      : $ac_cv_enable_compface"
 660 echo "IPv6          : $ac_cv_enable_ipv6"
 661 echo "GNU/aspell    : $ac_cv_enable_aspell"
 662 echo "Crash dialog  : $ac_cv_enable_crash_dialog"
 663 echo "Plugins       : $PLUGINS"
 664 echo "Config dir    : $ac_cv_with_config_dir"
 665 echo ""
 666 echo "The binary will be installed in $prefix/bin"
 667 echo ""
 668 echo "Configure finished, type 'make' to build."