611a58875daf2bd3510a7d5a7288762a149e6f59
[claws.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script.
2 AC_PREREQ(2.50)
3 AC_INIT(src/main.c)
4 AC_CONFIG_AUX_DIR(config)
5
6 PACKAGE=sylpheed-claws
7
8 dnl version number
9 MAJOR_VERSION=0
10 MINOR_VERSION=9
11 MICRO_VERSION=12
12 INTERFACE_AGE=0
13 BINARY_AGE=0
14 EXTRA_VERSION=35
15 EXTRA_RELEASE=
16
17 if test \( $EXTRA_VERSION -eq 0 \) -o \( "x$EXTRA_RELEASE" != "x" \); then
18     VERSION=${MAJOR_VERSION}.${MINOR_VERSION}.${MICRO_VERSION}${EXTRA_RELEASE}
19 else
20     VERSION=${MAJOR_VERSION}.${MINOR_VERSION}.${MICRO_VERSION}cvs${EXTRA_VERSION}
21 fi
22
23 dnl set $target
24 AC_CANONICAL_SYSTEM
25
26 dnl
27 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
28 dnl AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
29 dnl AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
30 AC_SUBST(PACKAGE)
31 AC_SUBST(VERSION)
32 AC_SUBST(MAJOR_VERSION)
33 AC_SUBST(MINOR_VERSION)
34 AC_SUBST(MICRO_VERSION)
35 AC_SUBST(EXTRA_VERSION)
36
37 dnl GNOME installed?
38 AC_PATH_PROG(GNOME_CONFIG, gnome-config, no)
39 if test "$GNOME_CONFIG" != no; then
40         gnomedatadir="`gnome-config --datadir`"
41         gnomeprefix="`gnome-config --prefix`"
42         if test "${prefix}" = "NONE"; then
43                 gnomedatadir="${ac_default_prefix}/${gnomedatadir#${gnomeprefix}}"
44         else
45                 gnomedatadir="${prefix}/${gnomedatadir#${gnomeprefix}}"
46         fi
47         AC_SUBST(gnomedatadir)
48 fi
49 AM_CONDITIONAL(SYLPHEED_GNOME, test -n "$gnomedatadir")
50
51 dnl Claws version
52 AC_DEFINE(CLAWS, 1, Compiling Claws branch of sylpheed)
53
54 dnl libtool versioning
55 LT_RELEASE=$MAJOR_VERSION.$MINOR_VERSION
56 LT_CURRENT=`expr $MICRO_VERSION - $INTERFACE_AGE`
57 LT_REVISION=$INTERFACE_AGE
58 LT_AGE=`expr $BINARY_AGE - $INTERFACE_AGE`
59 AC_SUBST(LT_RELEASE)
60 AC_SUBST(LT_CURRENT)
61 AC_SUBST(LT_REVISION)
62 AC_SUBST(LT_AGE)
63
64 dnl Specify a header configuration file
65 AC_CONFIG_HEADERS(config.h)
66
67 AM_MAINTAINER_MODE
68
69 dnl Checks for programs.
70 dnl AC_ARG_PROGRAM
71 AC_PROG_CC
72 AC_ISC_POSIX
73 AC_PROG_INSTALL
74 AC_PROG_LN_S
75 AC_PROG_MAKE_SET
76 AC_PROG_CPP
77 dnl AC_PROG_RANLIB
78 AM_PROG_LEX
79 AC_PROG_YACC
80 AC_PROG_LIBTOOL
81
82 SYLPHEED_ACLOCAL_INCLUDE(m4)
83
84 case "$target" in
85 *-darwin*)
86         CFLAGS="$CFLAGS -traditional-cpp -fno-common"
87         ;;
88 esac
89
90 AM_ICONV
91
92 dnl for gettext
93 ALL_LINGUAS="bg cs de el en_GB es fr hr hu it ja ko nl pl pt_BR ru sk sr sv zh_CN zh_TW.Big5"
94 AM_GNU_GETTEXT([use-libtool])
95 AM_GNU_GETTEXT_VERSION(0.12.1)
96 dnl AC_CHECK_FUNC(gettext, AC_CHECK_LIB(intl, gettext))
97 localedir='${datadir}/locale'
98 AC_SUBST(localedir)
99
100 manualdir='${prefix}/${DATADIRNAME}/${PACKAGE}/manual'
101 AC_SUBST(manualdir)
102 faqdir='${prefix}/${DATADIRNAME}/${PACKAGE}/faq'
103 AC_SUBST(faqdir)
104
105 dnl Set PACKAGE_DATA_DIR in config.h.
106 if test "x${datadir}" = 'x${prefix}/share'; then
107   if test "x${prefix}" = "xNONE"; then
108     AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${ac_default_prefix}/share/${PACKAGE}", PACKAGE_DATA_DIR)
109   else
110     AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${prefix}/share/${PACKAGE}", PACKAGE_DATA_DIR)
111   fi
112 else
113   AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${datadir}/${PACKAGE}", PACKAGE_DATA_DIR)
114 fi
115
116 AC_CHECK_LIB(xpg4, setlocale)
117
118 dnl for GThread support (currently disabled)
119 dnl AC_ARG_ENABLE(threads,
120 dnl     [  --enable-threads        Enable multithread support [default=no]],
121 dnl     [use_threads=$enableval], [use_threads=no])
122
123 AC_MSG_CHECKING([whether to use threads])
124 if test x"$use_threads" = xyes ; then
125         AC_MSG_RESULT(yes)
126         if test ! -z `$GLIB_CONFIG --help 2>&1 |grep 'gthread'` ; then
127                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
128                 LIBS="$LIBS `$GLIB_CONFIG --libs gthread`"
129                 AC_DEFINE(USE_THREADS, 1, Whether to use multithread or not)
130         else
131                 AC_MSG_ERROR([Sylpheed requires GThread from GLib to use threading.])
132         fi
133 else
134         AC_MSG_RESULT(no)
135 fi
136
137 dnl Check for d_type member in struct dirent
138 AC_MSG_CHECKING([whether struct dirent has d_type member])
139 AC_CACHE_VAL(ac_cv_dirent_d_type,[
140         AC_TRY_COMPILE([#include <dirent.h>],
141                        [struct dirent d; d.d_type = DT_REG;],
142                        ac_cv_dirent_d_type=yes, ac_cv_dirent_d_type=no)
143 ])
144 AC_MSG_RESULT($ac_cv_dirent_d_type)
145 if test $ac_cv_dirent_d_type = yes; then
146         AC_DEFINE(HAVE_DIRENT_D_TYPE, 1,
147                   Define if `struct dirent' has `d_type' member.)
148 fi
149
150 dnl Checks for header files.
151 AC_HEADER_DIRENT
152 AC_HEADER_STDC
153 AC_HEADER_SYS_WAIT
154 AC_CHECK_HEADERS(fcntl.h sys/file.h unistd.h paths.h \
155                  sys/param.h sys/utsname.h sys/select.h \
156                  wchar.h wctype.h locale.h)
157
158 dnl alf - Check for apache installation f*ck up. apache may also install an 
159 dnl fnmatch, which includes their own regex stuff if USE_HSREGEX is defined
160 AC_TRY_COMPILE([#include <stdlib.h>
161                 #include <fnmatch.h>],
162         [int x = USE_HSREGEX;],
163         ac_cv_have_apache_fnmatch=yes, ac_cv_have_apache_fnmatch=no)
164 if test $ac_cv_have_apache_fnmatch = yes; then
165         AC_DEFINE(HAVE_APACHE_FNMATCH, 1, Define if you need to work around apache regex/fnmatch !KLUDGE!)
166 fi
167 AC_MSG_CHECKING([whether to use Apache regex header kludge])
168 AC_MSG_RESULT($ac_cv_have_apache_fnmatch)
169
170 dnl Checks for typedefs, structures, and compiler characteristics.
171 AC_C_CONST
172 AC_TYPE_OFF_T
173 AC_TYPE_PID_T
174 AC_TYPE_SIZE_T
175 AC_STRUCT_TM
176
177 dnl AC_CHECK_TYPE(wint_t, unsigned int) does not work because wint_t
178 dnl may be defined only in wchar.h (this happens with gcc-2.96).
179 dnl So we need to use this extended macro.
180 SYLPHEED_CHECK_TYPE(wint_t, unsigned int,
181 [
182 #if HAVE_WCHAR_H
183 #include <wchar.h>
184 #endif
185 ], Define to `unsigned int' if <stddef.h> or <wchar.h> doesn't define.)
186
187 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF, Used to test for a u32 typedef)
188 AC_CHECK_SIZEOF(unsigned short, 2)
189 AC_CHECK_SIZEOF(unsigned int, 4)
190 AC_CHECK_SIZEOF(unsigned long, 4)
191
192 dnl Checks for library functions.
193 AC_FUNC_ALLOCA
194 AC_CHECK_FUNCS(gethostname mkdir mktime socket strstr strchr \
195                wcsstr wcswcs iswalnum iswspace towlower \
196                wcslen wcscpy wcsncpy \
197                uname flock lockf inet_aton inet_addr \
198                fchmod mkstemp)
199
200 dnl *****************
201 dnl ** common code **
202 dnl *****************
203
204 dnl check for glib
205 AM_PATH_GLIB(1.2.6,,
206         AC_MSG_ERROR(Test for GLIB failed. See the file 'INSTALL' for help.),
207         gthread)
208
209 dnl check for IPv6 option
210 AC_ARG_ENABLE(ipv6,
211         [  --disable-ipv6           Disable IPv6 support],
212         [ac_cv_enable_ipv6=$enableval], [ac_cv_enable_ipv6=yes])
213
214 dnl automated checks for IPv6 support.
215 AC_MSG_CHECKING([whether to use IPv6])
216 if test x"$ac_cv_enable_ipv6" = xyes; then
217         AC_MSG_RESULT(yes)
218         AC_MSG_CHECKING([for IPv6 support])
219         AC_CACHE_VAL(ac_cv_ipv6,[
220                 AC_TRY_COMPILE([#define INET6
221                                 #include <sys/types.h>
222                                 #include <netinet/in.h>],
223                         [int x = IPPROTO_IPV6; struct in6_addr a;],
224                         ac_cv_ipv6=yes, ac_cv_ipv6=no)
225         ])
226         AC_MSG_RESULT($ac_cv_ipv6)
227         if test $ac_cv_ipv6 = yes; then
228                 AC_DEFINE(INET6, 1, Define if you want IPv6 support.)
229         else
230                 AC_MSG_WARN(*** IPv6 will not be supported ***)
231                 ac_cv_enable_ipv6=no
232         fi
233 else
234         AC_MSG_RESULT(no)
235 fi
236
237 dnl Check for OpenSSL
238 AM_PATH_OPENSSL
239
240 dnl password encryption
241 OLDLIBS=$LIBS
242 LIBS=
243 AC_SEARCH_LIBS(encrypt, crypt, [], AC_MSG_ERROR(['encrypt'-function not found.]))
244 CRYPT_LIBS=$LIBS
245 AC_SUBST(CRYPT_LIBS)
246 LIBS=$OLDLIBS
247
248 AC_ARG_WITH(passcrypt-key, [  --with-passcrypt-key=KEY     Key used to encode passwords (8 byte string)],
249             with_passcrypt_key="$withval", with_passcrypt_key="passkey0")
250 AC_SUBST(PASSCRYPT_KEY, $with_passcrypt_key)
251
252 dnl RC dir (will be default at a certain point in time)
253 AC_ARG_WITH(config-dir,    [  --with-config-dir=RCDIR      Local configuration dir (default: .sylpheed)],
254               ac_cv_with_config_dir="$withval", ac_cv_with_config_dir=".sylpheed")
255 if test x"$ac_cv_with_config_dir" = x""; then
256         ac_cv_with_config_dir=".sylpheed"
257 fi 
258 AC_DEFINE_UNQUOTED(CFG_RC_DIR, "$ac_cv_with_config_dir", Configuration directory)
259
260 dnl ************************
261 dnl ** GTK user interface **
262 dnl ************************
263
264 dnl Checks for GTK
265 AM_PATH_GTK(1.2.6,,
266         AC_MSG_ERROR(Test for GTK failed. See the file 'INSTALL' for help.))
267
268 dnl check if gdk / gtk was compiled with USE_XIM
269 AC_MSG_CHECKING([whether GTK was compiled with XIM support])
270 CFLAGS_SAVE="$CFLAGS"
271 LDFLAGS_SAVE="$LDFLAGS"
272 CFLAGS="$CFLAGS `$GTK_CONFIG --cflags`"
273 LDFLAGS="$LDFLAGS `$GTK_CONFIG --libs`"
274 AC_CACHE_VAL(ac_cv_use_xim, [
275         AC_TRY_LINK_FUNC([gdk_ic_attr_new],
276                          ac_cv_use_xim=yes, ac_cv_use_xim=no)
277 ])
278 AC_MSG_RESULT($ac_cv_use_xim)
279 if test $ac_cv_use_xim = yes; then
280         AC_DEFINE(USE_XIM, 1, Whether GTK was compiled with XIM support or not)
281 fi
282 CFLAGS="$CFLAGS_SAVE"
283 LDFLAGS="$LDFLAGS_SAVE"
284
285 dnl GNU/Aspell is used for spell checking
286 AC_ARG_ENABLE(aspell,
287         [  --enable-aspell         Enable GNU/aspell support [default=no]],
288         [ac_cv_enable_aspell=$enableval], [ac_cv_enable_aspell=no])
289 AC_MSG_CHECKING([whether to use GNU/aspell])
290 if test $ac_cv_enable_aspell = yes; then
291         AC_MSG_RESULT(yes)
292         AM_PATH_ASPELL(0.50, AC_DEFINE(USE_ASPELL, 1, Define if you use ASPELL to support spell checking),
293                       [use_aspell=no ac_cv_enable_aspell=no])
294 else
295         AC_MSG_RESULT(no)
296 fi
297
298 dnl want crash dialog
299 AC_ARG_ENABLE(crash-dialog,
300         [  --enable-crash-dialog   Enable crash dialog [default=no]],
301         [ac_cv_enable_crash_dialog=$enableval], [ac_cv_enable_crash_dialog=no])
302 if test $ac_cv_enable_crash_dialog = yes; then
303 dnl check if GDB is somewhere
304         AC_CHECK_PROG(ac_cv_enable_crash_dialog, gdb, yes, no)
305         AC_MSG_CHECKING([whether to use crash dialog])
306         if test $ac_cv_enable_crash_dialog = yes; then
307                 AC_DEFINE(CRASH_DIALOG, 1, Pop up crash dialog)
308         fi
309         AC_MSG_RESULT($ac_cv_enable_crash_dialog)
310 fi
311
312 dnl Check for X-Face support
313 AC_ARG_ENABLE(compface,
314         [  --disable-compface      Do not use compface (X-Face)],
315         [ac_cv_enable_compface=$enableval], [ac_cv_enable_compface=yes])
316 AC_MSG_CHECKING([whether to use compface])
317 if test x"$ac_cv_enable_compface" = xyes; then
318         AC_MSG_RESULT(yes)
319         AC_CHECK_LIB(compface, uncompface, 
320                 [AC_DEFINE(HAVE_LIBCOMPFACE, 1, Define if you want compface support.)],
321                 [ac_cv_enable_compface=no])
322         if test x"$ac_cv_enable_compface" = xyes; then
323                 COMPFACE_LIBS="-lcompface"
324         else
325                 COMPFACE_LIBS=""
326         fi
327         AC_SUBST(COMPFACE_LIBS)
328 else
329         AC_MSG_RESULT(no)
330 fi
331
332 dnl for LDAP support in addressbook
333 dnl no check for libraries; dynamically loaded
334 AC_ARG_ENABLE(ldap,
335         [  --enable-ldap           Enable LDAP support [default=no]],
336         [ac_cv_enable_ldap=$enableval], [ac_cv_enable_ldap=no])
337 AC_MSG_CHECKING([whether to use LDAP])
338 if test "$ac_cv_enable_ldap" = yes; then
339         AC_MSG_RESULT(yes)
340
341         dnl check for available libraries, and pull them in
342         AC_CHECK_LIB(resolv, res_query, LDAP_LIBS="$LDAP_LIBS -lresolv")
343         AC_CHECK_LIB(socket, bind, LDAP_LIBS="$LDAP_LIBS -lsocket")
344         AC_CHECK_LIB(nsl, gethostbyaddr, LDAP_LIBS="$LDAP_LIBS -lnsl")
345         AC_CHECK_LIB(lber, ber_get_tag, LDAP_LIBS="$LDAP_LIBS -llber",,
346                      $LDAP_LIBS)
347
348         dnl we need libpthread for sylpheed ldap,  until we find
349         dnl a better way to handle ldap requests asynchronously...
350         AC_CHECK_LIB(pthread, pthread_create, LDAP_LIBS="$LDAP_LIBS -lpthread")
351
352         AC_CHECK_HEADERS(ldap.h lber.h pthread.h,
353                          [ ac_cv_enable_ldap=yes ],
354                          [ ac_cv_enable_ldap=no ])
355
356         if test "$ac_cv_enable_ldap" = yes; then
357                 AC_CHECK_LIB(ldap, ldap_open,
358                              [ ac_cv_enable_ldap=yes ],
359                              [ ac_cv_enable_ldap=no ],
360                              $LDAP_LIBS)
361
362                 AC_CHECK_LIB(ldap, ldap_start_tls_s,
363                              [ ac_cv_have_tls=yes ],
364                              [ ac_cv_have_tls=no ])
365
366         fi
367
368         AC_MSG_CHECKING([whether ldap library is available])
369         AC_MSG_RESULT($ac_cv_enable_ldap)
370
371         AC_MSG_CHECKING([whether TLS library is available])
372         AC_MSG_RESULT($ac_cv_have_tls)
373
374         if test "$ac_cv_enable_ldap" = yes; then
375                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
376                 LDAP_LIBS="$LDAP_LIBS -lldap `$GLIB_CONFIG --libs gthread`"
377                 AC_DEFINE(USE_LDAP, 1, Define if you want LDAP support in addressbook.)
378                 AC_SUBST(LDAP_LIBS)
379                 if test "$ac_cv_have_tls" = yes; then
380                         AC_DEFINE(USE_LDAP_TLS, 1, Define if you want LDAP TLS support in addressbook.)
381                 fi
382         fi
383 else
384         AC_MSG_RESULT(no)
385 fi
386
387 dnl for JPilot support in addressbook
388 dnl no check for libraries; these are dynamically loaded
389 AC_ARG_ENABLE(jpilot,
390         [  --enable-jpilot         Enable JPilot support [default=no]],
391         [ac_cv_enable_jpilot=$enableval], [ac_cv_enable_jpilot=no])
392 AC_MSG_CHECKING([whether to use JPilot])
393 if test "$ac_cv_enable_jpilot" = yes; then
394         AC_MSG_RESULT(yes)
395         AC_CHECK_HEADERS(pi-args.h pi-appinfo.h pi-address.h,
396                          [ AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ],
397                          [ ac_cv_enable_jpilot=no ])
398         if test "$ac_cv_enable_jpilot" = no; then
399                 AC_CHECK_HEADERS(libpisock/pi-args.h libpisock/pi-appinfo.h libpisock/pi-address.h,
400                                  [ ac_cv_enable_jpilot=yes
401                                    AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ])
402         fi
403
404         AC_CHECK_LIB(pisock, unpack_Address, [JPILOT_LIBS="-lpisock"], [JPILOT_LIBS="" ac_cv_enable_jpilot="no"])
405         if test x"$ac_cv_enable_jpilot" = xyes; then
406                 AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.)
407         else
408                 AC_MSG_NOTICE([JPilot support not available])
409         fi
410         AC_SUBST(JPILOT_LIBS)
411 else
412         AC_MSG_RESULT(no)
413 fi
414
415 dnl GPGME is used to support OpenPGP 
416 AC_ARG_ENABLE(gpgme,
417         [  --enable-gpgme          Enable GnuPG support using GPGME [default=no]],
418         [ac_cv_enable_gpgme=$enableval], [ac_cv_enable_gpgme=no])
419 AC_MSG_CHECKING([whether to use GPGME])
420 if test $ac_cv_enable_gpgme = yes; then
421         AC_MSG_RESULT(yes)
422         AM_PATH_GPGME(0.3.10, AC_DEFINE(USE_GPGME, 1, Define if you use GPGME to support OpenPGP.),
423                       [use_gpgme=no
424                        ac_cv_enable_gpgme=no])
425 else
426         AC_MSG_RESULT(no)
427 fi
428
429 dnl *************************
430 dnl ** section for plugins **
431 dnl *************************
432
433 PLUGINS=""
434
435 dnl --- Trayicon ---
436 AC_ARG_ENABLE(trayicon-plugin,
437         [  --disable-trayicon-plugin         Do not build System Tray Icon plugin],
438         [ac_cv_enable_trayicon_plugin=$enableval], [ac_cv_enable_trayicon_plugin=yes])
439 if test x"$ac_cv_enable_trayicon_plugin" = xyes; then
440         PLUGINS="trayicon $PLUGINS"
441 fi
442 AM_CONDITIONAL(BUILD_TRAYICON_PLUGIN, test x"$ac_cv_enable_trayicon_plugin" = xyes)
443
444 dnl --- SpamAssassin ---
445 AC_ARG_ENABLE(spamassassin-plugin,
446         [  --enable-spamassassin-plugin      Build SpamAssassin plugin [default=no]],
447         [ac_cv_enable_spamassassin_plugin=$enableval], [ac_cv_enable_spamassassin_plugin=no])
448 if test x"$ac_cv_enable_spamassassin_plugin" = xyes; then
449         AC_SPAMASSASSIN
450         PLUGINS="spamassassin $PLUGINS"
451 fi
452 AM_CONDITIONAL(BUILD_SPAMASSASSIN_PLUGIN, test x"$ac_cv_enable_spamassassin_plugin" = xyes)
453
454 dnl --- MathML Viewer ---
455 AC_ARG_ENABLE(mathml-viewer-plugin,
456         [  --disable-mathml-viewer-plugin    Do not build MathML-Viewer plugin],
457         [ac_cv_enable_mathml_viewer_plugin=$enableval], [ac_cv_enable_mathml_viewer_plugin=yes])
458 if test x"$ac_cv_enable_mathml_viewer_plugin" = xyes; then
459         PKG_CHECK_MODULES(GTK_MATH_VIEW, gtkmathview >= 0.4.2 gtkmathview < 0.5, :, ac_cv_enable_mathml_viewer_plugin=no)
460
461         if test x"$ac_cv_enable_mathml_viewer_plugin" = xyes; then
462                 AC_SUBST(GTK_MATH_VIEW_CFLAGS)
463                 AC_SUBST(GTK_MATH_VIEW_LIBS)
464
465                 PLUGINS="mathml-viewer $PLUGINS"
466         fi
467 fi
468 AM_CONDITIONAL(BUILD_MATHML_VIEWER_PLUGIN, test x"$ac_cv_enable_mathml_viewer_plugin" = xyes)
469
470 dnl --- Image Viewer ---
471 AC_ARG_ENABLE(image-viewer-plugin,
472         [  --disable-image-viewer-plugin     Do not build image viewer plugin],
473         [ac_cv_enable_image_viewer_plugin=$enableval], [ac_cv_enable_image_viewer_plugin=yes])
474 if test x"$ac_cv_enable_image_viewer_plugin" = xyes; then
475         AC_ARG_ENABLE(gdk-pixbuf,
476                 [  --disable-gdk-pixbuf              Do not use gdk-pixbuf],
477                 [ac_cv_enable_gdk_pixbuf=$enableval], [ac_cv_enable_gdk_pixbuf=yes])
478         AC_ARG_ENABLE(imlib,
479                 [  --disable-imlib                   Do not use imlib],
480                 [ac_cv_enable_imlib=$enableval], [ac_cv_enable_imlib=yes])
481
482         if test "$ac_cv_enable_gdk_pixbuf" = yes; then
483                 AM_PATH_GDK_PIXBUF(0.8.0,
484                         [AC_DEFINE(HAVE_GDK_PIXBUF, 1, Define if you use gdk-pixbuf to support image viewer)
485                          ac_cv_enable_imlib=no], [ac_cv_enable_gdk_pixbuf=no])
486         fi
487         if test "$ac_cv_enable_imlib" = yes; then
488                 AM_PATH_GDK_IMLIB(1.9,
489                         AC_DEFINE(HAVE_GDK_IMLIB, 1, Define if you use gdk_imlib to support image viewer),
490                         [ac_cv_enable_imlib=no])
491         fi
492
493         if test "$ac_cv_enable_gdk_pixbuf" = yes; then
494                 PLUGINS="image-viewer(gdk-pixbuf) $PLUGINS"
495         elif test "$ac_cv_enable_imlib" = yes; then
496                 PLUGINS="image-viewer(gdk_imlib) $PLUGINS"
497         else
498                 ac_cv_enable_image_viewer_plugin=no
499         fi
500 fi
501 AM_CONDITIONAL(BUILD_IMAGE_VIEWER_PLUGIN, test x"$ac_cv_enable_image_viewer_plugin" = xyes)
502
503 dnl --- Dillo Viewer ---
504 AC_ARG_ENABLE(dillo-viewer-plugin,
505         [  --disable-dillo-viewer-plugin     Do not build Dillo plugin for html mail rendering],
506         [ac_cv_enable_dillo_viewer_plugin=$enableval], [ac_cv_enable_dillo_viewer_plugin=yes])
507 if test x"$ac_cv_enable_dillo_viewer_plugin" = xyes; then
508         PLUGINS="dillo-viewer $PLUGINS"
509 fi
510 AM_CONDITIONAL(BUILD_DILLO_VIEWER_PLUGIN, test x"$ac_cv_enable_dillo_viewer_plugin" = xyes)
511
512 dnl --- Demo ---
513 AC_ARG_ENABLE(demo-plugin,
514         [  --enable-demo-plugin              Build demo plugin [default=no]],
515         [ac_cv_enable_demo_plugin=$enableval], [ac_cv_enable_demo_plugin=no])
516 if test x"$ac_cv_enable_demo_plugin" = xyes; then
517         PLUGINS="demo $PLUGINS"
518 fi
519 AM_CONDITIONAL(BUILD_DEMO_PLUGIN, test x"$ac_cv_enable_demo_plugin" = xyes)
520
521 dnl --- ClamAV ---
522 AC_ARG_ENABLE(clamav-plugin,
523         [  --disable-clamav-plugin           Do not build Clam AntiVirus plugin],
524         [ac_cv_enable_clamav_plugin=$enableval], [ac_cv_enable_clamav_plugin=yes])
525 if test x"$ac_cv_enable_clamav_plugin" = xyes; then
526         AC_CHECK_LIB(clamav, cl_scanfile, clamav_lib=-lclamav, ac_cv_enable_clamav_plugin=no)
527         AC_CHECK_HEADERS(clamav.h, :, ac_cv_enable_clamav_plugin=no)
528         if test x"$ac_cv_enable_clamav_plugin" = xyes; then
529                 CLAMAV_LIBS="${clamav_lib}"
530                 AC_SUBST(CLAMAV_LIBS)
531
532                 PLUGINS="clamav $PLUGINS"
533         else
534                 AC_MSG_NOTICE([clamav library not found, will not build clamav plugin])
535         fi
536 fi
537 AM_CONDITIONAL(BUILD_CLAMAV_PLUGIN, test x"$ac_cv_enable_clamav_plugin" = xyes)
538
539 dnl ****************************
540 dnl ** Final configure output **
541 dnl ****************************
542
543 AC_OUTPUT([
544 Makefile
545 sylpheed.spec
546 intl/Makefile
547 m4/Makefile
548 po/Makefile.in
549 src/common/version.h
550 src/Makefile
551 src/common/Makefile
552 src/common/passcrypt.h
553 src/gtk/Makefile
554 src/plugins/Makefile
555 src/plugins/demo/Makefile
556 src/plugins/spamassassin/Makefile
557 src/plugins/mathml_viewer/Makefile
558 src/plugins/dillo_viewer/Makefile
559 src/plugins/image_viewer/Makefile
560 src/plugins/trayicon/Makefile
561 src/plugins/trayicon/libeggtrayicon/Makefile
562 src/plugins/clamav/Makefile
563 doc/Makefile
564 doc/faq/Makefile
565 doc/faq/de/Makefile
566 doc/faq/en/Makefile
567 doc/faq/es/Makefile
568 doc/faq/fr/Makefile
569 doc/faq/it/Makefile
570 doc/man/Makefile
571 doc/manual/Makefile
572 doc/manual/de/Makefile
573 doc/manual/en/Makefile
574 doc/manual/es/Makefile
575 doc/manual/fr/Makefile
576 doc/manual/ja/Makefile
577 tools/Makefile
578 config/Makefile
579 sylpheed-claws.pc
580 ])
581
582 dnl Output the configuration summary
583 echo ""
584 echo "$PACKAGE $VERSION"
585 echo ""
586 echo "GnuPG         : $ac_cv_enable_gpgme"
587 echo "JPilot        : $ac_cv_enable_jpilot"
588 echo "LDAP          : $ac_cv_enable_ldap"
589 echo "OpenSSL       : $ac_cv_enable_openssl"
590 echo "iconv         : $am_cv_func_iconv"
591 echo "compface      : $ac_cv_enable_compface"
592 echo "IPv6          : $ac_cv_enable_ipv6"
593 echo "GNU/aspell    : $ac_cv_enable_aspell"
594 echo "Crash dialog  : $ac_cv_enable_crash_dialog"
595 echo "Plugins       : $PLUGINS"
596 echo "Config dir    : $ac_cv_with_config_dir"
597 echo ""
598 echo "The binary will be installed in $prefix/bin"
599 echo ""
600 echo "Configure finished, type 'make' to build."