2004-11-18 [paul] 0.9.12cvs158.1
[claws.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script.
2 AC_PREREQ(2.50)
3 AC_INIT(src/main.c)
4 AC_CONFIG_AUX_DIR(config)
5
6 PACKAGE=sylpheed-claws
7
8 dnl version number
9 MAJOR_VERSION=0
10 MINOR_VERSION=9
11 MICRO_VERSION=12
12 INTERFACE_AGE=0
13 BINARY_AGE=0
14 EXTRA_VERSION=158
15 EXTRA_RELEASE=
16 EXTRA_GTK2_VERSION=.1
17
18 if test \( $EXTRA_VERSION -eq 0 \) -o \( "x$EXTRA_RELEASE" != "x" \); then
19     VERSION=${MAJOR_VERSION}.${MINOR_VERSION}.${MICRO_VERSION}${EXTRA_RELEASE}${EXTRA_GTK2_VERSION}
20 else
21     VERSION=${MAJOR_VERSION}.${MINOR_VERSION}.${MICRO_VERSION}cvs${EXTRA_VERSION}${EXTRA_GTK2_VERSION}
22 fi
23
24 dnl set $target
25 AC_CANONICAL_SYSTEM
26
27 dnl
28 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
29 dnl AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
30 dnl AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
31 AC_SUBST(PACKAGE)
32 AC_SUBST(VERSION)
33 AC_SUBST(MAJOR_VERSION)
34 AC_SUBST(MINOR_VERSION)
35 AC_SUBST(MICRO_VERSION)
36 AC_SUBST(EXTRA_VERSION)
37
38 dnl GNOME installed?
39 AC_PATH_PROG(GNOME_CONFIG, gnome-config, no)
40 if test "$GNOME_CONFIG" != no; then
41         gnomedatadir="`gnome-config --datadir`"
42         gnomeprefix="`gnome-config --prefix`"
43         if test "${prefix}" = "NONE"; then
44                 gnomedatadir="${ac_default_prefix}/${gnomedatadir#${gnomeprefix}}"
45         else
46                 gnomedatadir="${prefix}/${gnomedatadir#${gnomeprefix}}"
47         fi
48         AC_SUBST(gnomedatadir)
49 fi
50 AM_CONDITIONAL(SYLPHEED_GNOME, test -n "$gnomedatadir")
51
52 dnl Claws version
53 AC_DEFINE(CLAWS, 1, Compiling Claws branch of sylpheed)
54
55 dnl libtool versioning
56 LT_RELEASE=$MAJOR_VERSION.$MINOR_VERSION
57 LT_CURRENT=`expr $MICRO_VERSION - $INTERFACE_AGE`
58 LT_REVISION=$INTERFACE_AGE
59 LT_AGE=`expr $BINARY_AGE - $INTERFACE_AGE`
60 AC_SUBST(LT_RELEASE)
61 AC_SUBST(LT_CURRENT)
62 AC_SUBST(LT_REVISION)
63 AC_SUBST(LT_AGE)
64
65 dnl Specify a header configuration file
66 AC_CONFIG_HEADERS(config.h)
67
68 AM_MAINTAINER_MODE
69
70 dnl Checks for programs.
71 dnl AC_ARG_PROGRAM
72 AC_PROG_CC
73 AC_ISC_POSIX
74 AC_PROG_INSTALL
75 AC_PROG_LN_S
76 AC_PROG_MAKE_SET
77 AC_PROG_CPP
78 dnl AC_PROG_RANLIB
79 AM_PROG_LEX
80 AC_PROG_YACC
81 AC_PROG_LIBTOOL
82
83 SYLPHEED_ACLOCAL_INCLUDE(m4)
84   
85 dnl ******************************
86 dnl Checks for host
87 dnl ******************************
88 AC_CANONICAL_HOST
89
90 dnl Copied from the official gtk+-2 configure.in
91 AC_MSG_CHECKING([for some Win32 platform])
92 case "$host" in
93   *-*-mingw*|*-*-cygwin*)
94     platform_win32=yes
95     LDFLAGS="$LDFLAGS -mwindows"
96     ;;
97   *)
98     platform_win32=no
99     ;;
100 esac
101 AC_MSG_RESULT([$platform_win32])
102 AM_CONDITIONAL(PLATFORM_WIN32, test x"$platform_win32" = x"yes")
103
104 if test x"$platform_win32" = x"yes"; then
105     WINDRES=windres
106     AC_SUBST(WINDRES)
107 fi
108
109 AC_MSG_CHECKING([for native Win32])
110 case "$host" in
111   *-*-mingw*)
112     os_win32=yes
113     ;;
114   *)
115     os_win32=no
116     ;;
117 esac
118 AC_MSG_RESULT([$os_win32])
119 AM_CONDITIONAL(OS_WIN32, test x"$os_win32" = x"yes")
120
121 case "$target" in
122 *-darwin*)
123         CFLAGS="$CFLAGS -traditional-cpp -fno-common"
124         ;;
125 esac
126   
127 dnl Checks for iconv
128 AM_ICONV
129
130 dnl for gettext
131 ALL_LINGUAS="bg cs de el en_GB es fr hr hu it ja ko nl pl pt_BR ru sk sr sv zh_CN zh_TW.Big5"
132 AM_GNU_GETTEXT([use-libtool])
133 AM_GNU_GETTEXT_VERSION(0.12.1)
134 dnl AC_CHECK_FUNC(gettext, AC_CHECK_LIB(intl, gettext))
135 localedir='${prefix}/${DATADIRNAME}/locale'
136 AC_SUBST(localedir)
137
138 manualdir='${prefix}/${DATADIRNAME}/${PACKAGE}/manual'
139 AC_SUBST(manualdir)
140 faqdir='${prefix}/${DATADIRNAME}/${PACKAGE}/faq'
141 AC_SUBST(faqdir)
142
143 dnl Set PACKAGE_DATA_DIR in config.h.
144 if test "x${datadir}" = 'x${prefix}/share'; then
145   if test "x${prefix}" = "xNONE"; then
146     AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${ac_default_prefix}/share/${PACKAGE}", PACKAGE_DATA_DIR)
147   else
148     AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${prefix}/share/${PACKAGE}", PACKAGE_DATA_DIR)
149   fi
150 else
151   AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${datadir}/${PACKAGE}", PACKAGE_DATA_DIR)
152 fi
153
154 AC_CHECK_LIB(xpg4, setlocale)
155
156 dnl for GThread support (currently disabled)
157 dnl AC_ARG_ENABLE(threads,
158 dnl     [  --enable-threads        Enable multithread support [default=no]],
159 dnl     [use_threads=$enableval], [use_threads=no])
160
161 AC_MSG_CHECKING([whether to use threads])
162 if test x"$use_threads" = xyes ; then
163         AC_MSG_RESULT(yes)
164         if test ! -z `$GLIB_CONFIG --help 2>&1 |grep 'gthread'` ; then
165                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
166                 LIBS="$LIBS `$GLIB_CONFIG --libs gthread`"
167                 AC_DEFINE(USE_THREADS, 1, Whether to use multithread or not)
168         else
169                 AC_MSG_ERROR([Sylpheed requires GThread from GLib to use threading.])
170         fi
171 else
172         AC_MSG_RESULT(no)
173 fi
174
175 dnl Check for d_type member in struct dirent
176 AC_MSG_CHECKING([whether struct dirent has d_type member])
177 AC_CACHE_VAL(ac_cv_dirent_d_type,[
178         AC_TRY_COMPILE([#include <dirent.h>],
179                        [struct dirent d; d.d_type = DT_REG;],
180                        ac_cv_dirent_d_type=yes, ac_cv_dirent_d_type=no)
181 ])
182 AC_MSG_RESULT($ac_cv_dirent_d_type)
183 if test $ac_cv_dirent_d_type = yes; then
184         AC_DEFINE(HAVE_DIRENT_D_TYPE, 1,
185                   Define if `struct dirent' has `d_type' member.)
186 fi
187
188 dnl Checks for header files.
189 AC_HEADER_DIRENT
190 AC_HEADER_STDC
191 AC_HEADER_SYS_WAIT
192 AC_CHECK_HEADERS(fcntl.h sys/file.h unistd.h paths.h \
193                  sys/param.h sys/utsname.h sys/select.h \
194                  wchar.h wctype.h locale.h)
195
196 dnl alf - Check for apache installation f*ck up. apache may also install an 
197 dnl fnmatch, which includes their own regex stuff if USE_HSREGEX is defined
198 AC_TRY_COMPILE([#include <stdlib.h>
199                 #include <fnmatch.h>],
200         [int x = USE_HSREGEX;],
201         ac_cv_have_apache_fnmatch=yes, ac_cv_have_apache_fnmatch=no)
202 if test $ac_cv_have_apache_fnmatch = yes; then
203         AC_DEFINE(HAVE_APACHE_FNMATCH, 1, Define if you need to work around apache regex/fnmatch !KLUDGE!)
204 fi
205 AC_MSG_CHECKING([whether to use Apache regex header kludge])
206 AC_MSG_RESULT($ac_cv_have_apache_fnmatch)
207
208 dnl Checks for typedefs, structures, and compiler characteristics.
209 AC_C_CONST
210 AC_TYPE_OFF_T
211 AC_TYPE_PID_T
212 AC_TYPE_SIZE_T
213 AC_STRUCT_TM
214
215 dnl AC_CHECK_TYPE(wint_t, unsigned int) does not work because wint_t
216 dnl may be defined only in wchar.h (this happens with gcc-2.96).
217 dnl So we need to use this extended macro.
218 SYLPHEED_CHECK_TYPE(wint_t, unsigned int,
219 [
220 #if HAVE_WCHAR_H
221 #include <wchar.h>
222 #endif
223 ], Define to `unsigned int' if <stddef.h> or <wchar.h> doesn't define.)
224
225 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF, Used to test for a u32 typedef)
226 AC_CHECK_SIZEOF(unsigned short, 2)
227 AC_CHECK_SIZEOF(unsigned int, 4)
228 AC_CHECK_SIZEOF(unsigned long, 4)
229
230 dnl Checks for library functions.
231 AC_FUNC_ALLOCA
232 AC_CHECK_FUNCS(gethostname mkdir mktime socket strstr strchr \
233                wcsstr wcswcs iswalnum iswspace towlower \
234                wcslen wcscpy wcsncpy \
235                uname flock lockf inet_aton inet_addr \
236                fchmod mkstemp)
237
238 dnl *****************
239 dnl ** common code **
240 dnl *****************
241
242 dnl check for glib
243 AM_PATH_GLIB_2_0(2.0.0,,
244         AC_MSG_ERROR(Test for GLIB failed. See the file 'INSTALL' for help.),
245         gmodule gobject gthread)
246
247 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
248 syl_save_LIBS=$LIBS
249 LIBS="$LIBS $GTK_LIBS"
250 AC_CHECK_FUNCS(bind_textdomain_codeset)
251 LIBS=$syl_save_LIBS
252
253 dnl check for IPv6 option
254 AC_ARG_ENABLE(ipv6,
255         [  --disable-ipv6           Disable IPv6 support],
256         [ac_cv_enable_ipv6=$enableval], [ac_cv_enable_ipv6=yes])
257
258 dnl automated checks for IPv6 support.
259 AC_MSG_CHECKING([whether to use IPv6])
260 if test x"$ac_cv_enable_ipv6" = xyes; then
261         AC_MSG_RESULT(yes)
262         AC_MSG_CHECKING([for IPv6 support])
263         AC_CACHE_VAL(ac_cv_ipv6,[
264                 AC_TRY_COMPILE([#define INET6
265                                 #include <sys/types.h>
266                                 #include <netinet/in.h>],
267                         [int x = IPPROTO_IPV6; struct in6_addr a;],
268                         ac_cv_ipv6=yes, ac_cv_ipv6=no)
269         ])
270         AC_MSG_RESULT($ac_cv_ipv6)
271         if test $ac_cv_ipv6 = yes; then
272                 AC_DEFINE(INET6, 1, Define if you want IPv6 support.)
273         else
274                 AC_MSG_WARN(*** IPv6 will not be supported ***)
275                 ac_cv_enable_ipv6=no
276         fi
277 else
278         AC_MSG_RESULT(no)
279 fi
280
281 dnl Check for OpenSSL
282 AC_ARG_ENABLE(openssl,
283         [  --enable-openssl    Attempt to use OpenSSL for SSL support.],
284         [ac_cv_enable_openssl=$enableval], [ac_cv_enable_openssl=yes])
285 if test x"$ac_cv_enable_openssl" = xyes; then
286         PKG_CHECK_MODULES(OPENSSL, openssl >= 0.9.7, :, ac_cv_enable_openssl=no)
287         if test x$ac_cv_enable_openssl = xyes; then
288                 AC_DEFINE(USE_OPENSSL, 1, Define if you want OpenSSL support)
289         fi
290 fi
291 AC_SUBST(OPENSSL_CFLAGS)
292 AC_SUBST(OPENSSL_LIBS)
293
294 dnl password encryption
295 OLDLIBS=$LIBS
296 LIBS=
297 AC_SEARCH_LIBS(encrypt, crypt, [], AC_MSG_ERROR(['encrypt'-function not found.]))
298 CRYPT_LIBS=$LIBS
299 AC_SUBST(CRYPT_LIBS)
300 LIBS=$OLDLIBS
301
302 AC_ARG_WITH(passcrypt-key, [  --with-passcrypt-key=KEY     Key used to encode passwords (8 byte string)],
303             with_passcrypt_key="$withval", with_passcrypt_key="passkey0")
304 AC_SUBST(PASSCRYPT_KEY, $with_passcrypt_key)
305
306 dnl RC dir (will be default at a certain point in time)
307 AC_ARG_WITH(config-dir,    [  --with-config-dir=RCDIR      Local configuration dir (default: .sylpheed)],
308               ac_cv_with_config_dir="$withval", ac_cv_with_config_dir=".sylpheed")
309 if test x"$ac_cv_with_config_dir" = x""; then
310         ac_cv_with_config_dir=".sylpheed"
311 fi 
312 AC_DEFINE_UNQUOTED(CFG_RC_DIR, "$ac_cv_with_config_dir", Configuration directory)
313
314 dnl ************************
315 dnl ** GTK user interface **
316 dnl ************************
317
318 dnl Checks for GTK
319 AM_PATH_GTK_2_0(2.4.0,,
320         AC_MSG_ERROR(Test for GTK failed. See the file 'INSTALL' for help.))
321
322 dnl GNU/Aspell is used for spell checking
323 AC_ARG_ENABLE(aspell,
324         [  --enable-aspell         Enable GNU/aspell support [default=no]],
325         [ac_cv_enable_aspell=$enableval], [ac_cv_enable_aspell=no])
326 AC_MSG_CHECKING([whether to use GNU/aspell])
327 if test $ac_cv_enable_aspell = yes; then
328         AC_MSG_RESULT(yes)
329         AM_PATH_ASPELL(0.50, AC_DEFINE(USE_ASPELL, 1, Define if you use ASPELL to support spell checking),
330                       [use_aspell=no ac_cv_enable_aspell=no])
331 else
332         AC_MSG_RESULT(no)
333 fi
334
335 dnl want crash dialog
336 AC_ARG_ENABLE(crash-dialog,
337         [  --enable-crash-dialog   Enable crash dialog [default=no]],
338         [ac_cv_enable_crash_dialog=$enableval], [ac_cv_enable_crash_dialog=no])
339 if test $ac_cv_enable_crash_dialog = yes; then
340 dnl check if GDB is somewhere
341         AC_CHECK_PROG(ac_cv_enable_crash_dialog, gdb, yes, no)
342         AC_MSG_CHECKING([whether to use crash dialog])
343         if test $ac_cv_enable_crash_dialog = yes; then
344                 AC_DEFINE(CRASH_DIALOG, 1, Pop up crash dialog)
345         fi
346         AC_MSG_RESULT($ac_cv_enable_crash_dialog)
347 fi
348
349 dnl Check for X-Face support
350 AC_ARG_ENABLE(compface,
351         [  --disable-compface      Do not use compface (X-Face)],
352         [ac_cv_enable_compface=$enableval], [ac_cv_enable_compface=yes])
353 AC_MSG_CHECKING([whether to use compface])
354 if test x"$ac_cv_enable_compface" = xyes; then
355         AC_MSG_RESULT(yes)
356         AC_CHECK_LIB(compface, uncompface, 
357                 [AC_DEFINE(HAVE_LIBCOMPFACE, 1, Define if you want compface support.)],
358                 [ac_cv_enable_compface=no])
359         if test x"$ac_cv_enable_compface" = xyes; then
360                 COMPFACE_LIBS="-lcompface"
361         else
362                 COMPFACE_LIBS=""
363         fi
364         AC_SUBST(COMPFACE_LIBS)
365 else
366         AC_MSG_RESULT(no)
367 fi
368
369 dnl check for pthread support
370 AC_ARG_ENABLE(pthread,
371         [  --disable-pthread           Disable pthread support],
372         [ac_cv_enable_pthread=$enableval], [ac_cv_enable_pthread=yes])
373 AC_MSG_CHECKING([whether to use pthread])
374 if test x$ac_cv_enable_pthread = xno; then
375         AC_MSG_RESULT(no)
376 else
377         AC_MSG_RESULT(yes)
378
379         AC_CHECK_LIB(pthread, pthread_create, :, ac_cv_enable_pthread=no)
380         AC_CHECK_HEADERS(pthread.h, :, ac_cv_enable_pthread=no)
381
382         if test x$ac_cv_enable_pthread = xyes; then
383                 AC_DEFINE(USE_PTHREAD, 1, Define if you have pthread)
384                 PTHREAD_LIBS="-lpthread"
385         fi
386
387 fi
388 AC_SUBST(PTHREAD_LIBS)
389
390 dnl for LDAP support in addressbook
391 dnl no check for libraries; dynamically loaded
392 AC_ARG_ENABLE(ldap,
393         [  --enable-ldap           Enable LDAP support [default=no]],
394         [ac_cv_enable_ldap=$enableval], [ac_cv_enable_ldap=no])
395 AC_MSG_CHECKING([whether to use LDAP])
396 if test x"$ac_cv_enable_ldap" = xno; then
397         AC_MSG_RESULT(no)
398 elif test x"$ac_cv_enable_ldap" = xyes -a x"$ac_cv_enable_pthread" = xno; then
399         AC_MSG_RESULT(no - LDAP support needs pthread support)
400
401         ac_cv_enable_ldap=no
402 else
403         AC_MSG_RESULT(yes)
404
405         dnl check for available libraries, and pull them in
406         AC_CHECK_LIB(resolv, res_query, LDAP_LIBS="$LDAP_LIBS -lresolv")
407         AC_CHECK_LIB(socket, bind, LDAP_LIBS="$LDAP_LIBS -lsocket")
408         AC_CHECK_LIB(nsl, gethostbyaddr, LDAP_LIBS="$LDAP_LIBS -lnsl")
409         AC_CHECK_LIB(lber, ber_get_tag, LDAP_LIBS="$LDAP_LIBS -llber",,
410                      $LDAP_LIBS)
411
412         AC_CHECK_HEADERS(ldap.h lber.h,
413                          [ ac_cv_enable_ldap=yes ],
414                          [ ac_cv_enable_ldap=no ])
415
416         if test "$ac_cv_enable_ldap" = yes; then
417                 AC_CHECK_LIB(ldap, ldap_open,
418                              [ ac_cv_enable_ldap=yes ],
419                              [ ac_cv_enable_ldap=no ],
420                              $LDAP_LIBS)
421
422                 AC_CHECK_LIB(ldap, ldap_start_tls_s,
423                              [ ac_cv_have_tls=yes ],
424                              [ ac_cv_have_tls=no ])
425
426         fi
427
428         AC_MSG_CHECKING([whether ldap library is available])
429         AC_MSG_RESULT($ac_cv_enable_ldap)
430
431         AC_MSG_CHECKING([whether TLS library is available])
432         AC_MSG_RESULT($ac_cv_have_tls)
433
434         if test "$ac_cv_enable_ldap" = yes; then
435                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
436                 LDAP_LIBS="$LDAP_LIBS -lldap `$GLIB_CONFIG --libs gthread`"
437                 AC_DEFINE(USE_LDAP, 1, Define if you want LDAP support in addressbook.)
438                 AC_SUBST(LDAP_LIBS)
439                 if test "$ac_cv_have_tls" = yes; then
440                         AC_DEFINE(USE_LDAP_TLS, 1, Define if you want LDAP TLS support in addressbook.)
441                 fi
442         fi
443 fi
444
445 dnl for JPilot support in addressbook
446 dnl no check for libraries; these are dynamically loaded
447 AC_ARG_ENABLE(jpilot,
448         [  --enable-jpilot         Enable JPilot support [default=no]],
449         [ac_cv_enable_jpilot=$enableval], [ac_cv_enable_jpilot=no])
450 AC_MSG_CHECKING([whether to use JPilot])
451 if test "$ac_cv_enable_jpilot" = yes; then
452         AC_MSG_RESULT(yes)
453         AC_CHECK_HEADERS(pi-args.h pi-appinfo.h pi-address.h,
454                          [ AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ],
455                          [ ac_cv_enable_jpilot=no ])
456         if test "$ac_cv_enable_jpilot" = no; then
457                 AC_CHECK_HEADERS(libpisock/pi-args.h libpisock/pi-appinfo.h libpisock/pi-address.h,
458                                  [ ac_cv_enable_jpilot=yes
459                                    AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ])
460         fi
461
462         AC_CHECK_LIB(pisock, unpack_Address, [JPILOT_LIBS="-lpisock"], [JPILOT_LIBS="" ac_cv_enable_jpilot="no"])
463         if test x"$ac_cv_enable_jpilot" = xyes; then
464                 AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.)
465         else
466                 AC_MSG_NOTICE([JPilot support not available])
467         fi
468         AC_SUBST(JPILOT_LIBS)
469 else
470         AC_MSG_RESULT(no)
471 fi
472
473 dnl GPGME is used to support OpenPGP 
474 AC_ARG_ENABLE(gpgme,
475         [  --enable-gpgme          Enable GnuPG support using GPGME [default=no]],
476         [ac_cv_enable_gpgme=$enableval], [ac_cv_enable_gpgme=no])
477 AC_MSG_CHECKING([whether to use GPGME])
478 if test $ac_cv_enable_gpgme = yes; then
479         AC_MSG_RESULT(yes)
480         AM_PATH_GPGME(0.3.10, AC_DEFINE(USE_GPGME, 1, Define if you use GPGME to support OpenPGP.),
481                       [use_gpgme=no
482                        ac_cv_enable_gpgme=no])
483 else
484         AC_MSG_RESULT(no)
485 fi
486
487 dnl #######################################################################
488 dnl # Check for startup notification
489 dnl #######################################################################
490 AC_ARG_ENABLE(startup-notification, [  --disable-startup-notification    compile without startup notification support],,enable_startup_notification=yes)
491
492 if test "x$enable_startup_notification" = "xyes"; then
493         PKG_CHECK_MODULES(STARTUP_NOTIFICATION, libstartup-notification-1.0 >= 0.5,
494         [
495                 AC_DEFINE(HAVE_STARTUP_NOTIFICATION, 1, [Define if we're using libstartup-notification.])
496                 echo "Building with libstartup-notification"
497                 enable_startup_notification=yes
498         ],
499         [
500                 echo "Building without libstartup-notification"
501                 enable_startup_notification=no
502         ])
503
504         AC_SUBST(STARTUP_NOTIFICATION_CFLAGS)
505         AC_SUBST(STARTUP_NOTIFICATION_LIBS)
506 fi
507
508 dnl *************************
509 dnl ** section for plugins **
510 dnl *************************
511
512 PLUGINS=""
513
514 dnl --- Trayicon ---
515 AC_ARG_ENABLE(trayicon-plugin,
516         [  --disable-trayicon-plugin         Do not build System Tray Icon plugin],
517         [ac_cv_enable_trayicon_plugin=$enableval], [ac_cv_enable_trayicon_plugin=yes])
518 if test x"$ac_cv_enable_trayicon_plugin" = xyes; then
519         PLUGINS="trayicon $PLUGINS"
520 fi
521 AM_CONDITIONAL(BUILD_TRAYICON_PLUGIN, test x"$ac_cv_enable_trayicon_plugin" = xyes)
522
523 dnl --- SpamAssassin ---
524 AC_ARG_ENABLE(spamassassin-plugin,
525         [  --enable-spamassassin-plugin      Build SpamAssassin plugin [default=no]],
526         [ac_cv_enable_spamassassin_plugin=$enableval], [ac_cv_enable_spamassassin_plugin=no])
527 if test x"$ac_cv_enable_spamassassin_plugin" = xyes; then
528         AC_SPAMASSASSIN
529         PLUGINS="spamassassin $PLUGINS"
530 fi
531 AM_CONDITIONAL(BUILD_SPAMASSASSIN_PLUGIN, test x"$ac_cv_enable_spamassassin_plugin" = xyes)
532
533 dnl --- PGP/MIME ---
534 AC_ARG_ENABLE(pgpmime-plugin,
535         [  --disable-pgpmime-plugin           Do not build PGP/MIME plugin],
536         [ac_cv_enable_pgpmime_plugin=$enableval], [ac_cv_enable_pgpmime_plugin=yes])
537 if test x"$ac_cv_enable_pgpmime_plugin" = xyes; then
538         if test x"$ac_cv_enable_gpgme" != xyes; then
539                 ac_cv_enable_pgpmime_plugin=no
540         fi
541
542         if test x"$ac_cv_enable_pgpmime_plugin" = xyes; then
543                 PLUGINS="pgpmime $PLUGINS"
544         fi
545 fi
546 AM_CONDITIONAL(BUILD_PGPMIME_PLUGIN, test x"$ac_cv_enable_pgpmime_plugin" = xyes)
547
548 dnl --- MathML Viewer ---
549 AC_ARG_ENABLE(mathml-viewer-plugin,
550         [  --disable-mathml-viewer-plugin    Do not build MathML-Viewer plugin],
551         [ac_cv_enable_mathml_viewer_plugin=$enableval], [ac_cv_enable_mathml_viewer_plugin=yes])
552 if test x"$ac_cv_enable_mathml_viewer_plugin" = xyes; then
553         PKG_CHECK_MODULES(GTK_MATH_VIEW, gtkmathview >= 0.5, :, ac_cv_enable_mathml_viewer_plugin=no)
554
555         if test x"$ac_cv_enable_mathml_viewer_plugin" = xyes; then
556
557                 PLUGINS="mathml-viewer $PLUGINS"
558         fi
559 fi
560 AC_SUBST(GTK_MATH_VIEW_CFLAGS)
561 AC_SUBST(GTK_MATH_VIEW_LIBS)
562 AM_CONDITIONAL(BUILD_MATHML_VIEWER_PLUGIN, test x"$ac_cv_enable_mathml_viewer_plugin" = xyes)
563
564 dnl --- Image Viewer ---
565 AC_ARG_ENABLE(image-viewer-plugin,
566         [  --disable-image-viewer-plugin     Do not build image viewer plugin],
567         [ac_cv_enable_image_viewer_plugin=$enableval], [ac_cv_enable_image_viewer_plugin=yes])
568 if test x"$ac_cv_enable_image_viewer_plugin" = xyes; then
569         AC_ARG_ENABLE(gdk-pixbuf,
570                 [  --disable-gdk-pixbuf              Do not use gdk-pixbuf],
571                 [ac_cv_enable_gdk_pixbuf=$enableval], [ac_cv_enable_gdk_pixbuf=yes])
572         AC_ARG_ENABLE(imlib,
573                 [  --disable-imlib                   Do not use imlib],
574                 [ac_cv_enable_imlib=$enableval], [ac_cv_enable_imlib=yes])
575
576         if test "$ac_cv_enable_gdk_pixbuf" = yes; then
577                 PKG_CHECK_MODULES(GDK_PIXBUF, \
578                         [ gdk-pixbuf-2.0 ],
579                         [ AC_DEFINE(HAVE_GDK_PIXBUF, 1, Define if you use gdk-pixbuf to support image viewer) ],
580                         [ ac_cv_enable_gdk_pixbuf=no ])
581         fi
582
583         if test "$ac_cv_enable_gdk_pixbuf" = yes; then
584                 PLUGINS="image-viewer(gdk-pixbuf) $PLUGINS"
585         else
586                 ac_cv_enable_image_viewer_plugin=no
587         fi
588 fi
589 AM_CONDITIONAL(BUILD_IMAGE_VIEWER_PLUGIN, test x"$ac_cv_enable_image_viewer_plugin" = xyes)
590
591 dnl --- Dillo Viewer ---
592 AC_ARG_ENABLE(dillo-viewer-plugin,
593         [  --disable-dillo-viewer-plugin     Do not build Dillo plugin for html mail rendering],
594         [ac_cv_enable_dillo_viewer_plugin=$enableval], [ac_cv_enable_dillo_viewer_plugin=yes])
595 if test x"$ac_cv_enable_dillo_viewer_plugin" = xyes; then
596         PLUGINS="dillo-viewer $PLUGINS"
597 fi
598 AM_CONDITIONAL(BUILD_DILLO_VIEWER_PLUGIN, test x"$ac_cv_enable_dillo_viewer_plugin" = xyes)
599
600 dnl --- Demo ---
601 AC_ARG_ENABLE(demo-plugin,
602         [  --enable-demo-plugin              Build demo plugin [default=no]],
603         [ac_cv_enable_demo_plugin=$enableval], [ac_cv_enable_demo_plugin=no])
604 if test x"$ac_cv_enable_demo_plugin" = xyes; then
605         PLUGINS="demo $PLUGINS"
606 fi
607 AM_CONDITIONAL(BUILD_DEMO_PLUGIN, test x"$ac_cv_enable_demo_plugin" = xyes)
608
609 dnl --- ClamAV ---
610 AC_ARG_ENABLE(clamav-plugin,
611         [  --disable-clamav-plugin           Do not build Clam AntiVirus plugin],
612         [ac_cv_enable_clamav_plugin=$enableval], [ac_cv_enable_clamav_plugin=yes])
613 if test x"$ac_cv_enable_clamav_plugin" = xyes; then
614         AC_CHECK_LIB(clamav, cl_scanfile, clamav_lib=-lclamav, ac_cv_enable_clamav_plugin=no)
615         AC_CHECK_HEADERS(clamav.h, :, ac_cv_enable_clamav_plugin=no)
616         if test x"$ac_cv_enable_clamav_plugin" = xyes; then
617                 CLAMAV_LIBS="${clamav_lib}"
618
619                 PLUGINS="clamav $PLUGINS"
620         else
621                 AC_MSG_NOTICE([clamav library not found, will not build clamav plugin])
622         fi
623 fi
624 AC_SUBST(CLAMAV_LIBS)
625 AM_CONDITIONAL(BUILD_CLAMAV_PLUGIN, test x"$ac_cv_enable_clamav_plugin" = xyes)
626
627 dnl ****************************
628 dnl ** Final configure output **
629 dnl ****************************
630
631 AC_OUTPUT([
632 Makefile
633 sylpheed.spec
634 intl/Makefile
635 m4/Makefile
636 po/Makefile.in
637 src/common/version.h
638 src/Makefile
639 src/common/Makefile
640 src/common/passcrypt.h
641 src/gtk/Makefile
642 src/plugins/Makefile
643 src/plugins/demo/Makefile
644 src/plugins/spamassassin/Makefile
645 src/plugins/mathml_viewer/Makefile
646 src/plugins/dillo_viewer/Makefile
647 src/plugins/image_viewer/Makefile
648 src/plugins/trayicon/Makefile
649 src/plugins/trayicon/libeggtrayicon/Makefile
650 src/plugins/clamav/Makefile
651 src/plugins/pgpmime/Makefile
652 doc/Makefile
653 doc/faq/Makefile
654 doc/faq/de/Makefile
655 doc/faq/en/Makefile
656 doc/faq/es/Makefile
657 doc/faq/fr/Makefile
658 doc/faq/it/Makefile
659 doc/man/Makefile
660 doc/manual/Makefile
661 doc/manual/de/Makefile
662 doc/manual/en/Makefile
663 doc/manual/es/Makefile
664 doc/manual/fr/Makefile
665 doc/manual/ja/Makefile
666 tools/Makefile
667 config/Makefile
668 sylpheed-claws.pc
669 ])
670
671 dnl Output the configuration summary
672 echo ""
673 echo "$PACKAGE $VERSION"
674 echo ""
675 echo "GnuPG         : $ac_cv_enable_gpgme"
676 echo "JPilot        : $ac_cv_enable_jpilot"
677 echo "LDAP          : $ac_cv_enable_ldap"
678 echo "OpenSSL       : $ac_cv_enable_openssl"
679 echo "iconv         : $am_cv_func_iconv"
680 echo "compface      : $ac_cv_enable_compface"
681 echo "IPv6          : $ac_cv_enable_ipv6"
682 echo "GNU/aspell    : $ac_cv_enable_aspell"
683 echo "Crash dialog  : $ac_cv_enable_crash_dialog"
684 echo "Plugins       : $PLUGINS"
685 echo "Config dir    : $ac_cv_with_config_dir"
686 echo ""
687 echo "The binary will be installed in $prefix/bin"
688 echo ""
689 echo "Configure finished, type 'make' to build."