0e0061cb7d81c0dcebf85a86d0ec4ebb315bb1c5
[claws.git] / configure.ac
1
2 AC_PREREQ(2.60)
3 AC_INIT(src/main.c)
4 AC_CONFIG_AUX_DIR(config)
5
6 PACKAGE=claws-mail
7
8 dnl version number
9 MAJOR_VERSION=3
10 MINOR_VERSION=6
11 MICRO_VERSION=1
12 INTERFACE_AGE=0
13 BINARY_AGE=0
14 EXTRA_VERSION=8
15 EXTRA_RELEASE=
16 EXTRA_GTK2_VERSION=
17
18 if test \( $EXTRA_VERSION -eq 0 \) -o \( "x$EXTRA_RELEASE" != "x" \); then
19     VERSION=${MAJOR_VERSION}.${MINOR_VERSION}.${MICRO_VERSION}${EXTRA_RELEASE}${EXTRA_GTK2_VERSION}
20 else
21     VERSION=${MAJOR_VERSION}.${MINOR_VERSION}.${MICRO_VERSION}cvs${EXTRA_VERSION}${EXTRA_GTK2_VERSION}
22 fi
23
24 dnl set $target
25 AC_CANONICAL_SYSTEM
26
27 dnl
28 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
29 dnl AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
30 dnl AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
31 AC_SUBST(PACKAGE)
32 AC_SUBST(VERSION)
33 AC_SUBST(MAJOR_VERSION)
34 AC_SUBST(MINOR_VERSION)
35 AC_SUBST(MICRO_VERSION)
36 AC_SUBST(EXTRA_VERSION)
37
38 dnl GNOME installed?
39 AC_PATH_PROG(GNOME_CONFIG, gnome-config, no)
40 if test "$GNOME_CONFIG" != no; then
41         gnomedatadir="`gnome-config --datadir`"
42         gnomeprefix="`gnome-config --prefix`"
43         if test "${prefix}" = "NONE"; then
44                 gnomedatadir="${ac_default_prefix}/${gnomedatadir#${gnomeprefix}}"
45         else
46                 gnomedatadir="${prefix}/${gnomedatadir#${gnomeprefix}}"
47         fi
48         AC_SUBST(gnomedatadir)
49 fi
50 AM_CONDITIONAL(CLAWS_GNOME, test -n "$gnomedatadir")
51
52 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
53 if test x$PKG_CONFIG = xno ; then
54   AC_MSG_ERROR([*** pkg-config not found. See http://www.freedesktop.org/software/pkgconfig/])
55 fi
56
57 dnl GNOME 2.x installed?
58 PKG_CHECK_MODULES(GNOME2, libgnome-2.0 >= 2.0, ac_enable_gnome2=yes, ac_enable_gnome2=no)
59 AM_CONDITIONAL(CLAWS_GNOME2, test x"$ac_enable_gnome2" = x"yes")
60
61 dnl libtool versioning
62 LT_RELEASE=$MAJOR_VERSION.$MINOR_VERSION
63 LT_CURRENT=`expr $MICRO_VERSION - $INTERFACE_AGE`
64 LT_REVISION=$INTERFACE_AGE
65 LT_AGE=`expr $BINARY_AGE - $INTERFACE_AGE`
66 AC_SUBST(LT_RELEASE)
67 AC_SUBST(LT_CURRENT)
68 AC_SUBST(LT_REVISION)
69 AC_SUBST(LT_AGE)
70
71 dnl Specify a header configuration file
72 AC_CONFIG_HEADERS(config.h)
73
74 AM_MAINTAINER_MODE
75
76 dnl Checks for programs.
77 dnl AC_ARG_PROGRAM
78 AC_PROG_CC
79 AC_ISC_POSIX
80 AC_PROG_INSTALL
81 AC_PROG_LN_S
82 AC_PROG_MAKE_SET
83 AC_PROG_CPP
84 dnl AC_PROG_RANLIB
85 AM_PROG_LEX
86 AC_PROG_YACC
87 AC_LIB_PREFIX
88 AC_LIBTOOL_WIN32_DLL
89 AC_LIBTOOL_RC
90 AC_PROG_LIBTOOL
91
92 CLAWS_ACLOCAL_INCLUDE(m4)
93   
94 dnl ******************************
95 dnl Checks for host
96 dnl Not needed anymore because we 
97 dnl do AC_CANONICAL_SYSTEM above
98 dnl ******************************
99 dnl AC_CANONICAL_HOST
100
101 dnl Copied from the official gtk+-2 configure.in
102 AC_MSG_CHECKING([for some Win32 platform])
103 case "$host" in
104   *-*-mingw*|*-*-cygwin*)
105     platform_win32=yes
106     LDFLAGS="$LDFLAGS -mwindows"
107     ;;
108   *)
109     platform_win32=no
110     ;;
111 esac
112 AC_MSG_RESULT([$platform_win32])
113 AM_CONDITIONAL(PLATFORM_WIN32, test x"$platform_win32" = x"yes")
114
115 AC_MSG_CHECKING([for native Win32])
116 case "$host" in
117   *-*-mingw*)
118     os_win32=yes
119     ;;
120   *)
121     os_win32=no
122     ;;
123 esac
124 AC_MSG_RESULT([$os_win32])
125 AM_CONDITIONAL(OS_WIN32, test x"$os_win32" = x"yes")
126
127 AC_MSG_CHECKING([for Cygwin])
128 case "$host" in
129   *-*-cygwin*)
130     env_cygwin=yes
131     ;;
132   *)
133     env_cygwin=no
134     ;;
135 esac
136 AC_MSG_RESULT([$env_cygwin])
137 AM_CONDITIONAL(CYGWIN, test x"$env_cygwin" = x"yes")
138
139 if test "$GCC" = "yes"
140 then
141         CFLAGS="$CFLAGS -Wno-unused-function"
142 fi
143
144 CFLAGS="$CFLAGS -Wall"
145
146 if test $USE_MAINTAINER_MODE = yes; then
147         CFLAGS="$CFLAGS -DGTK_DISABLE_DEPRECATED -DGDK_DISABLE_DEPRECATED -DG_DISABLE_DEPRECATED -DGTK_DISABLE_SINGLE_INCLUDES"
148 fi
149
150 pthread_name=
151 case "$target" in
152 *-darwin*)
153         CFLAGS="$CFLAGS -no-cpp-precomp -fno-common"
154         ;;
155 *-*-mingw*)
156         # Note that we need to link to pthreadGC2 in all cases. This
157         # is because some locking is used even when pthread support is
158         # disabled.
159         pthread_name=pthreadGC2
160         CFLAGS="$CFLAGS -mms-bitfields"
161         LIBS="$LIBS -l${pthread_name} -lws2_32 -lregex"
162         ;;
163 *-*-solaris*)
164         CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
165         CFLAGS="$CFLAGS -DSOLARIS"
166         ;;
167 esac
168   
169 dnl Checks for iconv
170 AM_ICONV
171
172 dnl
173 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
174 dnl
175 syl_save_LIBS=$LIBS
176 LIBS="$LIBS $GTK_LIBS"
177 AC_CHECK_FUNCS(bind_textdomain_codeset)
178 LIBS=$syl_save_LIBS
179
180 dnl for gettext
181 ALL_LINGUAS="bg ca de en_GB es fi fr hu it nl pl pt_BR ru sk sr sv zh_CN"
182 GETTEXT_PACKAGE=claws-mail
183 AC_SUBST(GETTEXT_PACKAGE)
184 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Define text domain.])
185
186 AM_GNU_GETTEXT_VERSION([0.15])
187 AM_GNU_GETTEXT([external])
188
189 manualdir='${docdir}/manual'
190 AC_ARG_WITH(manualdir,
191         [  --with-manualdir=DIR    Manual directory],
192         [manualdir="$withval"])
193 AC_SUBST(manualdir)
194
195 AC_ARG_ENABLE(manual,
196         [  --disable-manual           do not build manual],
197         [ac_cv_enable_manual=$enableval], [ac_cv_enable_manual=yes])
198
199 AM_CONDITIONAL(BUILD_MANUAL, test x"$ac_cv_enable_manual" = xyes)
200
201 dnl Set PACKAGE_DATA_DIR in config.h.
202 if test "x${datarootdir}" = 'x${prefix}/share'; then
203         if test "x${prefix}" = "xNONE"; then
204                 AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${ac_default_prefix}/share/${PACKAGE}",[PACKAGE_DATA_DIR])
205         else
206                 AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${prefix}/share/${PACKAGE}",[PACKAGE_DATA_DIR])
207         fi
208 else
209         AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${datarootdir}/${PACKAGE}",[PACKAGE_DATA_DIR])
210 fi
211
212 AC_CHECK_LIB(xpg4, setlocale)
213
214 SM_LIBS=""
215 dnl Check for LibSM
216 AC_ARG_ENABLE(libsm,
217         [  --disable-libsm    disable libSM support for session management.],
218         [ac_cv_enable_libsm=$enableval], [ac_cv_enable_libsm=yes])
219 AC_MSG_CHECKING([whether to use LibSM])
220 if test x"$ac_cv_enable_libsm" = xyes; then
221         AC_MSG_RESULT(yes)
222         AC_CHECK_LIB(SM, SmcSaveYourselfDone,
223                 [SM_LIBS="$X_LIBS -lSM -lICE"],ac_cv_enable_libsm=no,
224                 $X_LIBS -lICE)
225         AC_CHECK_HEADERS(X11/SM/SMlib.h,,ac_cv_enable_libsm=no)
226         if test x"$ac_cv_enable_libsm" = xyes; then
227                 AC_DEFINE(HAVE_LIBSM, 1, [Define to 1 if you have libSM installed])
228         else
229                 AC_MSG_RESULT(not found)
230                 AC_MSG_WARN([*** LibSM will not be supported ***])
231         fi
232 else
233         AC_MSG_RESULT(no)
234 fi
235 AC_SUBST(SM_LIBS)
236
237 dnl for GThread support (currently disabled)
238 dnl AC_ARG_ENABLE(threads,
239 dnl     [  --enable-threads        Enable multithread support [default=no]],
240 dnl     [use_threads=$enableval], [use_threads=no])
241
242 AC_MSG_CHECKING([whether to use threads])
243 if test x"$use_threads" = xyes ; then
244         AC_MSG_RESULT(yes)
245         if test ! -z `$GLIB_CONFIG --help 2>&1 |grep 'gthread'` ; then
246                 CFLAGS="$CFLAGS `$GLIB_CONFIG --cflags gthread`"
247                 LIBS="$LIBS `$GLIB_CONFIG --libs gthread`"
248                 AC_DEFINE(USE_THREADS, 1, Whether to use multithread or not)
249         else
250                 AC_MSG_ERROR([Sylpheed requires GThread from GLib to use threading.])
251         fi
252 else
253         AC_MSG_RESULT(no)
254 fi
255
256 dnl Check for d_type member in struct dirent
257 AC_MSG_CHECKING([whether struct dirent has d_type member])
258 AC_CACHE_VAL(ac_cv_dirent_d_type,[
259         AC_TRY_COMPILE([#include <dirent.h>],
260                        [struct dirent d; d.d_type = DT_REG;],
261                        ac_cv_dirent_d_type=yes, ac_cv_dirent_d_type=no)
262 ])
263 AC_MSG_RESULT($ac_cv_dirent_d_type)
264 if test $ac_cv_dirent_d_type = yes; then
265         AC_DEFINE(HAVE_DIRENT_D_TYPE, 1,
266                   Define if `struct dirent' has `d_type' member.)
267 fi
268
269 # Check whether mkdir does not take the permission argument.
270 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
271
272 dnl Checks for header files.
273 AC_HEADER_DIRENT
274 AC_HEADER_STDC
275 AC_HEADER_SYS_WAIT
276 AC_CHECK_HEADERS(fcntl.h sys/file.h unistd.h paths.h \
277                  sys/param.h sys/utsname.h sys/select.h \
278                  wchar.h wctype.h locale.h netdb.h)
279
280 dnl alf - Check for apache installation f*ck up. apache may also install an 
281 dnl fnmatch, which includes their own regex stuff if USE_HSREGEX is defined
282 AC_TRY_COMPILE([#include <stdlib.h>
283                 #include <fnmatch.h>],
284         [int x = USE_HSREGEX;],
285         ac_cv_have_apache_fnmatch=yes, ac_cv_have_apache_fnmatch=no)
286 if test $ac_cv_have_apache_fnmatch = yes; then
287         AC_DEFINE(HAVE_APACHE_FNMATCH, 1, Define if you need to work around apache regex/fnmatch !KLUDGE!)
288 fi
289 AC_MSG_CHECKING([whether to use Apache regex header kludge])
290 AC_MSG_RESULT($ac_cv_have_apache_fnmatch)
291
292 dnl Checks for typedefs, structures, and compiler characteristics.
293 AC_C_CONST
294 AC_TYPE_OFF_T
295 AC_TYPE_PID_T
296 AC_TYPE_SIZE_T
297 AC_STRUCT_TM
298
299 dnl AC_CHECK_TYPE(wint_t, unsigned int) does not work because wint_t
300 dnl may be defined only in wchar.h (this happens with gcc-2.96).
301 dnl So we need to use this extended macro.
302 CLAWS_CHECK_TYPE(wint_t, unsigned int,
303 [
304 #if HAVE_WCHAR_H
305 #include <wchar.h>
306 #endif
307 ], Define to `unsigned int' if <stddef.h> or <wchar.h> doesn't define.)
308
309 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF, Used to test for a u32 typedef)
310 AC_CHECK_SIZEOF(unsigned short, 2)
311 AC_CHECK_SIZEOF(unsigned int, 4)
312 AC_CHECK_SIZEOF(unsigned long, 4)
313
314 dnl Checks for library functions.
315 AC_FUNC_ALLOCA
316 AC_CHECK_FUNCS(gethostname mkdir mktime socket strstr strchr \
317                uname flock lockf inet_aton inet_addr \
318                fchmod mkstemp truncate getuid regcomp)
319
320 AC_CHECK_FUNCS(fgets_unlocked fwrite_unlocked)
321
322 dnl *****************
323 dnl ** common code **
324 dnl *****************
325
326 dnl check for glib
327 PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.6 gmodule-2.0 >= 2.6 gobject-2.0 >= 2.6 gthread-2.0 >= 2.6)
328       
329 GLIB_GENMARSHAL=`pkg-config --variable=glib_genmarshal glib-2.0`
330 AC_SUBST(GLIB_GENMARSHAL)
331
332 AC_SUBST(GLIB_CFLAGS)
333 AC_SUBST(GLIB_LIBS)
334
335 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
336 syl_save_LIBS=$LIBS
337 LIBS="$LIBS $GTK_LIBS"
338 AC_CHECK_FUNCS(bind_textdomain_codeset)
339 LIBS=$syl_save_LIBS
340
341 dnl check for IPv6 option
342 AC_ARG_ENABLE(ipv6,
343         [  --disable-ipv6           disable build IPv6 support],
344         [ac_cv_enable_ipv6=$enableval], [ac_cv_enable_ipv6=yes])
345
346 dnl automated checks for IPv6 support.
347 AC_MSG_CHECKING([whether to use IPv6])
348 if test x"$ac_cv_enable_ipv6" = xyes; then
349         AC_MSG_RESULT(yes)
350         AC_MSG_CHECKING([for IPv6 support])
351         AC_CACHE_VAL(ac_cv_ipv6,[
352                 AC_TRY_COMPILE([#define INET6
353                                 #include <sys/types.h>
354                                 #include <netinet/in.h>],
355                         [int x = IPPROTO_IPV6; struct in6_addr a;],
356                         ac_cv_ipv6=yes, ac_cv_ipv6=no)
357         ])
358         AC_MSG_RESULT($ac_cv_ipv6)
359         if test $ac_cv_ipv6 = yes; then
360                 AC_DEFINE(INET6, 1, Define if you want IPv6 support.)
361         else
362                 AC_MSG_WARN(*** IPv6 will not be supported ***)
363                 ac_cv_enable_ipv6=no
364         fi
365 else
366         AC_MSG_RESULT(no)
367 fi
368
369 dnl GNUTLS
370 AC_ARG_ENABLE(openssl,    [ --enable-openssl      enable GnuTLS support],
371             [ac_cv_enable_openssl=$enableval], [ac_cv_enable_openssl=no])
372 AC_ARG_ENABLE(gnutls,    [ --enable-gnutls      enable GnuTLS support],
373             [ac_cv_enable_gnutls=$enableval], [ac_cv_enable_gnutls=yes])
374
375 if test "x$ac_cv_enable_gnutls" != "xyes"; then
376         if test "x$ac_cv_enable_openssl" = "xyes"; then
377                 AC_MSG_ERROR(*** Use GnuTLS instead of OpenSSL due to licensing ***)
378         fi
379 fi
380 AC_MSG_CHECKING([whether to use GnuTLS])
381 if test "x$ac_cv_enable_gnutls" != "xno"; then
382   OCPPFLAGS="$CPPFLAGS"
383   OLDFLAGS="$LDFLAGS"
384   GNUTLS_LIBS=""
385   AC_CHECK_HEADER(gnutls/gnutls.h, [
386         AC_CHECK_LIB(gnutls, gnutls_global_deinit, 
387                 [AC_DEFINE(USE_GNUTLS, 1, Define to use GnuTLS.)],
388                 [ac_cv_enable_gnutls=no])
389   ],[ac_cv_enable_gnutls=no])
390   if test "x$ac_cv_enable_gnutls" != "xyes"; then
391    CPPFLAGS="$OCPPFLAGS"
392    LDFLAGS="$OLDFLAGS"
393   fi
394 fi
395 if test "x$ac_cv_enable_gnutls" = "xyes"; then
396   AC_DEFINE([USE_GNUTLS],1, [Define to use GnuTLS])
397   GNUTLS_LIBS="-lgnutls"
398 else
399   GNUTLS_LIBS=""
400 fi
401 AC_SUBST(GNUTLS_LIBS)
402
403 dnl password encryption
404 OLDLIBS=$LIBS
405 LIBS=
406 case $host_os in
407         *dragonfly*)
408                 AC_SEARCH_LIBS(encrypt, cipher, [], AC_MSG_ERROR(['encrypt'-function not found.]))
409         ;;
410         *)
411                 AC_SEARCH_LIBS(encrypt, crypt, [], AC_MSG_ERROR(['encrypt'-function not found.]))
412         ;;
413 esac
414 CRYPT_LIBS=$LIBS
415 AC_SUBST(CRYPT_LIBS)
416 LIBS=$OLDLIBS
417
418 AC_ARG_WITH(passcrypt-key, [  --with-passcrypt-key=KEY     Key used to encode passwords (8 byte string)],
419             with_passcrypt_key="$withval", with_passcrypt_key="passkey0")
420 AC_SUBST(PASSCRYPT_KEY, $with_passcrypt_key)
421
422 dnl RC dir (will be default at a certain point in time)
423 AC_ARG_WITH(config-dir,    [  --with-config-dir=RCDIR      Local configuration dir (default: .claws-mail)],
424               ac_cv_with_config_dir="$withval", ac_cv_with_config_dir=".claws-mail")
425 if test x"$ac_cv_with_config_dir" = x""; then
426         ac_cv_with_config_dir=".claws-mail"
427 fi 
428 AC_DEFINE_UNQUOTED(CFG_RC_DIR, "$ac_cv_with_config_dir", Configuration directory)
429
430 dnl ************************
431 dnl ** GTK user interface **
432 dnl ************************
433
434 dnl Checks for GTK
435 PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.6)
436
437 dnl --disable-deprecated switch for GTK2 purification
438 AC_ARG_ENABLE(deprecated, [  --disable-deprecated  disable deprecated GTK functions. ],
439                           [GTK_CFLAGS="$GTK_CFLAGS -DG_DISABLE_DEPRECATED -DGTK_DISABLE_DEPRECATED"], [])
440
441 AC_SUBST(GTK_CFLAGS)
442 AC_SUBST(GTK_LIBS)
443
444 dnl enchant is used for spell checking
445 AC_ARG_ENABLE(enchant,
446         [  --disable-enchant         disable enchant support],
447         [ac_cv_enable_enchant=$enableval], [ac_cv_enable_enchant=yes])
448 AC_MSG_CHECKING([whether to use enchant])
449 if test $ac_cv_enable_enchant = yes; then
450         PKG_CHECK_MODULES(ENCHANT, enchant >= 1.0.0,
451         [
452                 AC_DEFINE(USE_ENCHANT, 1, enchant)
453                 echo "Building with enchant"
454                 ac_cv_enable_enchant=yes
455         ],
456         [
457                 echo "Building without enchant-notification"
458                 ac_cv_enable_enchant=no
459         ])
460         AC_SUBST(ENCHANT_CFLAGS)
461         AC_SUBST(ENCHANT_LIBS)
462 fi
463
464 dnl want crash dialog
465 AC_ARG_ENABLE(crash-dialog,
466         [  --enable-crash-dialog   Enable crash dialog [default=no]],
467         [ac_cv_enable_crash_dialog=$enableval], [ac_cv_enable_crash_dialog=no])
468 if test $ac_cv_enable_crash_dialog = yes; then
469 dnl check if GDB is somewhere
470         AC_CHECK_PROG(ac_cv_enable_crash_dialog, gdb, yes, no)
471         AC_MSG_CHECKING([whether to use crash dialog])
472         if test $ac_cv_enable_crash_dialog = yes; then
473                 AC_DEFINE(CRASH_DIALOG, 1, Pop up crash dialog)
474         fi
475         AC_MSG_RESULT($ac_cv_enable_crash_dialog)
476 fi
477
478 dnl generic umpc
479 AC_ARG_ENABLE(generic-umpc,
480         [  --enable-generic-umpc   Enable generic UMPC code [default=no]],
481         [ac_cv_enable_generic_umpc=$enableval], [ac_cv_enable_generic_umpc=no])
482 if test $ac_cv_enable_generic_umpc = yes; then
483         AC_DEFINE(GENERIC_UMPC, 1, Generic UMPC code)
484         AC_MSG_RESULT($ac_cv_enable_generic_umpc)
485 fi
486
487 dnl Maemo platform
488 AC_ARG_ENABLE(maemo,
489         [  --enable-maemo   build for the Maemo platform [default=no]],
490         [ac_cv_enable_maemo=$enableval], [ac_cv_enable_maemo=no])
491 if test $ac_cv_enable_maemo = yes; then
492         PKG_CHECK_MODULES(MAEMO, libosso hildon-libs hildon-fm gnome-vfs-2.0, ac_cv_enable_maemo=yes,
493                   ac_cv_enable_maemo=no)
494         AC_SUBST(MAEMO_CFLAGS)
495         AC_SUBST(MAEMO_LIBS)
496         if test $ac_cv_enable_maemo = no; then
497                 #test for chinook
498                 PKG_CHECK_MODULES(MAEMO, libosso hildon-1 hildon-fm-2 gnome-vfs-2.0 hal, ac_cv_enable_maemo=yes,
499                           ac_cv_enable_maemo=no)
500                 AC_SUBST(MAEMO_CFLAGS)
501                 AC_SUBST(MAEMO_LIBS)
502                 if test $ac_cv_enable_maemo = no; then
503                         AC_MSG_ERROR(one of libosso hildon-libs hildon-fm hildon-1 hildon-fm-2 not found)
504                 else
505                         AC_DEFINE(MAEMO, 1, Build for maemo)
506                         AC_DEFINE(CHINOOK, 1, Maemo chinook)
507                         AC_DEFINE(GENERIC_UMPC, 1, Generic UMPC code)
508                         ac_cv_enable_generic_umpc=yes
509                 fi
510         else
511                 AC_DEFINE(MAEMO, 1, Build for maemo)
512                 AC_DEFINE(GENERIC_UMPC, 1, Generic UMPC code)
513                 ac_cv_enable_generic_umpc=yes
514         fi
515 fi
516
517 PKG_CHECK_MODULES(CONIC, conic, ac_cv_enable_conic=yes,
518           ac_cv_enable_conic=no)
519 AC_SUBST(CONIC_CFLAGS)
520 AC_SUBST(CONIC_LIBS)
521 if test $ac_cv_enable_conic = yes; then
522         AC_DEFINE(CONIC, 1, Have conic lib)
523 fi
524
525 dnl Check for X-Face support
526 AC_ARG_ENABLE(compface,
527         [  --disable-compface      disable compface (X-Face) support],
528         [ac_cv_enable_compface=$enableval], [ac_cv_enable_compface=yes])
529 AC_MSG_CHECKING([whether to use compface])
530 if test x"$ac_cv_enable_compface" = xyes; then
531         AC_MSG_RESULT(yes)
532         AC_CHECK_LIB(compface, uncompface, 
533                 [AC_DEFINE(HAVE_LIBCOMPFACE, 1, Define if you want compface support.)],
534                 [ac_cv_enable_compface=no])
535         if test x"$ac_cv_enable_compface" = xyes; then
536                 COMPFACE_LIBS="-lcompface"
537         else
538                 COMPFACE_LIBS=""
539         fi
540         AC_SUBST(COMPFACE_LIBS)
541 else
542         AC_MSG_RESULT(no)
543 fi
544
545 dnl check for pthread support
546 AC_ARG_ENABLE(pthread,
547         [  --disable-pthread           disable pthread support],
548         [ac_cv_enable_pthread=$enableval], [ac_cv_enable_pthread=yes])
549 AC_MSG_CHECKING([whether to use pthread])
550 if test x$ac_cv_enable_pthread = xno; then
551         AC_MSG_RESULT(no)
552 else
553         AC_MSG_RESULT(yes)
554
555         # For W32 we need to use a special ptrhead lib. In this case we can't
556         # use AC_CHECK_LIB because it has no means of checking for a
557         # library installed under a different name.  Checking for the
558         # header is okay.
559         if test -n "${pthread_name}" ; then
560            ac_cv_enable_pthread=yes
561         else
562         AC_CHECK_LIB(pthread, pthread_create, :, ac_cv_enable_pthread=no)
563         fi
564         AC_CHECK_HEADERS(pthread.h, :, ac_cv_enable_pthread=no)
565
566         if test x$ac_cv_enable_pthread = xyes; then
567                 AC_DEFINE(USE_PTHREAD, 1, Define if you have pthread)
568                 if test -z "${pthread_name}" ; then
569                 PTHREAD_LIBS="-lpthread"
570         fi
571         fi
572
573 fi
574 AC_SUBST(PTHREAD_LIBS)
575
576 dnl
577 dnl Check whether we need to pass -lresolv
578 dnl We know that we don't need it for W32.
579 dnl
580 if test x$os_win32 = xno; then
581   t_oldLibs="$LIBS"
582   LIBS="$LIBS"
583   ac_cv_var__res_options=no
584   AC_TRY_LINK([#include <sys/types.h>
585              #include <sys/socket.h>
586              #include <netinet/in.h>
587              #include <arpa/nameser.h>
588              #include <resolv.h>],
589                 [_res.options = RES_INIT;],
590                 ac_cv_var__res_options=yes);
591   if test "$ac_cv_var__res_options" != "yes"; then
592         LIBRESOLV="-lresolv"
593   fi
594   LIBS="$t_oldLibs"
595
596   if test "x$LIBRESOLV" = "x"; then
597         AC_CHECK_LIB(resolv, res_query, [LIBRESOLV=-lresolv])
598         LIBS="$t_oldLibs"
599   fi
600 fi
601 AC_SUBST(LIBRESOLV)
602
603 LIBS="$LIBS $LIBRESOLV"
604                  
605 dnl for LDAP support in addressbook
606 dnl no check for libraries; dynamically loaded
607 AC_ARG_ENABLE(ldap,
608         [  --disable-ldap         disable LDAP support],
609         [ac_cv_enable_ldap=$enableval], [ac_cv_enable_ldap=yes])
610 AC_MSG_CHECKING([whether to use LDAP])
611 if test x"$ac_cv_enable_ldap" = xno; then
612         AC_MSG_RESULT(no)
613 elif test x"$ac_cv_enable_ldap" = xyes -a x"$ac_cv_enable_pthread" = xno; then
614         AC_MSG_RESULT(no - LDAP support needs pthread support)
615
616         ac_cv_enable_ldap=no
617 else
618         AC_MSG_RESULT(yes)
619
620         dnl check for available libraries, and pull them in
621         AC_CHECK_LIB(resolv, res_query, LDAP_LIBS="$LDAP_LIBS -lresolv")
622         AC_CHECK_LIB(socket, bind, LDAP_LIBS="$LDAP_LIBS -lsocket")
623         AC_CHECK_LIB(nsl, gethostbyaddr, LDAP_LIBS="$LDAP_LIBS -lnsl")
624         AC_CHECK_LIB(lber, ber_get_tag, LDAP_LIBS="$LDAP_LIBS -llber",,
625                      $LDAP_LIBS)
626
627         AC_CHECK_HEADERS(ldap.h lber.h,
628                          [ ac_cv_enable_ldap=yes ],
629                          [ ac_cv_enable_ldap=no ])
630
631         if test "$ac_cv_enable_ldap" = yes; then
632                 AC_CHECK_LIB(ldap, ldap_open,
633                              [ ac_cv_enable_ldap=yes ],
634                              [ ac_cv_enable_ldap=no ],
635                              $LDAP_LIBS)
636
637                 AC_CHECK_LIB(ldap, ldap_start_tls_s,
638                              [ ac_cv_have_tls=yes ],
639                              [ ac_cv_have_tls=no ])
640
641         fi
642
643         AC_MSG_CHECKING([whether ldap library is available])
644         AC_MSG_RESULT($ac_cv_enable_ldap)
645
646         AC_MSG_CHECKING([whether TLS library is available])
647         AC_MSG_RESULT($ac_cv_have_tls)
648
649         if test "$ac_cv_enable_ldap" = yes; then
650                 AC_DEFINE(USE_LDAP, 1, Define if you want LDAP support in addressbook.)
651                 LDAP_LIBS="$LDAP_LIBS -lldap"
652                 AC_SUBST(LDAP_LIBS)
653                 if test "$ac_cv_have_tls" = yes; then
654                         AC_DEFINE(USE_LDAP_TLS, 1, Define if you want LDAP TLS support in addressbook.)
655                 fi
656                 dnl As of OpenLDAP API version 3000 a number of functions has
657                 dnl been deprecated. As Claws-mail compiles and runs on many
658                 dnl platforms and many versions of OpenLDAP we need to be able
659                 dnl to switch between the old and new API because new API has
660                 dnl added new functions replacing old ones and at the same time
661                 dnl old functions has been changed.
662                 dnl If cross-compiling defaults to enable deprecated features
663                 dnl for maximum portability
664                 AC_MSG_CHECKING([The API version of OpenLDAP])
665                 AC_RUN_IFELSE(
666                         [AC_LANG_PROGRAM(
667                          [#include <ldap.h>],
668                          [if (LDAP_API_VERSION >= 3000)
669                                         return 1
670                         ])],
671                         [AC_MSG_RESULT([version < 3000])
672                          AC_DEFINE(OPEN_LDAP_API_AT_LEAST_3000, 0, Define if OpenLDAP API is at least version 3000.)],
673                         [AC_MSG_RESULT([version >= 3000])
674                          AC_DEFINE(OPEN_LDAP_API_AT_LEAST_3000, 1, Define if OpenLDAP API is at least version 3000.)],
675                         [AC_MSG_RESULT([Enabling deprecated features in OpenLDAP])
676                          AC_DEFINE(OPEN_LDAP_API_AT_LEAST_3000, 0, Define if OpenLDAP API is at least version 3000.)
677                          AC_DEFINE(LDAP_DEPRECATED, 1, Define to activate deprecated features in OpenLDAP)]
678                 )
679         fi
680 fi
681
682 dnl for JPilot support in addressbook
683 dnl no check for libraries; these are dynamically loaded
684 AC_ARG_ENABLE(jpilot,
685         [  --disable-jpilot         disable JPilot support],
686         [ac_cv_enable_jpilot=$enableval], [ac_cv_enable_jpilot=yes])
687 AC_MSG_CHECKING([whether to use JPilot])
688 if test "$ac_cv_enable_jpilot" = yes; then
689         AC_MSG_RESULT(yes)
690         AC_CHECK_HEADERS(pi-args.h pi-appinfo.h pi-address.h pi-version.h,
691                          [ AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ],
692                          [ ac_cv_enable_jpilot=no ])
693         if test "$ac_cv_enable_jpilot" = no; then
694                 AC_CHECK_HEADERS(libpisock/pi-args.h libpisock/pi-appinfo.h libpisock/pi-address.h libpisock/pi-version.h,
695                                  [ ac_cv_enable_jpilot=yes
696                                    AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ])
697         fi
698
699         AC_CHECK_LIB(pisock, unpack_Address, [JPILOT_LIBS="-lpisock"], [JPILOT_LIBS="" ac_cv_enable_jpilot="no"])
700         if test x"$ac_cv_enable_jpilot" = xyes; then
701                 AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.)
702         else
703                 AC_MSG_NOTICE([JPilot support not available])
704         fi
705         AC_SUBST(JPILOT_LIBS)
706 else
707         AC_MSG_RESULT(no)
708 fi
709
710 dnl #######################################################################
711 dnl # Check for startup notification
712 dnl #######################################################################
713 AC_ARG_ENABLE(startup-notification, [  --disable-startup-notification    disable startup notification support],,enable_startup_notification=yes)
714
715 if test "x$enable_startup_notification" = "xyes"; then
716         PKG_CHECK_MODULES(STARTUP_NOTIFICATION, libstartup-notification-1.0 >= 0.5,
717         [
718                 AC_DEFINE(HAVE_STARTUP_NOTIFICATION, 1, [Define if we're using libstartup-notification.])
719                 echo "Building with libstartup-notification"
720                 enable_startup_notification=yes
721         ],
722         [
723                 echo "Building without libstartup-notification"
724                 enable_startup_notification=no
725         ])
726
727         AC_SUBST(STARTUP_NOTIFICATION_CFLAGS)
728         AC_SUBST(STARTUP_NOTIFICATION_LIBS)
729 fi
730
731 dnl #######################################################################
732 dnl # Check for D-Bus support
733 dnl #######################################################################
734 AC_ARG_ENABLE(dbus, [  --disable-dbus    disable dbus support],,enable_dbus=yes)
735
736 if test "x$enable_dbus" = "xyes"; then
737         PKG_CHECK_MODULES(DBUS, [dbus-1 >= 0.60, dbus-glib-1 >= 0.60],
738         [
739                 AC_DEFINE(HAVE_DBUS_GLIB, 1, [Define if glib bindings of D-Bus are available])
740                 enable_dbus_glib=yes
741         ],
742         [
743                 echo "D-Bus requirements not met. D-Bus support not activated."
744                 enable_dbus_glib=no
745         ])
746         AC_SUBST(DBUS_CFLAGS)
747         AC_SUBST(DBUS_LIBS)
748 fi
749
750 dnl #######################################################################
751 dnl # Check for NetworkManager support
752 dnl #######################################################################
753 if test x"$enable_dbus_glib" = xyes; then
754         AC_ARG_ENABLE(networkmanager-support, [  --disable-networkmanager-support  disable NetworkManager support],,enable_networkmanager_support=yes)
755         if test x"$enable_networkmanager_support" = xyes; then
756                 PKG_CHECK_MODULES(NETWORKMANAGER_SUPPORT, NetworkManager >= 0.6.2,
757                 [
758                         AC_DEFINE(HAVE_NETWORKMANAGER_SUPPORT, 1, [Define if NetworkManager support is to be included.])
759                         echo "Building with NetworkManager support"
760                         enable_networkmanager_support=yes
761                 ],
762                 [
763                         echo "NetworkManager not found."
764                         enable_networkmanager_support=no
765                 ])
766                 AC_SUBST(NETWORKMANAGER_SUPPORT_CFLAGS)
767         fi
768 else
769         echo "NetworkManager support deactivated as D-Bus requirements were not met."
770         enable_networkmanager_support=no
771 fi
772
773 dnl *************************
774 dnl ** section for plugins **
775 dnl *************************
776
777 PLUGINS=""
778
779 dnl --- Trayicon ---
780 AC_MSG_CHECKING([whether to build Trayicon plugin])
781 AC_ARG_ENABLE(trayicon-plugin,
782         [  --disable-trayicon-plugin         do not build System Tray Icon plugin],
783         [ac_cv_enable_trayicon_plugin=$enableval], [ac_cv_enable_trayicon_plugin=yes])
784 if test x"$ac_cv_enable_trayicon_plugin" = xyes; then
785         AC_MSG_RESULT(yes)
786         PLUGINS="trayicon $PLUGINS"
787 else
788         AC_MSG_RESULT(no)
789 fi
790 AM_CONDITIONAL(BUILD_TRAYICON_PLUGIN, test x"$ac_cv_enable_trayicon_plugin" = xyes)
791
792 dnl --- SpamAssassin ---
793 AC_MSG_CHECKING([whether to build SpamAssassin plugin])
794 AC_ARG_ENABLE(spamassassin-plugin,
795         [  --disable-spamassassin-plugin      do not build SpamAssassin plugin],
796         [ac_cv_enable_spamassassin_plugin=$enableval], [ac_cv_enable_spamassassin_plugin=yes])
797 if test x"$ac_cv_enable_spamassassin_plugin" = xyes; then
798         AC_MSG_RESULT(yes)
799         AC_SPAMASSASSIN
800         PLUGINS="spamassassin $PLUGINS"
801         AC_DEFINE(USE_SPAMASSASSIN_PLUGIN, 1, Define if spamassassin plugin is being built.)
802 else
803         AC_MSG_RESULT(no)
804 fi
805 AM_CONDITIONAL(BUILD_SPAMASSASSIN_PLUGIN, test x"$ac_cv_enable_spamassassin_plugin" = xyes)
806
807 dnl --- Bogofilter ---
808 AC_MSG_CHECKING([whether to build Bogofilter plugin])
809 AC_ARG_ENABLE(bogofilter-plugin,
810         [  --disable-bogofilter-plugin      do not build bogofilter plugin],
811         [ac_cv_enable_bogofilter_plugin=$enableval], [ac_cv_enable_bogofilter_plugin=yes])
812 if test x"$ac_cv_enable_bogofilter_plugin" = xyes; then
813         AC_MSG_RESULT(yes)
814         PLUGINS="bogofilter $PLUGINS"
815         AC_DEFINE(USE_BOGOFILTER_PLUGIN, 1, Define if bogofilter plugin is being built.)
816 else
817         AC_MSG_RESULT(no)
818 fi
819 AM_CONDITIONAL(BUILD_BOGOFILTER_PLUGIN, test x"$ac_cv_enable_bogofilter_plugin" = xyes)
820
821 dnl --- PGP/CORE ---
822 AC_MSG_CHECKING([whether to build PGP/CORE plugin])
823 AC_ARG_ENABLE(pgpcore-plugin,
824         [  --disable-pgpcore-plugin           do not build PGP/Core plugin],
825         [ac_cv_enable_pgpcore_plugin=$enableval], [ac_cv_enable_pgpcore_plugin=yes])
826 if test x"$ac_cv_enable_pgpcore_plugin" = xyes; then
827         AC_MSG_RESULT(yes)
828         AM_PATH_GPGME(1.0.0, AC_DEFINE(USE_GPGME, 1, Define if you use GPGME to support OpenPGP.),
829                       [ac_cv_enable_pgpcore_plugin=no])
830         if test x"$ac_cv_enable_pgpcore_plugin" = xyes; then
831                 PLUGINS="pgpcore $PLUGINS"
832                 AM_PATH_GPGME(1.1.1,
833                               AC_DEFINE(HAVE_GPGME_PKA_TRUST, 1,
834                                         [Define if GPGME supports PKA.]))
835                 #needed to get GPGME_LIBS and al correctly
836                 AM_PATH_GPGME(1.0.0, AC_DEFINE(USE_GPGME, 1, Define if you use GPGME to support OpenPGP.),
837                           [ac_cv_enable_pgpcore_plugin=no])
838         else
839                 AC_MSG_WARN([*** PGP/CORE plugin will not be built ***])
840         fi
841 else
842         AC_MSG_RESULT(no)
843 fi
844 AM_CONDITIONAL(BUILD_PGPCORE_PLUGIN, test x"$ac_cv_enable_pgpcore_plugin" = xyes)
845
846 AC_MSG_CHECKING([whether to build PGP/MIME plugin])
847 AC_ARG_ENABLE(pgpmime-plugin,
848         [  --disable-pgpmime-plugin           do not build PGP/MIME plugin],
849         [ac_cv_enable_pgpmime_plugin=$enableval], [ac_cv_enable_pgpmime_plugin=yes])
850 if test x"$ac_cv_enable_pgpmime_plugin" = xyes; then
851         AC_MSG_RESULT(yes)
852         if test x"$ac_cv_enable_pgpcore_plugin" = xyes; then
853                 PLUGINS="pgpmime $PLUGINS"
854         else
855                 AC_MSG_WARN([*** PGP/MIME plugin cannot be built ***])
856                 AC_MSG_WARN([*** without the PGP/CORE plugin     ***])
857         fi
858 else
859         AC_MSG_RESULT(no)
860 fi
861 AM_CONDITIONAL(BUILD_PGPMIME_PLUGIN, test x"$ac_cv_enable_pgpmime_plugin" = xyes)
862
863 AC_MSG_CHECKING([whether to build PGP/Inline plugin])
864 AC_ARG_ENABLE(pgpinline-plugin,
865         [  --disable-pgpinline-plugin           do not build PGP/Inline plugin],
866         [ac_cv_enable_pgpinline_plugin=$enableval], [ac_cv_enable_pgpinline_plugin=yes])
867 if test x"$ac_cv_enable_pgpinline_plugin" = xyes; then
868         AC_MSG_RESULT(yes)
869         if test x"$ac_cv_enable_pgpcore_plugin" = xyes; then
870                 PLUGINS="pgpinline $PLUGINS"
871         else
872                 AC_MSG_WARN([*** PGP/Inline plugin cannot be built ***])
873                 AC_MSG_WARN([*** without the PGP/CORE plugin     ***])
874         fi
875 else
876         AC_MSG_RESULT(no)
877 fi
878 AM_CONDITIONAL(BUILD_PGPINLINE_PLUGIN, test x"$ac_cv_enable_pgpinline_plugin" = xyes)
879
880 AC_MSG_CHECKING([whether to build S/Mime plugin])
881 AC_ARG_ENABLE(smime-plugin,
882         [  --disable-smime-plugin           do not build S/Mime plugin],
883         [ac_cv_enable_smime_plugin=$enableval], [ac_cv_enable_smime_plugin=yes])
884 if test x"$ac_cv_enable_smime_plugin" = xyes; then
885         AC_MSG_RESULT(yes)
886         if test x"$ac_cv_enable_pgpcore_plugin" = xyes; then
887                 PLUGINS="smime $PLUGINS"
888         else
889                 AC_MSG_WARN([*** S/Mime plugin cannot be built ***])
890                 AC_MSG_WARN([*** without the PGP/CORE plugin     ***])
891         fi
892 else
893         AC_MSG_RESULT(no)
894 fi
895 AM_CONDITIONAL(BUILD_SMIME_PLUGIN, test x"$ac_cv_enable_smime_plugin" = xyes)
896
897 dnl --- Dillo Viewer ---
898 AC_MSG_CHECKING([whether to build Dillo plugin])
899 AC_ARG_ENABLE(dillo-viewer-plugin,
900         [  --disable-dillo-viewer-plugin     do not build Dillo plugin for html mail rendering],
901         [ac_cv_enable_dillo_viewer_plugin=$enableval], [ac_cv_enable_dillo_viewer_plugin=yes])
902 if test x"$ac_cv_enable_dillo_viewer_plugin" = xyes; then
903         AC_MSG_RESULT(yes)
904         PLUGINS="dillo-viewer $PLUGINS"
905 else
906         AC_MSG_RESULT(no)
907 fi
908 AM_CONDITIONAL(BUILD_DILLO_VIEWER_PLUGIN, test x"$ac_cv_enable_dillo_viewer_plugin" = xyes)
909
910 dnl --- Demo ---
911 AC_ARG_ENABLE(demo-plugin,
912         [  --enable-demo-plugin              build demo plugin],
913         [ac_cv_enable_demo_plugin=$enableval], [ac_cv_enable_demo_plugin=no])
914 if test x"$ac_cv_enable_demo_plugin" = xyes; then
915         PLUGINS="demo $PLUGINS"
916 fi
917 AM_CONDITIONAL(BUILD_DEMO_PLUGIN, test x"$ac_cv_enable_demo_plugin" = xyes)
918
919 dnl Libetpan
920 AC_MSG_CHECKING([whether to use libetpan])
921 AC_ARG_ENABLE(libetpan,
922         [  --disable-libetpan           disable IMAP4/NNTP (libetpan) support],
923         [ac_cv_enable_libetpan=$enableval], [ac_cv_enable_libetpan=yes])
924 if test x"$ac_cv_enable_libetpan" = xyes; then
925         AC_MSG_RESULT(yes)
926         libetpan_result=no
927         AC_PATH_PROG(libetpanconfig, [libetpan-config])
928         if test "x$libetpanconfig" != "x"; then
929           CPPFLAGS="$CPPFLAGS `$libetpanconfig --cflags 2>/dev/null`"
930           AC_CHECK_HEADER(libetpan/libetpan.h, [libetpan_result=yes])
931           if test "x$libetpan_result" = "xyes"; then
932             AC_MSG_CHECKING([whether libetpan-config hints compiles and links fine])
933             LIBS="$LIBS `$libetpanconfig --libs 2>/dev/null`"
934             AC_TRY_LINK([#include <libetpan/dbstorage.h>], [db_mailstorage_init(NULL, NULL);], [libetpan_result=yes], [libetpan_result=no])
935             AC_MSG_RESULT([$libetpan_result])
936           fi
937         fi
938         if test "x$libetpan_result" = "xyes"; then
939            LIBETPAN_CPPFLAGS="`$libetpanconfig --cflags`"
940            LIBETPAN_LIBS="`$libetpanconfig --libs`"
941            LIBETPAN_VERSION=`$libetpanconfig --version | sed "s/\.//g" | sed "s/-.*$//"`
942            if test "$LIBETPAN_VERSION" -lt "057"; then
943                 AC_MSG_RESULT([*** Claws Mail requires libetpan 0.57 or newer. See http://www.etpan.org/])
944                 AC_MSG_RESULT([*** You can use --disable-libetpan if you don't need IMAP4 and/or NNTP support.])
945                 AC_MSG_ERROR([libetpan 0.57 not found])
946            fi
947            AC_SUBST(LIBETPAN_FLAGS)
948            AC_SUBST(LIBETPAN_LIBS)
949            AC_DEFINE(HAVE_LIBETPAN, 1, Define if you want IMAP and/or NNTP support.)
950         else
951            AC_MSG_RESULT([*** Claws Mail requires libetpan 0.57 or newer. See http://www.etpan.org/ ])
952            AC_MSG_RESULT([*** You can use --disable-libetpan if you don't need IMAP4 and/or NNTP support.])
953            AC_MSG_ERROR([libetpan 0.57 not found])
954         fi
955 else
956         AC_MSG_RESULT(no)
957 fi
958 AM_CONDITIONAL(CLAWS_LIBETPAN, test "x$libetpan_result" = "xyes")
959
960
961 dnl Printing support.
962 PKG_CHECK_MODULES(GTK210, gtk+-2.0 >= 2.10, ac_cv_have_gtk210=yes, ac_cv_have_gtk210=no)
963
964 AC_MSG_CHECKING([whether to use libgnomeprint])
965 AC_ARG_ENABLE(gnomeprint,
966         [  --disable-gnomeprint         disable libgnomeprint support],
967         [ac_cv_enable_gnomeprint=$enableval], [ac_cv_enable_gnomeprint=auto])
968
969 if test x$ac_cv_have_gtk210 = xyes; then
970         ac_cv_enable_gnomeprint="no"
971 fi
972
973 if test x$ac_cv_enable_gnomeprint = xyes \
974         -o \( x$ac_cv_enable_gnomeprint = xauto \
975            -a x$ac_cv_have_gtk210 = xno \); then
976         AC_MSG_RESULT(yes)
977         PKG_CHECK_MODULES(GNOMEPRINT, libgnomeprint-2.2 libgnomeprintui-2.2,
978                           ac_cv_enable_gnomeprint=yes, ac_cv_enable_gnomeprint=no)
979         if test x"$ac_cv_enable_gnomeprint" = xyes; then
980                 AC_DEFINE(USE_GNOMEPRINT, 1, Define if you want libgnomeprint support)
981         else
982                 AC_MSG_RESULT(not found)
983                 AC_MSG_WARN([*** libgnomeprintui wasn't found    ***])
984                 AC_MSG_WARN([*** using built-in printing support ***])
985         fi
986 else
987         ac_cv_enable_gnomeprint=no
988         AC_MSG_RESULT(no)
989 fi
990 AM_CONDITIONAL(CLAWS_GNOMEPRINT, test x"$ac_cv_enable_gnomeprint" = x"yes")
991
992 AC_MSG_CHECKING([whether to use valgrind])
993 AC_ARG_ENABLE(valgrind,
994         [  --disable-valgrind           disable valgrind support for debugging],
995         [ac_cv_enable_valgrind=$enableval], [ac_cv_enable_valgrind=yes])
996 if test x$ac_cv_enable_valgrind = xyes; then
997         AC_MSG_RESULT(yes)
998         PKG_CHECK_MODULES(VALGRIND, valgrind >= 2.4.0,
999                           ac_cv_enable_valgrind=yes, ac_cv_enable_valgrind=no)
1000         if test x"$ac_cv_enable_valgrind" = xyes; then
1001                 AC_DEFINE(HAVE_VALGRIND, 1, Define if you want valgrind support)
1002         else
1003                 AC_MSG_RESULT(not found)
1004         fi
1005 else
1006         AC_MSG_RESULT(no)
1007 fi
1008 AM_CONDITIONAL(CLAWS_VALGRIND, test x"$ac_cv_enable_valgrind" = x"yes")
1009
1010 dnl ****************************
1011 dnl ** Final configure output **
1012 dnl ****************************
1013
1014 AC_OUTPUT([
1015 Makefile
1016 m4/Makefile
1017 po/Makefile.in
1018 src/common/version.h
1019 src/Makefile
1020 src/common/Makefile
1021 src/common/passcrypt.h
1022 src/gtk/Makefile
1023 src/etpan/Makefile
1024 src/plugins/Makefile
1025 src/plugins/demo/Makefile
1026 src/plugins/bogofilter/Makefile
1027 src/plugins/spamassassin/Makefile
1028 src/plugins/dillo_viewer/Makefile
1029 src/plugins/trayicon/Makefile
1030 src/plugins/trayicon/libeggtrayicon/Makefile
1031 src/plugins/pgpcore/Makefile
1032 src/plugins/pgpmime/Makefile
1033 src/plugins/pgpinline/Makefile
1034 src/plugins/smime/Makefile
1035 doc/Makefile
1036 doc/man/Makefile
1037 tools/Makefile
1038 config/Makefile
1039 manual/Makefile
1040 manual/dtd/Makefile
1041 manual/dist/Makefile
1042 manual/dist/pdf/Makefile
1043 manual/dist/ps/Makefile
1044 manual/dist/html/Makefile
1045 manual/dist/txt/Makefile
1046 manual/fr/Makefile
1047 manual/fr/dist/Makefile
1048 manual/fr/dist/pdf/Makefile
1049 manual/fr/dist/ps/Makefile
1050 manual/fr/dist/html/Makefile
1051 manual/fr/dist/txt/Makefile
1052 manual/pl/Makefile
1053 manual/pl/dist/Makefile
1054 manual/pl/dist/pdf/Makefile
1055 manual/pl/dist/ps/Makefile
1056 manual/pl/dist/html/Makefile
1057 manual/pl/dist/txt/Makefile
1058 manual/es/Makefile
1059 manual/es/dist/Makefile
1060 manual/es/dist/pdf/Makefile
1061 manual/es/dist/ps/Makefile
1062 manual/es/dist/html/Makefile
1063 manual/es/dist/txt/Makefile
1064 claws-mail.pc
1065 ])
1066
1067 dnl Output the configuration summary
1068 echo ""
1069 echo "$PACKAGE $VERSION"
1070 echo ""
1071 echo "JPilot            : $ac_cv_enable_jpilot"
1072 echo "LDAP              : $ac_cv_enable_ldap"
1073 echo "gnuTLS            : $ac_cv_enable_gnutls"
1074 echo "iconv             : $am_cv_func_iconv"
1075 echo "compface          : $ac_cv_enable_compface"
1076 echo "IPv6              : $ac_cv_enable_ipv6"
1077 echo "enchant           : $ac_cv_enable_enchant"
1078 echo "IMAP4             : $ac_cv_enable_libetpan"
1079 echo "NNTP              : $ac_cv_enable_libetpan"
1080 echo "Crash dialog      : $ac_cv_enable_crash_dialog"
1081 echo "Libgnomeprint     : $ac_cv_enable_gnomeprint"
1082 echo "GTK+ print support: $ac_cv_have_gtk210"
1083 echo "LibSM             : $ac_cv_enable_libsm"
1084 echo "DBUS              : $enable_dbus"
1085 echo "NetworkManager    : $enable_networkmanager_support"
1086 echo "Manual            : $ac_cv_enable_manual"
1087 echo "Plugins           : $PLUGINS"
1088 echo "Generic UMPC code : $ac_cv_enable_generic_umpc"
1089 echo "Maemo  build      : $ac_cv_enable_maemo"
1090 echo "Config dir        : $ac_cv_with_config_dir"
1091 echo ""
1092 echo "The binary will be installed in $prefix/bin"
1093 echo ""
1094 echo "Configure finished, type 'make' to build."