2011-10-07 [colin] 3.7.10cvs21
[claws.git] / configure.ac
1
2 AC_PREREQ(2.59)
3 AC_INIT(src/main.c)
4 AC_CONFIG_AUX_DIR(config)
5 AC_CONFIG_MACRO_DIR([m4])
6
7 PACKAGE=claws-mail
8
9 dnl version number
10 MAJOR_VERSION=3
11 MINOR_VERSION=7
12 MICRO_VERSION=10
13 INTERFACE_AGE=0
14 BINARY_AGE=0
15 EXTRA_VERSION=21
16 EXTRA_RELEASE=
17 EXTRA_GTK2_VERSION=
18
19 if test \( $EXTRA_VERSION -eq 0 \) -o \( "x$EXTRA_RELEASE" != "x" \); then
20     VERSION=${MAJOR_VERSION}.${MINOR_VERSION}.${MICRO_VERSION}${EXTRA_RELEASE}${EXTRA_GTK2_VERSION}
21 else
22     VERSION=${MAJOR_VERSION}.${MINOR_VERSION}.${MICRO_VERSION}cvs${EXTRA_VERSION}${EXTRA_GTK2_VERSION}
23 fi
24
25 dnl set $target
26 AC_CANONICAL_SYSTEM
27
28 dnl
29 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
30 dnl AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
31 dnl AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
32 AC_SUBST(PACKAGE)
33 AC_SUBST(VERSION)
34 AC_SUBST(MAJOR_VERSION)
35 AC_SUBST(MINOR_VERSION)
36 AC_SUBST(MICRO_VERSION)
37 AC_SUBST(EXTRA_VERSION)
38
39 dnl GNOME installed?
40 AC_PATH_PROG(GNOME_CONFIG, gnome-config, no)
41 if test "$GNOME_CONFIG" != no; then
42         gnomedatadir="`gnome-config --datadir`"
43         gnomeprefix="`gnome-config --prefix`"
44         if test "${prefix}" = "NONE"; then
45                 gnomedatadir="${ac_default_prefix}/${gnomedatadir#${gnomeprefix}}"
46         else
47                 gnomedatadir="${prefix}/${gnomedatadir#${gnomeprefix}}"
48         fi
49         AC_SUBST(gnomedatadir)
50 fi
51 AM_CONDITIONAL(CLAWS_GNOME, test -n "$gnomedatadir")
52
53 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
54 if test x$PKG_CONFIG = xno ; then
55   AC_MSG_ERROR([*** pkg-config not found. See http://www.freedesktop.org/software/pkgconfig/])
56 fi
57
58 dnl GNOME 2.x installed?
59 PKG_CHECK_MODULES(GNOME2, libgnome-2.0 >= 2.0, ac_enable_gnome2=yes, ac_enable_gnome2=no)
60 AM_CONDITIONAL(CLAWS_GNOME2, test x"$ac_enable_gnome2" = x"yes")
61
62 dnl libtool versioning
63 LT_RELEASE=$MAJOR_VERSION.$MINOR_VERSION
64 LT_CURRENT=`expr $MICRO_VERSION - $INTERFACE_AGE`
65 LT_REVISION=$INTERFACE_AGE
66 LT_AGE=`expr $BINARY_AGE - $INTERFACE_AGE`
67 AC_SUBST(LT_RELEASE)
68 AC_SUBST(LT_CURRENT)
69 AC_SUBST(LT_REVISION)
70 AC_SUBST(LT_AGE)
71
72 dnl Specify a header configuration file
73 AC_CONFIG_HEADERS(config.h)
74
75 AM_MAINTAINER_MODE
76
77 dnl Checks for programs.
78 dnl AC_ARG_PROGRAM
79 AC_PROG_CC
80 AC_ISC_POSIX
81 AC_PROG_INSTALL
82 AC_PROG_LN_S
83 AC_PROG_MAKE_SET
84 AC_PROG_CPP
85 dnl AC_PROG_RANLIB
86 AM_PROG_LEX
87 AC_PROG_YACC
88 AC_LIB_PREFIX
89 AC_LIBTOOL_WIN32_DLL
90 LT_INIT
91 LT_AC_PROG_RC
92 AC_LIBTOOL_RC
93 AC_PROG_LIBTOOL
94
95 AC_SYS_LARGEFILE
96
97 dnl ******************************
98 dnl Checks for host
99 dnl Not needed anymore because we 
100 dnl do AC_CANONICAL_SYSTEM above
101 dnl ******************************
102 dnl AC_CANONICAL_HOST
103
104 dnl Copied from the official gtk+-2 configure.in
105 AC_MSG_CHECKING([for some Win32 platform])
106 case "$host" in
107   *-*-mingw*|*-*-cygwin*)
108     platform_win32=yes
109     LDFLAGS="$LDFLAGS -mwindows"
110     ;;
111   *)
112     platform_win32=no
113     ;;
114 esac
115 AC_MSG_RESULT([$platform_win32])
116 AM_CONDITIONAL(PLATFORM_WIN32, test x"$platform_win32" = x"yes")
117
118 AC_MSG_CHECKING([for native Win32])
119 case "$host" in
120   *-*-mingw*)
121     os_win32=yes
122     ;;
123   *)
124     os_win32=no
125     ;;
126 esac
127 AC_MSG_RESULT([$os_win32])
128 AM_CONDITIONAL(OS_WIN32, test x"$os_win32" = x"yes")
129
130 AC_MSG_CHECKING([for Cygwin])
131 case "$host" in
132   *-*-cygwin*)
133     env_cygwin=yes
134     ;;
135   *)
136     env_cygwin=no
137     ;;
138 esac
139 AC_MSG_RESULT([$env_cygwin])
140 AM_CONDITIONAL(CYGWIN, test x"$env_cygwin" = x"yes")
141
142 if test "$GCC" = "yes"
143 then
144         CFLAGS="$CFLAGS -Wno-unused-function"
145 fi
146
147 AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
148 _gcc_cflags_save=$CFLAGS
149 CFLAGS="-Wno-pointer-sign"
150 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],_gcc_psign=yes,_gcc_psign=no)
151 AC_MSG_RESULT($_gcc_psign)
152 CFLAGS=$_gcc_cflags_save;
153 if test x"$_gcc_psign" = xyes ; then
154         CFLAGS="$CFLAGS -Wno-pointer-sign"
155 fi
156
157 CFLAGS="$CFLAGS -Wall"
158
159 #if test $USE_MAINTAINER_MODE = yes; then
160 #       CFLAGS="-g -Wall -Wno-pointer-sign -DGTK_DISABLE_DEPRECATED -DGDK_DISABLE_DEPRECATED -DG_DISABLE_DEPRECATED -DGTK_DISABLE_SINGLE_INCLUDESi -DGDK_PIXBUF_DISABLE_DEPRECATED -DGSEAL_ENABLE"
161 #fi
162
163 pthread_name=
164 case "$target" in
165 *-darwin*)
166         CFLAGS="$CFLAGS -no-cpp-precomp -fno-common"
167         ;;
168 *-*-mingw*)
169         # Note that we need to link to pthreadGC2 in all cases. This
170         # is because some locking is used even when pthread support is
171         # disabled.
172         pthread_name=pthreadGC2
173         CFLAGS="$CFLAGS -mms-bitfields"
174         LIBS="$LIBS -l${pthread_name} -lws2_32 -lregex"
175         ;;
176 *-*-solaris*)
177         CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
178         CFLAGS="$CFLAGS -std=gnu99 -DSOLARIS"
179         ;;
180 esac
181   
182 dnl Checks for iconv
183 AM_ICONV
184
185 dnl
186 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
187 dnl
188 syl_save_LIBS=$LIBS
189 LIBS="$LIBS $GTK_LIBS"
190 AC_CHECK_FUNCS(bind_textdomain_codeset)
191 LIBS=$syl_save_LIBS
192
193 dnl for gettext
194 ALL_LINGUAS="bg ca cs de en_GB es fi fr hu id it ja lt nl pl pt_BR pt_PT ru sk sv uk zh_CN"
195 GETTEXT_PACKAGE=claws-mail
196 AC_SUBST(GETTEXT_PACKAGE)
197 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Define text domain.])
198
199 AM_GNU_GETTEXT_VERSION([0.15])
200 AM_GNU_GETTEXT([external])
201
202 manualdir='${docdir}/manual'
203 AC_ARG_WITH(manualdir,
204         [  --with-manualdir=DIR    Manual directory],
205         [manualdir="$withval"])
206 AC_SUBST(manualdir)
207
208 AC_ARG_ENABLE(manual,
209         [  --disable-manual           do not build manual],
210         [ac_cv_enable_manual=$enableval], [ac_cv_enable_manual=yes])
211
212 dnl ******************************
213 dnl ** Check for required tools **
214 dnl ** to build manuals         **
215 dnl ******************************
216
217 AC_PATH_PROG(DOCBOOK2HTML, docbook2html)
218 AC_PATH_PROG(DOCBOOK2TXT, docbook2txt)
219 AC_PATH_PROG(DOCBOOK2PS, docbook2ps)
220 AC_PATH_PROG(DOCBOOK2PDF, docbook2pdf)
221
222 AM_CONDITIONAL(MANUAL_HTML, test -n "$DOCBOOK2HTML")
223 AM_CONDITIONAL(MANUAL_TXT, test -n "$DOCBOOK2TXT")
224 AM_CONDITIONAL(MANUAL_PDF, test -n "$DOCBOOK2PDF")
225 AM_CONDITIONAL(MANUAL_PS, test -n "$DOCBOOK2PS")
226
227 if test x"$ac_cv_enable_manual" = x"yes"; then
228     if test -n "$DOCBOOK2TXT" -o -n "$DOCBOOK2HTML" \
229         -o -n "$DOCBOOK2PS" -o -n "$DOCBOOK2PDF"; then
230             ac_cv_enable_manual=yes
231         else
232             ac_cv_enable_manual=no
233     fi
234 fi
235
236 AM_CONDITIONAL(BUILD_MANUAL, test x"$ac_cv_enable_manual" = xyes)
237
238 dnl Set PACKAGE_DATA_DIR in config.h.
239 if test "x${datarootdir}" = 'x${prefix}/share'; then
240         if test "x${prefix}" = "xNONE"; then
241                 AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${ac_default_prefix}/share/${PACKAGE}",[PACKAGE_DATA_DIR])
242         else
243                 AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${prefix}/share/${PACKAGE}",[PACKAGE_DATA_DIR])
244         fi
245 else
246         AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${datarootdir}/${PACKAGE}",[PACKAGE_DATA_DIR])
247 fi
248
249 AC_CHECK_LIB(xpg4, setlocale)
250
251 SM_LIBS=""
252 dnl Check for LibSM
253 AC_ARG_ENABLE(libsm,
254         [  --disable-libsm    disable libSM support for session management.],
255         [ac_cv_enable_libsm=$enableval], [ac_cv_enable_libsm=yes])
256 AC_MSG_CHECKING([whether to use LibSM])
257 if test x"$ac_cv_enable_libsm" = xyes; then
258         AC_MSG_RESULT(yes)
259         AC_CHECK_LIB(SM, SmcSaveYourselfDone,
260                 [SM_LIBS="$X_LIBS -lSM -lICE"],ac_cv_enable_libsm=no,
261                 $X_LIBS -lICE)
262         AC_CHECK_HEADERS(X11/SM/SMlib.h,,ac_cv_enable_libsm=no)
263         if test x"$ac_cv_enable_libsm" = xyes; then
264                 AC_DEFINE(HAVE_LIBSM, 1, [Define to 1 if you have libSM installed])
265         else
266                 AC_MSG_RESULT(not found)
267                 AC_MSG_WARN([*** LibSM will not be supported ***])
268         fi
269 else
270         AC_MSG_RESULT(no)
271 fi
272 AC_SUBST(SM_LIBS)
273
274 dnl for GThread support (currently disabled)
275 dnl AC_ARG_ENABLE(threads,
276 dnl     [  --enable-threads        Enable multithread support [default=no]],
277 dnl     [use_threads=$enableval], [use_threads=no])
278
279 AC_MSG_CHECKING([whether to use threads])
280 if test x"$use_threads" = xyes ; then
281         AC_MSG_RESULT(yes)
282         if test ! -z `$GLIB_CONFIG --help 2>&1 |grep 'gthread'` ; then
283                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
284                 LIBS="$LIBS `$GLIB_CONFIG --libs gthread`"
285                 AC_DEFINE(USE_THREADS, 1, Whether to use multithread or not)
286         else
287                 AC_MSG_ERROR([Claws Mail requires GThread from GLib to use threading.])
288         fi
289 else
290         AC_MSG_RESULT(no)
291 fi
292
293 dnl Check for d_type member in struct dirent
294 AC_MSG_CHECKING([whether struct dirent has d_type member])
295 AC_CACHE_VAL(ac_cv_dirent_d_type,[
296         AC_TRY_COMPILE([#include <dirent.h>],
297                        [struct dirent d; d.d_type = DT_REG;],
298                        ac_cv_dirent_d_type=yes, ac_cv_dirent_d_type=no)
299 ])
300 AC_MSG_RESULT($ac_cv_dirent_d_type)
301 if test $ac_cv_dirent_d_type = yes; then
302         AC_DEFINE(HAVE_DIRENT_D_TYPE, 1,
303                   Define if `struct dirent' has `d_type' member.)
304 fi
305
306 # Check whether mkdir does not take the permission argument.
307 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
308
309 dnl Checks for header files.
310 AC_HEADER_DIRENT
311 AC_HEADER_STDC
312 AC_HEADER_SYS_WAIT
313 AC_CHECK_HEADERS(fcntl.h sys/file.h unistd.h paths.h \
314                  sys/param.h sys/utsname.h sys/select.h \
315                  wchar.h wctype.h locale.h netdb.h)
316 AC_CHECK_HEADER([execinfo.h], [AC_DEFINE(HAVE_BACKTRACE,1,[Has backtrace*() needed for retrieving stack traces])])
317 AC_SEARCH_LIBS(backtrace_symbols, [execinfo])
318
319 dnl alf - Check for apache installation f*ck up. apache may also install an 
320 dnl fnmatch, which includes their own regex stuff if USE_HSREGEX is defined
321 AC_TRY_COMPILE([#include <stdlib.h>
322                 #include <fnmatch.h>],
323         [int x = USE_HSREGEX;],
324         ac_cv_have_apache_fnmatch=yes, ac_cv_have_apache_fnmatch=no)
325 if test $ac_cv_have_apache_fnmatch = yes; then
326         AC_DEFINE(HAVE_APACHE_FNMATCH, 1, Define if you need to work around apache regex/fnmatch !KLUDGE!)
327 fi
328 AC_MSG_CHECKING([whether to use Apache regex header kludge])
329 AC_MSG_RESULT($ac_cv_have_apache_fnmatch)
330
331 dnl Checks for typedefs, structures, and compiler characteristics.
332 AC_C_CONST
333 AC_TYPE_OFF_T
334 AC_TYPE_PID_T
335 AC_TYPE_SIZE_T
336 AC_STRUCT_TM
337
338 dnl AC_CHECK_TYPE(wint_t, unsigned int) does not work because wint_t
339 dnl may be defined only in wchar.h (this happens with gcc-2.96).
340 dnl So we need to use this extended macro.
341 CLAWS_CHECK_TYPE(wint_t, unsigned int,
342 [
343 #if HAVE_WCHAR_H
344 #include <wchar.h>
345 #endif
346 ], Define to `unsigned int' if <stddef.h> or <wchar.h> doesn't define.)
347
348 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF, Used to test for a u32 typedef)
349 AC_CHECK_SIZEOF(unsigned short, 2)
350 AC_CHECK_SIZEOF(unsigned int, 4)
351 AC_CHECK_SIZEOF(unsigned long, 4)
352
353 dnl Checks for library functions.
354 AC_FUNC_ALLOCA
355 AC_CHECK_FUNCS(gethostname mkdir mktime socket strstr strchr \
356                uname flock lockf inet_aton inet_addr \
357                fchmod mkstemp truncate getuid regcomp)
358
359 AC_CHECK_FUNCS(fgets_unlocked fwrite_unlocked)
360
361 dnl *****************
362 dnl ** common code **
363 dnl *****************
364
365 dnl check for glib
366 PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.6 gmodule-2.0 >= 2.6 gobject-2.0 >= 2.6 gthread-2.0 >= 2.6)
367       
368 GLIB_GENMARSHAL=`pkg-config --variable=glib_genmarshal glib-2.0`
369 AC_SUBST(GLIB_GENMARSHAL)
370
371 AC_SUBST(GLIB_CFLAGS)
372 AC_SUBST(GLIB_LIBS)
373
374 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
375 syl_save_LIBS=$LIBS
376 LIBS="$LIBS $GTK_LIBS"
377 AC_CHECK_FUNCS(bind_textdomain_codeset)
378 LIBS=$syl_save_LIBS
379
380 dnl check for IPv6 option
381 AC_ARG_ENABLE(ipv6,
382         [  --disable-ipv6           disable build IPv6 support],
383         [ac_cv_enable_ipv6=$enableval], [ac_cv_enable_ipv6=yes])
384
385 dnl automated checks for IPv6 support.
386 AC_MSG_CHECKING([whether to use IPv6])
387 if test x"$ac_cv_enable_ipv6" = xyes; then
388         AC_MSG_RESULT(yes)
389         AC_MSG_CHECKING([for IPv6 support])
390         AC_CACHE_VAL(ac_cv_ipv6,[
391                 AC_TRY_COMPILE([#define INET6
392                                 #include <sys/types.h>
393                                 #include <netinet/in.h>],
394                         [int x = IPPROTO_IPV6; struct in6_addr a;],
395                         ac_cv_ipv6=yes, ac_cv_ipv6=no)
396         ])
397         AC_MSG_RESULT($ac_cv_ipv6)
398         if test $ac_cv_ipv6 = yes; then
399                 AC_DEFINE(INET6, 1, Define if you want IPv6 support.)
400         else
401                 AC_MSG_WARN(*** IPv6 will not be supported ***)
402                 ac_cv_enable_ipv6=no
403         fi
404 else
405         AC_MSG_RESULT(no)
406 fi
407
408 dnl GNUTLS
409 AC_MSG_CHECKING([whether to use GnuTLS])
410 AC_ARG_ENABLE(gnutls,    [  --enable-gnutls      enable GnuTLS support],
411             [ac_cv_enable_gnutls=$enableval], [ac_cv_enable_gnutls=yes])
412
413 AC_MSG_RESULT($ac_cv_enable_gnutls)
414 if test "x$ac_cv_enable_gnutls" != "xno"; then
415         PKG_CHECK_MODULES(GNUTLS, gnutls >= 2.2,
416         [
417                 AC_DEFINE(USE_GNUTLS, 1, gnutls)
418                 echo "Building with GnuTLS"
419         ],
420         [
421                 echo "Building without gnutls"
422         ])
423         PKG_CHECK_MODULES(GNUTLS, gnutls >= 2.11,
424         [
425                 dnl No linking against libgcrypt needed
426         ],
427         [
428                 dnl linking against libgcrypt *is* needed
429                 GNUTLS_LIBS="$GNUTLS_LIBS -lgcrypt"
430         ])
431         AC_SUBST(GNUTLS_LIBS)
432         AC_SUBST(GNUTLS_CFLAGS)
433 fi
434
435 dnl password encryption
436 OLDLIBS=$LIBS
437 LIBS=
438 case $host_os in
439         *dragonfly*)
440                 AC_SEARCH_LIBS(encrypt, cipher, [], AC_MSG_ERROR(['encrypt'-function not found.]))
441         ;;
442         *)
443                 AC_SEARCH_LIBS(encrypt, crypt, [], AC_MSG_ERROR(['encrypt'-function not found.]))
444         ;;
445 esac
446 CRYPT_LIBS=$LIBS
447 AC_SUBST(CRYPT_LIBS)
448 LIBS=$OLDLIBS
449
450 AC_ARG_WITH(passcrypt-key, [  --with-passcrypt-key=KEY     Key used to encode passwords (8 byte string)],
451             with_passcrypt_key="$withval", with_passcrypt_key="passkey0")
452 AC_SUBST(PASSCRYPT_KEY, $with_passcrypt_key)
453
454 dnl RC dir (will be default at a certain point in time)
455 AC_ARG_WITH(config-dir,    [  --with-config-dir=RCDIR      Local configuration dir (default: .claws-mail)],
456               ac_cv_with_config_dir="$withval", ac_cv_with_config_dir=".claws-mail")
457 if test x"$ac_cv_with_config_dir" = x""; then
458         ac_cv_with_config_dir=".claws-mail"
459 fi 
460 AC_DEFINE_UNQUOTED(CFG_RC_DIR, "$ac_cv_with_config_dir", Configuration directory)
461
462 dnl ************************
463 dnl ** GTK user interface **
464 dnl ************************
465
466 dnl Checks for GTK
467 AC_ARG_ENABLE(gtk3,
468         AS_HELP_STRING([--enable-gtk3],
469                 [Determines whether to use Gtk+ 3.0 vclplug on platforms where Gtk+ 3.0 is available.]),
470                 [ac_cv_enable_gtk3=$enableval],[ac_cv_enable_gtk3=no])
471 if test x"$ac_cv_enable_gtk3" = x"yes"; then
472         PKG_CHECK_MODULES(GTK, gtk+-3.0 >= 3.0 cairo)
473         AC_SUBST(GTK3, 1)
474 else
475         PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.10)
476         AC_SUBST(GTK2, 1)
477
478 dnl --disable-deprecated switch for GTK2 purification
479 AC_ARG_ENABLE(deprecated, [  --disable-deprecated  disable deprecated GTK functions. ],
480                           [GTK_CFLAGS="$GTK_CFLAGS -DG_DISABLE_DEPRECATED -DGTK_DISABLE_DEPRECATED"], [])
481 fi
482
483 AC_SUBST(GTK_CFLAGS)
484 AC_SUBST(GTK_LIBS)
485
486 dnl enchant is used for spell checking
487 AC_MSG_CHECKING([whether to use enchant])
488 AC_ARG_ENABLE(enchant,
489         [  --disable-enchant         disable enchant support],
490         [ac_cv_enable_enchant=$enableval], [ac_cv_enable_enchant=yes])
491 AC_MSG_RESULT($ac_cv_enable_enchant)
492 if test $ac_cv_enable_enchant = yes; then
493         PKG_CHECK_MODULES(ENCHANT, enchant >= 1.0.0,
494         [
495                 AC_DEFINE(USE_ENCHANT, 1, enchant)
496                 echo "Building with enchant"
497                 ac_cv_enable_enchant=yes
498                 CFLAGS="$CFLAGS `$PKG_CONFIG --cflags enchant`"
499         ],
500         [
501                 echo "Building without enchant-notification"
502                 ac_cv_enable_enchant=no
503         ])
504         AC_SUBST(ENCHANT_CFLAGS)
505         AC_SUBST(ENCHANT_LIBS)
506 fi
507
508 dnl want crash dialog
509 AC_ARG_ENABLE(crash-dialog,
510         [  --enable-crash-dialog   Enable crash dialog [default=no]],
511         [ac_cv_enable_crash_dialog=$enableval], [ac_cv_enable_crash_dialog=no])
512 if test $ac_cv_enable_crash_dialog = yes; then
513 dnl check if GDB is somewhere
514         AC_CHECK_PROG(ac_cv_enable_crash_dialog, gdb, yes, no)
515         AC_MSG_CHECKING([whether to use crash dialog])
516         if test $ac_cv_enable_crash_dialog = yes; then
517                 AC_DEFINE(CRASH_DIALOG, 1, Pop up crash dialog)
518         fi
519         AC_MSG_RESULT($ac_cv_enable_crash_dialog)
520 fi
521
522 dnl generic umpc
523 AC_ARG_ENABLE(generic-umpc,
524         [  --enable-generic-umpc   Enable generic UMPC code [default=no]],
525         [ac_cv_enable_generic_umpc=$enableval], [ac_cv_enable_generic_umpc=no])
526 if test $ac_cv_enable_generic_umpc = yes; then
527         AC_DEFINE(GENERIC_UMPC, 1, Generic UMPC code)
528         AC_MSG_RESULT($ac_cv_enable_generic_umpc)
529 fi
530
531 dnl Maemo platform
532 AC_ARG_ENABLE(maemo,
533         [  --enable-maemo   build for the Maemo platform [default=no]],
534         [ac_cv_enable_maemo=$enableval], [ac_cv_enable_maemo=no])
535 if test $ac_cv_enable_maemo = yes; then
536         PKG_CHECK_MODULES(MAEMO, libosso hildon-libs hildon-fm gnome-vfs-2.0, ac_cv_enable_maemo=yes,
537                   ac_cv_enable_maemo=no)
538         AC_SUBST(MAEMO_CFLAGS)
539         AC_SUBST(MAEMO_LIBS)
540         if test $ac_cv_enable_maemo = no; then
541                 #test for chinook
542                 PKG_CHECK_MODULES(MAEMO, libosso hildon-1 hildon-fm-2 gnome-vfs-2.0 hal, ac_cv_enable_maemo=yes,
543                           ac_cv_enable_maemo=no)
544                 AC_SUBST(MAEMO_CFLAGS)
545                 AC_SUBST(MAEMO_LIBS)
546                 if test $ac_cv_enable_maemo = no; then
547                         AC_MSG_ERROR(one of libosso hildon-libs hildon-fm hildon-1 hildon-fm-2 not found)
548                 else
549                         AC_DEFINE(MAEMO, 1, Build for maemo)
550                         AC_DEFINE(CHINOOK, 1, Maemo chinook)
551                         AC_DEFINE(GENERIC_UMPC, 1, Generic UMPC code)
552                         ac_cv_enable_generic_umpc=yes
553                 fi
554         else
555                 AC_DEFINE(MAEMO, 1, Build for maemo)
556                 AC_DEFINE(GENERIC_UMPC, 1, Generic UMPC code)
557                 ac_cv_enable_generic_umpc=yes
558         fi
559 fi
560
561 PKG_CHECK_MODULES(CONIC, conic, ac_cv_enable_conic=yes,
562           ac_cv_enable_conic=no)
563 AC_SUBST(CONIC_CFLAGS)
564 AC_SUBST(CONIC_LIBS)
565 if test $ac_cv_enable_conic = yes; then
566         AC_DEFINE(CONIC, 1, Have conic lib)
567 fi
568
569 dnl Check for X-Face support
570 AC_ARG_ENABLE(compface,
571         [  --disable-compface      disable compface (X-Face) support],
572         [ac_cv_enable_compface=$enableval], [ac_cv_enable_compface=yes])
573 AC_MSG_CHECKING([whether to use compface])
574 if test x"$ac_cv_enable_compface" = xyes; then
575         AC_MSG_RESULT(yes)
576         AC_CHECK_LIB(compface, uncompface, 
577                 [AC_DEFINE(HAVE_LIBCOMPFACE, 1, Define if you want compface support.)],
578                 [ac_cv_enable_compface=no])
579         if test x"$ac_cv_enable_compface" = xyes; then
580                 COMPFACE_LIBS="-lcompface"
581         else
582                 COMPFACE_LIBS=""
583         fi
584         AC_SUBST(COMPFACE_LIBS)
585 else
586         AC_MSG_RESULT(no)
587 fi
588
589 dnl check for pthread support
590 AC_ARG_ENABLE(pthread,
591         [  --disable-pthread           disable pthread support],
592         [ac_cv_enable_pthread=$enableval], [ac_cv_enable_pthread=yes])
593 AC_MSG_CHECKING([whether to use pthread])
594 if test x$ac_cv_enable_pthread = xno; then
595         AC_MSG_RESULT(no)
596 else
597         AC_MSG_RESULT(yes)
598
599         # For W32 we need to use a special ptrhead lib. In this case we can't
600         # use AC_CHECK_LIB because it has no means of checking for a
601         # library installed under a different name.  Checking for the
602         # header is okay.
603         if test -n "${pthread_name}" ; then
604            ac_cv_enable_pthread=yes
605         else
606         AC_CHECK_LIB(pthread, pthread_create, :, ac_cv_enable_pthread=no)
607         fi
608         AC_CHECK_HEADERS(pthread.h, :, ac_cv_enable_pthread=no)
609
610         if test x$ac_cv_enable_pthread = xyes; then
611                 AC_DEFINE(USE_PTHREAD, 1, Define if you have pthread)
612                 if test -z "${pthread_name}" ; then
613                 PTHREAD_LIBS="-lpthread"
614         fi
615         fi
616
617 fi
618 AC_SUBST(PTHREAD_LIBS)
619
620 dnl
621 dnl Check whether we need to pass -lresolv
622 dnl We know that we don't need it for W32.
623 dnl
624 if test x$os_win32 = xno; then
625   t_oldLibs="$LIBS"
626   LIBS="$LIBS"
627   ac_cv_var__res_options=no
628   AC_TRY_LINK([#include <sys/types.h>
629              #include <sys/socket.h>
630              #include <netinet/in.h>
631              #include <arpa/nameser.h>
632              #include <resolv.h>],
633                 [_res.options = RES_INIT;],
634                 ac_cv_var__res_options=yes);
635   if test "$ac_cv_var__res_options" != "yes"; then
636         LIBRESOLV="-lresolv"
637   fi
638   LIBS="$t_oldLibs"
639
640   if test "x$LIBRESOLV" = "x"; then
641         AC_CHECK_LIB(resolv, res_query, [LIBRESOLV=-lresolv])
642         LIBS="$t_oldLibs"
643   fi
644 fi
645 AC_SUBST(LIBRESOLV)
646
647 LIBS="$LIBS $LIBRESOLV"
648                  
649 dnl for LDAP support in addressbook
650 dnl no check for libraries; dynamically loaded
651 AC_ARG_ENABLE(ldap,
652         [  --disable-ldap         disable LDAP support],
653         [ac_cv_enable_ldap=$enableval], [ac_cv_enable_ldap=yes])
654 AC_MSG_CHECKING([whether to use LDAP])
655 if test x"$ac_cv_enable_ldap" = xno; then
656         AC_MSG_RESULT(no)
657 elif test x"$ac_cv_enable_ldap" = xyes -a x"$ac_cv_enable_pthread" = xno; then
658         AC_MSG_RESULT(no - LDAP support needs pthread support)
659
660         ac_cv_enable_ldap=no
661 elif test x"$platform_win32" = xyes; then
662         AC_MSG_RESULT(yes)
663         AC_DEFINE(USE_LDAP, 1, Define if you want LDAP support in addressbook.)
664         LDAP_LIBS="-lwldap32"
665         AC_SUBST(LDAP_LIBS)
666 else
667         AC_MSG_RESULT(yes)
668
669         dnl check for available libraries, and pull them in
670         AC_CHECK_LIB(resolv, res_query, LDAP_LIBS="$LDAP_LIBS -lresolv")
671         AC_CHECK_LIB(socket, bind, LDAP_LIBS="$LDAP_LIBS -lsocket")
672         AC_CHECK_LIB(nsl, gethostbyaddr, LDAP_LIBS="$LDAP_LIBS -lnsl")
673         AC_CHECK_LIB(lber, ber_get_tag, LDAP_LIBS="$LDAP_LIBS -llber",,
674                      $LDAP_LIBS)
675
676         AC_CHECK_HEADERS(ldap.h lber.h,
677                          [ ac_cv_enable_ldap=yes ],
678                          [ ac_cv_enable_ldap=no ])
679
680         if test "$ac_cv_enable_ldap" = yes; then
681                 AC_CHECK_LIB(ldap, ldap_open,
682                              [ ac_cv_enable_ldap=yes ],
683                              [ ac_cv_enable_ldap=no ],
684                              $LDAP_LIBS)
685
686                 AC_CHECK_LIB(ldap, ldap_start_tls_s,
687                              [ ac_cv_have_tls=yes ],
688                              [ ac_cv_have_tls=no ])
689
690         fi
691
692         AC_MSG_CHECKING([whether ldap library is available])
693         AC_MSG_RESULT($ac_cv_enable_ldap)
694
695         AC_MSG_CHECKING([whether TLS library is available])
696         AC_MSG_RESULT($ac_cv_have_tls)
697
698         if test "$ac_cv_enable_ldap" = yes; then
699                 AC_DEFINE(USE_LDAP, 1, Define if you want LDAP support in addressbook.)
700                 LDAP_LIBS="$LDAP_LIBS -lldap"
701                 AC_SUBST(LDAP_LIBS)
702                 if test "$ac_cv_have_tls" = yes; then
703                         AC_DEFINE(USE_LDAP_TLS, 1, Define if you want LDAP TLS support in addressbook.)
704                 fi
705                 dnl As of OpenLDAP API version 3000 a number of functions has
706                 dnl been deprecated. As Claws-mail compiles and runs on many
707                 dnl platforms and many versions of OpenLDAP we need to be able
708                 dnl to switch between the old and new API because new API has
709                 dnl added new functions replacing old ones and at the same time
710                 dnl old functions has been changed.
711                 dnl If cross-compiling defaults to enable deprecated features
712                 dnl for maximum portability
713                 AC_MSG_CHECKING([The API version of OpenLDAP])
714                 AC_RUN_IFELSE(
715                         [AC_LANG_PROGRAM(
716                          [#include <ldap.h>],
717                          [if (LDAP_API_VERSION >= 3000)
718                                         return 1
719                         ])],
720                         [AC_MSG_RESULT([version < 3000])
721                          AC_DEFINE(OPEN_LDAP_API_AT_LEAST_3000, 0, Define if OpenLDAP API is at least version 3000.)],
722                         [AC_MSG_RESULT([version >= 3000])
723                          AC_DEFINE(OPEN_LDAP_API_AT_LEAST_3000, 1, Define if OpenLDAP API is at least version 3000.)],
724                         [AC_MSG_RESULT([Enabling deprecated features in OpenLDAP])
725                          AC_DEFINE(OPEN_LDAP_API_AT_LEAST_3000, 0, Define if OpenLDAP API is at least version 3000.)
726                          AC_DEFINE(LDAP_DEPRECATED, 1, Define to activate deprecated features in OpenLDAP)]
727                 )
728         fi
729 fi
730
731 dnl for JPilot support in addressbook
732 dnl no check for libraries; these are dynamically loaded
733 AC_ARG_ENABLE(jpilot,
734         [  --disable-jpilot         disable JPilot support],
735         [ac_cv_enable_jpilot=$enableval], [ac_cv_enable_jpilot=yes])
736 AC_MSG_CHECKING([whether to use JPilot])
737 if test "$ac_cv_enable_jpilot" = yes; then
738         AC_MSG_RESULT(yes)
739         AC_CHECK_HEADERS(pi-args.h pi-appinfo.h pi-address.h pi-version.h,
740                          [ AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ],
741                          [ ac_cv_enable_jpilot=no ])
742         if test "$ac_cv_enable_jpilot" = no; then
743                 AC_CHECK_HEADERS(libpisock/pi-args.h libpisock/pi-appinfo.h libpisock/pi-address.h libpisock/pi-version.h,
744                                  [ ac_cv_enable_jpilot=yes
745                                    AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ])
746         fi
747
748         AC_CHECK_LIB(pisock, unpack_Address, [JPILOT_LIBS="-lpisock"], [JPILOT_LIBS="" ac_cv_enable_jpilot="no"])
749         if test x"$ac_cv_enable_jpilot" = xyes; then
750                 AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.)
751         else
752                 AC_MSG_NOTICE([JPilot support not available])
753         fi
754         AC_SUBST(JPILOT_LIBS)
755 else
756         AC_MSG_RESULT(no)
757 fi
758
759 dnl #######################################################################
760 dnl # Check for startup notification
761 dnl #######################################################################
762 AC_ARG_ENABLE(startup-notification, [  --disable-startup-notification    disable startup notification support],,enable_startup_notification=yes)
763
764 if test "x$enable_startup_notification" = "xyes"; then
765         PKG_CHECK_MODULES(STARTUP_NOTIFICATION, libstartup-notification-1.0 >= 0.5,
766         [
767                 AC_DEFINE(HAVE_STARTUP_NOTIFICATION, 1, [Define if we're using libstartup-notification.])
768                 echo "Building with libstartup-notification"
769                 enable_startup_notification=yes
770         ],
771         [
772                 echo "Building without libstartup-notification"
773                 enable_startup_notification=no
774         ])
775
776         AC_SUBST(STARTUP_NOTIFICATION_CFLAGS)
777         AC_SUBST(STARTUP_NOTIFICATION_LIBS)
778 fi
779
780 dnl #######################################################################
781 dnl # Check for D-Bus support
782 dnl #######################################################################
783 AC_ARG_ENABLE(dbus, [  --disable-dbus    disable dbus support],,enable_dbus=yes)
784
785 if test "x$enable_dbus" = "xyes"; then
786         PKG_CHECK_MODULES(DBUS, [dbus-1 >= 0.60, dbus-glib-1 >= 0.60],
787         [
788                 AC_DEFINE(HAVE_DBUS_GLIB, 1, [Define if glib bindings of D-Bus are available])
789                 enable_dbus_glib=yes
790         ],
791         [
792                 echo "D-Bus requirements not met. D-Bus support not activated."
793                 enable_dbus_glib=no
794         ])
795         AC_SUBST(DBUS_CFLAGS)
796         AC_SUBST(DBUS_LIBS)
797 fi
798
799 dnl #######################################################################
800 dnl # Check for NetworkManager support
801 dnl #######################################################################
802 if test x"$enable_dbus_glib" = xyes; then
803         AC_ARG_ENABLE(networkmanager-support, [  --disable-networkmanager-support  disable NetworkManager support],,enable_networkmanager_support=yes)
804         if test x"$enable_networkmanager_support" = xyes; then
805                 PKG_CHECK_MODULES(NETWORKMANAGER_SUPPORT, NetworkManager >= 0.6.2,
806                 [
807                         AC_DEFINE(HAVE_NETWORKMANAGER_SUPPORT, 1, [Define if NetworkManager support is to be included.])
808                         echo "Building with NetworkManager support"
809                         enable_networkmanager_support=yes
810                 ],
811                 [
812                         echo "NetworkManager not found."
813                         enable_networkmanager_support=no
814                 ])
815                 AC_SUBST(NETWORKMANAGER_SUPPORT_CFLAGS)
816         fi
817 else
818         echo "NetworkManager support deactivated as D-Bus requirements were not met."
819         enable_networkmanager_support=no
820 fi
821
822 dnl *************************
823 dnl ** section for plugins **
824 dnl *************************
825
826 PLUGINS=""
827
828 dnl --- Trayicon ---
829 AC_MSG_CHECKING([whether to build Trayicon plugin])
830 AC_ARG_ENABLE(trayicon-plugin,
831         [  --disable-trayicon-plugin         do not build System Tray Icon plugin],
832         [ac_cv_enable_trayicon_plugin=$enableval], [ac_cv_enable_trayicon_plugin=yes])
833 if test x"$ac_cv_enable_trayicon_plugin" = xyes; then
834         AC_MSG_RESULT(yes)
835         PLUGINS="trayicon $PLUGINS"
836 else
837         AC_MSG_RESULT(no)
838 fi
839 AM_CONDITIONAL(BUILD_TRAYICON_PLUGIN, test x"$ac_cv_enable_trayicon_plugin" = xyes)
840
841 dnl --- SpamAssassin ---
842 AC_MSG_CHECKING([whether to build SpamAssassin plugin])
843 AC_ARG_ENABLE(spamassassin-plugin,
844         [  --disable-spamassassin-plugin      do not build SpamAssassin plugin],
845         [ac_cv_enable_spamassassin_plugin=$enableval], [ac_cv_enable_spamassassin_plugin=yes])
846 if test x"$ac_cv_enable_spamassassin_plugin" = xyes; then
847         AC_MSG_RESULT(yes)
848         AC_SPAMASSASSIN
849         PLUGINS="spamassassin $PLUGINS"
850         AC_DEFINE(USE_SPAMASSASSIN_PLUGIN, 1, Define if spamassassin plugin is being built.)
851 else
852         AC_MSG_RESULT(no)
853 fi
854 AM_CONDITIONAL(BUILD_SPAMASSASSIN_PLUGIN, test x"$ac_cv_enable_spamassassin_plugin" = xyes)
855
856 dnl --- Bogofilter ---
857 AC_MSG_CHECKING([whether to build Bogofilter plugin])
858 AC_ARG_ENABLE(bogofilter-plugin,
859         [  --disable-bogofilter-plugin      do not build bogofilter plugin],
860         [ac_cv_enable_bogofilter_plugin=$enableval], [ac_cv_enable_bogofilter_plugin=yes])
861 if test x"$ac_cv_enable_bogofilter_plugin" = xyes; then
862         AC_MSG_RESULT(yes)
863         PLUGINS="bogofilter $PLUGINS"
864         AC_DEFINE(USE_BOGOFILTER_PLUGIN, 1, Define if bogofilter plugin is being built.)
865 else
866         AC_MSG_RESULT(no)
867 fi
868 AM_CONDITIONAL(BUILD_BOGOFILTER_PLUGIN, test x"$ac_cv_enable_bogofilter_plugin" = xyes)
869
870 dnl --- PGP/CORE ---
871 AC_MSG_CHECKING([whether to build PGP/CORE plugin])
872 AC_ARG_ENABLE(pgpcore-plugin,
873         [  --disable-pgpcore-plugin           do not build PGP/Core plugin],
874         [ac_cv_enable_pgpcore_plugin=$enableval], [ac_cv_enable_pgpcore_plugin=yes])
875 if test x"$ac_cv_enable_pgpcore_plugin" = xyes; then
876         AC_MSG_RESULT(yes)
877         AM_PATH_GPGME(1.0.0, AC_DEFINE(USE_GPGME, 1, Define if you use GPGME to support OpenPGP.),
878                       [ac_cv_enable_pgpcore_plugin=no])
879         if test x"$ac_cv_enable_pgpcore_plugin" = xyes; then
880                 PLUGINS="pgpcore $PLUGINS"
881                 AM_PATH_GPGME(1.1.1,
882                               AC_DEFINE(HAVE_GPGME_PKA_TRUST, 1,
883                                         [Define if GPGME supports PKA.]))
884                 #needed to get GPGME_LIBS and al correctly
885                 AM_PATH_GPGME(1.0.0, AC_DEFINE(USE_GPGME, 1, Define if you use GPGME to support OpenPGP.),
886                           [ac_cv_enable_pgpcore_plugin=no])
887         else
888                 AC_MSG_WARN([*** PGP/CORE plugin will not be built ***])
889         fi
890 else
891         AC_MSG_RESULT(no)
892 fi
893 AM_CONDITIONAL(BUILD_PGPCORE_PLUGIN, test x"$ac_cv_enable_pgpcore_plugin" = xyes)
894
895 AC_MSG_CHECKING([whether to build PGP/MIME plugin])
896 AC_ARG_ENABLE(pgpmime-plugin,
897         [  --disable-pgpmime-plugin           do not build PGP/MIME plugin],
898         [ac_cv_enable_pgpmime_plugin=$enableval], [ac_cv_enable_pgpmime_plugin=yes])
899 if test x"$ac_cv_enable_pgpmime_plugin" = xyes; then
900         AC_MSG_RESULT(yes)
901         if test x"$ac_cv_enable_pgpcore_plugin" = xyes; then
902                 PLUGINS="pgpmime $PLUGINS"
903         else
904                 AC_MSG_WARN([*** PGP/MIME plugin cannot be built ***])
905                 AC_MSG_WARN([*** without the PGP/CORE plugin     ***])
906         fi
907 else
908         AC_MSG_RESULT(no)
909 fi
910 AM_CONDITIONAL(BUILD_PGPMIME_PLUGIN, test x"$ac_cv_enable_pgpmime_plugin" = xyes)
911
912 AC_MSG_CHECKING([whether to build PGP/Inline plugin])
913 AC_ARG_ENABLE(pgpinline-plugin,
914         [  --disable-pgpinline-plugin           do not build PGP/Inline plugin],
915         [ac_cv_enable_pgpinline_plugin=$enableval], [ac_cv_enable_pgpinline_plugin=yes])
916 if test x"$ac_cv_enable_pgpinline_plugin" = xyes; then
917         AC_MSG_RESULT(yes)
918         if test x"$ac_cv_enable_pgpcore_plugin" = xyes; then
919                 PLUGINS="pgpinline $PLUGINS"
920         else
921                 AC_MSG_WARN([*** PGP/Inline plugin cannot be built ***])
922                 AC_MSG_WARN([*** without the PGP/CORE plugin     ***])
923         fi
924 else
925         AC_MSG_RESULT(no)
926 fi
927 AM_CONDITIONAL(BUILD_PGPINLINE_PLUGIN, test x"$ac_cv_enable_pgpinline_plugin" = xyes)
928
929 AC_MSG_CHECKING([whether to build S/Mime plugin])
930 AC_ARG_ENABLE(smime-plugin,
931         [  --disable-smime-plugin           do not build S/Mime plugin],
932         [ac_cv_enable_smime_plugin=$enableval], [ac_cv_enable_smime_plugin=yes])
933 if test x"$ac_cv_enable_smime_plugin" = xyes; then
934         AC_MSG_RESULT(yes)
935         if test x"$ac_cv_enable_pgpcore_plugin" = xyes; then
936                 PLUGINS="smime $PLUGINS"
937         else
938                 AC_MSG_WARN([*** S/Mime plugin cannot be built ***])
939                 AC_MSG_WARN([*** without the PGP/CORE plugin     ***])
940         fi
941 else
942         AC_MSG_RESULT(no)
943 fi
944 AM_CONDITIONAL(BUILD_SMIME_PLUGIN, test x"$ac_cv_enable_smime_plugin" = xyes)
945
946 dnl --- Dillo Viewer ---
947 AC_MSG_CHECKING([whether to build Dillo plugin])
948 AC_ARG_ENABLE(dillo-viewer-plugin,
949         [  --disable-dillo-viewer-plugin     do not build Dillo plugin for html mail rendering],
950         [ac_cv_enable_dillo_viewer_plugin=$enableval], [ac_cv_enable_dillo_viewer_plugin=yes])
951 if test x"$ac_cv_enable_dillo_viewer_plugin" = xyes; then
952         AC_MSG_RESULT(yes)
953         PLUGINS="dillo-viewer $PLUGINS"
954 else
955         AC_MSG_RESULT(no)
956 fi
957 AM_CONDITIONAL(BUILD_DILLO_VIEWER_PLUGIN, test x"$ac_cv_enable_dillo_viewer_plugin" = xyes)
958
959 dnl --- Demo ---
960 AC_ARG_ENABLE(demo-plugin,
961         [  --enable-demo-plugin              build demo plugin],
962         [ac_cv_enable_demo_plugin=$enableval], [ac_cv_enable_demo_plugin=no])
963 if test x"$ac_cv_enable_demo_plugin" = xyes; then
964         PLUGINS="demo $PLUGINS"
965 fi
966 AM_CONDITIONAL(BUILD_DEMO_PLUGIN, test x"$ac_cv_enable_demo_plugin" = xyes)
967
968 dnl Libetpan
969 AC_MSG_CHECKING([whether to use libetpan])
970 AC_ARG_ENABLE(libetpan,
971         [  --disable-libetpan           disable IMAP4/NNTP (libetpan) support],
972         [ac_cv_enable_libetpan=$enableval], [ac_cv_enable_libetpan=yes])
973 if test x"$ac_cv_enable_libetpan" = xyes; then
974         AC_MSG_RESULT(yes)
975         libetpan_result=no
976         AC_PATH_PROG(libetpanconfig, [libetpan-config])
977         if test "x$libetpanconfig" != "x"; then
978           CPPFLAGS="$CPPFLAGS `$libetpanconfig --cflags 2>/dev/null`"
979           AC_CHECK_HEADER(libetpan/libetpan.h, [libetpan_result=yes])
980           if test "x$libetpan_result" = "xyes"; then
981             AC_MSG_CHECKING([whether libetpan-config hints compiles and links fine])
982             LIBS="$LIBS `$libetpanconfig --libs 2>/dev/null`"
983             AC_TRY_LINK([#include <libetpan/dbstorage.h>], [db_mailstorage_init(NULL, NULL);], [libetpan_result=yes], [libetpan_result=no])
984             AC_MSG_RESULT([$libetpan_result])
985           fi
986         fi
987         if test "x$libetpan_result" = "xyes"; then
988            LIBETPAN_CPPFLAGS="`$libetpanconfig --cflags`"
989            LIBETPAN_LIBS="`$libetpanconfig --libs`"
990            LIBETPAN_STABLE=`$libetpanconfig --version | grep -v ^0`
991            LIBETPAN_VERSION=`$libetpanconfig --version | sed "s/\.//g" | sed "s/-.*$//"`
992            if test x"$LIBETPAN_STABLE" != "x"; then
993                 LIBETPAN_VERSION="100"
994            fi
995            if test "$LIBETPAN_VERSION" -lt "057"; then
996                 AC_MSG_RESULT([*** Claws Mail requires libetpan 0.57 or newer. See http://www.etpan.org/])
997                 AC_MSG_RESULT([*** You can use --disable-libetpan if you don't need IMAP4 and/or NNTP support.])
998                 AC_MSG_ERROR([libetpan 0.57 not found])
999            fi
1000            AC_SUBST(LIBETPAN_FLAGS)
1001            AC_SUBST(LIBETPAN_LIBS)
1002            AC_DEFINE(HAVE_LIBETPAN, 1, Define if you want IMAP and/or NNTP support.)
1003         else
1004            AC_MSG_RESULT([*** Claws Mail requires libetpan 0.57 or newer. See http://www.etpan.org/ ])
1005            AC_MSG_RESULT([*** You can use --disable-libetpan if you don't need IMAP4 and/or NNTP support.])
1006            AC_MSG_ERROR([libetpan 0.57 not found])
1007         fi
1008 else
1009         AC_MSG_RESULT(no)
1010 fi
1011 AM_CONDITIONAL(CLAWS_LIBETPAN, test "x$libetpan_result" = "xyes")
1012
1013 AC_MSG_CHECKING([whether to use valgrind])
1014 AC_ARG_ENABLE(valgrind,
1015         [  --disable-valgrind           disable valgrind support for debugging],
1016         [ac_cv_enable_valgrind=$enableval], [ac_cv_enable_valgrind=yes])
1017 if test x$ac_cv_enable_valgrind = xyes; then
1018         AC_MSG_RESULT(yes)
1019         PKG_CHECK_MODULES(VALGRIND, valgrind >= 2.4.0,
1020                           ac_cv_enable_valgrind=yes, ac_cv_enable_valgrind=no)
1021         if test x"$ac_cv_enable_valgrind" = xyes; then
1022                 AC_DEFINE(HAVE_VALGRIND, 1, Define if you want valgrind support)
1023         else
1024                 AC_MSG_RESULT(not found)
1025         fi
1026 else
1027         AC_MSG_RESULT(no)
1028 fi
1029 AM_CONDITIONAL(CLAWS_VALGRIND, test x"$ac_cv_enable_valgrind" = x"yes")
1030
1031 dnl ****************************
1032 dnl ** Final configure output **
1033 dnl ****************************
1034
1035 AC_OUTPUT([
1036 Makefile
1037 m4/Makefile
1038 po/Makefile.in
1039 src/common/version.h
1040 src/Makefile
1041 src/common/Makefile
1042 src/common/passcrypt.h
1043 src/gtk/Makefile
1044 src/etpan/Makefile
1045 src/plugins/Makefile
1046 src/plugins/demo/Makefile
1047 src/plugins/bogofilter/Makefile
1048 src/plugins/spamassassin/Makefile
1049 src/plugins/dillo_viewer/Makefile
1050 src/plugins/trayicon/Makefile
1051 src/plugins/pgpcore/Makefile
1052 src/plugins/pgpmime/Makefile
1053 src/plugins/pgpinline/Makefile
1054 src/plugins/smime/Makefile
1055 doc/Makefile
1056 doc/man/Makefile
1057 tools/Makefile
1058 config/Makefile
1059 manual/Makefile
1060 manual/dtd/Makefile
1061 manual/dist/Makefile
1062 manual/dist/pdf/Makefile
1063 manual/dist/ps/Makefile
1064 manual/dist/html/Makefile
1065 manual/dist/txt/Makefile
1066 manual/fr/Makefile
1067 manual/fr/dist/Makefile
1068 manual/fr/dist/pdf/Makefile
1069 manual/fr/dist/ps/Makefile
1070 manual/fr/dist/html/Makefile
1071 manual/fr/dist/txt/Makefile
1072 manual/pl/Makefile
1073 manual/pl/dist/Makefile
1074 manual/pl/dist/pdf/Makefile
1075 manual/pl/dist/ps/Makefile
1076 manual/pl/dist/html/Makefile
1077 manual/pl/dist/txt/Makefile
1078 manual/es/Makefile
1079 manual/es/dist/Makefile
1080 manual/es/dist/pdf/Makefile
1081 manual/es/dist/ps/Makefile
1082 manual/es/dist/html/Makefile
1083 manual/es/dist/txt/Makefile
1084 manual/de/Makefile
1085 manual/de/dist/Makefile
1086 manual/de/dist/pdf/Makefile
1087 manual/de/dist/ps/Makefile
1088 manual/de/dist/html/Makefile
1089 manual/de/dist/txt/Makefile
1090 claws-mail.pc
1091 ])
1092
1093 dnl Output the configuration summary
1094 echo ""
1095 echo "$PACKAGE $VERSION"
1096 echo ""
1097 echo "JPilot            : $ac_cv_enable_jpilot"
1098 echo "LDAP              : $ac_cv_enable_ldap"
1099 echo "gnuTLS            : $ac_cv_enable_gnutls"
1100 echo "iconv             : $am_cv_func_iconv"
1101 echo "compface          : $ac_cv_enable_compface"
1102 echo "IPv6              : $ac_cv_enable_ipv6"
1103 echo "enchant           : $ac_cv_enable_enchant"
1104 echo "IMAP4             : $ac_cv_enable_libetpan"
1105 echo "NNTP              : $ac_cv_enable_libetpan"
1106 echo "Crash dialog      : $ac_cv_enable_crash_dialog"
1107 echo "LibSM             : $ac_cv_enable_libsm"
1108 echo "DBUS              : $enable_dbus"
1109 echo "NetworkManager    : $enable_networkmanager_support"
1110 echo "Manual            : $ac_cv_enable_manual"
1111 echo "Plugins           : $PLUGINS"
1112 echo "Generic UMPC code : $ac_cv_enable_generic_umpc"
1113 echo "Maemo  build      : $ac_cv_enable_maemo"
1114 echo "Config dir        : $ac_cv_with_config_dir"
1115 echo ""
1116 echo "The binary will be installed in $prefix/bin"
1117 echo ""
1118 echo "Configure finished, type 'make' to build."