configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.50)
   3 AC_INIT(src/main.c)
   4 AC_CONFIG_AUX_DIR(config)
   5
   6 PACKAGE=sylpheed-claws
   7
   8 dnl version number
   9 MAJOR_VERSION=0
  10 MINOR_VERSION=9
  11 MICRO_VERSION=12
  12 INTERFACE_AGE=0
  13 BINARY_AGE=0
  14 EXTRA_VERSION=46
  15 EXTRA_RELEASE=
  16 EXTRA_GTK2_VERSION=.1
  17
  18 if test \( $EXTRA_VERSION -eq 0 \) -o \( "x$EXTRA_RELEASE" != "x" \); then
  19     VERSION=${MAJOR_VERSION}.${MINOR_VERSION}.${MICRO_VERSION}${EXTRA_RELEASE}${EXTRA_GTK2_VERSION}
  20 else
  21     VERSION=${MAJOR_VERSION}.${MINOR_VERSION}.${MICRO_VERSION}cvs${EXTRA_VERSION}${EXTRA_GTK2_VERSION}
  22 fi
  23
  24 dnl set $target
  25 AC_CANONICAL_SYSTEM
  26
  27 dnl
  28 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  29 dnl AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
  30 dnl AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
  31 AC_SUBST(PACKAGE)
  32 AC_SUBST(VERSION)
  33 AC_SUBST(MAJOR_VERSION)
  34 AC_SUBST(MINOR_VERSION)
  35 AC_SUBST(MICRO_VERSION)
  36 AC_SUBST(EXTRA_VERSION)
  37
  38 dnl GNOME installed?
  39 AC_PATH_PROG(GNOME_CONFIG, gnome-config, no)
  40 if test "$GNOME_CONFIG" != no; then
  41         gnomedatadir="`gnome-config --datadir`"
  42         gnomeprefix="`gnome-config --prefix`"
  43         if test "${prefix}" = "NONE"; then
  44                 gnomedatadir="${ac_default_prefix}/${gnomedatadir#${gnomeprefix}}"
  45         else
  46                 gnomedatadir="${prefix}/${gnomedatadir#${gnomeprefix}}"
  47         fi
  48         AC_SUBST(gnomedatadir)
  49 fi
  50 AM_CONDITIONAL(SYLPHEED_GNOME, test -n "$gnomedatadir")
  51
  52 dnl Claws version
  53 AC_DEFINE(CLAWS, 1, Compiling Claws branch of sylpheed)
  54
  55 dnl libtool versioning
  56 LT_RELEASE=$MAJOR_VERSION.$MINOR_VERSION
  57 LT_CURRENT=`expr $MICRO_VERSION - $INTERFACE_AGE`
  58 LT_REVISION=$INTERFACE_AGE
  59 LT_AGE=`expr $BINARY_AGE - $INTERFACE_AGE`
  60 AC_SUBST(LT_RELEASE)
  61 AC_SUBST(LT_CURRENT)
  62 AC_SUBST(LT_REVISION)
  63 AC_SUBST(LT_AGE)
  64
  65 dnl Specify a header configuration file
  66 AC_CONFIG_HEADERS(config.h)
  67
  68 AM_MAINTAINER_MODE
  69
  70 dnl Checks for programs.
  71 dnl AC_ARG_PROGRAM
  72 AC_PROG_CC
  73 AC_ISC_POSIX
  74 AC_PROG_INSTALL
  75 AC_PROG_LN_S
  76 AC_PROG_MAKE_SET
  77 AC_PROG_CPP
  78 dnl AC_PROG_RANLIB
  79 AM_PROG_LEX
  80 AC_PROG_YACC
  81 AC_PROG_LIBTOOL
  82
  83 SYLPHEED_ACLOCAL_INCLUDE(m4)
  84
  85 dnl ******************************
  86 dnl Checks for host
  87 dnl ******************************
  88 AC_CANONICAL_HOST
  89
  90 dnl Copied from the official gtk+-2 configure.in
  91 AC_MSG_CHECKING([for some Win32 platform])
  92 case "$host" in
  93   *-*-mingw*|*-*-cygwin*)
  94     platform_win32=yes
  95     LDFLAGS="$LDFLAGS -mwindows"
  96     ;;
  97   *)
  98     platform_win32=no
  99     ;;
 100 esac
 101 AC_MSG_RESULT([$platform_win32])
 102 AM_CONDITIONAL(PLATFORM_WIN32, test x"$platform_win32" = x"yes")
 103
 104 if test x"$platform_win32" = x"yes"; then
 105     WINDRES=windres
 106     AC_SUBST(WINDRES)
 107 fi
 108
 109 AC_MSG_CHECKING([for native Win32])
 110 case "$host" in
 111   *-*-mingw*)
 112     os_win32=yes
 113     ;;
 114   *)
 115     os_win32=no
 116     ;;
 117 esac
 118 AC_MSG_RESULT([$os_win32])
 119 AM_CONDITIONAL(OS_WIN32, test x"$os_win32" = x"yes")
 120
 121 case "$target" in
 122 *-darwin*)
 123         CFLAGS="$CFLAGS -traditional-cpp -fno-common"
 124         ;;
 125 esac
 126
 127 dnl Checks for iconv
 128 AM_ICONV
 129
 130 dnl for gettext
 131 ALL_LINGUAS="bg cs de el en_GB es fr hr hu it ja ko nl pl pt_BR ru sk sr sv zh_CN zh_TW.Big5"
 132 AM_GNU_GETTEXT([use-libtool])
 133 AM_GNU_GETTEXT_VERSION(0.12.1)
 134 dnl AC_CHECK_FUNC(gettext, AC_CHECK_LIB(intl, gettext))
 135 localedir='${prefix}/${DATADIRNAME}/locale'
 136 AC_SUBST(localedir)
 137
 138 manualdir='${prefix}/${DATADIRNAME}/${PACKAGE}/manual'
 139 AC_SUBST(manualdir)
 140 faqdir='${prefix}/${DATADIRNAME}/${PACKAGE}/faq'
 141 AC_SUBST(faqdir)
 142
 143 dnl Set PACKAGE_DATA_DIR in config.h.
 144 if test "x${datadir}" = 'x${prefix}/share'; then
 145   if test "x${prefix}" = "xNONE"; then
 146     AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${ac_default_prefix}/share/${PACKAGE}", PACKAGE_DATA_DIR)
 147   else
 148     AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${prefix}/share/${PACKAGE}", PACKAGE_DATA_DIR)
 149   fi
 150 else
 151   AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${datadir}/${PACKAGE}", PACKAGE_DATA_DIR)
 152 fi
 153
 154 AC_CHECK_LIB(xpg4, setlocale)
 155
 156 dnl for GThread support (currently disabled)
 157 dnl AC_ARG_ENABLE(threads,
 158 dnl     [  --enable-threads        Enable multithread support [default=no]],
 159 dnl     [use_threads=$enableval], [use_threads=no])
 160
 161 AC_MSG_CHECKING([whether to use threads])
 162 if test x"$use_threads" = xyes ; then
 163         AC_MSG_RESULT(yes)
 164         if test ! -z `$GLIB_CONFIG --help 2>&1 |grep 'gthread'` ; then
 165                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
 166                 LIBS="$LIBS `$GLIB_CONFIG --libs gthread`"
 167                 AC_DEFINE(USE_THREADS, 1, Whether to use multithread or not)
 168         else
 169                 AC_MSG_ERROR([Sylpheed requires GThread from GLib to use threading.])
 170         fi
 171 else
 172         AC_MSG_RESULT(no)
 173 fi
 174
 175 dnl Check for d_type member in struct dirent
 176 AC_MSG_CHECKING([whether struct dirent has d_type member])
 177 AC_CACHE_VAL(ac_cv_dirent_d_type,[
 178         AC_TRY_COMPILE([#include <dirent.h>],
 179                        [struct dirent d; d.d_type = DT_REG;],
 180                        ac_cv_dirent_d_type=yes, ac_cv_dirent_d_type=no)
 181 ])
 182 AC_MSG_RESULT($ac_cv_dirent_d_type)
 183 if test $ac_cv_dirent_d_type = yes; then
 184         AC_DEFINE(HAVE_DIRENT_D_TYPE, 1,
 185                   Define if `struct dirent' has `d_type' member.)
 186 fi
 187
 188 dnl Checks for header files.
 189 AC_HEADER_DIRENT
 190 AC_HEADER_STDC
 191 AC_HEADER_SYS_WAIT
 192 AC_CHECK_HEADERS(fcntl.h sys/file.h unistd.h paths.h \
 193                  sys/param.h sys/utsname.h sys/select.h \
 194                  wchar.h wctype.h locale.h)
 195
 196 dnl alf - Check for apache installation f*ck up. apache may also install an
 197 dnl fnmatch, which includes their own regex stuff if USE_HSREGEX is defined
 198 AC_TRY_COMPILE([#include <stdlib.h>
 199                 #include <fnmatch.h>],
 200         [int x = USE_HSREGEX;],
 201         ac_cv_have_apache_fnmatch=yes, ac_cv_have_apache_fnmatch=no)
 202 if test $ac_cv_have_apache_fnmatch = yes; then
 203         AC_DEFINE(HAVE_APACHE_FNMATCH, 1, Define if you need to work around apache regex/fnmatch !KLUDGE!)
 204 fi
 205 AC_MSG_CHECKING([whether to use Apache regex header kludge])
 206 AC_MSG_RESULT($ac_cv_have_apache_fnmatch)
 207
 208 dnl Checks for typedefs, structures, and compiler characteristics.
 209 AC_C_CONST
 210 AC_TYPE_OFF_T
 211 AC_TYPE_PID_T
 212 AC_TYPE_SIZE_T
 213 AC_STRUCT_TM
 214
 215 dnl AC_CHECK_TYPE(wint_t, unsigned int) does not work because wint_t
 216 dnl may be defined only in wchar.h (this happens with gcc-2.96).
 217 dnl So we need to use this extended macro.
 218 SYLPHEED_CHECK_TYPE(wint_t, unsigned int,
 219 [
 220 #if HAVE_WCHAR_H
 221 #include <wchar.h>
 222 #endif
 223 ], Define to `unsigned int' if <stddef.h> or <wchar.h> doesn't define.)
 224
 225 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF, Used to test for a u32 typedef)
 226 AC_CHECK_SIZEOF(unsigned short, 2)
 227 AC_CHECK_SIZEOF(unsigned int, 4)
 228 AC_CHECK_SIZEOF(unsigned long, 4)
 229
 230 dnl Checks for library functions.
 231 AC_FUNC_ALLOCA
 232 AC_CHECK_FUNCS(gethostname mkdir mktime socket strstr strchr \
 233                wcsstr wcswcs iswalnum iswspace towlower \
 234                wcslen wcscpy wcsncpy \
 235                uname flock lockf inet_aton inet_addr \
 236                fchmod mkstemp)
 237
 238 dnl *****************
 239 dnl ** common code **
 240 dnl *****************
 241
 242 dnl check for glib
 243 AM_PATH_GLIB_2_0(2.0.0,,
 244         AC_MSG_ERROR(Test for GLIB failed. See the file 'INSTALL' for help.),
 245         gmodule gobject gthread)
 246
 247 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 248 syl_save_LIBS=$LIBS
 249 LIBS="$LIBS $GTK_LIBS"
 250 AC_CHECK_FUNCS(bind_textdomain_codeset)
 251 LIBS=$syl_save_LIBS
 252
 253 dnl check for IPv6 option
 254 AC_ARG_ENABLE(ipv6,
 255         [  --disable-ipv6           Disable IPv6 support],
 256         [ac_cv_enable_ipv6=$enableval], [ac_cv_enable_ipv6=yes])
 257
 258 dnl automated checks for IPv6 support.
 259 AC_MSG_CHECKING([whether to use IPv6])
 260 if test x"$ac_cv_enable_ipv6" = xyes; then
 261         AC_MSG_RESULT(yes)
 262         AC_MSG_CHECKING([for IPv6 support])
 263         AC_CACHE_VAL(ac_cv_ipv6,[
 264                 AC_TRY_COMPILE([#define INET6
 265                                 #include <sys/types.h>
 266                                 #include <netinet/in.h>],
 267                         [int x = IPPROTO_IPV6; struct in6_addr a;],
 268                         ac_cv_ipv6=yes, ac_cv_ipv6=no)
 269         ])
 270         AC_MSG_RESULT($ac_cv_ipv6)
 271         if test $ac_cv_ipv6 = yes; then
 272                 AC_DEFINE(INET6, 1, Define if you want IPv6 support.)
 273         else
 274                 AC_MSG_WARN(*** IPv6 will not be supported ***)
 275                 ac_cv_enable_ipv6=no
 276         fi
 277 else
 278         AC_MSG_RESULT(no)
 279 fi
 280
 281 dnl Check for OpenSSL
 282 AC_ARG_ENABLE(openssl,
 283         [  --enable-openssl    Attempt to use OpenSSL for SSL support.],
 284         [ac_cv_enable_openssl=$enableval], [ac_cv_enable_openssl=yes])
 285 if test x"$ac_cv_enable_openssl" = xyes; then
 286         PKG_CHECK_MODULES(OPENSSL, openssl >= 0.9.7, :, ac_cv_enable_openssl=no)
 287         AC_DEFINE(USE_OPENSSL, 1, Define if you want OpenSSL support)
 288 fi
 289 AC_SUBST(OPENSSL_CFLAGS)
 290 AC_SUBST(OPENSSL_LIBS)
 291
 292 dnl password encryption
 293 OLDLIBS=$LIBS
 294 LIBS=
 295 AC_SEARCH_LIBS(encrypt, crypt, [], AC_MSG_ERROR(['encrypt'-function not found.]))
 296 CRYPT_LIBS=$LIBS
 297 AC_SUBST(CRYPT_LIBS)
 298 LIBS=$OLDLIBS
 299
 300 AC_ARG_WITH(passcrypt-key, [  --with-passcrypt-key=KEY     Key used to encode passwords (8 byte string)],
 301             with_passcrypt_key="$withval", with_passcrypt_key="passkey0")
 302 AC_SUBST(PASSCRYPT_KEY, $with_passcrypt_key)
 303
 304 dnl RC dir (will be default at a certain point in time)
 305 AC_ARG_WITH(config-dir,    [  --with-config-dir=RCDIR      Local configuration dir (default: .sylpheed)],
 306               ac_cv_with_config_dir="$withval", ac_cv_with_config_dir=".sylpheed")
 307 if test x"$ac_cv_with_config_dir" = x""; then
 308         ac_cv_with_config_dir=".sylpheed"
 309 fi
 310 AC_DEFINE_UNQUOTED(CFG_RC_DIR, "$ac_cv_with_config_dir", Configuration directory)
 311
 312 dnl ************************
 313 dnl ** GTK user interface **
 314 dnl ************************
 315
 316 dnl Checks for GTK
 317 AM_PATH_GTK_2_0(2.4.0,,
 318         AC_MSG_ERROR(Test for GTK failed. See the file 'INSTALL' for help.))
 319
 320 dnl GNU/Aspell is used for spell checking
 321 AC_ARG_ENABLE(aspell,
 322         [  --enable-aspell         Enable GNU/aspell support [default=no]],
 323         [ac_cv_enable_aspell=$enableval], [ac_cv_enable_aspell=no])
 324 AC_MSG_CHECKING([whether to use GNU/aspell])
 325 if test $ac_cv_enable_aspell = yes; then
 326         AC_MSG_RESULT(yes)
 327         AM_PATH_ASPELL(0.50, AC_DEFINE(USE_ASPELL, 1, Define if you use ASPELL to support spell checking),
 328                       [use_aspell=no ac_cv_enable_aspell=no])
 329 else
 330         AC_MSG_RESULT(no)
 331 fi
 332
 333 dnl want crash dialog
 334 AC_ARG_ENABLE(crash-dialog,
 335         [  --enable-crash-dialog   Enable crash dialog [default=no]],
 336         [ac_cv_enable_crash_dialog=$enableval], [ac_cv_enable_crash_dialog=no])
 337 if test $ac_cv_enable_crash_dialog = yes; then
 338 dnl check if GDB is somewhere
 339         AC_CHECK_PROG(ac_cv_enable_crash_dialog, gdb, yes, no)
 340         AC_MSG_CHECKING([whether to use crash dialog])
 341         if test $ac_cv_enable_crash_dialog = yes; then
 342                 AC_DEFINE(CRASH_DIALOG, 1, Pop up crash dialog)
 343         fi
 344         AC_MSG_RESULT($ac_cv_enable_crash_dialog)
 345 fi
 346
 347 dnl Check for X-Face support
 348 AC_ARG_ENABLE(compface,
 349         [  --disable-compface      Do not use compface (X-Face)],
 350         [ac_cv_enable_compface=$enableval], [ac_cv_enable_compface=yes])
 351 AC_MSG_CHECKING([whether to use compface])
 352 if test x"$ac_cv_enable_compface" = xyes; then
 353         AC_MSG_RESULT(yes)
 354         AC_CHECK_LIB(compface, uncompface,
 355                 [AC_DEFINE(HAVE_LIBCOMPFACE, 1, Define if you want compface support.)],
 356                 [ac_cv_enable_compface=no])
 357         if test x"$ac_cv_enable_compface" = xyes; then
 358                 COMPFACE_LIBS="-lcompface"
 359         else
 360                 COMPFACE_LIBS=""
 361         fi
 362         AC_SUBST(COMPFACE_LIBS)
 363 else
 364         AC_MSG_RESULT(no)
 365 fi
 366
 367 dnl for LDAP support in addressbook
 368 dnl no check for libraries; dynamically loaded
 369 AC_ARG_ENABLE(ldap,
 370         [  --enable-ldap           Enable LDAP support [default=no]],
 371         [ac_cv_enable_ldap=$enableval], [ac_cv_enable_ldap=no])
 372 AC_MSG_CHECKING([whether to use LDAP])
 373 if test "$ac_cv_enable_ldap" = yes; then
 374         AC_MSG_RESULT(yes)
 375
 376         dnl check for available libraries, and pull them in
 377         AC_CHECK_LIB(resolv, res_query, LDAP_LIBS="$LDAP_LIBS -lresolv")
 378         AC_CHECK_LIB(socket, bind, LDAP_LIBS="$LDAP_LIBS -lsocket")
 379         AC_CHECK_LIB(nsl, gethostbyaddr, LDAP_LIBS="$LDAP_LIBS -lnsl")
 380         AC_CHECK_LIB(lber, ber_get_tag, LDAP_LIBS="$LDAP_LIBS -llber",,
 381                      $LDAP_LIBS)
 382
 383         dnl we need libpthread for sylpheed ldap,  until we find
 384         dnl a better way to handle ldap requests asynchronously...
 385         AC_CHECK_LIB(pthread, pthread_create, LDAP_LIBS="$LDAP_LIBS -lpthread")
 386
 387         AC_CHECK_HEADERS(ldap.h lber.h pthread.h,
 388                          [ ac_cv_enable_ldap=yes ],
 389                          [ ac_cv_enable_ldap=no ])
 390
 391         if test "$ac_cv_enable_ldap" = yes; then
 392                 AC_CHECK_LIB(ldap, ldap_open,
 393                              [ ac_cv_enable_ldap=yes ],
 394                              [ ac_cv_enable_ldap=no ],
 395                              $LDAP_LIBS)
 396         fi
 397
 398         AC_MSG_CHECKING([whether ldap library is available])
 399         AC_MSG_RESULT($ac_cv_enable_ldap)
 400
 401         if test "$ac_cv_enable_ldap" = yes; then
 402                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
 403                 LDAP_LIBS="$LDAP_LIBS -lldap `$GLIB_CONFIG --libs gthread`"
 404                 AC_DEFINE(USE_LDAP, 1, Define if you want LDAP support in addressbook.)
 405                 AC_SUBST(LDAP_LIBS)
 406         fi
 407 else
 408         AC_MSG_RESULT(no)
 409 fi
 410
 411 dnl for JPilot support in addressbook
 412 dnl no check for libraries; these are dynamically loaded
 413 AC_ARG_ENABLE(jpilot,
 414         [  --enable-jpilot         Enable JPilot support [default=no]],
 415         [ac_cv_enable_jpilot=$enableval], [ac_cv_enable_jpilot=no])
 416 AC_MSG_CHECKING([whether to use JPilot])
 417 if test "$ac_cv_enable_jpilot" = yes; then
 418         AC_MSG_RESULT(yes)
 419         AC_CHECK_HEADERS(pi-args.h pi-appinfo.h pi-address.h,
 420                          [ AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ],
 421                          [ ac_cv_enable_jpilot=no ])
 422         if test "$ac_cv_enable_jpilot" = no; then
 423                 AC_CHECK_HEADERS(libpisock/pi-args.h libpisock/pi-appinfo.h libpisock/pi-address.h,
 424                                  [ ac_cv_enable_jpilot=yes
 425                                    AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ])
 426         fi
 427
 428         AC_CHECK_LIB(pisock, unpack_Address, [JPILOT_LIBS="-lpisock"], [JPILOT_LIBS="" ac_cv_enable_jpilot="no"])
 429         if test x"$ac_cv_enable_jpilot" = xyes; then
 430                 AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.)
 431         else
 432                 AC_MSG_NOTICE([JPilot support not available])
 433         fi
 434         AC_SUBST(JPILOT_LIBS)
 435 else
 436         AC_MSG_RESULT(no)
 437 fi
 438
 439 dnl GPGME is used to support OpenPGP
 440 AC_ARG_ENABLE(gpgme,
 441         [  --enable-gpgme          Enable GnuPG support using GPGME [default=no]],
 442         [ac_cv_enable_gpgme=$enableval], [ac_cv_enable_gpgme=no])
 443 AC_MSG_CHECKING([whether to use GPGME])
 444 if test $ac_cv_enable_gpgme = yes; then
 445         AC_MSG_RESULT(yes)
 446         AM_PATH_GPGME(0.3.10, AC_DEFINE(USE_GPGME, 1, Define if you use GPGME to support OpenPGP.),
 447                       [use_gpgme=no
 448                        ac_cv_enable_gpgme=no])
 449 else
 450         AC_MSG_RESULT(no)
 451 fi
 452
 453 dnl *************************
 454 dnl ** section for plugins **
 455 dnl *************************
 456
 457 PLUGINS=""
 458
 459 dnl --- Trayicon ---
 460 AC_ARG_ENABLE(trayicon-plugin,
 461         [  --disable-trayicon-plugin         Do not build System Tray Icon plugin],
 462         [ac_cv_enable_trayicon_plugin=$enableval], [ac_cv_enable_trayicon_plugin=yes])
 463 if test x"$ac_cv_enable_trayicon_plugin" = xyes; then
 464         PLUGINS="trayicon $PLUGINS"
 465 fi
 466 AM_CONDITIONAL(BUILD_TRAYICON_PLUGIN, test x"$ac_cv_enable_trayicon_plugin" = xyes)
 467
 468 dnl --- SpamAssassin ---
 469 AC_ARG_ENABLE(spamassassin-plugin,
 470         [  --enable-spamassassin-plugin      Build SpamAssassin plugin [default=no]],
 471         [ac_cv_enable_spamassassin_plugin=$enableval], [ac_cv_enable_spamassassin_plugin=no])
 472 if test x"$ac_cv_enable_spamassassin_plugin" = xyes; then
 473         AC_SPAMASSASSIN
 474         PLUGINS="spamassassin $PLUGINS"
 475 fi
 476 AM_CONDITIONAL(BUILD_SPAMASSASSIN_PLUGIN, test x"$ac_cv_enable_spamassassin_plugin" = xyes)
 477
 478 dnl --- MathML Viewer ---
 479 AC_ARG_ENABLE(mathml-viewer-plugin,
 480         [  --disable-mathml-viewer-plugin    Do not build MathML-Viewer plugin],
 481         [ac_cv_enable_mathml_viewer_plugin=$enableval], [ac_cv_enable_mathml_viewer_plugin=yes])
 482 if test x"$ac_cv_enable_mathml_viewer_plugin" = xyes; then
 483         PKG_CHECK_MODULES(GTK_MATH_VIEW, gtkmathview >= 0.5, :, ac_cv_enable_mathml_viewer_plugin=no)
 484
 485         if test x"$ac_cv_enable_mathml_viewer_plugin" = xyes; then
 486
 487                 PLUGINS="mathml-viewer $PLUGINS"
 488         fi
 489 fi
 490 AC_SUBST(GTK_MATH_VIEW_CFLAGS)
 491 AC_SUBST(GTK_MATH_VIEW_LIBS)
 492 AM_CONDITIONAL(BUILD_MATHML_VIEWER_PLUGIN, test x"$ac_cv_enable_mathml_viewer_plugin" = xyes)
 493
 494 dnl --- Image Viewer ---
 495 AC_ARG_ENABLE(image-viewer-plugin,
 496         [  --disable-image-viewer-plugin     Do not build image viewer plugin],
 497         [ac_cv_enable_image_viewer_plugin=$enableval], [ac_cv_enable_image_viewer_plugin=yes])
 498 if test x"$ac_cv_enable_image_viewer_plugin" = xyes; then
 499         AC_ARG_ENABLE(gdk-pixbuf,
 500                 [  --disable-gdk-pixbuf              Do not use gdk-pixbuf],
 501                 [ac_cv_enable_gdk_pixbuf=$enableval], [ac_cv_enable_gdk_pixbuf=yes])
 502         AC_ARG_ENABLE(imlib,
 503                 [  --disable-imlib                   Do not use imlib],
 504                 [ac_cv_enable_imlib=$enableval], [ac_cv_enable_imlib=yes])
 505
 506         if test "$ac_cv_enable_gdk_pixbuf" = yes; then
 507                 PKG_CHECK_MODULES(GDK_PIXBUF, \
 508                         [ gdk-pixbuf-2.0 ],
 509                         [ AC_DEFINE(HAVE_GDK_PIXBUF, 1, Define if you use gdk-pixbuf to support image viewer) ],
 510                         [ ac_cv_enable_gdk_pixbuf=no ])
 511         fi
 512
 513         if test "$ac_cv_enable_gdk_pixbuf" = yes; then
 514                 PLUGINS="image-viewer(gdk-pixbuf) $PLUGINS"
 515         else
 516                 ac_cv_enable_image_viewer_plugin=no
 517         fi
 518 fi
 519 AM_CONDITIONAL(BUILD_IMAGE_VIEWER_PLUGIN, test x"$ac_cv_enable_image_viewer_plugin" = xyes)
 520
 521 dnl --- Dillo Viewer ---
 522 AC_ARG_ENABLE(dillo-viewer-plugin,
 523         [  --disable-dillo-viewer-plugin     Do not build Dillo plugin for html mail rendering],
 524         [ac_cv_enable_dillo_viewer_plugin=$enableval], [ac_cv_enable_dillo_viewer_plugin=yes])
 525 if test x"$ac_cv_enable_dillo_viewer_plugin" = xyes; then
 526         PLUGINS="dillo-viewer $PLUGINS"
 527 fi
 528 AM_CONDITIONAL(BUILD_DILLO_VIEWER_PLUGIN, test x"$ac_cv_enable_dillo_viewer_plugin" = xyes)
 529
 530 dnl --- Demo ---
 531 AC_ARG_ENABLE(demo-plugin,
 532         [  --enable-demo-plugin              Build demo plugin [default=no]],
 533         [ac_cv_enable_demo_plugin=$enableval], [ac_cv_enable_demo_plugin=no])
 534 if test x"$ac_cv_enable_demo_plugin" = xyes; then
 535         PLUGINS="demo $PLUGINS"
 536 fi
 537 AM_CONDITIONAL(BUILD_DEMO_PLUGIN, test x"$ac_cv_enable_demo_plugin" = xyes)
 538
 539 dnl --- ClamAV ---
 540 AC_ARG_ENABLE(clamav-plugin,
 541         [  --disable-clamav-plugin           Do not build Clam AntiVirus plugin],
 542         [ac_cv_enable_clamav_plugin=$enableval], [ac_cv_enable_clamav_plugin=yes])
 543 if test x"$ac_cv_enable_clamav_plugin" = xyes; then
 544         AC_CHECK_LIB(clamav, cl_scanfile, clamav_lib=-lclamav, ac_cv_enable_clamav_plugin=no)
 545         AC_CHECK_HEADERS(clamav.h, :, ac_cv_enable_clamav_plugin=no)
 546         if test x"$ac_cv_enable_clamav_plugin" = xyes; then
 547                 CLAMAV_LIBS="${clamav_lib}"
 548
 549                 PLUGINS="clamav $PLUGINS"
 550         else
 551                 AC_MSG_NOTICE([clamav library not found, will not build clamav plugin])
 552         fi
 553 fi
 554 AC_SUBST(CLAMAV_LIBS)
 555 AM_CONDITIONAL(BUILD_CLAMAV_PLUGIN, test x"$ac_cv_enable_clamav_plugin" = xyes)
 556
 557 dnl ****************************
 558 dnl ** Final configure output **
 559 dnl ****************************
 560
 561 AC_OUTPUT([
 562 Makefile
 563 sylpheed.spec
 564 intl/Makefile
 565 m4/Makefile
 566 po/Makefile.in
 567 src/common/version.h
 568 src/Makefile
 569 src/common/Makefile
 570 src/common/passcrypt.h
 571 src/gtk/Makefile
 572 src/plugins/Makefile
 573 src/plugins/demo/Makefile
 574 src/plugins/spamassassin/Makefile
 575 src/plugins/mathml_viewer/Makefile
 576 src/plugins/dillo_viewer/Makefile
 577 src/plugins/image_viewer/Makefile
 578 src/plugins/trayicon/Makefile
 579 src/plugins/trayicon/libeggtrayicon/Makefile
 580 src/plugins/clamav/Makefile
 581 doc/Makefile
 582 doc/faq/Makefile
 583 doc/faq/de/Makefile
 584 doc/faq/en/Makefile
 585 doc/faq/es/Makefile
 586 doc/faq/fr/Makefile
 587 doc/faq/it/Makefile
 588 doc/man/Makefile
 589 doc/manual/Makefile
 590 doc/manual/de/Makefile
 591 doc/manual/en/Makefile
 592 doc/manual/es/Makefile
 593 doc/manual/fr/Makefile
 594 doc/manual/ja/Makefile
 595 tools/Makefile
 596 config/Makefile
 597 sylpheed-claws.pc
 598 ])
 599
 600 dnl Output the configuration summary
 601 echo ""
 602 echo "$PACKAGE $VERSION"
 603 echo ""
 604 echo "GnuPG         : $ac_cv_enable_gpgme"
 605 echo "JPilot        : $ac_cv_enable_jpilot"
 606 echo "LDAP          : $ac_cv_enable_ldap"
 607 echo "OpenSSL       : $ac_cv_enable_openssl"
 608 echo "iconv         : $am_cv_func_iconv"
 609 echo "compface      : $ac_cv_enable_compface"
 610 echo "IPv6          : $ac_cv_enable_ipv6"
 611 echo "GNU/aspell    : $ac_cv_enable_aspell"
 612 echo "Crash dialog  : $ac_cv_enable_crash_dialog"
 613 echo "Plugins       : $PLUGINS"
 614 echo "Config dir    : $ac_cv_with_config_dir"
 615 echo ""
 616 echo "The binary will be installed in $prefix/bin"
 617 echo ""
 618 echo "Configure finished, type 'make' to build."