configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.50)
   3 AC_INIT(src/main.c)
   4 AC_CONFIG_AUX_DIR(config)
   5
   6 PACKAGE=sylpheed
   7
   8 dnl version number
   9 MAJOR_VERSION=0
  10 MINOR_VERSION=9
  11 MICRO_VERSION=3
  12 INTERFACE_AGE=0
  13 BINARY_AGE=0
  14 EXTRA_VERSION=claws
  15 VERSION=$MAJOR_VERSION.$MINOR_VERSION.$MICRO_VERSION$EXTRA_VERSION
  16
  17 dnl set $target
  18 AC_CANONICAL_SYSTEM
  19
  20 dnl
  21 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  22 dnl AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
  23 dnl AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
  24 AC_SUBST(PACKAGE)
  25 AC_SUBST(VERSION)
  26
  27 dnl GNOME installed?
  28 AC_PATH_PROG(GNOME_CONFIG, gnome-config, no)
  29 if test "$GNOME_CONFIG" != no; then
  30         gnomedatadir="`gnome-config --datadir`"
  31         gnomeprefix="`gnome-config --prefix`"
  32         if test "${prefix}" = "NONE"; then
  33                 gnomedatadir="${ac_default_prefix}/${gnomedatadir#${gnomeprefix}}"
  34         else
  35                 gnomedatadir="${prefix}/${gnomedatadir#${gnomeprefix}}"
  36         fi
  37         AC_SUBST(gnomedatadir)
  38 fi
  39 AM_CONDITIONAL(SYLPHEED_GNOME, test -n "$gnomedatadir")
  40
  41 dnl Claws version
  42 AC_DEFINE(CLAWS, 1, Compiling Claws branch of sylpheed)
  43
  44 dnl libtool versioning
  45 LT_RELEASE=$MAJOR_VERSION.$MINOR_VERSION
  46 LT_CURRENT=`expr $MICRO_VERSION - $INTERFACE_AGE`
  47 LT_REVISION=$INTERFACE_AGE
  48 LT_AGE=`expr $BINARY_AGE - $INTERFACE_AGE`
  49 AC_SUBST(LT_RELEASE)
  50 AC_SUBST(LT_CURRENT)
  51 AC_SUBST(LT_REVISION)
  52 AC_SUBST(LT_AGE)
  53
  54 dnl Specify a header configuration file
  55 AM_CONFIG_HEADER(config.h)
  56
  57 AM_MAINTAINER_MODE
  58
  59 dnl Checks for programs.
  60 dnl AC_ARG_PROGRAM
  61 AC_PROG_CC
  62 AC_ISC_POSIX
  63 AM_PROG_CC_STDC
  64 AC_PROG_INSTALL
  65 AC_PROG_LN_S
  66 AC_PROG_MAKE_SET
  67 AC_PROG_CPP
  68 dnl AC_PROG_RANLIB
  69 AM_PROG_LEX
  70 AC_PROG_YACC
  71 AM_PROG_LIBTOOL
  72
  73 SYLPHEED_ACLOCAL_INCLUDE(ac)
  74
  75 case "$target" in
  76 *-darwin*)
  77         CFLAGS="$CFLAGS -traditional-cpp -fno-common"
  78         ;;
  79 esac
  80
  81 AM_ICONV
  82
  83 dnl for gettext
  84 ALL_LINGUAS="bg cs de el en_GB es fr hr hu it ja ko nl pl pt_BR ru sr sv zh_TW.Big5"
  85 AM_GNU_GETTEXT([use-libtool])
  86 dnl AC_CHECK_FUNC(gettext, AC_CHECK_LIB(intl, gettext))
  87 localedir='${prefix}/${DATADIRNAME}/locale'
  88 AC_SUBST(localedir)
  89
  90 manualdir='${prefix}/${DATADIRNAME}/${PACKAGE}/manual'
  91 AC_SUBST(manualdir)
  92 faqdir='${prefix}/${DATADIRNAME}/${PACKAGE}/faq'
  93 AC_SUBST(faqdir)
  94
  95 dnl Set PACKAGE_DATA_DIR in config.h.
  96 if test "x${datadir}" = 'x${prefix}/share'; then
  97   if test "x${prefix}" = "xNONE"; then
  98     AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${ac_default_prefix}/share/${PACKAGE}", PACKAGE_DATA_DIR)
  99   else
 100     AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${prefix}/share/${PACKAGE}", PACKAGE_DATA_DIR)
 101   fi
 102 else
 103   AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${datadir}/${PACKAGE}", PACKAGE_DATA_DIR)
 104 fi
 105
 106 AC_CHECK_LIB(xpg4, setlocale)
 107
 108 dnl for GThread support (currently disabled)
 109 dnl AC_ARG_ENABLE(threads,
 110 dnl     [  --enable-threads        Enable multithread support [default=no]],
 111 dnl     [use_threads=$enableval], [use_threads=no])
 112
 113 AC_MSG_CHECKING([whether to use threads])
 114 if test x"$use_threads" = xyes ; then
 115         AC_MSG_RESULT(yes)
 116         if test ! -z `$GLIB_CONFIG --help 2>&1 |grep 'gthread'` ; then
 117                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
 118                 LIBS="$LIBS `$GLIB_CONFIG --libs gthread`"
 119                 AC_DEFINE(USE_THREADS, 1, Whether to use multithread or not)
 120         else
 121                 AC_MSG_ERROR([Sylpheed requires GThread from GLib to use threading.])
 122         fi
 123 else
 124         AC_MSG_RESULT(no)
 125 fi
 126
 127 dnl Checks for header files.
 128 AC_HEADER_DIRENT
 129 AC_HEADER_STDC
 130 AC_HEADER_SYS_WAIT
 131 AC_CHECK_HEADERS(fcntl.h sys/file.h unistd.h paths.h \
 132                  sys/param.h sys/utsname.h sys/select.h \
 133                  wchar.h wctype.h locale.h)
 134
 135 dnl alf - Check for apache installation f*ck up. apache may also install an
 136 dnl fnmatch, which includes their own regex stuff if USE_HSREGEX is defined
 137 AC_TRY_COMPILE([#include <stdlib.h>
 138                 #include <fnmatch.h>],
 139         [int x = USE_HSREGEX;],
 140         ac_cv_have_apache_fnmatch=yes, ac_cv_have_apache_fnmatch=no)
 141 if test $ac_cv_have_apache_fnmatch = yes; then
 142         AC_DEFINE(HAVE_APACHE_FNMATCH, 1, Define if you need to work around apache regex/fnmatch !KLUDGE!)
 143 fi
 144 AC_MSG_CHECKING([whether to use Apache regex header kludge])
 145 AC_MSG_RESULT($ac_cv_have_apache_fnmatch)
 146
 147 dnl Checks for typedefs, structures, and compiler characteristics.
 148 AC_C_CONST
 149 AC_TYPE_OFF_T
 150 AC_TYPE_PID_T
 151 AC_TYPE_SIZE_T
 152 AC_STRUCT_TM
 153
 154 dnl AC_CHECK_TYPE(wint_t, unsigned int) does not work because wint_t
 155 dnl may be defined only in wchar.h (this happens with gcc-2.96).
 156 dnl So we need to use this extended macro.
 157 SYLPHEED_CHECK_TYPE(wint_t, unsigned int,
 158 [
 159 #if HAVE_WCHAR_H
 160 #include <wchar.h>
 161 #endif
 162 ], Define to `unsigned int' if <stddef.h> or <wchar.h> doesn't define.)
 163
 164 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF, Used to test for a u32 typedef)
 165 AC_CHECK_SIZEOF(unsigned short, 2)
 166 AC_CHECK_SIZEOF(unsigned int, 4)
 167 AC_CHECK_SIZEOF(unsigned long, 4)
 168
 169 dnl Checks for library functions.
 170 AC_FUNC_ALLOCA
 171 AC_CHECK_FUNCS(gethostname mkdir mktime socket strstr strchr \
 172                wcsstr wcswcs iswalnum iswspace towlower \
 173                wcslen wcscpy wcsncpy \
 174                uname flock lockf inet_aton inet_addr \
 175                fchmod mkstemp)
 176
 177 dnl *****************
 178 dnl ** common code **
 179 dnl *****************
 180
 181 dnl check for glib
 182 AM_PATH_GLIB(1.2.6,,
 183         AC_MSG_ERROR(Test for GLIB failed. See the file 'INSTALL' for help.),
 184         gthread)
 185
 186 dnl check for IPv6 option
 187 AC_ARG_ENABLE(ipv6,
 188         [  --enable-ipv6           Enable IPv6 support [default=no]],
 189         [ac_cv_enable_ipv6=$enableval], [ac_cv_enable_ipv6=no])
 190
 191 dnl automated checks for IPv6 support.
 192 AC_MSG_CHECKING([whether to use IPv6])
 193 if test x"$ac_cv_enable_ipv6" = xyes; then
 194         AC_MSG_RESULT(yes)
 195         AC_MSG_CHECKING([for IPv6 support])
 196         AC_CACHE_VAL(ac_cv_ipv6,[
 197                 AC_TRY_COMPILE([#define INET6
 198                                 #include <sys/types.h>
 199                                 #include <netinet/in.h>],
 200                         [int x = IPPROTO_IPV6; struct in6_addr a;],
 201                         ac_cv_ipv6=yes, ac_cv_ipv6=no)
 202         ])
 203         AC_MSG_RESULT($ac_cv_ipv6)
 204         if test $ac_cv_ipv6 = yes; then
 205                 AC_DEFINE(INET6, 1, Define if you want IPv6 support.)
 206         else
 207                 AC_MSG_WARN(*** IPv6 will not be supported ***)
 208                 ac_cv_enable_ipv6=no
 209         fi
 210 else
 211         AC_MSG_RESULT(no)
 212 fi
 213
 214 dnl Check for OpenSSL
 215 AM_PATH_OPENSSL
 216
 217 dnl Key for password encryption
 218 AC_ARG_WITH(passcrypt-key, [  --with-passcrypt-key=KEY     Key used to encode passwords (8 byte string)],
 219             with_passcrypt_key="$withval", with_passcrypt_key="passkey0")
 220 AC_SUBST(PASSCRYPT_KEY, $with_passcrypt_key)
 221
 222 dnl RC dir (will be default at a certain point in time)
 223 AC_ARG_WITH(config-dir,    [  --with-config-dir=RCDIR      Local configuration dir (default: .sylpheed)],
 224               ac_cv_with_config_dir="$withval", ac_cv_with_config_dir=".sylpheed")
 225 if test x"$ac_cv_with_config_dir" = x""; then
 226         ac_cv_with_config_dir=".sylpheed"
 227 fi
 228 AC_DEFINE_UNQUOTED(CFG_RC_DIR, "$ac_cv_with_config_dir", Configuration directory)
 229
 230 dnl ************************
 231 dnl ** GTK user interface **
 232 dnl ************************
 233
 234 dnl Checks for GTK
 235 AM_PATH_GTK(1.2.6,,
 236         AC_MSG_ERROR(Test for GTK failed. See the file 'INSTALL' for help.))
 237
 238 dnl check if gdk / gtk was compiled with USE_XIM
 239 AC_MSG_CHECKING([whether GTK was compiled with XIM support])
 240 CFLAGS_SAVE="$CFLAGS"
 241 LDFLAGS_SAVE="$LDFLAGS"
 242 CFLAGS="$CFLAGS `$GTK_CONFIG --cflags`"
 243 LDFLAGS="$LDFLAGS `$GTK_CONFIG --libs`"
 244 AC_CACHE_VAL(ac_cv_use_xim, [
 245         AC_TRY_LINK_FUNC([gdk_ic_attr_new],
 246                          ac_cv_use_xim=yes, ac_cv_use_xim=no)
 247 ])
 248 AC_MSG_RESULT($ac_cv_use_xim)
 249 if test $ac_cv_use_xim = yes; then
 250         AC_DEFINE(USE_XIM, 1, Whether GTK was compiled with XIM support or not)
 251 fi
 252 CFLAGS="$CFLAGS_SAVE"
 253 LDFLAGS="$LDFLAGS_SAVE"
 254
 255 dnl GNU/Aspell is used for spell checking
 256 AC_ARG_ENABLE(aspell,
 257         [  --enable-aspell         Enable GNU/aspell support [default=no]],
 258         [ac_cv_enable_aspell=$enableval], [ac_cv_enable_aspell=no])
 259 AC_MSG_CHECKING([whether to use GNU/aspell])
 260 if test $ac_cv_enable_aspell = yes; then
 261         AC_MSG_RESULT(yes)
 262         AM_PATH_ASPELL(0.50, AC_DEFINE(USE_ASPELL, 1, Define if you use ASPELL to support spell checking),
 263                       [use_aspell=no ac_cv_enable_aspell=no])
 264 else
 265         AC_MSG_RESULT(no)
 266 fi
 267
 268 dnl want crash dialog
 269 AC_ARG_ENABLE(crash-dialog,
 270         [  --enable-crash-dialog   Enable crash dialog [default=no]],
 271         [ac_cv_enable_crash_dialog=$enableval], [ac_cv_enable_crash_dialog=no])
 272 if test $ac_cv_enable_crash_dialog = yes; then
 273 dnl check if GDB is somewhere
 274         AC_CHECK_PROG(ac_cv_enable_crash_dialog, gdb, yes, no)
 275         AC_MSG_CHECKING([whether to use crash dialog])
 276         if test $ac_cv_enable_crash_dialog = yes; then
 277                 AC_DEFINE(CRASH_DIALOG, 1, Pop up crash dialog)
 278         fi
 279         AC_MSG_RESULT($ac_cv_enable_crash_dialog)
 280 fi
 281
 282 dnl Check for X-Face support
 283 AC_ARG_ENABLE(compface,
 284         [  --disable-compface      Do not use compface (X-Face)],
 285         [ac_cv_enable_compface=$enableval], [ac_cv_enable_compface=yes])
 286 if test "$ac_cv_enable_compface" = yes; then
 287         AC_CHECK_LIB(compface, uncompface,,[ac_cv_enable_compface=no])
 288 fi
 289
 290 dnl for LDAP support in addressbook
 291 dnl no check for libraries; dynamically loaded
 292 AC_ARG_ENABLE(ldap,
 293         [  --enable-ldap           Enable LDAP support [default=no]],
 294         [ac_cv_enable_ldap=$enableval], [ac_cv_enable_ldap=no])
 295 AC_MSG_CHECKING([whether to use LDAP])
 296 if test "$ac_cv_enable_ldap" = yes; then
 297         AC_MSG_RESULT(yes)
 298
 299         dnl check for available libraries, and pull them in
 300         AC_CHECK_LIB(resolv, res_query, LDAP_LIBS="$LDAP_LIBS -lresolv")
 301         AC_CHECK_LIB(socket, bind, LDAP_LIBS="$LDAP_LIBS -lsocket")
 302         AC_CHECK_LIB(nsl, gethostbyaddr, LDAP_LIBS="$LDAP_LIBS -lnsl")
 303         AC_CHECK_LIB(lber, ber_get_tag, LDAP_LIBS="$LDAP_LIBS -llber",,
 304                      $LDAP_LIBS)
 305
 306         dnl we need libpthread for sylpheed ldap,  until we find
 307         dnl a better way to handle ldap requests asynchronously...
 308         AC_CHECK_LIB(pthread, pthread_create, LDAP_LIBS="$LDAP_LIBS -lpthread")
 309
 310         AC_CHECK_HEADERS(ldap.h lber.h pthread.h,
 311                          [ ac_cv_enable_ldap=yes ],
 312                          [ ac_cv_enable_ldap=no ])
 313
 314         if test "$ac_cv_enable_ldap" = yes; then
 315                 AC_CHECK_LIB(ldap, ldap_open,
 316                              [ ac_cv_enable_ldap=yes ],
 317                              [ ac_cv_enable_ldap=no ],
 318                              $LDAP_LIBS)
 319         fi
 320
 321         AC_MSG_CHECKING([whether ldap library is available])
 322         AC_MSG_RESULT($ac_cv_enable_ldap)
 323
 324         if test "$ac_cv_enable_ldap" = yes; then
 325                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
 326                 LDAP_LIBS="$LDAP_LIBS -lldap `$GLIB_CONFIG --libs gthread`"
 327                 AC_DEFINE(USE_LDAP, 1, Define if you want LDAP support in addressbook.)
 328                 AC_SUBST(LDAP_LIBS)
 329         fi
 330 else
 331         AC_MSG_RESULT(no)
 332 fi
 333
 334 dnl for JPilot support in addressbook
 335 dnl no check for libraries; these are dynamically loaded
 336 AC_ARG_ENABLE(jpilot,
 337         [  --enable-jpilot         Enable JPilot support [default=no]],
 338         [ac_cv_enable_jpilot=$enableval], [ac_cv_enable_jpilot=no])
 339 AC_MSG_CHECKING([whether to use JPilot])
 340 if test "$ac_cv_enable_jpilot" = yes; then
 341         AC_MSG_RESULT(yes)
 342         AC_CHECK_HEADERS(pi-args.h pi-appinfo.h pi-address.h,
 343                          [ AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ],
 344                          [ ac_cv_enable_jpilot=no ])
 345         if test "$ac_cv_enable_jpilot" = no; then
 346                 AC_CHECK_HEADERS(libpisock/pi-args.h libpisock/pi-appinfo.h libpisock/pi-address.h,
 347                                  [ ac_cv_enable_jpilot=yes
 348                                    AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ])
 349         fi
 350         AC_MSG_CHECKING([whether jpilot is available])
 351         AC_MSG_RESULT($ac_cv_enable_jpilot)
 352
 353         if test "$ac_cv_enable_jpilot" = yes; then
 354                 LIBS="$LIBS -lpisock"
 355         fi
 356 else
 357         AC_MSG_RESULT(no)
 358 fi
 359
 360 dnl GPGME is used to support OpenPGP
 361 AC_ARG_ENABLE(gpgme,
 362         [  --enable-gpgme          Enable GnuPG support using GPGME [default=no]],
 363         [ac_cv_enable_gpgme=$enableval], [ac_cv_enable_gpgme=no])
 364 AC_MSG_CHECKING([whether to use GPGME])
 365 if test $ac_cv_enable_gpgme = yes; then
 366         AC_MSG_RESULT(yes)
 367         AM_PATH_GPGME(0.3.10, AC_DEFINE(USE_GPGME, 1, Define if you use GPGME to support OpenPGP.),
 368                       [use_gpgme=no
 369                        ac_cv_enable_gpgme=no])
 370 else
 371         AC_MSG_RESULT(no)
 372 fi
 373
 374 dnl *************************
 375 dnl ** section for plugins **
 376 dnl *************************
 377
 378 PLUGINS=""
 379
 380 AC_ARG_ENABLE(trayicon-plugin,
 381         [  --enable-trayicon-plugin   System Tray Icon [default=no]],
 382         [ac_cv_enable_trayicon_plugin=$enableval], [ac_cv_enable_trayicon_plugin=no])
 383 AM_CONDITIONAL(BUILD_TRAYICON_PLUGIN, test x"$ac_cv_enable_trayicon_plugin" = xyes)
 384 if test x"$ac_cv_enable_trayicon_plugin" = xyes; then
 385         PLUGINS="trayicon $PLUGINS"
 386 fi
 387
 388 AC_ARG_ENABLE(spamassassin-plugin,
 389         [  --enable-spamassassin-plugin    Build SpamAssassin plugin [default=no]],
 390         [ac_cv_enable_spamassassin_plugin=$enableval], [ac_cv_enable_spamassassin_plugin=no])
 391 AM_CONDITIONAL(BUILD_SPAMASSASSIN_PLUGIN, test x"$ac_cv_enable_spamassassin_plugin" = xyes)
 392 if test x"$ac_cv_enable_spamassassin_plugin" = xyes; then
 393         AC_SPAMASSASSIN
 394         PLUGINS="spamassassin $PLUGINS"
 395 fi
 396
 397 AC_ARG_ENABLE(mathml-viewer-plugin,
 398         [  --enable-mathml-viewer-plugin    Build MathML-Viewer plugin [default=no]],
 399         [ac_cv_enable_mathml_viewer_plugin=$enableval], [ac_cv_enable_mathml_viewer_plugin=no])
 400 AM_CONDITIONAL(BUILD_MATHML_VIEWER_PLUGIN, test x"$ac_cv_enable_mathml_viewer_plugin" = xyes)
 401 if test x"$ac_cv_enable_mathml_viewer_plugin" = xyes; then
 402         PKG_CHECK_MODULES(GTK_MATH_VIEW, gtkmathview >= 0.4.2)
 403         AC_SUBST(GTK_MATH_VIEW_CFLAGS)
 404         AC_SUBST(GTK_MATH_VIEW_LIBS)
 405
 406         PLUGINS="mathml-viewer $PLUGINS"
 407 fi
 408
 409 AC_ARG_ENABLE(image-viewer-plugin,
 410         [  --disable-image-viewer-plugin   Do not build image viewer plugin],
 411         [ac_cv_enable_image_viewer_plugin=$enableval], [ac_cv_enable_image_viewer_plugin=yes])
 412 if test x"$ac_cv_enable_image_viewer_plugin" = xyes; then
 413         AC_ARG_ENABLE(gdk-pixbuf,
 414                 [  --disable-gdk-pixbuf    Do not use gdk-pixbuf],
 415                 [ac_cv_enable_gdk_pixbuf=$enableval], [ac_cv_enable_gdk_pixbuf=yes])
 416         AC_ARG_ENABLE(imlib,
 417                 [  --disable-imlib         Do not use imlib],
 418                 [ac_cv_enable_imlib=$enableval], [ac_cv_enable_imlib=yes])
 419
 420         if test "$ac_cv_enable_gdk_pixbuf" = yes; then
 421                 AM_PATH_GDK_PIXBUF(0.8.0,
 422                         [AC_DEFINE(HAVE_GDK_PIXBUF, 1, Define if you use gdk-pixbuf to support image viewer)
 423                          ac_cv_enable_imlib=no], [ac_cv_enable_gdk_pixbuf=no])
 424         fi
 425         if test "$ac_cv_enable_imlib" = yes; then
 426                 AM_PATH_GDK_IMLIB(1.9,
 427                         AC_DEFINE(HAVE_GDK_IMLIB, 1, Define if you use gdk_imlib to support image viewer),
 428                         [ac_cv_enable_imlib=no])
 429         fi
 430         if test x"$ac_cv_enable_gdk_pixbuf" = xno -a x"$ac_cv_enable_imlib" = xno; then
 431                 $ac_cv_enable_image_viewer_plugin = no
 432         fi
 433 fi
 434 AM_CONDITIONAL(BUILD_IMAGE_VIEWER_PLUGIN, test x"$ac_cv_enable_image_viewer_plugin" = xyes)
 435 if test x"$ac_cv_enable_image_viewer_plugin" = xyes; then
 436         if test "$ac_cv_enable_gdk_pixbuf" = yes; then
 437                 PLUGINS="image-viewer(gdk-pixbuf) $PLUGINS"
 438         elif test "$ac_cv_enable_imlib" = yes; then
 439                 PLUGINS="image-viewer(gdk_imlib) $PLUGINS"
 440         fi
 441 fi
 442
 443 AC_ARG_ENABLE(dillo-viewer-plugin,
 444         [  --enable-dillo-viewer-plugin   Build Dillo plugin for html mail rendering [default=no]],
 445         [ac_cv_enable_dillo_viewer_plugin=$enableval], [ac_cv_enable_dillo_viewer_plugin=no])
 446 AM_CONDITIONAL(BUILD_DILLO_VIEWER_PLUGIN, test x"$ac_cv_enable_dillo_viewer_plugin" = xyes)
 447 if test x"$ac_cv_enable_dillo_viewer_plugin" = xyes; then
 448         PLUGINS="dillo-viewer $PLUGINS"
 449 fi
 450
 451 AC_ARG_ENABLE(demo-plugin,
 452         [  --enable-demo-plugin    Build demo plugin [default=no]],
 453         [ac_cv_enable_demo_plugin=$enableval], [ac_cv_enable_demo_plugin=no])
 454 AM_CONDITIONAL(BUILD_DEMO_PLUGIN, test x"$ac_cv_enable_demo_plugin" = xyes)
 455 if test x"$ac_cv_enable_demo_plugin" = xyes; then
 456         PLUGINS="demo $PLUGINS"
 457 fi
 458
 459 AC_ARG_ENABLE(clamav-plugin,
 460         [  --enable-clamav-plugin    Build Clam AntiVirus plugin [default=no]],
 461         [ac_cv_enable_clamav_plugin=$enableval], [ac_cv_enable_clamav_plugin=no])
 462 AM_CONDITIONAL(BUILD_CLAMAV_PLUGIN, test x"$ac_cv_enable_clamav_plugin" = xyes)
 463 if test x"$ac_cv_enable_clamav_plugin" = xyes; then
 464         AC_CHECK_LIB(clamav, cl_scanfile, clamav_lib=-lclamav)
 465         if test -z "${clamav_lib}"
 466         then
 467                 AC_MSG_ERROR(clamav library not found)
 468         fi
 469         CLAMAV_LIBS="${clamav_lib}"
 470         AC_SUBST(CLAMAV_LIBS)
 471
 472         PLUGINS="clamav $PLUGINS"
 473 fi
 474
 475 dnl ****************************
 476 dnl ** Final configure output **
 477 dnl ****************************
 478
 479 AC_OUTPUT([
 480 Makefile
 481 sylpheed.spec
 482 intl/Makefile
 483 ac/Makefile
 484 po/Makefile.in
 485 src/common/version.h
 486 src/Makefile
 487 src/common/Makefile
 488 src/common/passcrypt.h
 489 src/gtk/Makefile
 490 src/plugins/Makefile
 491 src/plugins/demo/Makefile
 492 src/plugins/spamassassin/Makefile
 493 src/plugins/mathml_viewer/Makefile
 494 src/plugins/dillo_viewer/Makefile
 495 src/plugins/image_viewer/Makefile
 496 src/plugins/trayicon/Makefile
 497 src/plugins/trayicon/libeggtrayicon/Makefile
 498 src/plugins/clamav/Makefile
 499 faq/Makefile
 500 faq/de/Makefile
 501 faq/en/Makefile
 502 faq/es/Makefile
 503 faq/fr/Makefile
 504 faq/it/Makefile
 505 man/Makefile
 506 manual/Makefile
 507 manual/de/Makefile
 508 manual/en/Makefile
 509 manual/es/Makefile
 510 manual/fr/Makefile
 511 manual/ja/Makefile
 512 tools/Makefile
 513 config/Makefile
 514 ])
 515
 516 dnl Output the configuration summary
 517 echo ""
 518 echo "$PACKAGE $VERSION"
 519 echo ""
 520 echo "GnuPG         : $ac_cv_enable_gpgme"
 521 echo "JPilot        : $ac_cv_enable_jpilot"
 522 echo "LDAP          : $ac_cv_enable_ldap"
 523 echo "OpenSSL       : $ac_cv_enable_openssl"
 524 echo "iconv         : $am_cv_func_iconv"
 525 echo "compface      : $ac_cv_enable_compface"
 526 echo "IPv6          : $ac_cv_enable_ipv6"
 527 echo "GNU/aspell    : $ac_cv_enable_aspell"
 528 echo "Crash dialog  : $ac_cv_enable_crash_dialog"
 529 echo "Plugins       : $PLUGINS"
 530 echo "Config dir    : $ac_cv_with_config_dir"
 531 echo ""
 532 echo "The binary will be installed in $prefix/bin"
 533 echo ""
 534 echo "Configure finished, type 'make' to build."