2008-09-14 [colin] 3.5.0cvs104
[claws.git] / configure.ac
1
2 AC_PREREQ(2.60)
3 AC_INIT(src/main.c)
4 AC_CONFIG_AUX_DIR(config)
5
6 PACKAGE=claws-mail
7
8 dnl version number
9 MAJOR_VERSION=3
10 MINOR_VERSION=5
11 MICRO_VERSION=0
12 INTERFACE_AGE=0
13 BINARY_AGE=0
14 EXTRA_VERSION=104
15 EXTRA_RELEASE=
16 EXTRA_GTK2_VERSION=
17
18 if test \( $EXTRA_VERSION -eq 0 \) -o \( "x$EXTRA_RELEASE" != "x" \); then
19     VERSION=${MAJOR_VERSION}.${MINOR_VERSION}.${MICRO_VERSION}${EXTRA_RELEASE}${EXTRA_GTK2_VERSION}
20 else
21     VERSION=${MAJOR_VERSION}.${MINOR_VERSION}.${MICRO_VERSION}cvs${EXTRA_VERSION}${EXTRA_GTK2_VERSION}
22 fi
23
24 dnl set $target
25 AC_CANONICAL_SYSTEM
26
27 dnl
28 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
29 dnl AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
30 dnl AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
31 AC_SUBST(PACKAGE)
32 AC_SUBST(VERSION)
33 AC_SUBST(MAJOR_VERSION)
34 AC_SUBST(MINOR_VERSION)
35 AC_SUBST(MICRO_VERSION)
36 AC_SUBST(EXTRA_VERSION)
37
38 dnl GNOME installed?
39 AC_PATH_PROG(GNOME_CONFIG, gnome-config, no)
40 if test "$GNOME_CONFIG" != no; then
41         gnomedatadir="`gnome-config --datadir`"
42         gnomeprefix="`gnome-config --prefix`"
43         if test "${prefix}" = "NONE"; then
44                 gnomedatadir="${ac_default_prefix}/${gnomedatadir#${gnomeprefix}}"
45         else
46                 gnomedatadir="${prefix}/${gnomedatadir#${gnomeprefix}}"
47         fi
48         AC_SUBST(gnomedatadir)
49 fi
50 AM_CONDITIONAL(CLAWS_GNOME, test -n "$gnomedatadir")
51
52 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
53 if test x$PKG_CONFIG = xno ; then
54   AC_MSG_ERROR([*** pkg-config not found. See http://www.freedesktop.org/software/pkgconfig/])
55 fi
56
57 dnl GNOME 2.x installed?
58 PKG_CHECK_MODULES(GNOME2, libgnome-2.0 >= 2.0, ac_enable_gnome2=yes, ac_enable_gnome2=no)
59 AM_CONDITIONAL(CLAWS_GNOME2, test x"$ac_enable_gnome2" = x"yes")
60
61 dnl libtool versioning
62 LT_RELEASE=$MAJOR_VERSION.$MINOR_VERSION
63 LT_CURRENT=`expr $MICRO_VERSION - $INTERFACE_AGE`
64 LT_REVISION=$INTERFACE_AGE
65 LT_AGE=`expr $BINARY_AGE - $INTERFACE_AGE`
66 AC_SUBST(LT_RELEASE)
67 AC_SUBST(LT_CURRENT)
68 AC_SUBST(LT_REVISION)
69 AC_SUBST(LT_AGE)
70
71 dnl Specify a header configuration file
72 AC_CONFIG_HEADERS(config.h)
73
74 AM_MAINTAINER_MODE
75
76 dnl Checks for programs.
77 dnl AC_ARG_PROGRAM
78 AC_PROG_CC
79 AC_ISC_POSIX
80 AC_PROG_INSTALL
81 AC_PROG_LN_S
82 AC_PROG_MAKE_SET
83 AC_PROG_CPP
84 dnl AC_PROG_RANLIB
85 AM_PROG_LEX
86 AC_PROG_YACC
87 AC_LIB_PREFIX
88 AC_LIBTOOL_WIN32_DLL
89 AC_LIBTOOL_RC
90 AC_PROG_LIBTOOL
91
92 CLAWS_ACLOCAL_INCLUDE(m4)
93   
94 dnl ******************************
95 dnl Checks for host
96 dnl Not needed anymore because we 
97 dnl do AC_CANONICAL_SYSTEM above
98 dnl ******************************
99 dnl AC_CANONICAL_HOST
100
101 dnl Copied from the official gtk+-2 configure.in
102 AC_MSG_CHECKING([for some Win32 platform])
103 case "$host" in
104   *-*-mingw*|*-*-cygwin*)
105     platform_win32=yes
106     LDFLAGS="$LDFLAGS -mwindows"
107     ;;
108   *)
109     platform_win32=no
110     ;;
111 esac
112 AC_MSG_RESULT([$platform_win32])
113 AM_CONDITIONAL(PLATFORM_WIN32, test x"$platform_win32" = x"yes")
114
115 AC_MSG_CHECKING([for native Win32])
116 case "$host" in
117   *-*-mingw*)
118     os_win32=yes
119     ;;
120   *)
121     os_win32=no
122     ;;
123 esac
124 AC_MSG_RESULT([$os_win32])
125 AM_CONDITIONAL(OS_WIN32, test x"$os_win32" = x"yes")
126
127 AC_MSG_CHECKING([for Cygwin])
128 case "$host" in
129   *-*-cygwin*)
130     env_cygwin=yes
131     ;;
132   *)
133     env_cygwin=no
134     ;;
135 esac
136 AC_MSG_RESULT([$env_cygwin])
137 AM_CONDITIONAL(CYGWIN, test x"$env_cygwin" = x"yes")
138
139 if test "$GCC" = "yes"
140 then
141         CFLAGS="$CFLAGS -Wno-unused-function"
142 fi
143
144 CFLAGS="$CFLAGS -Wall"
145
146 if test $USE_MAINTAINER_MODE = yes; then
147         CFLAGS="$CFLAGS -DGTK_DISABLE_DEPRECATED -DGDK_DISABLE_DEPRECATED -DG_DISABLE_DEPRECATED -DGTK_DISABLE_SINGLE_INCLUDES"
148 fi
149
150 pthread_name=
151 case "$target" in
152 *-darwin*)
153         CFLAGS="$CFLAGS -no-cpp-precomp -fno-common"
154         ;;
155 *-*-mingw*)
156         # Note that we need to link to pthreadGC2 in all cases. This
157         # is because some locking is used even when pthread support is
158         # disabled.
159         pthread_name=pthreadGC2
160         CFLAGS="$CFLAGS -mms-bitfields"
161         LIBS="$LIBS -l${pthread_name} -lws2_32 -lregex"
162         ;;
163 *-*-solaris*)
164         CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
165         CFLAGS="$CFLAGS -DSOLARIS"
166         ;;
167 esac
168   
169 dnl Checks for iconv
170 AM_ICONV
171
172 dnl
173 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
174 dnl
175 syl_save_LIBS=$LIBS
176 LIBS="$LIBS $GTK_LIBS"
177 AC_CHECK_FUNCS(bind_textdomain_codeset)
178 LIBS=$syl_save_LIBS
179
180 dnl for gettext
181 ALL_LINGUAS="ca de en_GB es fi fr hu it pl pt_BR sk sr zh_CN"
182 GETTEXT_PACKAGE=claws-mail
183 AC_SUBST(GETTEXT_PACKAGE)
184 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Define text domain.])
185
186 AM_GNU_GETTEXT_VERSION([0.15])
187 AM_GNU_GETTEXT([external])
188
189 manualdir='${docdir}/manual'
190 AC_ARG_WITH(manualdir,
191         [  --with-manualdir=DIR    Manual directory],
192         [manualdir="$withval"])
193 AC_SUBST(manualdir)
194
195 AC_ARG_ENABLE(manual,
196         [  --disable-manual           do not build manual],
197         [ac_cv_enable_manual=$enableval], [ac_cv_enable_manual=yes])
198
199 AM_CONDITIONAL(BUILD_MANUAL, test x"$ac_cv_enable_manual" = xyes)
200
201 dnl Set PACKAGE_DATA_DIR in config.h.
202 if test "x${datarootdir}" = 'x${prefix}/share'; then
203         if test "x${prefix}" = "xNONE"; then
204                 AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${ac_default_prefix}/share/${PACKAGE}",[PACKAGE_DATA_DIR])
205         else
206                 AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${prefix}/share/${PACKAGE}",[PACKAGE_DATA_DIR])
207         fi
208 else
209         AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${datarootdir}/${PACKAGE}",[PACKAGE_DATA_DIR])
210 fi
211
212 AC_CHECK_LIB(xpg4, setlocale)
213
214 SM_LIBS=""
215 dnl Check for LibSM
216 AC_ARG_ENABLE(libsm,
217         [  --disable-libsm    disable libSM support for session management.],
218         [ac_cv_enable_libsm=$enableval], [ac_cv_enable_libsm=yes])
219 AC_MSG_CHECKING([whether to use LibSM])
220 if test x"$ac_cv_enable_libsm" = xyes; then
221         AC_MSG_RESULT(yes)
222         AC_CHECK_LIB(SM, SmcSaveYourselfDone,
223                 [SM_LIBS="$X_LIBS -lSM -lICE"],ac_cv_enable_libsm=no,
224                 $X_LIBS -lICE)
225         AC_CHECK_HEADERS(X11/SM/SMlib.h,,ac_cv_enable_libsm=no)
226         if test x"$ac_cv_enable_libsm" = xyes; then
227                 AC_DEFINE(HAVE_LIBSM, 1, [Define to 1 if you have libSM installed])
228         else
229                 AC_MSG_RESULT(not found)
230                 AC_MSG_WARN([*** LibSM will not be supported ***])
231         fi
232 else
233         AC_MSG_RESULT(no)
234 fi
235 AC_SUBST(SM_LIBS)
236
237 dnl for GThread support (currently disabled)
238 dnl AC_ARG_ENABLE(threads,
239 dnl     [  --enable-threads        Enable multithread support [default=no]],
240 dnl     [use_threads=$enableval], [use_threads=no])
241
242 AC_MSG_CHECKING([whether to use threads])
243 if test x"$use_threads" = xyes ; then
244         AC_MSG_RESULT(yes)
245         if test ! -z `$GLIB_CONFIG --help 2>&1 |grep 'gthread'` ; then
246                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
247                 LIBS="$LIBS `$GLIB_CONFIG --libs gthread`"
248                 AC_DEFINE(USE_THREADS, 1, Whether to use multithread or not)
249         else
250                 AC_MSG_ERROR([Sylpheed requires GThread from GLib to use threading.])
251         fi
252 else
253         AC_MSG_RESULT(no)
254 fi
255
256 dnl Check for d_type member in struct dirent
257 AC_MSG_CHECKING([whether struct dirent has d_type member])
258 AC_CACHE_VAL(ac_cv_dirent_d_type,[
259         AC_TRY_COMPILE([#include <dirent.h>],
260                        [struct dirent d; d.d_type = DT_REG;],
261                        ac_cv_dirent_d_type=yes, ac_cv_dirent_d_type=no)
262 ])
263 AC_MSG_RESULT($ac_cv_dirent_d_type)
264 if test $ac_cv_dirent_d_type = yes; then
265         AC_DEFINE(HAVE_DIRENT_D_TYPE, 1,
266                   Define if `struct dirent' has `d_type' member.)
267 fi
268
269 # Check whether mkdir does not take the permission argument.
270 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
271
272 dnl Checks for header files.
273 AC_HEADER_DIRENT
274 AC_HEADER_STDC
275 AC_HEADER_SYS_WAIT
276 AC_CHECK_HEADERS(fcntl.h sys/file.h unistd.h paths.h \
277                  sys/param.h sys/utsname.h sys/select.h \
278                  wchar.h wctype.h locale.h netdb.h)
279
280 dnl alf - Check for apache installation f*ck up. apache may also install an 
281 dnl fnmatch, which includes their own regex stuff if USE_HSREGEX is defined
282 AC_TRY_COMPILE([#include <stdlib.h>
283                 #include <fnmatch.h>],
284         [int x = USE_HSREGEX;],
285         ac_cv_have_apache_fnmatch=yes, ac_cv_have_apache_fnmatch=no)
286 if test $ac_cv_have_apache_fnmatch = yes; then
287         AC_DEFINE(HAVE_APACHE_FNMATCH, 1, Define if you need to work around apache regex/fnmatch !KLUDGE!)
288 fi
289 AC_MSG_CHECKING([whether to use Apache regex header kludge])
290 AC_MSG_RESULT($ac_cv_have_apache_fnmatch)
291
292 dnl Checks for typedefs, structures, and compiler characteristics.
293 AC_C_CONST
294 AC_TYPE_OFF_T
295 AC_TYPE_PID_T
296 AC_TYPE_SIZE_T
297 AC_STRUCT_TM
298
299 dnl AC_CHECK_TYPE(wint_t, unsigned int) does not work because wint_t
300 dnl may be defined only in wchar.h (this happens with gcc-2.96).
301 dnl So we need to use this extended macro.
302 CLAWS_CHECK_TYPE(wint_t, unsigned int,
303 [
304 #if HAVE_WCHAR_H
305 #include <wchar.h>
306 #endif
307 ], Define to `unsigned int' if <stddef.h> or <wchar.h> doesn't define.)
308
309 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF, Used to test for a u32 typedef)
310 AC_CHECK_SIZEOF(unsigned short, 2)
311 AC_CHECK_SIZEOF(unsigned int, 4)
312 AC_CHECK_SIZEOF(unsigned long, 4)
313
314 dnl Checks for library functions.
315 AC_FUNC_ALLOCA
316 AC_CHECK_FUNCS(gethostname mkdir mktime socket strstr strchr \
317                uname flock lockf inet_aton inet_addr \
318                fchmod mkstemp truncate getuid regcomp)
319
320 AC_CHECK_FUNCS(fgets_unlocked fwrite_unlocked)
321
322 dnl *****************
323 dnl ** common code **
324 dnl *****************
325
326 dnl check for glib
327 PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.6 gmodule-2.0 >= 2.6 gobject-2.0 >= 2.6 gthread-2.0 >= 2.6)
328       
329 GLIB_GENMARSHAL=`pkg-config --variable=glib_genmarshal glib-2.0`
330 AC_SUBST(GLIB_GENMARSHAL)
331
332 AC_SUBST(GLIB_CFLAGS)
333 AC_SUBST(GLIB_LIBS)
334
335 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
336 syl_save_LIBS=$LIBS
337 LIBS="$LIBS $GTK_LIBS"
338 AC_CHECK_FUNCS(bind_textdomain_codeset)
339 LIBS=$syl_save_LIBS
340
341 dnl check for IPv6 option
342 AC_ARG_ENABLE(ipv6,
343         [  --disable-ipv6           disable build IPv6 support],
344         [ac_cv_enable_ipv6=$enableval], [ac_cv_enable_ipv6=yes])
345
346 dnl automated checks for IPv6 support.
347 AC_MSG_CHECKING([whether to use IPv6])
348 if test x"$ac_cv_enable_ipv6" = xyes; then
349         AC_MSG_RESULT(yes)
350         AC_MSG_CHECKING([for IPv6 support])
351         AC_CACHE_VAL(ac_cv_ipv6,[
352                 AC_TRY_COMPILE([#define INET6
353                                 #include <sys/types.h>
354                                 #include <netinet/in.h>],
355                         [int x = IPPROTO_IPV6; struct in6_addr a;],
356                         ac_cv_ipv6=yes, ac_cv_ipv6=no)
357         ])
358         AC_MSG_RESULT($ac_cv_ipv6)
359         if test $ac_cv_ipv6 = yes; then
360                 AC_DEFINE(INET6, 1, Define if you want IPv6 support.)
361         else
362                 AC_MSG_WARN(*** IPv6 will not be supported ***)
363                 ac_cv_enable_ipv6=no
364         fi
365 else
366         AC_MSG_RESULT(no)
367 fi
368
369 dnl Check for OpenSSL
370 AC_ARG_ENABLE(openssl,
371         [  --disable-openssl    disable OpenSSL support.],
372         [ac_cv_enable_openssl=$enableval], [ac_cv_enable_openssl=yes])
373 dnl GNUTLS
374 AC_ARG_ENABLE(gnutls,    [ --enable-gnutls      enable GnuTLS support],
375             [ac_cv_enable_gnutls=$enableval], [ac_cv_enable_gnutls=no])
376 if test x$ac_cv_enable_openssl = xyes && test x$ac_cv_enable_gnutls != xyes; then
377         ac_cv_enable_gnutls="no"
378 fi
379 if test x$ac_cv_enable_gnutls = xyes; then
380           ac_cv_enable_openssl="no"
381 fi
382
383 AC_MSG_CHECKING([whether to use OpenSSL])
384 if test x"$ac_cv_enable_openssl" = xyes; then
385         AC_MSG_RESULT(yes)
386         PKG_CHECK_MODULES(OPENSSL, openssl >= 0.9.7, :, ac_cv_enable_openssl=no)
387         if test x$ac_cv_enable_openssl = xyes; then
388                 AC_DEFINE(USE_OPENSSL, 1, Define if you want OpenSSL support)
389         else
390                 AC_MSG_RESULT(not found)
391                 AC_MSG_WARN([*** OpenSSL will not be supported ***])
392         fi
393 else
394         AC_MSG_RESULT(no)
395 fi
396 AC_SUBST(OPENSSL_CFLAGS)
397 AC_SUBST(OPENSSL_LIBS)
398
399 AC_MSG_CHECKING([whether to use GnuTLS])
400 if test "x$ac_cv_enable_gnutls" != "xno"; then
401   OCPPFLAGS="$CPPFLAGS"
402   OLDFLAGS="$LDFLAGS"
403   GNUTLS_LIBS=""
404   AC_CHECK_HEADER(gnutls/gnutls.h, [
405         AC_CHECK_LIB(gnutls, gnutls_global_deinit, 
406                 [AC_DEFINE(USE_GNUTLS, 1, Define to use GnuTLS.)],
407                 [ac_cv_enable_gnutls=no])
408   ],[ac_cv_enable_gnutls=no])
409   if test "x$ac_cv_enable_gnutls" != "xyes"; then
410    CPPFLAGS="$OCPPFLAGS"
411    LDFLAGS="$OLDFLAGS"
412   fi
413 fi
414 if test "x$ac_cv_enable_gnutls" = "xyes"; then
415   AC_DEFINE([USE_GNUTLS],1, [Define to use GnuTLS])
416   GNUTLS_LIBS="-lgnutls"
417 else
418   GNUTLS_LIBS=""
419 fi
420 AC_SUBST(GNUTLS_LIBS)
421
422 dnl password encryption
423 OLDLIBS=$LIBS
424 LIBS=
425 case $host_os in
426         *dragonfly*)
427                 AC_SEARCH_LIBS(encrypt, cipher, [], AC_MSG_ERROR(['encrypt'-function not found.]))
428         ;;
429         *)
430                 AC_SEARCH_LIBS(encrypt, crypt, [], AC_MSG_ERROR(['encrypt'-function not found.]))
431         ;;
432 esac
433 CRYPT_LIBS=$LIBS
434 AC_SUBST(CRYPT_LIBS)
435 LIBS=$OLDLIBS
436
437 AC_ARG_WITH(passcrypt-key, [  --with-passcrypt-key=KEY     Key used to encode passwords (8 byte string)],
438             with_passcrypt_key="$withval", with_passcrypt_key="passkey0")
439 AC_SUBST(PASSCRYPT_KEY, $with_passcrypt_key)
440
441 dnl RC dir (will be default at a certain point in time)
442 AC_ARG_WITH(config-dir,    [  --with-config-dir=RCDIR      Local configuration dir (default: .claws-mail)],
443               ac_cv_with_config_dir="$withval", ac_cv_with_config_dir=".claws-mail")
444 if test x"$ac_cv_with_config_dir" = x""; then
445         ac_cv_with_config_dir=".claws-mail"
446 fi 
447 AC_DEFINE_UNQUOTED(CFG_RC_DIR, "$ac_cv_with_config_dir", Configuration directory)
448
449 dnl ************************
450 dnl ** GTK user interface **
451 dnl ************************
452
453 dnl Checks for GTK
454 PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.6)
455
456 dnl --disable-deprecated switch for GTK2 purification
457 AC_ARG_ENABLE(deprecated, [  --disable-deprecated  disable deprecated GTK functions. ],
458                           [GTK_CFLAGS="$GTK_CFLAGS -DG_DISABLE_DEPRECATED -DGTK_DISABLE_DEPRECATED"], [])
459
460 AC_SUBST(GTK_CFLAGS)
461 AC_SUBST(GTK_LIBS)
462
463 dnl enchant is used for spell checking
464 AC_ARG_ENABLE(enchant,
465         [  --disable-enchant         disable enchant support],
466         [ac_cv_enable_enchant=$enableval], [ac_cv_enable_enchant=yes])
467 AC_MSG_CHECKING([whether to use enchant])
468 if test $ac_cv_enable_enchant = yes; then
469         PKG_CHECK_MODULES(ENCHANT, enchant >= 1.0.0,
470         [
471                 AC_DEFINE(USE_ENCHANT, 1, enchant)
472                 echo "Building with enchant"
473                 ac_cv_enable_enchant=yes
474         ],
475         [
476                 echo "Building without enchant-notification"
477                 ac_cv_enable_enchant=no
478         ])
479         AC_SUBST(ENCHANT_CFLAGS)
480         AC_SUBST(ENCHANT_LIBS)
481 fi
482
483 dnl want crash dialog
484 AC_ARG_ENABLE(crash-dialog,
485         [  --enable-crash-dialog   Enable crash dialog [default=no]],
486         [ac_cv_enable_crash_dialog=$enableval], [ac_cv_enable_crash_dialog=no])
487 if test $ac_cv_enable_crash_dialog = yes; then
488 dnl check if GDB is somewhere
489         AC_CHECK_PROG(ac_cv_enable_crash_dialog, gdb, yes, no)
490         AC_MSG_CHECKING([whether to use crash dialog])
491         if test $ac_cv_enable_crash_dialog = yes; then
492                 AC_DEFINE(CRASH_DIALOG, 1, Pop up crash dialog)
493         fi
494         AC_MSG_RESULT($ac_cv_enable_crash_dialog)
495 fi
496
497 dnl generic umpc
498 AC_ARG_ENABLE(generic-umpc,
499         [  --enable-generic-umpc   Enable generic UMPC code [default=no]],
500         [ac_cv_enable_generic_umpc=$enableval], [ac_cv_enable_generic_umpc=no])
501 if test $ac_cv_enable_generic_umpc = yes; then
502         AC_DEFINE(GENERIC_UMPC, 1, Generic UMPC code)
503         AC_MSG_RESULT($ac_cv_enable_generic_umpc)
504 fi
505
506 dnl Maemo platform
507 AC_ARG_ENABLE(maemo,
508         [  --enable-maemo   build for the Maemo platform [default=no]],
509         [ac_cv_enable_maemo=$enableval], [ac_cv_enable_maemo=no])
510 if test $ac_cv_enable_maemo = yes; then
511         PKG_CHECK_MODULES(MAEMO, libosso hildon-libs hildon-fm gnome-vfs-2.0, ac_cv_enable_maemo=yes,
512                   ac_cv_enable_maemo=no)
513         AC_SUBST(MAEMO_CFLAGS)
514         AC_SUBST(MAEMO_LIBS)
515         if test $ac_cv_enable_maemo = no; then
516                 #test for chinook
517                 PKG_CHECK_MODULES(MAEMO, libosso hildon-1 hildon-fm-2 gnome-vfs-2.0 hal, ac_cv_enable_maemo=yes,
518                           ac_cv_enable_maemo=no)
519                 AC_SUBST(MAEMO_CFLAGS)
520                 AC_SUBST(MAEMO_LIBS)
521                 if test $ac_cv_enable_maemo = no; then
522                         AC_MSG_ERROR(one of libosso hildon-libs hildon-fm hildon-1 hildon-fm-2 not found)
523                 else
524                         AC_DEFINE(MAEMO, 1, Build for maemo)
525                         AC_DEFINE(CHINOOK, 1, Maemo chinook)
526                         AC_DEFINE(GENERIC_UMPC, 1, Generic UMPC code)
527                         ac_cv_enable_generic_umpc=yes
528                 fi
529         else
530                 AC_DEFINE(MAEMO, 1, Build for maemo)
531                 AC_DEFINE(GENERIC_UMPC, 1, Generic UMPC code)
532                 ac_cv_enable_generic_umpc=yes
533         fi
534 fi
535
536 PKG_CHECK_MODULES(CONIC, conic, ac_cv_enable_conic=yes,
537           ac_cv_enable_conic=no)
538 AC_SUBST(CONIC_CFLAGS)
539 AC_SUBST(CONIC_LIBS)
540 if test $ac_cv_enable_conic = yes; then
541         AC_DEFINE(CONIC, 1, Have conic lib)
542 fi
543
544 dnl Check for X-Face support
545 AC_ARG_ENABLE(compface,
546         [  --disable-compface      disable compface (X-Face) support],
547         [ac_cv_enable_compface=$enableval], [ac_cv_enable_compface=yes])
548 AC_MSG_CHECKING([whether to use compface])
549 if test x"$ac_cv_enable_compface" = xyes; then
550         AC_MSG_RESULT(yes)
551         AC_CHECK_LIB(compface, uncompface, 
552                 [AC_DEFINE(HAVE_LIBCOMPFACE, 1, Define if you want compface support.)],
553                 [ac_cv_enable_compface=no])
554         if test x"$ac_cv_enable_compface" = xyes; then
555                 COMPFACE_LIBS="-lcompface"
556         else
557                 COMPFACE_LIBS=""
558         fi
559         AC_SUBST(COMPFACE_LIBS)
560 else
561         AC_MSG_RESULT(no)
562 fi
563
564 dnl check for pthread support
565 AC_ARG_ENABLE(pthread,
566         [  --disable-pthread           disable pthread support],
567         [ac_cv_enable_pthread=$enableval], [ac_cv_enable_pthread=yes])
568 AC_MSG_CHECKING([whether to use pthread])
569 if test x$ac_cv_enable_pthread = xno; then
570         AC_MSG_RESULT(no)
571 else
572         AC_MSG_RESULT(yes)
573
574         # For W32 we need to use a special ptrhead lib. In this case we can't
575         # use AC_CHECK_LIB because it has no means of checking for a
576         # library installed under a different name.  Checking for the
577         # header is okay.
578         if test -n "${pthread_name}" ; then
579            ac_cv_enable_pthread=yes
580         else
581         AC_CHECK_LIB(pthread, pthread_create, :, ac_cv_enable_pthread=no)
582         fi
583         AC_CHECK_HEADERS(pthread.h, :, ac_cv_enable_pthread=no)
584
585         if test x$ac_cv_enable_pthread = xyes; then
586                 AC_DEFINE(USE_PTHREAD, 1, Define if you have pthread)
587                 if test -z "${pthread_name}" ; then
588                 PTHREAD_LIBS="-lpthread"
589         fi
590         fi
591
592 fi
593 AC_SUBST(PTHREAD_LIBS)
594
595 dnl
596 dnl Check whether we need to pass -lresolv
597 dnl We know that we don't need it for W32.
598 dnl
599 if test x$os_win32 = xno; then
600   t_oldLibs="$LIBS"
601   LIBS="$LIBS"
602   ac_cv_var__res_options=no
603   AC_TRY_LINK([#include <sys/types.h>
604              #include <sys/socket.h>
605              #include <netinet/in.h>
606              #include <arpa/nameser.h>
607              #include <resolv.h>],
608                 [_res.options = RES_INIT;],
609                 ac_cv_var__res_options=yes);
610   if test "$ac_cv_var__res_options" != "yes"; then
611         LIBRESOLV="-lresolv"
612   fi
613   LIBS="$t_oldLibs"
614
615   if test "x$LIBRESOLV" = "x"; then
616         AC_CHECK_LIB(resolv, res_query, [LIBRESOLV=-lresolv])
617         LIBS="$t_oldLibs"
618   fi
619 fi
620 AC_SUBST(LIBRESOLV)
621
622 LIBS="$LIBS $LIBRESOLV"
623                  
624 dnl for LDAP support in addressbook
625 dnl no check for libraries; dynamically loaded
626 AC_ARG_ENABLE(ldap,
627         [  --disable-ldap         disable LDAP support],
628         [ac_cv_enable_ldap=$enableval], [ac_cv_enable_ldap=yes])
629 AC_MSG_CHECKING([whether to use LDAP])
630 if test x"$ac_cv_enable_ldap" = xno; then
631         AC_MSG_RESULT(no)
632 elif test x"$ac_cv_enable_ldap" = xyes -a x"$ac_cv_enable_pthread" = xno; then
633         AC_MSG_RESULT(no - LDAP support needs pthread support)
634
635         ac_cv_enable_ldap=no
636 else
637         AC_MSG_RESULT(yes)
638
639         dnl check for available libraries, and pull them in
640         AC_CHECK_LIB(resolv, res_query, LDAP_LIBS="$LDAP_LIBS -lresolv")
641         AC_CHECK_LIB(socket, bind, LDAP_LIBS="$LDAP_LIBS -lsocket")
642         AC_CHECK_LIB(nsl, gethostbyaddr, LDAP_LIBS="$LDAP_LIBS -lnsl")
643         AC_CHECK_LIB(lber, ber_get_tag, LDAP_LIBS="$LDAP_LIBS -llber",,
644                      $LDAP_LIBS)
645
646         AC_CHECK_HEADERS(ldap.h lber.h,
647                          [ ac_cv_enable_ldap=yes ],
648                          [ ac_cv_enable_ldap=no ])
649
650         if test "$ac_cv_enable_ldap" = yes; then
651                 AC_CHECK_LIB(ldap, ldap_open,
652                              [ ac_cv_enable_ldap=yes ],
653                              [ ac_cv_enable_ldap=no ],
654                              $LDAP_LIBS)
655
656                 AC_CHECK_LIB(ldap, ldap_start_tls_s,
657                              [ ac_cv_have_tls=yes ],
658                              [ ac_cv_have_tls=no ])
659
660         fi
661
662         AC_MSG_CHECKING([whether ldap library is available])
663         AC_MSG_RESULT($ac_cv_enable_ldap)
664
665         AC_MSG_CHECKING([whether TLS library is available])
666         AC_MSG_RESULT($ac_cv_have_tls)
667
668         if test "$ac_cv_enable_ldap" = yes; then
669                 AC_DEFINE(USE_LDAP, 1, Define if you want LDAP support in addressbook.)
670                 LDAP_LIBS="$LDAP_LIBS -lldap"
671                 AC_SUBST(LDAP_LIBS)
672                 if test "$ac_cv_have_tls" = yes; then
673                         AC_DEFINE(USE_LDAP_TLS, 1, Define if you want LDAP TLS support in addressbook.)
674                 fi
675                 dnl As of OpenLDAP API version 3000 a number of functions has
676                 dnl been deprecated. As Claws-mail compiles and runs on many
677                 dnl platforms and many versions of OpenLDAP we need to be able
678                 dnl to switch between the old and new API because new API has
679                 dnl added new functions replacing old ones and at the same time
680                 dnl old functions has been changed.
681                 dnl If cross-compiling defaults to enable deprecated features
682                 dnl for maximum portability
683                 AC_MSG_CHECKING([The API version of OpenLDAP])
684                 AC_RUN_IFELSE(
685                         [AC_LANG_PROGRAM(
686                          [#include <ldap.h>],
687                          [if (LDAP_API_VERSION >= 3000)
688                                         return 1
689                         ])],
690                         [AC_MSG_RESULT([version < 3000])
691                          AC_DEFINE(OPEN_LDAP_API_AT_LEAST_3000, 0, Define if OpenLDAP API is at least version 3000.)],
692                         [AC_MSG_RESULT([version >= 3000])
693                          AC_DEFINE(OPEN_LDAP_API_AT_LEAST_3000, 1, Define if OpenLDAP API is at least version 3000.)],
694                         [AC_MSG_RESULT([Enabling deprecated features in OpenLDAP])
695                          AC_DEFINE(OPEN_LDAP_API_AT_LEAST_3000, 0, Define if OpenLDAP API is at least version 3000.)
696                          AC_DEFINE(LDAP_DEPRECATED, 1, Define to activate deprecated features in OpenLDAP)]
697                 )
698         fi
699 fi
700
701 dnl for JPilot support in addressbook
702 dnl no check for libraries; these are dynamically loaded
703 AC_ARG_ENABLE(jpilot,
704         [  --disable-jpilot         disable JPilot support],
705         [ac_cv_enable_jpilot=$enableval], [ac_cv_enable_jpilot=yes])
706 AC_MSG_CHECKING([whether to use JPilot])
707 if test "$ac_cv_enable_jpilot" = yes; then
708         AC_MSG_RESULT(yes)
709         AC_CHECK_HEADERS(pi-args.h pi-appinfo.h pi-address.h pi-version.h,
710                          [ AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ],
711                          [ ac_cv_enable_jpilot=no ])
712         if test "$ac_cv_enable_jpilot" = no; then
713                 AC_CHECK_HEADERS(libpisock/pi-args.h libpisock/pi-appinfo.h libpisock/pi-address.h libpisock/pi-version.h,
714                                  [ ac_cv_enable_jpilot=yes
715                                    AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ])
716         fi
717
718         AC_CHECK_LIB(pisock, unpack_Address, [JPILOT_LIBS="-lpisock"], [JPILOT_LIBS="" ac_cv_enable_jpilot="no"])
719         if test x"$ac_cv_enable_jpilot" = xyes; then
720                 AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.)
721         else
722                 AC_MSG_NOTICE([JPilot support not available])
723         fi
724         AC_SUBST(JPILOT_LIBS)
725 else
726         AC_MSG_RESULT(no)
727 fi
728
729 dnl #######################################################################
730 dnl # Check for startup notification
731 dnl #######################################################################
732 AC_ARG_ENABLE(startup-notification, [  --disable-startup-notification    disable startup notification support],,enable_startup_notification=yes)
733
734 if test "x$enable_startup_notification" = "xyes"; then
735         PKG_CHECK_MODULES(STARTUP_NOTIFICATION, libstartup-notification-1.0 >= 0.5,
736         [
737                 AC_DEFINE(HAVE_STARTUP_NOTIFICATION, 1, [Define if we're using libstartup-notification.])
738                 echo "Building with libstartup-notification"
739                 enable_startup_notification=yes
740         ],
741         [
742                 echo "Building without libstartup-notification"
743                 enable_startup_notification=no
744         ])
745
746         AC_SUBST(STARTUP_NOTIFICATION_CFLAGS)
747         AC_SUBST(STARTUP_NOTIFICATION_LIBS)
748 fi
749
750 dnl #######################################################################
751 dnl # Check for D-Bus support
752 dnl #######################################################################
753 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 0.60, dbus-glib-1 >= 0.60],
754 [
755         AC_DEFINE(HAVE_DBUS_GLIB, 1, [Define if glib bindings of D-Bus are available])
756         enable_dbus_glib=yes
757 ],
758 [
759         echo "D-Bus requirements not met. D-Bus support not activated."
760         enable_dbus_glib=no
761 ])
762 AC_SUBST(DBUS_CFLAGS)
763 AC_SUBST(DBUS_LIBS)
764
765 dnl #######################################################################
766 dnl # Check for NetworkManager support
767 dnl #######################################################################
768 if test x"$enable_dbus_glib" = xyes; then
769         AC_ARG_ENABLE(networkmanager-support, [  --disable-networkmanager-support  disable NetworkManager support],,enable_networkmanager_support=yes)
770         if test x"$enable_networkmanager_support" = xyes; then
771                 PKG_CHECK_MODULES(NETWORKMANAGER_SUPPORT, NetworkManager >= 0.6.2,
772                 [
773                         AC_DEFINE(HAVE_NETWORKMANAGER_SUPPORT, 1, [Define if NetworkManager support is to be included.])
774                         echo "Building with NetworkManager support"
775                         enable_networkmanager_support=yes
776                 ],
777                 [
778                         echo "NetworkManager not found."
779                         enable_networkmanager_support=no
780                 ])
781                 AC_SUBST(NETWORKMANAGER_SUPPORT_CFLAGS)
782         fi
783 else
784         echo "NetworkManager support deactivated as D-Bus requirements were not met."
785         enable_networkmanager_support=no
786 fi
787
788 dnl *************************
789 dnl ** section for plugins **
790 dnl *************************
791
792 PLUGINS=""
793
794 dnl --- Trayicon ---
795 AC_MSG_CHECKING([whether to build Trayicon plugin])
796 AC_ARG_ENABLE(trayicon-plugin,
797         [  --disable-trayicon-plugin         do not build System Tray Icon plugin],
798         [ac_cv_enable_trayicon_plugin=$enableval], [ac_cv_enable_trayicon_plugin=yes])
799 if test x"$ac_cv_enable_trayicon_plugin" = xyes; then
800         AC_MSG_RESULT(yes)
801         PLUGINS="trayicon $PLUGINS"
802 else
803         AC_MSG_RESULT(no)
804 fi
805 AM_CONDITIONAL(BUILD_TRAYICON_PLUGIN, test x"$ac_cv_enable_trayicon_plugin" = xyes)
806
807 dnl --- SpamAssassin ---
808 AC_MSG_CHECKING([whether to build SpamAssassin plugin])
809 AC_ARG_ENABLE(spamassassin-plugin,
810         [  --disable-spamassassin-plugin      do not build SpamAssassin plugin],
811         [ac_cv_enable_spamassassin_plugin=$enableval], [ac_cv_enable_spamassassin_plugin=yes])
812 if test x"$ac_cv_enable_spamassassin_plugin" = xyes; then
813         AC_MSG_RESULT(yes)
814         AC_SPAMASSASSIN
815         PLUGINS="spamassassin $PLUGINS"
816         AC_DEFINE(USE_SPAMASSASSIN_PLUGIN, 1, Define if spamassassin plugin is being built.)
817 else
818         AC_MSG_RESULT(no)
819 fi
820 AM_CONDITIONAL(BUILD_SPAMASSASSIN_PLUGIN, test x"$ac_cv_enable_spamassassin_plugin" = xyes)
821
822 dnl --- Bogofilter ---
823 AC_MSG_CHECKING([whether to build Bogofilter plugin])
824 AC_ARG_ENABLE(bogofilter-plugin,
825         [  --disable-bogofilter-plugin      do not build bogofilter plugin],
826         [ac_cv_enable_bogofilter_plugin=$enableval], [ac_cv_enable_bogofilter_plugin=yes])
827 if test x"$ac_cv_enable_bogofilter_plugin" = xyes; then
828         AC_MSG_RESULT(yes)
829         PLUGINS="bogofilter $PLUGINS"
830         AC_DEFINE(USE_BOGOFILTER_PLUGIN, 1, Define if bogofilter plugin is being built.)
831 else
832         AC_MSG_RESULT(no)
833 fi
834 AM_CONDITIONAL(BUILD_BOGOFILTER_PLUGIN, test x"$ac_cv_enable_bogofilter_plugin" = xyes)
835
836 dnl --- PGP/CORE ---
837 AC_MSG_CHECKING([whether to build PGP/CORE plugin])
838 AC_ARG_ENABLE(pgpcore-plugin,
839         [  --disable-pgpcore-plugin           do not build PGP/Core plugin],
840         [ac_cv_enable_pgpcore_plugin=$enableval], [ac_cv_enable_pgpcore_plugin=yes])
841 if test x"$ac_cv_enable_pgpcore_plugin" = xyes; then
842         AC_MSG_RESULT(yes)
843         AM_PATH_GPGME(1.0.0, AC_DEFINE(USE_GPGME, 1, Define if you use GPGME to support OpenPGP.),
844                       [ac_cv_enable_pgpcore_plugin=no])
845         if test x"$ac_cv_enable_pgpcore_plugin" = xyes; then
846                 PLUGINS="pgpcore $PLUGINS"
847                 AM_PATH_GPGME(1.1.1,
848                               AC_DEFINE(HAVE_GPGME_PKA_TRUST, 1,
849                                         [Define if GPGME supports PKA.]))
850                 #needed to get GPGME_LIBS and al correctly
851                 AM_PATH_GPGME(1.0.0, AC_DEFINE(USE_GPGME, 1, Define if you use GPGME to support OpenPGP.),
852                           [ac_cv_enable_pgpcore_plugin=no])
853         else
854                 AC_MSG_WARN([*** PGP/CORE plugin will not be built ***])
855         fi
856 else
857         AC_MSG_RESULT(no)
858 fi
859 AM_CONDITIONAL(BUILD_PGPCORE_PLUGIN, test x"$ac_cv_enable_pgpcore_plugin" = xyes)
860
861 AC_MSG_CHECKING([whether to build PGP/MIME plugin])
862 AC_ARG_ENABLE(pgpmime-plugin,
863         [  --disable-pgpmime-plugin           do not build PGP/MIME plugin],
864         [ac_cv_enable_pgpmime_plugin=$enableval], [ac_cv_enable_pgpmime_plugin=yes])
865 if test x"$ac_cv_enable_pgpmime_plugin" = xyes; then
866         AC_MSG_RESULT(yes)
867         if test x"$ac_cv_enable_pgpcore_plugin" = xyes; then
868                 PLUGINS="pgpmime $PLUGINS"
869         else
870                 AC_MSG_WARN([*** PGP/MIME plugin cannot be built ***])
871                 AC_MSG_WARN([*** without the PGP/CORE plugin     ***])
872         fi
873 else
874         AC_MSG_RESULT(no)
875 fi
876 AM_CONDITIONAL(BUILD_PGPMIME_PLUGIN, test x"$ac_cv_enable_pgpmime_plugin" = xyes)
877
878 AC_MSG_CHECKING([whether to build PGP/Inline plugin])
879 AC_ARG_ENABLE(pgpinline-plugin,
880         [  --disable-pgpinline-plugin           do not build PGP/Inline plugin],
881         [ac_cv_enable_pgpinline_plugin=$enableval], [ac_cv_enable_pgpinline_plugin=yes])
882 if test x"$ac_cv_enable_pgpinline_plugin" = xyes; then
883         AC_MSG_RESULT(yes)
884         if test x"$ac_cv_enable_pgpcore_plugin" = xyes; then
885                 PLUGINS="pgpinline $PLUGINS"
886         else
887                 AC_MSG_WARN([*** PGP/Inline plugin cannot be built ***])
888                 AC_MSG_WARN([*** without the PGP/CORE plugin     ***])
889         fi
890 else
891         AC_MSG_RESULT(no)
892 fi
893 AM_CONDITIONAL(BUILD_PGPINLINE_PLUGIN, test x"$ac_cv_enable_pgpinline_plugin" = xyes)
894
895 dnl --- Dillo Viewer ---
896 AC_MSG_CHECKING([whether to build Dillo plugin])
897 AC_ARG_ENABLE(dillo-viewer-plugin,
898         [  --disable-dillo-viewer-plugin     do not build Dillo plugin for html mail rendering],
899         [ac_cv_enable_dillo_viewer_plugin=$enableval], [ac_cv_enable_dillo_viewer_plugin=yes])
900 if test x"$ac_cv_enable_dillo_viewer_plugin" = xyes; then
901         AC_MSG_RESULT(yes)
902         PLUGINS="dillo-viewer $PLUGINS"
903 else
904         AC_MSG_RESULT(no)
905 fi
906 AM_CONDITIONAL(BUILD_DILLO_VIEWER_PLUGIN, test x"$ac_cv_enable_dillo_viewer_plugin" = xyes)
907
908 dnl --- Demo ---
909 AC_ARG_ENABLE(demo-plugin,
910         [  --enable-demo-plugin              build demo plugin],
911         [ac_cv_enable_demo_plugin=$enableval], [ac_cv_enable_demo_plugin=no])
912 if test x"$ac_cv_enable_demo_plugin" = xyes; then
913         PLUGINS="demo $PLUGINS"
914 fi
915 AM_CONDITIONAL(BUILD_DEMO_PLUGIN, test x"$ac_cv_enable_demo_plugin" = xyes)
916
917 dnl Libetpan
918 AC_MSG_CHECKING([whether to use libetpan])
919 AC_ARG_ENABLE(libetpan,
920         [  --disable-libetpan           disable IMAP4/NNTP (libetpan) support],
921         [ac_cv_enable_libetpan=$enableval], [ac_cv_enable_libetpan=yes])
922 if test x"$ac_cv_enable_libetpan" = xyes; then
923         AC_MSG_RESULT(yes)
924         libetpan_result=no
925         AC_PATH_PROG(libetpanconfig, [libetpan-config])
926         if test "x$libetpanconfig" != "x"; then
927           CPPFLAGS="$CPPFLAGS `$libetpanconfig --cflags 2>/dev/null`"
928           AC_CHECK_HEADER(libetpan/libetpan.h, [libetpan_result=yes])
929           if test "x$libetpan_result" = "xyes"; then
930             AC_MSG_CHECKING([whether libetpan-config hints compiles and links fine])
931             LIBS="$LIBS `$libetpanconfig --libs 2>/dev/null`"
932             AC_TRY_LINK([#include <libetpan/dbstorage.h>], [db_mailstorage_init(NULL, NULL);], [libetpan_result=yes], [libetpan_result=no])
933             AC_MSG_RESULT([$libetpan_result])
934           fi
935         fi
936         if test "x$libetpan_result" = "xyes"; then
937            LIBETPAN_CPPFLAGS="`$libetpanconfig --cflags`"
938            LIBETPAN_LIBS="`$libetpanconfig --libs`"
939            LIBETPAN_VERSION=`$libetpanconfig --version | sed "s/\.//g" | sed "s/-.*$//"`
940            if test "$LIBETPAN_VERSION" -lt "055"; then
941                 AC_MSG_RESULT([*** Claws Mail requires libetpan 0.55 or newer. See http://www.etpan.org/])
942                 AC_MSG_RESULT([*** You can use --disable-libetpan if you don't need IMAP4 and/or NNTP support.])
943                 AC_MSG_ERROR([libetpan 0.55 not found])
944            fi
945            AC_SUBST(LIBETPAN_FLAGS)
946            AC_SUBST(LIBETPAN_LIBS)
947            AC_DEFINE(HAVE_LIBETPAN, 1, Define if you want IMAP and/or NNTP support.)
948         else
949            AC_MSG_RESULT([*** Claws Mail requires libetpan 0.55 or newer. See http://www.etpan.org/ ])
950            AC_MSG_RESULT([*** You can use --disable-libetpan if you don't need IMAP4 and/or NNTP support.])
951            AC_MSG_ERROR([libetpan 0.55 not found])
952         fi
953 else
954         AC_MSG_RESULT(no)
955 fi
956 AM_CONDITIONAL(CLAWS_LIBETPAN, test "x$libetpan_result" = "xyes")
957
958
959 dnl Printing support.
960 PKG_CHECK_MODULES(GTK210, gtk+-2.0 >= 2.10, ac_cv_have_gtk210=yes, ac_cv_have_gtk210=no)
961
962 AC_MSG_CHECKING([whether to use libgnomeprint])
963 AC_ARG_ENABLE(gnomeprint,
964         [  --disable-gnomeprint         disable libgnomeprint support],
965         [ac_cv_enable_gnomeprint=$enableval], [ac_cv_enable_gnomeprint=auto])
966
967 if test x$ac_cv_have_gtk210 = xyes; then
968         ac_cv_enable_gnomeprint="no"
969 fi
970
971 if test x$ac_cv_enable_gnomeprint = xyes \
972         -o \( x$ac_cv_enable_gnomeprint = xauto \
973            -a x$ac_cv_have_gtk210 = xno \); then
974         AC_MSG_RESULT(yes)
975         PKG_CHECK_MODULES(GNOMEPRINT, libgnomeprint-2.2 libgnomeprintui-2.2,
976                           ac_cv_enable_gnomeprint=yes, ac_cv_enable_gnomeprint=no)
977         if test x"$ac_cv_enable_gnomeprint" = xyes; then
978                 AC_DEFINE(USE_GNOMEPRINT, 1, Define if you want libgnomeprint support)
979         else
980                 AC_MSG_RESULT(not found)
981                 AC_MSG_WARN([*** libgnomeprintui wasn't found    ***])
982                 AC_MSG_WARN([*** using built-in printing support ***])
983         fi
984 else
985         ac_cv_enable_gnomeprint=no
986         AC_MSG_RESULT(no)
987 fi
988 AM_CONDITIONAL(CLAWS_GNOMEPRINT, test x"$ac_cv_enable_gnomeprint" = x"yes")
989
990 AC_MSG_CHECKING([whether to use valgrind])
991 AC_ARG_ENABLE(valgrind,
992         [  --disable-valgrind           disable valgrind support for debugging],
993         [ac_cv_enable_valgrind=$enableval], [ac_cv_enable_valgrind=yes])
994 if test x$ac_cv_enable_valgrind = xyes; then
995         AC_MSG_RESULT(yes)
996         PKG_CHECK_MODULES(VALGRIND, valgrind >= 2.4.0,
997                           ac_cv_enable_valgrind=yes, ac_cv_enable_valgrind=no)
998         if test x"$ac_cv_enable_valgrind" = xyes; then
999                 AC_DEFINE(HAVE_VALGRIND, 1, Define if you want valgrind support)
1000         else
1001                 AC_MSG_RESULT(not found)
1002         fi
1003 else
1004         AC_MSG_RESULT(no)
1005 fi
1006 AM_CONDITIONAL(CLAWS_VALGRIND, test x"$ac_cv_enable_valgrind" = x"yes")
1007
1008 dnl ****************************
1009 dnl ** Final configure output **
1010 dnl ****************************
1011
1012 AC_OUTPUT([
1013 Makefile
1014 m4/Makefile
1015 po/Makefile.in
1016 src/common/version.h
1017 src/Makefile
1018 src/common/Makefile
1019 src/common/passcrypt.h
1020 src/gtk/Makefile
1021 src/etpan/Makefile
1022 src/plugins/Makefile
1023 src/plugins/demo/Makefile
1024 src/plugins/bogofilter/Makefile
1025 src/plugins/spamassassin/Makefile
1026 src/plugins/dillo_viewer/Makefile
1027 src/plugins/trayicon/Makefile
1028 src/plugins/trayicon/libeggtrayicon/Makefile
1029 src/plugins/pgpcore/Makefile
1030 src/plugins/pgpmime/Makefile
1031 src/plugins/pgpinline/Makefile
1032 doc/Makefile
1033 doc/man/Makefile
1034 tools/Makefile
1035 config/Makefile
1036 manual/Makefile
1037 manual/dtd/Makefile
1038 manual/dist/Makefile
1039 manual/dist/pdf/Makefile
1040 manual/dist/ps/Makefile
1041 manual/dist/html/Makefile
1042 manual/dist/txt/Makefile
1043 manual/fr/Makefile
1044 manual/fr/dist/Makefile
1045 manual/fr/dist/pdf/Makefile
1046 manual/fr/dist/ps/Makefile
1047 manual/fr/dist/html/Makefile
1048 manual/fr/dist/txt/Makefile
1049 manual/pl/Makefile
1050 manual/pl/dist/Makefile
1051 manual/pl/dist/pdf/Makefile
1052 manual/pl/dist/ps/Makefile
1053 manual/pl/dist/html/Makefile
1054 manual/pl/dist/txt/Makefile
1055 manual/es/Makefile
1056 manual/es/dist/Makefile
1057 manual/es/dist/pdf/Makefile
1058 manual/es/dist/ps/Makefile
1059 manual/es/dist/html/Makefile
1060 manual/es/dist/txt/Makefile
1061 claws-mail.pc
1062 ])
1063
1064 dnl Output the configuration summary
1065 echo ""
1066 echo "$PACKAGE $VERSION"
1067 echo ""
1068 echo "JPilot            : $ac_cv_enable_jpilot"
1069 echo "LDAP              : $ac_cv_enable_ldap"
1070 echo "OpenSSL           : $ac_cv_enable_openssl"
1071 echo "gnuTLS            : $ac_cv_enable_gnutls"
1072 echo "iconv             : $am_cv_func_iconv"
1073 echo "compface          : $ac_cv_enable_compface"
1074 echo "IPv6              : $ac_cv_enable_ipv6"
1075 echo "enchant           : $ac_cv_enable_enchant"
1076 echo "IMAP4             : $ac_cv_enable_libetpan"
1077 echo "NNTP              : $ac_cv_enable_libetpan"
1078 echo "Crash dialog      : $ac_cv_enable_crash_dialog"
1079 echo "Libgnomeprint     : $ac_cv_enable_gnomeprint"
1080 echo "GTK+ print support: $ac_cv_have_gtk210"
1081 echo "LibSM             : $ac_cv_enable_libsm"
1082 echo "NetworkManager    : $enable_networkmanager_support"
1083 echo "Manual            : $ac_cv_enable_manual"
1084 echo "Plugins           : $PLUGINS"
1085 echo "Generic UMPC code : $ac_cv_enable_generic_umpc"
1086 echo "Maemo  build      : $ac_cv_enable_maemo"
1087 echo "Config dir        : $ac_cv_with_config_dir"
1088 echo ""
1089 echo "The binary will be installed in $prefix/bin"
1090 echo ""
1091 echo "Configure finished, type 'make' to build."